[scpubgit/stemmatology.git] / lib / Text / Tradition / Parser / CTE.pm

package Text::Tradition::Parser::CTE;

use strict;
use warnings;
use Encode qw/ decode /;
use Text::Tradition::Parser::Util qw/ collate_variants /;
use XML::LibXML;
use XML::LibXML::XPathContext;

=head1 NAME

Text::Tradition::Parser::CTE

=head1 DESCRIPTION

Parser module for Text::Tradition, given a TEI file exported from
Classical Text Editor.

=head1 METHODS

=over

=item B<parse>

my @apparatus = read( $xml_file );

Takes a Tradition object and a TEI file exported from Classical Text
Editor using double-endpoint-attachment critical apparatus encoding; 
initializes the Tradition from the file.

=cut

my %sigil_for;  # Save the XML IDs for witnesses.
my %apps;       # Save the apparatus XML for a given ID.    
my %has_ac;     # Keep track of witnesses that have corrections.

sub parse {
	my( $tradition, $opts ) = @_;
	my $c = $tradition->collation;	# Some shorthand
	
	# First, parse the XML.
    my( $tei, $xpc ) = _remove_formatting( $opts );
    return unless $tei; # we have already warned.

	# CTE uses a DTD rather than any xmlns-based parsing.  Thus we
	# need no namespace handling.
	# Get the witnesses and create the witness objects.
	foreach my $wit_el ( $xpc->findnodes( '//sourceDesc/listWit/witness' ) ) {
		# The witness xml:id is used internally, and is *not* the sigil name.
		my $id= $wit_el->getAttribute( 'xml:id' );
		my @sig_parts = $xpc->findnodes( 'descendant::text()', $wit_el );
		my $sig = _stringify_sigil( @sig_parts );
		print STDERR "Adding witness $sig\n";
		$tradition->add_witness( sigil => $sig, source => $wit_el->toString() );
		$sigil_for{'#'.$id} = $sig;  # Make life easy by keying on the ID ref syntax
	}
	
	# Now go through the text and find the base tokens, apparatus tags, and
	# anchors.  Make a giant array of all of these things in sequence.
	# TODO consider combining this with creation of graph below
	my @base_text;
	foreach my $pg_el ( $xpc->findnodes( '/TEI/text/body/p' ) ) {
		foreach my $xn ( $pg_el->childNodes ) {
			push( @base_text, _get_base( $xn ) );
		}
	}
	# We now have to work through this array applying the alternate 
	# apparatus readings to the base text.  Essentially we will put 
	# everything on the graph, from which we will delete the apps and
	# anchors when we are done.
	
	# First, put the base tokens, apps, and anchors in the graph.
	my $counter = 0;
	my $last = $c->start;
	foreach my $item ( @base_text ) {
	    my $r;
        if( $item->{'type'} eq 'token' ) {
            $r = $c->add_reading( { id => 'n'.$counter++, 
            						text => $item->{'content'} } );
        } elsif ( $item->{'type'} eq 'anchor' ) {
            $r = $c->add_reading( { id => '#ANCHOR_' . $item->{'content'} . '#', 
            						is_ph => 1 } );
        } elsif ( $item->{'type'} eq 'app' ) {
            my $tag = '#APP_' . $counter++ . '#';
            $r = $c->add_reading( { id => $tag, is_ph => 1 } );
            $apps{$tag} = $item->{'content'};
        }
        $c->add_path( $last, $r, $c->baselabel );
        $last = $r;
    }
    $c->add_path( $last, $c->end, $c->baselabel );
    
    # Now we can parse the apparatus entries, and add the variant readings 
    # to the graph.
    
    foreach my $app_id ( keys %apps ) {
        _add_readings( $c, $app_id );
    }
    
    # Finally, add explicit witness paths, remove the base paths, and remove
    # the app/anchor tags.
    expand_all_paths( $c );

    # Save the text for each witness so that we can ensure consistency
    # later on
	$tradition->collation->text_from_paths();	
	$tradition->collation->calculate_ranks();
	$tradition->collation->flatten_ranks();
}

sub _stringify_sigil {
    my( @nodes ) = @_;
    my @parts = grep { /\w/ } map { $_->data } @nodes;
    return join( '', @parts );
}

