[scpubgit/stemmatology.git] / lib / Text / Tradition / Parser / TEI.pm

package Text::Tradition::Parser::TEI;

use strict;
use warnings;
use Text::Tradition::Parser::Util qw( collate_variants );
use XML::LibXML;
use XML::LibXML::XPathContext;

=head1 NAME

Text::Tradition::Parser::TEI

=head1 SYNOPSIS

  use Text::Tradition;
  
  my $t_from_file = Text::Tradition->new( 
    'name' => 'my text',
    'input' => 'TEI',
    'file' => '/path/to/parallel_seg_file.xml'
    );
    
  my $t_from_string = Text::Tradition->new( 
    'name' => 'my text',
    'input' => 'TEI',
    'string' => $parallel_seg_xml,
    );


=head1 DESCRIPTION

Parser module for Text::Tradition, given a TEI parallel-segmentation file
that describes a text and its variants.  Normally called upon
initialization of Text::Tradition.

The witnesses for the tradition are taken from the <listWit/> element
within the TEI header; the readings are taken from any <p/> element that
appears in the text body (including <head/> elements therein.)

=head1 METHODS

=head2 B<parse>( $tradition, $option_hash )

Takes an initialized tradition and a set of options; creates the
appropriate nodes and edges on the graph, as well as the appropriate
witness objects.  The $option_hash must contain either a 'file' or a
'string' argument with the XML to be parsed.

=begin testing

use Text::Tradition;
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";
eval { no warnings; binmode $DB::OUT, ":utf8"; };

my $par_seg = 't/data/florilegium_tei_ps.xml';
my $t = Text::Tradition->new( 
    'name'  => 'inline', 
    'input' => 'TEI',
    'file'  => $par_seg,
    );

is( ref( $t ), 'Text::Tradition', "Parsed parallel-segmentation TEI" );
if( $t ) {
    is( scalar $t->collation->readings, 319, "Collation has all readings" );
    is( scalar $t->collation->paths, 375, "Collation has all paths" );
}

=end testing

=cut

my $text = {}; # Hash of arrays, one per eventual witness we find.
my $substitutions = {}; # Keep track of merged readings
my $app_anchors = {};   # Track apparatus references
my $app_ac = {};        # Save a.c. readings
my $app_count;          # Keep track of how many apps we have

# Create the package variables for tag names.

# Would really like to do this with varname variables, but apparently this
# is considered a bad idea.  The long way round then.
my( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM ) 
    = ( 'listWit', 'witness', 'text', 'w', 'seg', 'app', 'rdg', 'lem' );
sub _make_tagnames {
    my( $ns ) = @_;
    if( $ns ) {
        $LISTWIT = "$ns:$LISTWIT";
        $WITNESS = "$ns:$WITNESS";
        $TEXT = "$ns:$TEXT";
        $W = "$ns:$W";
        $SEG = "$ns:$SEG";
        $APP = "$ns:$APP";
        $RDG = "$ns:$RDG";
        $LEM = "$ns:$LEM";
    }
}

# Parse the TEI file.
sub parse {
    my( $tradition, $opts ) = @_;
    
    # First, parse the XML.
    my $parser = XML::LibXML->new();
    my $doc;
    if( exists $opts->{'string'} ) {
        $doc = $parser->parse_string( $opts->{'string'} );
    } elsif ( exists $opts->{'file'} ) {
        $doc = $parser->parse_file( $opts->{'file'} );
    } else {
        warn "Could not find string or file option to parse";
        return;
    }
    my $tei = $doc->documentElement();
    my $xpc = XML::LibXML::XPathContext->new( $tei );
    my $ns;
    if( $tei->namespaceURI ) {
        $ns = 'tei';
        $xpc->registerNs( $ns, $tei->namespaceURI );
    }
    _make_tagnames( $ns );

    # Then get the witnesses and create the witness objects.
    foreach my $wit_el ( $xpc->findnodes( "//$LISTWIT/$WITNESS" ) ) {
        my $sig = $wit_el->getAttribute( 'xml:id' );
        my $source = $wit_el->toString();
        $tradition->add_witness( sigil => $sig, source => $source );
    }
    map { $text->{$_->sigil} = [] } $tradition->witnesses;

    # Look for all word/seg node IDs and note their pre-existence.
    my @attrs = $xpc->findnodes( "//$W/attribute::xml:id" );
    _save_preexisting_nodeids( @attrs );

    # Count up how many apps we have.
    my @apps = $xpc->findnodes( "//$APP" );
    $app_count = scalar( @apps );

    # Now go through the children of the text element and pull out the
    # actual text.
    foreach my $xml_el ( $xpc->findnodes( "//$TEXT" ) ) {
        foreach my $xn ( $xml_el->childNodes ) {
            _get_readings( $tradition, $xn );
        }
    }
    # Our $text global now has lists of readings, one per witness.
    # Join them up.
    my $c = $tradition->collation;
    foreach my $sig ( keys %$text ) {
        # Determine the list of readings for 
        my $sequence = $text->{$sig};
        my @real_sequence = ( $c->start );
        push( @$sequence, $c->end );
        my $source = $c->start;
        foreach( _clean_sequence( $sig, $sequence ) ) {
            my $rdg = _return_rdg( $_ );
            push( @real_sequence, $rdg );
            $c->add_path( $source, $rdg, $sig );
            $source = $rdg;
        }
        # See if we need to make an a.c. version of the witness.
        if( exists $app_ac->{$sig} ) {
            my @uncorrected;
            push( @uncorrected, @real_sequence );
            foreach my $app ( keys %{$app_ac->{$sig}} ) {
                my $start = _return_rdg( $app_anchors->{$app}->{$sig}->{'start'} ); 
                my $end = _return_rdg( $app_anchors->{$app}->{$sig}->{'end'} );
                my @new = map { _return_rdg( $_ ) } @{$app_ac->{$sig}->{$app}};
                _replace_sequence( \@uncorrected, $start, $end, @new );
            }
            my $source = shift @uncorrected; # the start node
            warn "Something weird!" unless $source eq $c->start;
            foreach my $rdg ( @uncorrected ) {
            	my $source_base = grep { $_ eq $sig } $c->reading_witnesses( $source );
                my $target_base = grep { $_ eq $sig } $c->reading_witnesses( $rdg );
                unless( $source_base && $target_base ) {
                    # print STDERR sprintf( "Adding path %s from %s -> %s\n",
                    #     $sig.$c->ac_label, $source->id, $rdg->id );
                    $c->add_path( $source, $rdg, $sig.$c->ac_label );
                }
                $source = $rdg;
            }
            # print STDERR "Adding a.c. version for witness $sig\n";
            $tradition->witness( $sig )->is_layered( 1 );
        }
    }
    
    # Calculate the ranks for the nodes.
	$tradition->collation->calculate_ranks();
    
    # Now that we have ranks, see if we have distinct nodes with identical
    # text and identical rank that can be merged.
    $tradition->collation->flatten_ranks();
}

