use test data for Perls probe

[scpubgit/System-Introspector.git] / lib / System / Introspector / State.pm

package System::Introspector::State;
use Moo;
use File::Tree::Snapshot;
use System::Introspector::Gatherer;

use JSON::Diffable qw( encode_json );

has config => (is => 'ro', required => 1);

has root => (is => 'ro', required => 1);

sub user { $_[0]->config->user }

sub sudo_user { $_[0]->config->sudo_user }

sub gather {
    my ($self, @groups) = @_;
    for my $host ($self->config->hosts) {
        $self->fetch_and_store($host, @groups);
    }
    return 1;
}

sub introspectors {
    my ($self, $group) = @_;
    return $self->config->config_for_group($group)->{introspect};
}

sub fetch_and_store {
    my ($self, $host, @groups) = @_;
    my $data = $self->fetch($host, @groups);
    return $self->_store($host, $data);
}

sub fetch {
    my ($self, $host, @groups) = @_;
    return +{ map {
        ($_, $self->fetch_group($host, $_));
    } @groups };
}

sub fetch_group {
    my ($self, $host, $group) = @_;
    my $spec = $self->introspectors($group);
    my (@sudo, @nosudo);
    push(@{ $spec->{$_}{sudo} ? \@sudo : \@nosudo}, [$_, $spec->{$_}])
        for sort keys %$spec;
    my %report;
    if (@nosudo) {
        my $gatherer = $self->_create_gatherer(host => $host);
        %report = %{ $self->_fetch_with_gatherer($gatherer, @nosudo) || {} };
    }
    if (@sudo) {
        my $gatherer = $self->_create_gatherer(sudo => 1, host => $host);
        %report = (%report, %{ $self->_fetch_with_gatherer($gatherer, @sudo) || {} });
    }
    return \%report;
}

sub _fetch_with_gatherer {
    my ($self, $gatherer, @spec) = @_;
    my %report;
    for my $class_spec (@spec) {
        my ($class_base, $args) = @$class_spec;
        print "Gathering $class_base data\n";
        $report{ $class_base } = $gatherer
            ->gather($class_base, $args);
    }
    print "All gathered\n";
    return \%report;
}

sub storage {
    my ($self, @path) = @_;
    my $storage = File::Tree::Snapshot->new(
        allow_empty  => 0,
        storage_path => join('/', $self->root, @path),
    );
    $storage->create
        unless $storage->exists;
    return $storage;
}

sub _store {
    my ($self, $host, $data) = @_;
    for my $group (sort keys %$data) {
        my $storage = $self->storage($host, $group);
        my $gathered = $data->{$group};
        my @files;
        for my $class (sort keys %$gathered) {
            my $file = sprintf '%s.json', join '/',
                map lc, map {
                    s{([a-z0-9])([A-Z])}{${1}_${2}}g;
                    $_;
                } split m{::}, $class;
            my $fh = $storage->open('>:utf8', $file, mkpath => 1);
            print "Writing $file\n";
            print $fh encode_json($gathered->{$class});
            push @files, $storage->file($file);
        }
        $self->_cleanup($storage, [@files]);
        $storage->commit;
    }
    return 1;
}

sub _cleanup {
    my ($self, $storage, $known_files) = @_;
    my %known = map { ($_ => 1) } @$known_files;
    my @files = $storage->find_files('json');
    for my $file (@files) {
        next if $known{$file};
        print "Removing $file\n";
        unlink($file)
            or die "Unable to remove '$file': $!\n";
    }
    return 1;
}

sub _create_gatherer {
    my ($self, %arg) = @_;
    return System::Introspector::Gatherer->new_from_spec(
        user        => $self->user,
        host        => $arg{host},
        sudo_user   => $arg{sudo} && $self->sudo_user,
    );
}

1;

=head1 NAME

System::Introspector::State - Gather system state

=head1 SYNOPSIS

    my $state = System::Introspector::State->new(
        host    => 'foo.example.com',
        storage => $storage_obj,
        config  => {
            introspect => [qw( ProbeName )],
        },
    );

    my $data = $state->fetch;
    $state->fetch_and_store;

=head1 DESCRIPTION

Gathers system introspection data based on configuration and stores
it with a L<File::Tree::Snapshot> object.

=head1 ATTRIBUTES

=head2 config

A hash reference containing a C<introspect> key with an array reference
value containing a list of probe names without the
C<System::Introspector::Probe::> prefix. This attribute is required.

=head2 host

An optional hostname. If no hostname is supplied, the local configuration
data will be fetched.

=head2 storage

A L<File::Tree::Snapshot> object.

=head1 METHODS

=head2 fetch

    my $data = $state->fetch;

Fetches all probe data.

=head2 fetch_and_store

    $state->fetch_and_store;

Fetches all probe data and stores it in the L</storage>.

=cut