# Get rid of all the formatting elements that get in the way of tokenization.
sub _remove_formatting {
	my( $opts ) = @_;
	
	# First, parse the original XML
	my $parser = XML::LibXML->new();
    my $doc;
    if( exists $opts->{'string'} ) {
        $doc = $parser->parse_string( $opts->{'string'} );
    } elsif ( exists $opts->{'file'} ) {
        $doc = $parser->parse_file( $opts->{'file'} );
    } else {
        warn "Could not find string or file option to parse";
        return;
    }
    
    # Second, remove the formatting
	my $xpc = XML::LibXML::XPathContext->new( $doc->documentElement );
	my @useless = $xpc->findnodes( '//hi' );
	foreach my $n ( @useless ) {
		my $parent = $n->parentNode();
		my @children = $n->childNodes();
		my $first = shift @children;
		$parent->replaceChild( $first, $n );
		foreach my $c ( @children ) {
			$parent->insertAfter( $c, $first );
			$first = $c;
		}
	}
	
	# Third, write out and reparse to merge the text nodes.
	my $result = decode( $doc->encoding, $doc->toString() );
	my $tei = $parser->parse_string( $result )->documentElement;
	$xpc = XML::LibXML::XPathContext->new( $tei );
	return( $tei, $xpc );
}

## Helper function to help us navigate through nested XML, picking out 
## the words, the apparatus, and the anchors.

sub _get_base {
	my( $xn ) = @_;
	my @readings;
	if( $xn->nodeType == XML_TEXT_NODE ) {
	    # Base text, just split the words on whitespace and add them 
	    # to our sequence.
		my $str = $xn->data;
		$str =~ s/^\s+//;
		my @tokens = split( /\s+/, $str );
		push( @readings, map { { 'type' => 'token', 'content' => $_ } } @tokens );
	} elsif( $xn->nodeName eq 'app' ) {
		# Apparatus, just save the entire XML node.
		push( @readings, { 'type' => 'app', 'content' => $xn } );
	} elsif( $xn->nodeName eq 'anchor' ) {
		# Anchor to mark the end of some apparatus; save its ID.
		push( @readings, { 'type' => 'anchor', 
		    'content' => $xn->getAttribute( 'xml:id' ) } );
	} elsif ( $xn->nodeName ne 'note' ) {  # Any tag we don't know to disregard
	    print STDERR "Unrecognized tag " . $xn->nodeName . "\n";
	}
	return @readings;
}

sub _append_tokens {
	my( $list, @tokens ) = @_;
	if( @$list && $list->[-1]->{'content'} =~ /\#JOIN\#$/ ) {
		# The list evidently ended mid-word; join the next token onto it.
		my $t = shift @tokens;
		if( ref $t && $t->{'type'} eq 'token' ) {
			# Join the word
			$t = $t->{'content'};
		} elsif( ref $t ) {
			# An app or anchor intervened; end the word.
			unshift( @tokens, $t );
			$t = '';
		}
		$list->[-1]->{'content'} =~ s/\#JOIN\#$/$t/;
	}
	foreach my $t ( @tokens ) {
		unless( ref( $t ) ) {
			$t = { 'type' => 'token', 'content' => $t };
		}
		push( @$list, $t );
	}
}