sub _clean_sequence {
    my( $wit, $sequence ) = @_;
    my @clean_sequence;
    foreach my $rdg ( @$sequence ) {
        if( $rdg =~ /^PH-(.*)$/ ) {
            # It is a placeholder.  Keep it only if we need it.
            my $app_id = $1;
            if( exists $app_ac->{$wit} &&
                exists $app_ac->{$wit}->{$app_id} ) {
                # print STDERR "Retaining empty placeholder for $app_id\n";
                push( @clean_sequence, $rdg );
            }
        } else {
            push( @clean_sequence, $rdg );
        }
    }
    return @clean_sequence;
}

sub _replace_sequence {
    my( $arr, $start, $end, @new ) = @_;
    my( $start_idx, $end_idx );
    foreach my $i ( 0 .. $#{$arr} ) {
        $start_idx = $i if( $arr->[$i]->id eq $start );
        if( $arr->[$i]->id eq $end ) {
            $end_idx = $i;
            last;
        }
    }
    unless( $start_idx && $end_idx ) {
        warn "Could not find start and end";
        return;
    }
    my $length = $end_idx - $start_idx + 1;
    splice( @$arr, $start_idx, $length, @new );
}

sub _return_rdg {
    my( $rdg ) = @_;
    # If we were passed a reading name, return the name.  If we were
    # passed a reading object, return the object.
    my $wantobj = ref( $rdg ) eq 'Text::Tradition::Collation::Reading';
    my $real = $rdg;
    if( exists $substitutions->{ $wantobj ? $rdg->id : $rdg } ) {
        $real = $substitutions->{ $wantobj ? $rdg->id : $rdg };
        $real = $real->id unless $wantobj;
    }
    return $real;
}

## TODO test specific sorts of nodes of the parallel-seg XML.

## Recursive helper function to help us navigate through nested XML,
## picking out the text.  $tradition is the tradition, needed for
## making readings; $xn is the XML node currently being looked at,
## $in_var is a flag to say that we are inside a variant, $ac is a
## flag to say that we are inside an ante-correctionem reading, and
## @cur_wits is the list of witnesses to which this XML node applies.
## Returns the list of readings, if any, created on the run.

