convert anything that logged to o-r logging; add new log messages; tweak existing...

[scpubgit/System-Introspector-Report.git] / lib / System / Introspector / Report / Publish / MediaWiki / Updater.pm

package System::Introspector::Report::Publish::MediaWiki::Updater;
use Moo;
use Try::Tiny;
use Module::Runtime qw( use_module );
use System::Introspector::Report::Logging qw( :log );

has connection => (is => 'ro', lazy => 1, builder => 1, handles => {
  get_page => 'get',
  put_page => 'put',
});

sub _build_connection {
  my ($self) = @_;
  return use_module($self->connection_class)->new(
    api_uri         => $self->api_uri,
    username        => $self->username,
    password        => $self->password,
    allow_create    => 1,
    $self->http_auth ? (
      http_auth  => 1,
      http_realm => $self->http_realm,
    ) : (),
  );
}

sub process {
  my ($self, $stream) = @_;
  log_debug { "Updater is starting to process individual pages" };
  while (my $report = $stream->()) {
    log_trace { "Processing page" };
    $self->_process_page(@$report);
  }
  return 1;
}

sub _process_page {
  my ($self, $page_name, $options, $reports) = @_;
  unless (scalar @$reports) {
    log_verbose { "Skipping page '$page_name': No reports to publish" };
    return 1;
  }
  my $do_create = $options->{create};
  return try {
    my $page = $self->get_page($page_name);
    if ($page->is_new and not $do_create) {
      log_verbose { "Skipping page '$page_name': Does not yet exist" };
      return 1;
    }
    my $is_changed = $page->update($reports);
    unless ($is_changed) {
      log_verbose { "Not pushing page '$page_name': No changes" };
      return 1;
    }
    log_info { "Updating page '$page_name'" };
    $self->put_page($page);
    return 1;
  }
  catch {
    log_error { "Error during page update: $_" };
    return 1;
  };
}

with $_ for qw(
  System::Introspector::Report::Publish::MediaWiki::HasConnectInfo
);

1;