sub _add_readings {
    my( $c, $app_id ) = @_;
    my $xn = $apps{$app_id};
    my $anchor = _anchor_name( $xn->getAttribute( 'to' ) );
    # Get the lemma, which is all the readings between app and anchor,
    # excluding other apps or anchors.
    my @lemma = _return_lemma( $c, $app_id, $anchor );
    my $lemma_str = join( ' ', grep { $_ !~ /^\#/ } map { $_->text } @lemma );
    
    # For each reading, send its text to 'interpret' along with the lemma,
    # and then save the list of witnesses that these tokens belong to.
    my %wit_rdgs;  # Maps from witnesses to the variant text
    my $ctr = 0;
    my $tag = $app_id;
    $tag =~ s/^\#APP_(.*)\#$/$1/;

    foreach my $rdg ( $xn->getChildrenByTagName( 'rdg' ) ) {
        my @text;
        foreach ( $rdg->childNodes ) {
            push( @text, _get_base( $_ ) );
        }
        my( $interpreted, $flag ) = ( '', undef );
        if( @text ) {
        	( $interpreted, $flag ) = interpret( 
        		join( ' ', map { $_->{'content'} } @text ), $lemma_str );
        }
        next if( $interpreted eq $lemma_str ) && !$flag;  # Reading is lemma.
        
        my @rdg_nodes;
        if( $interpreted eq '#LACUNA#' ) {
        	push( @rdg_nodes, $c->add_reading( { id => $tag . "/" . $ctr++,
        										 is_lacuna => 1 } ) );
        } else {
			foreach my $w ( split( /\s+/, $interpreted ) ) {
				my $r = $c->add_reading( { id => $tag . "/" . $ctr++,
										   text => $w } );
				push( @rdg_nodes, $r );
			}
        }
        # For each listed wit, save the reading.
        foreach my $wit ( split( /\s+/, $rdg->getAttribute( 'wit' ) ) ) {
			$wit .= $flag if $flag;
            $wit_rdgs{$wit} = \@rdg_nodes;
        }
        		
        # Does the reading have an ID? If so it probably has a witDetail
        # attached, and we need to read it.
        if( $rdg->hasAttribute( 'xml:id' ) ) {
        	warn "Witdetail on meta reading" if $flag; # this could get complicated.
            my $rid = $rdg->getAttribute( 'xml:id' );
            my $xpc = XML::LibXML::XPathContext->new( $xn );
            my @details = $xpc->findnodes( './witDetail[@target="'.$rid.'"]' );
            foreach my $d ( @details ) {
                _parse_wit_detail( $d, \%wit_rdgs, \@lemma );
            }
        }
    }       
        
    # Now collate the variant readings, since it is not done for us.
    $DB::single = 1 if @lemma > 10;
    collate_variants( $c, \@lemma, values %wit_rdgs );
        
    # Now add the witness paths for each reading.
    foreach my $wit_id ( keys %wit_rdgs ) {
        my $witstr = get_sigil( $wit_id, $c );
        my $rdg_list = $wit_rdgs{$wit_id};
        _add_wit_path( $c, $rdg_list, $app_id, $anchor, $witstr );
    }
}

sub _anchor_name {
    my $xmlid = shift;
    $xmlid =~ s/^\#//;
    return sprintf( "#ANCHOR_%s#", $xmlid );
}

sub _return_lemma {
    my( $c, $app, $anchor ) = @_;
    my @nodes = grep { $_->id !~ /^\#A(PP|NCHOR)/ } 
        $c->reading_sequence( $c->reading( $app ), $c->reading( $anchor ),
        	$c->baselabel );
    return @nodes;
}

sub interpret {
	# A utility function to change apparatus-ese into a full variant.
	my( $reading, $lemma ) = @_;
	return $reading if $reading eq $lemma;
	my $oldreading = $reading;
	# $lemma =~ s/\s+[[:punct:]]+$//;
	my $flag;  # In case of p.c. indications
	my @words = split( /\s+/, $lemma );
	if( $reading =~ /^(.*) praem.$/ ) {
		$reading = "$1 $lemma";
	} elsif( $reading =~ /^(.*) add.$/ ) {
		$reading = "$lemma $1";
	} elsif( $reading =~ /add. alia manu/
		|| $reading =~ /inscriptionem compegi e/ # TODO huh?
		|| $reading eq 'inc.'  # TODO huh?
 		) {
		# Ignore it.
		$reading = $lemma;
	} elsif( $reading =~ /locus [uv]acuus/
	    || $reading eq 'def.'
	    || $reading eq 'illeg.'
	    || $reading eq 'onleesbar'
	    ) {
		$reading = '#LACUNA#';
	} elsif( $reading eq 'om.' ) {
		$reading = '';
	} elsif( $reading =~ /^in[uv]\.$/ 
			 || $reading eq 'transp.' ) {
		# Hope it is two words.
		print STDERR "WARNING: want to invert a lemma that is not two words\n" 
			unless scalar( @words ) == 2;
		$reading = join( ' ', reverse( @words ) );
	} elsif( $reading =~ /^iter(\.|at)$/ ) {
		# Repeat the lemma
		$reading = "$lemma $lemma";
	} elsif( $reading eq 'in marg.' ) {
		# There was nothing before a correction.
		$reading = '';
		$flag = '_ac';
	} elsif( $reading =~ /^(.*?)\s*\(?sic([\s\w.]+)?\)?$/ ) {
		# Discard any 'sic' notation; indeed, indeed.
		$reading = $1;
	} elsif( $reading =~ /^(.*) \.\.\. (.*)$/ ) {
		# The first and last N words captured should replace the first and
		# last N words of the lemma.
		my @begin = split( /\s+/, $1 );
		my @end = split( /\s+/, $2 );
		if( scalar( @begin ) + scalar ( @end ) > scalar( @words ) ) {
			# Something is wrong and we can't do the splice.
			print STDERR "ERROR: $lemma is too short to accommodate $oldreading\n";
		} else {
			splice( @words, 0, scalar @begin, @begin );
			splice( @words, -(scalar @end), scalar @end, @end );
			$reading = join( ' ', @words );
		}
	}
	if( $oldreading ne $reading || $flag || $oldreading =~ /\./ ) {
		my $int = $reading;
		$int .= " ($flag)" if $flag;
		print STDERR "Interpreted $oldreading as $int given $lemma\n";
	}
	return( $reading, $flag );
}

sub _parse_wit_detail {
    my( $detail, $readings, $lemma ) = @_;
    my $wit = $detail->getAttribute( 'wit' );
    my $content = $detail->textContent;
    if( $content =~ /a\.\s*c\./ ) {
        # Replace the key in the $readings hash
        my $rdg = delete $readings->{$wit};
        $readings->{$wit.'_ac'} = $rdg;
        $has_ac{$sigil_for{$wit}} = 1;
    } elsif( $content =~ /p\.\s*c\./ ) {
        # If no key for the wit a.c. exists, add one pointing to the lemma
        unless( exists $readings->{$wit.'_ac'} ) {
            $readings->{$wit.'_ac'} = $lemma;
        }
        $has_ac{$sigil_for{$wit}} = 1;
    } # else don't bother just yet
}

sub get_sigil {
    my( $xml_id, $c ) = @_;
    if( $xml_id =~ /^(.*)_ac$/ ) {
        my $real_id = $1;
        return $sigil_for{$real_id} . $c->ac_label;
    } else {
        return $sigil_for{$xml_id};
    }
}

sub expand_all_paths { 
    my( $c ) = @_;
    
    # Walk the collation and fish out the paths for each witness
    foreach my $wit ( $c->tradition->witnesses ) {
        my $sig = $wit->sigil;
        my @path = grep { !$_->is_ph } 
            $c->reading_sequence( $c->start, $c->end, $sig );
        $wit->path( \@path );
        if( $has_ac{$sig} ) {
            my @ac_path = grep { !$_->is_ph } 
                $c->reading_sequence( $c->start, $c->end, $sig.$c->ac_label );
            $wit->uncorrected_path( \@ac_path );
        }
    }   
    
    # Delete the anchors
    foreach my $anchor ( grep { $_->is_ph } $c->readings ) {
        $c->del_reading( $anchor );
    }
    # Delete the base edges
    map { $c->del_path( $_, $c->baselabel ) } $c->paths;
    
    # Make the path edges
    $c->make_witness_paths();
}

sub _add_wit_path {
    my( $c, $rdg, $app, $anchor, $wit ) = @_;
    my @nodes = @$rdg;
    push( @nodes, $c->reading( $anchor ) );
    
    my $cur = $c->reading( $app );
    foreach my $n ( @nodes ) {
        $c->add_path( $cur, $n, $wit );
        $cur = $n;
    }
}

=back

=head1 LICENSE

This package is free software and is provided "as is" without express
or implied warranty.  You can redistribute it and/or modify it under
the same terms as Perl itself.

=head1 AUTHOR

Tara L Andrews, aurum@cpan.org

=cut

1;
Commit	Line	Data
6f4946fb	1	package Text::Tradition::Parser::CTE;
	2
	3	use strict;
	4	use warnings;
c9158e60	5	use Encode qw/ decode /;
4d85a60e	6	use Text::Tradition::Parser::Util qw/ collate_variants /;
6f4946fb	7	use XML::LibXML;
	8	use XML::LibXML::XPathContext;
	9
	10	=head1 NAME
	11
	12	Text::Tradition::Parser::CTE
	13
	14	=head1 DESCRIPTION
	15
	16	Parser module for Text::Tradition, given a TEI file exported from
	17	Classical Text Editor.
	18
	19	=head1 METHODS
	20
	21	=over
	22
	23	=item B<parse>
	24
	25	my @apparatus = read( $xml_file );
	26
	27	Takes a Tradition object and a TEI file exported from Classical Text
4d85a60e	28	Editor using double-endpoint-attachment critical apparatus encoding;
4d85a60e	29	initializes the Tradition from the file.
6f4946fb	30
	31	=cut
	32
4d85a60e	33	my %sigil_for; # Save the XML IDs for witnesses.
4d85a60e	34	my %apps; # Save the apparatus XML for a given ID.
f6e19c7c	35	my %has_ac; # Keep track of witnesses that have corrections.
6f4946fb	36
6f4946fb	37	sub parse {
dfc37e38	38	my( $tradition, $opts ) = @_;
4d85a60e	39	my $c = $tradition->collation; # Some shorthand
	40
	41	# First, parse the XML.
c9158e60	42	my( $tei, $xpc ) = _remove_formatting( $opts );
c9158e60	43	return unless $tei; # we have already warned.
4d85a60e	44
	45	# CTE uses a DTD rather than any xmlns-based parsing. Thus we
	46	# need no namespace handling.
4d85a60e	47	# Get the witnesses and create the witness objects.
	48	foreach my $wit_el ( $xpc->findnodes( '//sourceDesc/listWit/witness' ) ) {
	49	# The witness xml:id is used internally, and is not the sigil name.
	50	my $id= $wit_el->getAttribute( 'xml:id' );
c9158e60	51	my @sig_parts = $xpc->findnodes( 'descendant::text()', $wit_el );
4d85a60e	52	my $sig = _stringify_sigil( @sig_parts );
c9158e60	53	print STDERR "Adding witness $sig\n";
b8f262e8	54	$tradition->add_witness( sigil => $sig, source => $wit_el->toString() );
b8f262e8	55	$sigil_for{'#'.$id} = $sig; # Make life easy by keying on the ID ref syntax
4d85a60e	56	}
c9158e60	57
4d85a60e	58	# Now go through the text and find the base tokens, apparatus tags, and
	59	# anchors. Make a giant array of all of these things in sequence.
	60	# TODO consider combining this with creation of graph below
	61	my @base_text;
	62	foreach my $pg_el ( $xpc->findnodes( '/TEI/text/body/p' ) ) {
	63	foreach my $xn ( $pg_el->childNodes ) {
	64	push( @base_text, _get_base( $xn ) );
	65	}
6f4946fb	66	}
4d85a60e	67	# We now have to work through this array applying the alternate
	68	# apparatus readings to the base text. Essentially we will put
	69	# everything on the graph, from which we will delete the apps and
	70	# anchors when we are done.
f6e19c7c	71
f6e19c7c	72	# First, put the base tokens, apps, and anchors in the graph.
4d85a60e	73	my $counter = 0;
	74	my $last = $c->start;
	75	foreach my $item ( @base_text ) {
	76	my $r;
	77	if( $item->{'type'} eq 'token' ) {
12720144	78	$r = $c->add_reading( { id => 'n'.$counter++,
12720144	79	text => $item->{'content'} } );
4d85a60e	80	} elsif ( $item->{'type'} eq 'anchor' ) {
12720144	81	$r = $c->add_reading( { id => '#ANCHOR_' . $item->{'content'} . '#',
12720144	82	is_ph => 1 } );
4d85a60e	83	} elsif ( $item->{'type'} eq 'app' ) {
4d85a60e	84	my $tag = '#APP_' . $counter++ . '#';
12720144	85	$r = $c->add_reading( { id => $tag, is_ph => 1 } );
4d85a60e	86	$apps{$tag} = $item->{'content'};
4d85a60e	87	}
f6e19c7c	88	$c->add_path( $last, $r, $c->baselabel );
4d85a60e	89	$last = $r;
6f4946fb	90	}
f6e19c7c	91	$c->add_path( $last, $c->end, $c->baselabel );
4d85a60e	92
	93	# Now we can parse the apparatus entries, and add the variant readings
	94	# to the graph.
	95
	96	foreach my $app_id ( keys %apps ) {
	97	_add_readings( $c, $app_id );
6f4946fb	98	}
4d85a60e	99
f6e19c7c	100	# Finally, add explicit witness paths, remove the base paths, and remove
	101	# the app/anchor tags.
	102	expand_all_paths( $c );
861c3e27	103
	104	# Save the text for each witness so that we can ensure consistency
	105	# later on
	106	$tradition->collation->text_from_paths();
c9158e60	107	$tradition->collation->calculate_ranks();
c9158e60	108	$tradition->collation->flatten_ranks();
6f4946fb	109	}
6f4946fb	110
4d85a60e	111	sub _stringify_sigil {
	112	my( @nodes ) = @_;
	113	my @parts = grep { /\w/ } map { $_->data } @nodes;
	114	return join( '', @parts );
	115	}
6f4946fb	116
c9158e60	117	# Get rid of all the formatting elements that get in the way of tokenization.
	118	sub _remove_formatting {
	119	my( $opts ) = @_;
	120
	121	# First, parse the original XML
	122	my $parser = XML::LibXML->new();
	123	my $doc;
	124	if( exists $opts->{'string'} ) {
	125	$doc = $parser->parse_string( $opts->{'string'} );
	126	} elsif ( exists $opts->{'file'} ) {
	127	$doc = $parser->parse_file( $opts->{'file'} );
	128	} else {
	129	warn "Could not find string or file option to parse";
	130	return;
	131	}
	132
	133	# Second, remove the formatting
	134	my $xpc = XML::LibXML::XPathContext->new( $doc->documentElement );
	135	my @useless = $xpc->findnodes( '//hi' );
	136	foreach my $n ( @useless ) {
	137	my $parent = $n->parentNode();
	138	my @children = $n->childNodes();
	139	my $first = shift @children;
	140	$parent->replaceChild( $first, $n );
	141	foreach my $c ( @children ) {
	142	$parent->insertAfter( $c, $first );
	143	$first = $c;
	144	}
	145	}
	146
	147	# Third, write out and reparse to merge the text nodes.
	148	my $result = decode( $doc->encoding, $doc->toString() );
	149	my $tei = $parser->parse_string( $result )->documentElement;
	150	$xpc = XML::LibXML::XPathContext->new( $tei );
	151	return( $tei, $xpc );
	152	}
	153
	154	## Helper function to help us navigate through nested XML, picking out
	155	## the words, the apparatus, and the anchors.
4d85a60e	156
	157	sub _get_base {
	158	my( $xn ) = @_;
	159	my @readings;
	160	if( $xn->nodeType == XML_TEXT_NODE ) {
	161	# Base text, just split the words on whitespace and add them
	162	# to our sequence.
	163	my $str = $xn->data;
	164	$str =~ s/^\s+//;
c9158e60	165	my @tokens = split( /\s+/, $str );
c9158e60	166	push( @readings, map { { 'type' => 'token', 'content' => $_ } } @tokens );
4d85a60e	167	} elsif( $xn->nodeName eq 'app' ) {
	168	# Apparatus, just save the entire XML node.
	169	push( @readings, { 'type' => 'app', 'content' => $xn } );
	170	} elsif( $xn->nodeName eq 'anchor' ) {
	171	# Anchor to mark the end of some apparatus; save its ID.
	172	push( @readings, { 'type' => 'anchor',
	173	'content' => $xn->getAttribute( 'xml:id' ) } );
	174	} elsif ( $xn->nodeName ne 'note' ) { # Any tag we don't know to disregard
	175	print STDERR "Unrecognized tag " . $xn->nodeName . "\n";
6f4946fb	176	}
4d85a60e	177	return @readings;
6f4946fb	178	}
6f4946fb	179
c9158e60	180	sub _append_tokens {
	181	my( $list, @tokens ) = @_;
	182	if( @$list && $list->[-1]->{'content'} =~ /\#JOIN\#$/ ) {
	183	# The list evidently ended mid-word; join the next token onto it.
	184	my $t = shift @tokens;
	185	if( ref $t && $t->{'type'} eq 'token' ) {
	186	# Join the word
	187	$t = $t->{'content'};
	188	} elsif( ref $t ) {
	189	# An app or anchor intervened; end the word.
	190	unshift( @tokens, $t );
	191	$t = '';
	192	}
	193	$list->[-1]->{'content'} =~ s/\#JOIN\#$/$t/;
	194	}
	195	foreach my $t ( @tokens ) {
	196	unless( ref( $t ) ) {
	197	$t = { 'type' => 'token', 'content' => $t };
	198	}
	199	push( @$list, $t );
	200	}
	201	}
	202
4d85a60e	203	sub _add_readings {
	204	my( $c, $app_id ) = @_;
	205	my $xn = $apps{$app_id};
	206	my $anchor = _anchor_name( $xn->getAttribute( 'to' ) );
	207	# Get the lemma, which is all the readings between app and anchor,
	208	# excluding other apps or anchors.
	209	my @lemma = _return_lemma( $c, $app_id, $anchor );
	210	my $lemma_str = join( ' ', grep { $_ !~ /^\#/ } map { $_->text } @lemma );
	211
	212	# For each reading, send its text to 'interpret' along with the lemma,
	213	# and then save the list of witnesses that these tokens belong to.
3a5d151b	214	my %wit_rdgs; # Maps from witnesses to the variant text
4d85a60e	215	my $ctr = 0;
	216	my $tag = $app_id;
	217	$tag =~ s/^\#APP_(.*)\#$/$1/;
c9158e60	218
4d85a60e	219	foreach my $rdg ( $xn->getChildrenByTagName( 'rdg' ) ) {
4d85a60e	220	my @text;
4d85a60e	221	foreach ( $rdg->childNodes ) {
	222	push( @text, _get_base( $_ ) );
	223	}
12720144	224	my( $interpreted, $flag ) = ( '', undef );
	225	if( @text ) {
	226	( $interpreted, $flag ) = interpret(
	227	join( ' ', map { $_->{'content'} } @text ), $lemma_str );
	228	}
b8f262e8	229	next if( $interpreted eq $lemma_str ) && !$flag; # Reading is lemma.
b8f262e8	230
4d85a60e	231	my @rdg_nodes;
b8f262e8	232	if( $interpreted eq '#LACUNA#' ) {
	233	push( @rdg_nodes, $c->add_reading( { id => $tag . "/" . $ctr++,
	234	is_lacuna => 1 } ) );
	235	} else {
	236	foreach my $w ( split( /\s+/, $interpreted ) ) {
	237	my $r = $c->add_reading( { id => $tag . "/" . $ctr++,
	238	text => $w } );
	239	push( @rdg_nodes, $r );
	240	}
4d85a60e	241	}
f6e19c7c	242	# For each listed wit, save the reading.
f6e19c7c	243	foreach my $wit ( split( /\s+/, $rdg->getAttribute( 'wit' ) ) ) {
12720144	244	$wit .= $flag if $flag;
f6e19c7c	245	$wit_rdgs{$wit} = \@rdg_nodes;
f6e19c7c	246	}
12720144	247
3a5d151b	248	# Does the reading have an ID? If so it probably has a witDetail
f6e19c7c	249	# attached, and we need to read it.
3a5d151b	250	if( $rdg->hasAttribute( 'xml:id' ) ) {
12720144	251	warn "Witdetail on meta reading" if $flag; # this could get complicated.
f6e19c7c	252	my $rid = $rdg->getAttribute( 'xml:id' );
	253	my $xpc = XML::LibXML::XPathContext->new( $xn );
	254	my @details = $xpc->findnodes( './witDetail[@target="'.$rid.'"]' );
	255	foreach my $d ( @details ) {
	256	_parse_wit_detail( $d, \%wit_rdgs, \@lemma );
	257	}
3a5d151b	258	}
f6e19c7c	259	}
f6e19c7c	260
4d85a60e	261	# Now collate the variant readings, since it is not done for us.
c9158e60	262	$DB::single = 1 if @lemma > 10;
12720144	263	collate_variants( $c, \@lemma, values %wit_rdgs );
b8f262e8	264
4d85a60e	265	# Now add the witness paths for each reading.
f6e19c7c	266	foreach my $wit_id ( keys %wit_rdgs ) {
	267	my $witstr = get_sigil( $wit_id, $c );
	268	my $rdg_list = $wit_rdgs{$wit_id};
	269	_add_wit_path( $c, $rdg_list, $app_id, $anchor, $witstr );
6f4946fb	270	}
4d85a60e	271	}
6f4946fb	272
4d85a60e	273	sub _anchor_name {
	274	my $xmlid = shift;
	275	$xmlid =~ s/^\#//;
	276	return sprintf( "#ANCHOR_%s#", $xmlid );
6f4946fb	277	}
6f4946fb	278
4d85a60e	279	sub _return_lemma {
4d85a60e	280	my( $c, $app, $anchor ) = @_;
12720144	281	my @nodes = grep { $_->id !~ /^\#A(PP\|NCHOR)/ }
	282	$c->reading_sequence( $c->reading( $app ), $c->reading( $anchor ),
	283	$c->baselabel );
4d85a60e	284	return @nodes;
4d85a60e	285	}
6f4946fb	286
6f4946fb	287	sub interpret {
4d85a60e	288	# A utility function to change apparatus-ese into a full variant.
	289	my( $reading, $lemma ) = @_;
	290	return $reading if $reading eq $lemma;
	291	my $oldreading = $reading;
	292	# $lemma =~ s/\s+[[:punct:]]+$//;
12720144	293	my $flag; # In case of p.c. indications
4d85a60e	294	my @words = split( /\s+/, $lemma );
	295	if( $reading =~ /^(.*) praem.$/ ) {
	296	$reading = "$1 $lemma";
	297	} elsif( $reading =~ /^(.*) add.$/ ) {
	298	$reading = "$lemma $1";
b8f262e8	299	} elsif( $reading =~ /add. alia manu/
	300	\|\| $reading =~ /inscriptionem compegi e/ # TODO huh?
	301	\|\| $reading eq 'inc.' # TODO huh?
	302	) {
12720144	303	# Ignore it.
12720144	304	$reading = $lemma;
b8f262e8	305	} elsif( $reading =~ /locus [uv]acuus/
b8f262e8	306	\|\| $reading eq 'def.'
c9158e60	307	\|\| $reading eq 'illeg.'
c9158e60	308	\|\| $reading eq 'onleesbar'
f6e19c7c	309	) {
b8f262e8	310	$reading = '#LACUNA#';
b8f262e8	311	} elsif( $reading eq 'om.' ) {
4d85a60e	312	$reading = '';
c9158e60	313	} elsif( $reading =~ /^in[uv]\.$/
c9158e60	314	\|\| $reading eq 'transp.' ) {
4d85a60e	315	# Hope it is two words.
	316	print STDERR "WARNING: want to invert a lemma that is not two words\n"
	317	unless scalar( @words ) == 2;
	318	$reading = join( ' ', reverse( @words ) );
12720144	319	} elsif( $reading =~ /^iter(\.\|at)$/ ) {
4d85a60e	320	# Repeat the lemma
4d85a60e	321	$reading = "$lemma $lemma";
12720144	322	} elsif( $reading eq 'in marg.' ) {
	323	# There was nothing before a correction.
	324	$reading = '';
	325	$flag = '_ac';
c9158e60	326	} elsif( $reading =~ /^(.?)\s\(?sic([\s\w.]+)?\)?$/ ) {
	327	# Discard any 'sic' notation; indeed, indeed.
	328	$reading = $1;
12720144	329	} elsif( $reading =~ /^(.) \.\.\. (.)$/ ) {
4d85a60e	330	# The first and last N words captured should replace the first and
	331	# last N words of the lemma.
	332	my @begin = split( /\s+/, $1 );
	333	my @end = split( /\s+/, $2 );
	334	if( scalar( @begin ) + scalar ( @end ) > scalar( @words ) ) {
	335	# Something is wrong and we can't do the splice.
	336	print STDERR "ERROR: $lemma is too short to accommodate $oldreading\n";
	337	} else {
	338	splice( @words, 0, scalar @begin, @begin );
	339	splice( @words, -(scalar @end), scalar @end, @end );
	340	$reading = join( ' ', @words );
	341	}
6f4946fb	342	}
12720144	343	if( $oldreading ne $reading \|\| $flag \|\| $oldreading =~ /\./ ) {
	344	my $int = $reading;
	345	$int .= " ($flag)" if $flag;
	346	print STDERR "Interpreted $oldreading as $int given $lemma\n";
	347	}
	348	return( $reading, $flag );
4d85a60e	349	}
4d85a60e	350
f6e19c7c	351	sub _parse_wit_detail {
	352	my( $detail, $readings, $lemma ) = @_;
	353	my $wit = $detail->getAttribute( 'wit' );
	354	my $content = $detail->textContent;
	355	if( $content =~ /a\.\s*c\./ ) {
	356	# Replace the key in the $readings hash
	357	my $rdg = delete $readings->{$wit};
	358	$readings->{$wit.'_ac'} = $rdg;
	359	$has_ac{$sigil_for{$wit}} = 1;
	360	} elsif( $content =~ /p\.\s*c\./ ) {
	361	# If no key for the wit a.c. exists, add one pointing to the lemma
	362	unless( exists $readings->{$wit.'_ac'} ) {
	363	$readings->{$wit.'_ac'} = $lemma;
	364	}
	365	$has_ac{$sigil_for{$wit}} = 1;
	366	} # else don't bother just yet
	367	}
	368
	369	sub get_sigil {
	370	my( $xml_id, $c ) = @_;
	371	if( $xml_id =~ /^(.*)_ac$/ ) {
	372	my $real_id = $1;
	373	return $sigil_for{$real_id} . $c->ac_label;
	374	} else {
	375	return $sigil_for{$xml_id};
	376	}
	377	}
	378
	379	sub expand_all_paths {
	380	my( $c ) = @_;
	381
	382	# Walk the collation and fish out the paths for each witness
	383	foreach my $wit ( $c->tradition->witnesses ) {
	384	my $sig = $wit->sigil;
12720144	385	my @path = grep { !$_->is_ph }
f6e19c7c	386	$c->reading_sequence( $c->start, $c->end, $sig );
	387	$wit->path( \@path );
	388	if( $has_ac{$sig} ) {
12720144	389	my @ac_path = grep { !$_->is_ph }
861c3e27	390	$c->reading_sequence( $c->start, $c->end, $sig.$c->ac_label );
f6e19c7c	391	$wit->uncorrected_path( \@ac_path );
	392	}
	393	}
	394
	395	# Delete the anchors
12720144	396	foreach my $anchor ( grep { $_->is_ph } $c->readings ) {
f6e19c7c	397	$c->del_reading( $anchor );
f6e19c7c	398	}
12720144	399	# Delete the base edges
12720144	400	map { $c->del_path( $_, $c->baselabel ) } $c->paths;
f6e19c7c	401
	402	# Make the path edges
	403	$c->make_witness_paths();
4d85a60e	404	}
	405
	406	sub _add_wit_path {
f6e19c7c	407	my( $c, $rdg, $app, $anchor, $wit ) = @_;
4d85a60e	408	my @nodes = @$rdg;
f6e19c7c	409	push( @nodes, $c->reading( $anchor ) );
4d85a60e	410
f6e19c7c	411	my $cur = $c->reading( $app );
4d85a60e	412	foreach my $n ( @nodes ) {
f6e19c7c	413	$c->add_path( $cur, $n, $wit );
4d85a60e	414	$cur = $n;
6f4946fb	415	}
6f4946fb	416	}
	417
	418	=back
	419
	420	=head1 LICENSE
	421
	422	This package is free software and is provided "as is" without express
	423	or implied warranty. You can redistribute it and/or modify it under
	424	the same terms as Perl itself.
	425
	426	=head1 AUTHOR
	427
	428	Tara L Andrews, aurum@cpan.org
	429
	430	=cut
	431
	432	1;
	433