{
    my %active_wits;
    my $current_app;
    my $seen_apps;

    sub _get_readings {
        my( $tradition, $xn, $in_var, $ac, @cur_wits ) = @_;
        @cur_wits = grep { $active_wits{$_} } keys %active_wits unless $in_var;

        my @new_readings;
        if( $xn->nodeType == XML_TEXT_NODE ) {
            # Some words, thus make some readings.
            my $str = $xn->data;
            return unless $str =~ /\S/; # skip whitespace-only text nodes
            #print STDERR "Handling text node " . $str . "\n";
            # Check that all the witnesses we have are active.
            foreach my $c ( @cur_wits ) {
                warn "$c is not among active wits" unless $active_wits{$c};
            }
            $str =~ s/^\s+//;
            my $final = $str =~ s/\s+$//;
            foreach my $w ( split( /\s+/, $str ) ) {
                # For now, skip punctuation.
                next if $w !~ /[[:alnum:]]/;
                my $rdg = _make_reading( $tradition->collation, $w );
                push( @new_readings, $rdg );
                foreach ( @cur_wits ) {
                    warn "Empty wit!" unless $_;
                    warn "Empty reading!" unless $rdg;
                    push( @{$text->{$_}}, $rdg ) unless $ac;
                }
            }
        } elsif( $xn->nodeName eq 'w' ) {
            # Everything in this tag is one word.  Also save any original XML ID.
            #print STDERR "Handling word " . $xn->toString . "\n";
            # Check that all the witnesses we have are active.
            foreach my $c ( @cur_wits ) {
                warn "$c is not among active wits" unless $active_wits{$c};
            }
            my $xml_id = $xn->getAttribute( 'xml:id' );
            my $rdg = _make_reading( $tradition->collation, $xn->textContent, $xml_id );
            push( @new_readings, $rdg );
            foreach( @cur_wits ) {
                warn "Empty wit!" unless $_;
                warn "Empty reading!" unless $rdg;
                push( @{$text->{$_}}, $rdg ) unless $ac;
            }
        } elsif ( $xn->nodeName eq 'app' ) {
            $seen_apps++;
            $current_app = $xn->getAttribute( 'xml:id' );
            # print STDERR "Handling app $current_app\n";
            # Keep the reading sets in this app.
            my @sets;
            # Recurse through all children (i.e. rdgs) for sets of words.
            foreach ( $xn->childNodes ) {
                my @rdg_set = _get_readings( $tradition, $_, $in_var, $ac, @cur_wits );
                push( @sets, \@rdg_set ) if @rdg_set;
            }
            # Now collate these sets if we have more than one.
            my $subs = collate_variants( $tradition->collation, @sets ) if @sets > 1;
            map { $substitutions->{$_} = $subs->{$_} } keys %$subs;
            # TODO Look through substitutions to see if we can make anything common now.
            # Return the entire set of unique readings.
            my %unique;
            foreach my $s ( @sets ) {
                map { $unique{$_->id} = $_ } @$s;
            }
            push( @new_readings, values( %unique ) );
            # Exit the current app.
            $current_app = '';
        } elsif ( $xn->nodeName eq 'lem' || $xn->nodeName eq 'rdg' ) {
            # Alter the current witnesses and recurse.
            #print STDERR "Handling reading for " . $xn->getAttribute( 'wit' ) . "\n";
            # TODO handle p.c. and s.l. designations too
            $ac = $xn->getAttribute( 'type' ) && $xn->getAttribute( 'type' ) eq 'a.c.';
            my @rdg_wits = _get_sigla( $xn );
            return unless @rdg_wits;  # Skip readings that appear in no witnesses
            my @words;
            foreach ( $xn->childNodes ) {
                my @rdg_set = _get_readings( $tradition, $_, 1, $ac, @rdg_wits );
                push( @words, @rdg_set ) if @rdg_set;
            }
            # If we have more than one word in a reading, it should become a segment.
            # $tradition->collation->add_segment( @words ) if @words > 1;
            
            if( $ac ) {
                # Add the reading set to the a.c. readings.
                foreach ( @rdg_wits ) {
                    $app_ac->{$_}->{$current_app} = \@words;
                }
            } else {
                # Add the reading set to the app anchors for each witness
                # or put in placeholders for empty p.c. readings
                foreach ( @rdg_wits ) {
                    my $start = @words ? $words[0]->id : "PH-$current_app";
                    my $end = @words ? $words[-1]->id : "PH-$current_app";
                    $app_anchors->{$current_app}->{$_}->{'start'} = $start;
                    $app_anchors->{$current_app}->{$_}->{'end'} = $end;
                    push( @{$text->{$_}}, $start ) unless @words;
                }
            }
            push( @new_readings, @words );
        } elsif( $xn->nodeName eq 'witStart' ) {
            # Add the relevant wit(s) to the active list.
            #print STDERR "Handling witStart\n";
            map { $active_wits{$_} = 1 } @cur_wits;
            # Record a lacuna in all non-active witnesses if this is
            # the first app. Get the full list from $text.
            if( $seen_apps == 1 ) {
                my $i = 0;
                foreach my $sig ( keys %$text ) {
                    next if $active_wits{$sig};
                    my $l = $tradition->collation->add_reading( {
                    	'id' => $current_app . "_$i",
                    	'is_lacuna' => 1 } );
                    $i++;
                    push( @{$text->{$sig}}, $l );
                }
            }
        } elsif( $xn->nodeName eq 'witEnd' ) {
            # Take the relevant wit(s) out of the list.
            #print STDERR "Handling witEnd\n";
            map { $active_wits{$_} = undef } @cur_wits;
            # Record a lacuna, unless this is the last app.
            unless( $seen_apps == $app_count ) {
                foreach my $i ( 0 .. $#cur_wits ) {
                    my $w = $cur_wits[$i];
                    my $l = $tradition->collation->add_reading( {
                    	'id' => $current_app . "_$i",
                    	'is_lacuna' => 1 } );
                    push( @{$text->{$w}}, $l );
                }
            }
        } elsif( $xn->nodeName eq 'witDetail' 
        		 || $xn->nodeName eq 'note' ) {
            # Ignore these for now.
            return;
        } else {
            # Recurse as if this tag weren't there.
            #print STDERR "Recursing on tag " . $xn->nodeName . "\n";
            foreach( $xn->childNodes ) {
                push( @new_readings, _get_readings( $tradition, $_, $in_var, $ac, @cur_wits ) );
            }
        }
        return @new_readings;
    }

}

=begin testing

use XML::LibXML;
use XML::LibXML::XPathContext;
use Text::Tradition::Parser::TEI;

my $xml_str = '<tei><rdg wit="#A #B #C #D">some text</rdg></tei>';
my $el = XML::LibXML->new()->parse_string( $xml_str )->documentElement;
my $xpc = XML::LibXML::XPathContext->new( $el );
my $obj = $xpc->find( '//rdg' );

my @wits = Text::Tradition::Parser::TEI::_get_sigla( $obj );
is( join( ' ', @wits) , "A B C D", "correctly parsed reading wit string" );

=end testing

=cut

# Helper to extract a list of witness sigla from a reading element.
sub _get_sigla {
    my( $rdg ) = @_;
    # Cope if we have been handed a NodeList.  There is only
    # one reading here.
    if( ref( $rdg ) eq 'XML::LibXML::NodeList' ) {
        $rdg = $rdg->shift;
    }

    my @wits;
    if( ref( $rdg ) eq 'XML::LibXML::Element' ) {
        my $witstr = $rdg->getAttribute( 'wit' );
        return () unless $witstr;
        $witstr =~ s/^\s+//;
        $witstr =~ s/\s+$//;
        @wits = split( /\s+/, $witstr );
        map { $_ =~ s/^\#// } @wits;
    }
    return @wits;
}

# Helper with its counters to actually make the readings.
{
    my $word_ctr = 0;
    my %used_nodeids;

    sub _save_preexisting_nodeids {
        foreach( @_ ) {
            $used_nodeids{$_->getValue()} = 1;
        }
    }

    sub _make_reading {
        my( $graph, $word, $xml_id ) = @_;
        if( $xml_id ) {
            if( exists $used_nodeids{$xml_id} ) {
                if( $used_nodeids{$xml_id} != 1 ) {
                    warn "Already used assigned XML ID somewhere else!";
                    $xml_id = undef;
                }
            } else {
                warn "Undetected pre-existing XML ID";
            }
        }
        if( !$xml_id ) {
            until( $xml_id ) {
                my $try_id = 'w'.$word_ctr++;
                next if exists $used_nodeids{$try_id};
                $xml_id = $try_id;
            }
        }
        my $rdg = $graph->add_reading(
        	{ 'id' => $xml_id,
        	  'text' => $word }
        	);
        $used_nodeids{$xml_id} = $rdg;
        return $rdg;
    }
}

1;

=head1 BUGS / TODO

=over

=item * More unit testing

=item * Handle special designations apart from a.c.

=item * Mark common nodes within collated variants

=back

=head1 LICENSE

This package is free software and is provided "as is" without express
or implied warranty.  You can redistribute it and/or modify it under
the same terms as Perl itself.

=head1 AUTHOR

Tara L Andrews E<lt>aurum@cpan.orgE<gt>
Commit	Line	Data
f6066bac	1	package Text::Tradition::Parser::TEI;
	2
	3	use strict;
	4	use warnings;
910a0a6d	5	use Text::Tradition::Parser::Util qw( collate_variants );
f6066bac	6	use XML::LibXML;
	7	use XML::LibXML::XPathContext;
	8
	9	=head1 NAME
	10
	11	Text::Tradition::Parser::TEI
	12
3b853983	13	=head1 SYNOPSIS
	14
	15	use Text::Tradition;
	16
	17	my $t_from_file = Text::Tradition->new(
	18	'name' => 'my text',
	19	'input' => 'TEI',
	20	'file' => '/path/to/parallel_seg_file.xml'
	21	);
	22
	23	my $t_from_string = Text::Tradition->new(
	24	'name' => 'my text',
	25	'input' => 'TEI',
	26	'string' => $parallel_seg_xml,
	27	);
	28
	29
f6066bac	30	=head1 DESCRIPTION
f6066bac	31
3b853983	32	Parser module for Text::Tradition, given a TEI parallel-segmentation file
	33	that describes a text and its variants. Normally called upon
	34	initialization of Text::Tradition.
	35
	36	The witnesses for the tradition are taken from the <listWit/> element
	37	within the TEI header; the readings are taken from any <p/> element that
	38	appears in the text body (including <head/> elements therein.)
f6066bac	39
	40	=head1 METHODS
	41
e867486f	42	=head2 B<parse>( $tradition, $option_hash )
3b853983	43
	44	Takes an initialized tradition and a set of options; creates the
	45	appropriate nodes and edges on the graph, as well as the appropriate
	46	witness objects. The $option_hash must contain either a 'file' or a
	47	'string' argument with the XML to be parsed.
	48
	49	=begin testing
	50
	51	use Text::Tradition;
	52	binmode STDOUT, ":utf8";
	53	binmode STDERR, ":utf8";
	54	eval { no warnings; binmode $DB::OUT, ":utf8"; };
	55
	56	my $par_seg = 't/data/florilegium_tei_ps.xml';
	57	my $t = Text::Tradition->new(
	58	'name' => 'inline',
	59	'input' => 'TEI',
	60	'file' => $par_seg,
	61	);
f6066bac	62
3b853983	63	is( ref( $t ), 'Text::Tradition', "Parsed parallel-segmentation TEI" );
	64	if( $t ) {
	65	is( scalar $t->collation->readings, 319, "Collation has all readings" );
5f52ddca	66	is( scalar $t->collation->paths, 375, "Collation has all paths" );
3b853983	67	}
f6066bac	68
3b853983	69	=end testing
f6066bac	70
	71	=cut
	72
910a0a6d	73	my $text = {}; # Hash of arrays, one per eventual witness we find.
910a0a6d	74	my $substitutions = {}; # Keep track of merged readings
	75	my $app_anchors = {}; # Track apparatus references
	76	my $app_ac = {}; # Save a.c. readings
eca16057	77	my $app_count; # Keep track of how many apps we have
910a0a6d	78
	79	# Create the package variables for tag names.
	80
	81	# Would really like to do this with varname variables, but apparently this
	82	# is considered a bad idea. The long way round then.
	83	my( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM )
	84	= ( 'listWit', 'witness', 'text', 'w', 'seg', 'app', 'rdg', 'lem' );
3b853983	85	sub _make_tagnames {
910a0a6d	86	my( $ns ) = @_;
	87	if( $ns ) {
	88	$LISTWIT = "$ns:$LISTWIT";
	89	$WITNESS = "$ns:$WITNESS";
	90	$TEXT = "$ns:$TEXT";
	91	$W = "$ns:$W";
	92	$SEG = "$ns:$SEG";
	93	$APP = "$ns:$APP";
	94	$RDG = "$ns:$RDG";
	95	$LEM = "$ns:$LEM";
	96	}
	97	}
	98
	99	# Parse the TEI file.
f6066bac	100	sub parse {
dfc37e38	101	my( $tradition, $opts ) = @_;
f6066bac	102
	103	# First, parse the XML.
	104	my $parser = XML::LibXML->new();
dfc37e38	105	my $doc;
	106	if( exists $opts->{'string'} ) {
	107	$doc = $parser->parse_string( $opts->{'string'} );
	108	} elsif ( exists $opts->{'file'} ) {
	109	$doc = $parser->parse_file( $opts->{'file'} );
	110	} else {
	111	warn "Could not find string or file option to parse";
	112	return;
	113	}
f6066bac	114	my $tei = $doc->documentElement();
f2b9605f	115	my $xpc = XML::LibXML::XPathContext->new( $tei );
910a0a6d	116	my $ns;
	117	if( $tei->namespaceURI ) {
	118	$ns = 'tei';
	119	$xpc->registerNs( $ns, $tei->namespaceURI );
	120	}
3b853983	121	_make_tagnames( $ns );
910a0a6d	122
f6066bac	123	# Then get the witnesses and create the witness objects.
910a0a6d	124	foreach my $wit_el ( $xpc->findnodes( "//$LISTWIT/$WITNESS" ) ) {
	125	my $sig = $wit_el->getAttribute( 'xml:id' );
	126	my $source = $wit_el->toString();
	127	$tradition->add_witness( sigil => $sig, source => $source );
f6066bac	128	}
910a0a6d	129	map { $text->{$_->sigil} = [] } $tradition->witnesses;
eca16057	130
910a0a6d	131	# Look for all word/seg node IDs and note their pre-existence.
a7fb3133	132	my @attrs = $xpc->findnodes( "//$W/attribute::xml:id" );
3b853983	133	_save_preexisting_nodeids( @attrs );
910a0a6d	134
eca16057	135	# Count up how many apps we have.
	136	my @apps = $xpc->findnodes( "//$APP" );
	137	$app_count = scalar( @apps );
	138
910a0a6d	139	# Now go through the children of the text element and pull out the
	140	# actual text.
	141	foreach my $xml_el ( $xpc->findnodes( "//$TEXT" ) ) {
	142	foreach my $xn ( $xml_el->childNodes ) {
	143	_get_readings( $tradition, $xn );
	144	}
	145	}
	146	# Our $text global now has lists of readings, one per witness.
	147	# Join them up.
	148	my $c = $tradition->collation;
	149	foreach my $sig ( keys %$text ) {
910a0a6d	150	# Determine the list of readings for
	151	my $sequence = $text->{$sig};
	152	my @real_sequence = ( $c->start );
	153	push( @$sequence, $c->end );
	154	my $source = $c->start;
	155	foreach( _clean_sequence( $sig, $sequence ) ) {
	156	my $rdg = _return_rdg( $_ );
	157	push( @real_sequence, $rdg );
	158	$c->add_path( $source, $rdg, $sig );
	159	$source = $rdg;
	160	}
910a0a6d	161	# See if we need to make an a.c. version of the witness.
	162	if( exists $app_ac->{$sig} ) {
	163	my @uncorrected;
	164	push( @uncorrected, @real_sequence );
	165	foreach my $app ( keys %{$app_ac->{$sig}} ) {
	166	my $start = _return_rdg( $app_anchors->{$app}->{$sig}->{'start'} );
	167	my $end = _return_rdg( $app_anchors->{$app}->{$sig}->{'end'} );
	168	my @new = map { _return_rdg( $_ ) } @{$app_ac->{$sig}->{$app}};
	169	_replace_sequence( \@uncorrected, $start, $end, @new );
	170	}
96dc90ec	171	my $source = shift @uncorrected; # the start node
96dc90ec	172	warn "Something weird!" unless $source eq $c->start;
910a0a6d	173	foreach my $rdg ( @uncorrected ) {
96dc90ec	174	my $source_base = grep { $_ eq $sig } $c->reading_witnesses( $source );
	175	my $target_base = grep { $_ eq $sig } $c->reading_witnesses( $rdg );
	176	unless( $source_base && $target_base ) {
0068967c	177	# print STDERR sprintf( "Adding path %s from %s -> %s\n",
0068967c	178	# $sig.$c->ac_label, $source->id, $rdg->id );
910a0a6d	179	$c->add_path( $source, $rdg, $sig.$c->ac_label );
	180	}
	181	$source = $rdg;
	182	}
0068967c	183	# print STDERR "Adding a.c. version for witness $sig\n";
1f7aa795	184	$tradition->witness( $sig )->is_layered( 1 );
910a0a6d	185	}
910a0a6d	186	}
3b853983	187
3b853983	188	# Calculate the ranks for the nodes.
a7fb3133	189	$tradition->collation->calculate_ranks();
3bc0cd18	190
	191	# Now that we have ranks, see if we have distinct nodes with identical
	192	# text and identical rank that can be merged.
0e476982	193	$tradition->collation->flatten_ranks();
910a0a6d	194	}
	195
	196	sub _clean_sequence {
	197	my( $wit, $sequence ) = @_;
	198	my @clean_sequence;
	199	foreach my $rdg ( @$sequence ) {
	200	if( $rdg =~ /^PH-(.*)$/ ) {
	201	# It is a placeholder. Keep it only if we need it.
	202	my $app_id = $1;
78fab1cf	203	if( exists $app_ac->{$wit} &&
78fab1cf	204	exists $app_ac->{$wit}->{$app_id} ) {
0068967c	205	# print STDERR "Retaining empty placeholder for $app_id\n";
910a0a6d	206	push( @clean_sequence, $rdg );
	207	}
	208	} else {
	209	push( @clean_sequence, $rdg );
	210	}
f6066bac	211	}
910a0a6d	212	return @clean_sequence;
910a0a6d	213	}
f6066bac	214
910a0a6d	215	sub _replace_sequence {
	216	my( $arr, $start, $end, @new ) = @_;
	217	my( $start_idx, $end_idx );
	218	foreach my $i ( 0 .. $#{$arr} ) {
e4b0f464	219	$start_idx = $i if( $arr->[$i]->id eq $start );
e4b0f464	220	if( $arr->[$i]->id eq $end ) {
910a0a6d	221	$end_idx = $i;
	222	last;
	223	}
	224	}
	225	unless( $start_idx && $end_idx ) {
	226	warn "Could not find start and end";
	227	return;
f2b9605f	228	}
910a0a6d	229	my $length = $end_idx - $start_idx + 1;
	230	splice( @$arr, $start_idx, $length, @new );
	231	}
f6066bac	232
910a0a6d	233	sub _return_rdg {
	234	my( $rdg ) = @_;
	235	# If we were passed a reading name, return the name. If we were
	236	# passed a reading object, return the object.
	237	my $wantobj = ref( $rdg ) eq 'Text::Tradition::Collation::Reading';
	238	my $real = $rdg;
e4b0f464	239	if( exists $substitutions->{ $wantobj ? $rdg->id : $rdg } ) {
	240	$real = $substitutions->{ $wantobj ? $rdg->id : $rdg };
	241	$real = $real->id unless $wantobj;
910a0a6d	242	}
910a0a6d	243	return $real;
f6066bac	244	}
f6066bac	245
3b853983	246	## TODO test specific sorts of nodes of the parallel-seg XML.
3b853983	247
910a0a6d	248	## Recursive helper function to help us navigate through nested XML,
	249	## picking out the text. $tradition is the tradition, needed for
	250	## making readings; $xn is the XML node currently being looked at,
	251	## $in_var is a flag to say that we are inside a variant, $ac is a
	252	## flag to say that we are inside an ante-correctionem reading, and
	253	## @cur_wits is the list of witnesses to which this XML node applies.
	254	## Returns the list of readings, if any, created on the run.
	255
	256	{
3bc0cd18	257	my %active_wits;
910a0a6d	258	my $current_app;
eca16057	259	my $seen_apps;
910a0a6d	260
	261	sub _get_readings {
	262	my( $tradition, $xn, $in_var, $ac, @cur_wits ) = @_;
3bc0cd18	263	@cur_wits = grep { $active_wits{$_} } keys %active_wits unless $in_var;
910a0a6d	264
	265	my @new_readings;
	266	if( $xn->nodeType == XML_TEXT_NODE ) {
	267	# Some words, thus make some readings.
	268	my $str = $xn->data;
	269	return unless $str =~ /\S/; # skip whitespace-only text nodes
	270	#print STDERR "Handling text node " . $str . "\n";
	271	# Check that all the witnesses we have are active.
	272	foreach my $c ( @cur_wits ) {
3bc0cd18	273	warn "$c is not among active wits" unless $active_wits{$c};
910a0a6d	274	}
	275	$str =~ s/^\s+//;
	276	my $final = $str =~ s/\s+$//;
	277	foreach my $w ( split( /\s+/, $str ) ) {
	278	# For now, skip punctuation.
	279	next if $w !~ /[[:alnum:]]/;
3b853983	280	my $rdg = _make_reading( $tradition->collation, $w );
910a0a6d	281	push( @new_readings, $rdg );
910a0a6d	282	foreach ( @cur_wits ) {
	283	warn "Empty wit!" unless $_;
	284	warn "Empty reading!" unless $rdg;
	285	push( @{$text->{$_}}, $rdg ) unless $ac;
	286	}
	287	}
	288	} elsif( $xn->nodeName eq 'w' ) {
	289	# Everything in this tag is one word. Also save any original XML ID.
	290	#print STDERR "Handling word " . $xn->toString . "\n";
	291	# Check that all the witnesses we have are active.
	292	foreach my $c ( @cur_wits ) {
3bc0cd18	293	warn "$c is not among active wits" unless $active_wits{$c};
910a0a6d	294	}
910a0a6d	295	my $xml_id = $xn->getAttribute( 'xml:id' );
3b853983	296	my $rdg = _make_reading( $tradition->collation, $xn->textContent, $xml_id );
910a0a6d	297	push( @new_readings, $rdg );
910a0a6d	298	foreach( @cur_wits ) {
	299	warn "Empty wit!" unless $_;
	300	warn "Empty reading!" unless $rdg;
	301	push( @{$text->{$_}}, $rdg ) unless $ac;
	302	}
	303	} elsif ( $xn->nodeName eq 'app' ) {
eca16057	304	$seen_apps++;
910a0a6d	305	$current_app = $xn->getAttribute( 'xml:id' );
	306	# print STDERR "Handling app $current_app\n";
	307	# Keep the reading sets in this app.
	308	my @sets;
	309	# Recurse through all children (i.e. rdgs) for sets of words.
	310	foreach ( $xn->childNodes ) {
	311	my @rdg_set = _get_readings( $tradition, $_, $in_var, $ac, @cur_wits );
	312	push( @sets, \@rdg_set ) if @rdg_set;
	313	}
	314	# Now collate these sets if we have more than one.
	315	my $subs = collate_variants( $tradition->collation, @sets ) if @sets > 1;
	316	map { $substitutions->{$_} = $subs->{$_} } keys %$subs;
	317	# TODO Look through substitutions to see if we can make anything common now.
	318	# Return the entire set of unique readings.
	319	my %unique;
	320	foreach my $s ( @sets ) {
e4b0f464	321	map { $unique{$_->id} = $_ } @$s;
910a0a6d	322	}
	323	push( @new_readings, values( %unique ) );
	324	# Exit the current app.
	325	$current_app = '';
	326	} elsif ( $xn->nodeName eq 'lem' \|\| $xn->nodeName eq 'rdg' ) {
	327	# Alter the current witnesses and recurse.
	328	#print STDERR "Handling reading for " . $xn->getAttribute( 'wit' ) . "\n";
3bc0cd18	329	# TODO handle p.c. and s.l. designations too
910a0a6d	330	$ac = $xn->getAttribute( 'type' ) && $xn->getAttribute( 'type' ) eq 'a.c.';
3b853983	331	my @rdg_wits = _get_sigla( $xn );
a7fb3133	332	return unless @rdg_wits; # Skip readings that appear in no witnesses
910a0a6d	333	my @words;
	334	foreach ( $xn->childNodes ) {
	335	my @rdg_set = _get_readings( $tradition, $_, 1, $ac, @rdg_wits );
	336	push( @words, @rdg_set ) if @rdg_set;
	337	}
	338	# If we have more than one word in a reading, it should become a segment.
	339	# $tradition->collation->add_segment( @words ) if @words > 1;
	340
	341	if( $ac ) {
	342	# Add the reading set to the a.c. readings.
	343	foreach ( @rdg_wits ) {
	344	$app_ac->{$_}->{$current_app} = \@words;
	345	}
	346	} else {
	347	# Add the reading set to the app anchors for each witness
	348	# or put in placeholders for empty p.c. readings
	349	foreach ( @rdg_wits ) {
e4b0f464	350	my $start = @words ? $words[0]->id : "PH-$current_app";
e4b0f464	351	my $end = @words ? $words[-1]->id : "PH-$current_app";
910a0a6d	352	$app_anchors->{$current_app}->{$_}->{'start'} = $start;
	353	$app_anchors->{$current_app}->{$_}->{'end'} = $end;
	354	push( @{$text->{$_}}, $start ) unless @words;
	355	}
	356	}
	357	push( @new_readings, @words );
	358	} elsif( $xn->nodeName eq 'witStart' ) {
	359	# Add the relevant wit(s) to the active list.
	360	#print STDERR "Handling witStart\n";
3bc0cd18	361	map { $active_wits{$_} = 1 } @cur_wits;
	362	# Record a lacuna in all non-active witnesses if this is
	363	# the first app. Get the full list from $text.
	364	if( $seen_apps == 1 ) {
	365	my $i = 0;
	366	foreach my $sig ( keys %$text ) {
	367	next if $active_wits{$sig};
e4b0f464	368	my $l = $tradition->collation->add_reading( {
e4b0f464	369	'id' => $current_app . "_$i",
e4b0f464	370	'is_lacuna' => 1 } );
3bc0cd18	371	$i++;
	372	push( @{$text->{$sig}}, $l );
	373	}
	374	}
910a0a6d	375	} elsif( $xn->nodeName eq 'witEnd' ) {
	376	# Take the relevant wit(s) out of the list.
	377	#print STDERR "Handling witEnd\n";
3bc0cd18	378	map { $active_wits{$_} = undef } @cur_wits;
eca16057	379	# Record a lacuna, unless this is the last app.
	380	unless( $seen_apps == $app_count ) {
	381	foreach my $i ( 0 .. $#cur_wits ) {
	382	my $w = $cur_wits[$i];
e4b0f464	383	my $l = $tradition->collation->add_reading( {
e4b0f464	384	'id' => $current_app . "_$i",
e4b0f464	385	'is_lacuna' => 1 } );
eca16057	386	push( @{$text->{$w}}, $l );
	387	}
	388	}
a7fb3133	389	} elsif( $xn->nodeName eq 'witDetail'
a7fb3133	390	\|\| $xn->nodeName eq 'note' ) {
910a0a6d	391	# Ignore these for now.
	392	return;
	393	} else {
	394	# Recurse as if this tag weren't there.
	395	#print STDERR "Recursing on tag " . $xn->nodeName . "\n";
	396	foreach( $xn->childNodes ) {
	397	push( @new_readings, _get_readings( $tradition, $_, $in_var, $ac, @cur_wits ) );
	398	}
	399	}
	400	return @new_readings;
	401	}
	402
	403	}
	404
3b853983	405	=begin testing
	406
	407	use XML::LibXML;
	408	use XML::LibXML::XPathContext;
	409	use Text::Tradition::Parser::TEI;
	410
	411	my $xml_str = '<tei><rdg wit="#A #B #C #D">some text</rdg></tei>';
	412	my $el = XML::LibXML->new()->parse_string( $xml_str )->documentElement;
	413	my $xpc = XML::LibXML::XPathContext->new( $el );
	414	my $obj = $xpc->find( '//rdg' );
	415
	416	my @wits = Text::Tradition::Parser::TEI::_get_sigla( $obj );
	417	is( join( ' ', @wits) , "A B C D", "correctly parsed reading wit string" );
	418
	419	=end testing
	420
	421	=cut
	422
910a0a6d	423	# Helper to extract a list of witness sigla from a reading element.
3b853983	424	sub _get_sigla {
f6066bac	425	my( $rdg ) = @_;
	426	# Cope if we have been handed a NodeList. There is only
	427	# one reading here.
	428	if( ref( $rdg ) eq 'XML::LibXML::NodeList' ) {
910a0a6d	429	$rdg = $rdg->shift;
f6066bac	430	}
	431
	432	my @wits;
	433	if( ref( $rdg ) eq 'XML::LibXML::Element' ) {
910a0a6d	434	my $witstr = $rdg->getAttribute( 'wit' );
a7fb3133	435	return () unless $witstr;
910a0a6d	436	$witstr =~ s/^\s+//;
	437	$witstr =~ s/\s+$//;
	438	@wits = split( /\s+/, $witstr );
	439	map { $_ =~ s/^\#// } @wits;
f6066bac	440	}
	441	return @wits;
	442	}
	443
910a0a6d	444	# Helper with its counters to actually make the readings.
f2b9605f	445	{
	446	my $word_ctr = 0;
	447	my %used_nodeids;
	448
3b853983	449	sub _save_preexisting_nodeids {
910a0a6d	450	foreach( @_ ) {
	451	$used_nodeids{$_->getValue()} = 1;
	452	}
	453	}
	454
3b853983	455	sub _make_reading {
910a0a6d	456	my( $graph, $word, $xml_id ) = @_;
	457	if( $xml_id ) {
	458	if( exists $used_nodeids{$xml_id} ) {
	459	if( $used_nodeids{$xml_id} != 1 ) {
	460	warn "Already used assigned XML ID somewhere else!";
	461	$xml_id = undef;
	462	}
	463	} else {
	464	warn "Undetected pre-existing XML ID";
	465	}
	466	}
	467	if( !$xml_id ) {
	468	until( $xml_id ) {
	469	my $try_id = 'w'.$word_ctr++;
	470	next if exists $used_nodeids{$try_id};
	471	$xml_id = $try_id;
	472	}
	473	}
e4b0f464	474	my $rdg = $graph->add_reading(
49d4f2ac	475	{ 'id' => $xml_id,
e4b0f464	476	'text' => $word }
e4b0f464	477	);
910a0a6d	478	$used_nodeids{$xml_id} = $rdg;
910a0a6d	479	return $rdg;
f2b9605f	480	}
	481	}
	482
f6066bac	483	1;
3b853983	484
	485	=head1 BUGS / TODO
	486
	487	=over
	488
	489	=item * More unit testing
	490
e867486f	491	=item * Handle special designations apart from a.c.
	492
	493	=item * Mark common nodes within collated variants
	494
3b853983	495	=back
	496
	497	=head1 LICENSE
	498
	499	This package is free software and is provided "as is" without express
	500	or implied warranty. You can redistribute it and/or modify it under
	501	the same terms as Perl itself.
	502
	503	=head1 AUTHOR
	504
	505	Tara L Andrews E<lt>aurum@cpan.orgE<gt>