[gitmo/Package-Stash.git] / lib / Stash / Manip.pm

package Stash::Manip;
use strict;
use warnings;

use Carp qw(confess);
use Scalar::Util qw(reftype);

=head1 NAME

Stash::Manip - routines for manipulating stashes

=head1 SYNOPSIS

  my $stash = Stash::Manip->new('Foo');
  $stash->add_package_symbol('%foo', {bar => 1});
  # $Foo::foo{bar} == 1
  $stash->has_package_symbol('$foo') # false
  my $namespace = $stash->namespace;
  *{ $namespace->{foo} }{HASH} # {bar => 1}

=head1 DESCRIPTION

Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
incredibly messy, and easy to get wrong. This module hides all of that behind a
simple API.

NOTE: Most methods in this class require a variable specification that includes
a sigil. If this sigil is absent, it is assumed to represent the IO slot.

=head1 METHODS

=cut

=head2 new $package_name

Creates a new C<Stash::Manip> object, for the package given as the only
argument.

=cut

sub new {
    my $class = shift;
    my ($namespace) = @_;
    return bless { package => $namespace }, $class;
}

=head2 name

Returns the name of the package that this object represents.

=cut

sub name {
    return $_[0]->{package};
}

=head2 namespace

Returns the raw stash itself.

=cut

sub namespace {
    # NOTE:
    # because of issues with the Perl API 
    # to the typeglob in some versions, we 
    # need to just always grab a new 
    # reference to the hash here. Ideally 
    # we could just store a ref and it would
    # Just Work, but oh well :\    
    no strict 'refs';
    return \%{$_[0]->name . '::'};
}

{
    my %SIGIL_MAP = (
        '$' => 'SCALAR',
        '@' => 'ARRAY',
        '%' => 'HASH',
        '&' => 'CODE',
        ''  => 'IO',
    );

    sub _deconstruct_variable_name {
        my ($self, $variable) = @_;

        (defined $variable && length $variable)
            || confess "You must pass a variable name";

        my $sigil = substr($variable, 0, 1, '');

        if (exists $SIGIL_MAP{$sigil}) {
            return ($variable, $sigil, $SIGIL_MAP{$sigil});
        }
        else {
            return ("${sigil}${variable}", '', $SIGIL_MAP{''});
        }
    }
}

=head2 add_package_symbol $variable $value

Adds a new package symbol, for the symbol given as C<$variable>, and optionally
gives it an initial value of C<$value>. C<$variable> should be the name of
variable including the sigil, so

  Stash::Manip->new('Foo')->add_package_symbol('%foo')

will create C<%Foo::foo>.

=cut

sub add_package_symbol {
    my ($self, $variable, $initial_value) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $pkg = $self->name;

    no strict 'refs';
    no warnings 'redefine', 'misc', 'prototype';
    *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
}

=head2 remove_package_glob $name

Removes all package variables with the given name, regardless of sigil.

=cut

sub remove_package_glob {
    my ($self, $name) = @_;
    no strict 'refs';
    delete ${$self->name . '::'}{$name};
}

# ... these functions deal with stuff on the namespace level

=head2 has_package_symbol $variable

Returns whether or not the given package variable (including sigil) exists.

=cut

sub has_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    return unless exists $namespace->{$name};

    my $entry_ref = \$namespace->{$name};
    if (reftype($entry_ref) eq 'GLOB') {
        if ( $type eq 'SCALAR' ) {
            return defined ${ *{$entry_ref}{SCALAR} };
        }
        else {
            return defined *{$entry_ref}{$type};
        }
    }
    else {
        # a symbol table entry can be -1 (stub), string (stub with prototype),
        # or reference (constant)
        return $type eq 'CODE';
    }
}

=head2 get_package_symbol $variable

Returns the value of the given package variable (including sigil).

=cut

sub get_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    # FIXME
    if (!exists $namespace->{$name}) {
        my $initial = $type eq 'ARRAY' ? []
                    : $type eq 'HASH'  ? {}
                    : \undef;
        $self->add_package_symbol($variable, $initial)
    }

    my $entry_ref = \$namespace->{$name};

    if (ref($entry_ref) eq 'GLOB') {
        return *{$entry_ref}{$type};
    }
    else {
        if ($type eq 'CODE') {
            no strict 'refs';
            return \&{ $self->name . '::' . $name };
        }
        else {
            return undef;
        }
    }
}

=head2 remove_package_symbol $variable

Removes the package variable described by C<$variable> (which includes the
sigil); other variables with the same name but different sigils will be
untouched.

=cut

sub remove_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    # FIXME:
    # no doubt this is grossly inefficient and 
    # could be done much easier and faster in XS

    my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
        { sigil => '$', type => 'SCALAR', name => $name },
        { sigil => '@', type => 'ARRAY',  name => $name },
        { sigil => '%', type => 'HASH',   name => $name },
        { sigil => '&', type => 'CODE',   name => $name },
        { sigil => '',  type => 'IO',     name => $name },
    );

    my ($scalar, $array, $hash, $code, $io);
    if ($type eq 'SCALAR') {
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'ARRAY') {
        $scalar = $self->get_package_symbol($scalar_desc) if $self->has_package_symbol($scalar_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'HASH') {
        $scalar = $self->get_package_symbol($scalar_desc) if $self->has_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'CODE') {
        $scalar = $self->get_package_symbol($scalar_desc) if $self->has_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'IO') {
        $scalar = $self->get_package_symbol($scalar_desc) if $self->has_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
    }
    else {
        confess "This should never ever ever happen";
    }

    $self->remove_package_glob($name);

    $self->add_package_symbol($scalar_desc => $scalar) if defined $scalar;
    $self->add_package_symbol($array_desc  => $array)  if defined $array;
    $self->add_package_symbol($hash_desc   => $hash)   if defined $hash;
    $self->add_package_symbol($code_desc   => $code)   if defined $code;
    $self->add_package_symbol($io_desc     => $io)     if defined $io;
}

=head2 list_all_package_symbols $type_filter

Returns a list of package variable names in the package, without sigils. If a
C<type_filter> is passed, it is used to select package variables of a given
type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
etc).

=cut

sub list_all_package_symbols {
    my ($self, $type_filter) = @_;

    my $namespace = $self->namespace;
    return keys %{$namespace} unless defined $type_filter;

    # NOTE:
    # or we can filter based on 
    # type (SCALAR|ARRAY|HASH|CODE)
    if ($type_filter eq 'CODE') {
        return grep {
            (ref($namespace->{$_})
                ? (ref($namespace->{$_}) eq 'SCALAR')
                : (ref(\$namespace->{$_}) eq 'GLOB'
                   && defined(*{$namespace->{$_}}{CODE})));
        } keys %{$namespace};
    } else {
        return grep { *{$namespace->{$_}}{$type_filter} } keys %{$namespace};
    }
}

=head1 BUGS

No known bugs.

Please report any bugs through RT: email
C<bug-stash-manip at rt.cpan.org>, or browse to
L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Stash-Manip>.

=head1 SEE ALSO

L<Class::MOP::Package> - this module is a factoring out of code that used to
live here

=head1 SUPPORT

You can find this documentation for this module with the perldoc command.

    perldoc Stash::Manip

You can also look for information at:

=over 4

=item * AnnoCPAN: Annotated CPAN documentation

L<http://annocpan.org/dist/Stash-Manip>

=item * CPAN Ratings

L<http://cpanratings.perl.org/d/Stash-Manip>

=item * RT: CPAN's request tracker

L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Stash-Manip>

=item * Search CPAN

L<http://search.cpan.org/dist/Stash-Manip>

=back

=head1 AUTHOR

  Jesse Luehrs <doy at tozt dot net>

Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
Moose Cabal.

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2010 by Jesse Luehrs.

This is free software; you can redistribute it and/or modify it under
the same terms as perl itself.

=cut

1;
Commit	Line	Data
f4979588	1	package Stash::Manip;
f10f6217	2	use strict;
	3	use warnings;
	4
	5	use Carp qw(confess);
	6	use Scalar::Util qw(reftype);
f4979588	7
	8	=head1 NAME
	9
683542f5	10	Stash::Manip - routines for manipulating stashes
f4979588	11
	12	=head1 SYNOPSIS
	13
683542f5	14	my $stash = Stash::Manip->new('Foo');
	15	$stash->add_package_symbol('%foo', {bar => 1});
	16	# $Foo::foo{bar} == 1
	17	$stash->has_package_symbol('$foo') # false
	18	my $namespace = $stash->namespace;
	19	*{ $namespace->{foo} }{HASH} # {bar => 1}
f4979588	20
	21	=head1 DESCRIPTION
	22
683542f5	23	Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
	24	incredibly messy, and easy to get wrong. This module hides all of that behind a
	25	simple API.
	26
56a29840	27	NOTE: Most methods in this class require a variable specification that includes
	28	a sigil. If this sigil is absent, it is assumed to represent the IO slot.
	29
683542f5	30	=head1 METHODS
	31
	32	=cut
	33
	34	=head2 new $package_name
	35
	36	Creates a new C<Stash::Manip> object, for the package given as the only
	37	argument.
f4979588	38
	39	=cut
	40
f10f6217	41	sub new {
	42	my $class = shift;
	43	my ($namespace) = @_;
	44	return bless { package => $namespace }, $class;
	45	}
	46
683542f5	47	=head2 name
	48
	49	Returns the name of the package that this object represents.
	50
	51	=cut
	52
f10f6217	53	sub name {
	54	return $_[0]->{package};
	55	}
	56
683542f5	57	=head2 namespace
	58
	59	Returns the raw stash itself.
	60
	61	=cut
	62
f10f6217	63	sub namespace {
	64	# NOTE:
	65	# because of issues with the Perl API
	66	# to the typeglob in some versions, we
	67	# need to just always grab a new
	68	# reference to the hash here. Ideally
	69	# we could just store a ref and it would
	70	# Just Work, but oh well :\
	71	no strict 'refs';
	72	return \%{$_[0]->name . '::'};
	73	}
	74
	75	{
	76	my %SIGIL_MAP = (
	77	'$' => 'SCALAR',
	78	'@' => 'ARRAY',
	79	'%' => 'HASH',
	80	'&' => 'CODE',
56a29840	81	'' => 'IO',
f10f6217	82	);
	83
	84	sub _deconstruct_variable_name {
	85	my ($self, $variable) = @_;
	86
56a29840	87	(defined $variable && length $variable)
f10f6217	88	\|\| confess "You must pass a variable name";
	89
	90	my $sigil = substr($variable, 0, 1, '');
	91
56a29840	92	if (exists $SIGIL_MAP{$sigil}) {
	93	return ($variable, $sigil, $SIGIL_MAP{$sigil});
	94	}
	95	else {
	96	return ("${sigil}${variable}", '', $SIGIL_MAP{''});
	97	}
f10f6217	98	}
	99	}
	100
683542f5	101	=head2 add_package_symbol $variable $value
	102
	103	Adds a new package symbol, for the symbol given as C<$variable>, and optionally
	104	gives it an initial value of C<$value>. C<$variable> should be the name of
	105	variable including the sigil, so
	106
	107	Stash::Manip->new('Foo')->add_package_symbol('%foo')
	108
	109	will create C<%Foo::foo>.
	110
	111	=cut
	112
f10f6217	113	sub add_package_symbol {
	114	my ($self, $variable, $initial_value) = @_;
	115
	116	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	117	? @{$variable}{qw[name sigil type]}
	118	: $self->_deconstruct_variable_name($variable);
	119
	120	my $pkg = $self->name;
	121
	122	no strict 'refs';
	123	no warnings 'redefine', 'misc', 'prototype';
	124	*{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
	125	}
	126
683542f5	127	=head2 remove_package_glob $name
	128
	129	Removes all package variables with the given name, regardless of sigil.
	130
	131	=cut
	132
f10f6217	133	sub remove_package_glob {
	134	my ($self, $name) = @_;
	135	no strict 'refs';
	136	delete ${$self->name . '::'}{$name};
	137	}
	138
	139	# ... these functions deal with stuff on the namespace level
	140
683542f5	141	=head2 has_package_symbol $variable
	142
	143	Returns whether or not the given package variable (including sigil) exists.
	144
	145	=cut
	146
f10f6217	147	sub has_package_symbol {
	148	my ($self, $variable) = @_;
	149
	150	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	151	? @{$variable}{qw[name sigil type]}
	152	: $self->_deconstruct_variable_name($variable);
	153
	154	my $namespace = $self->namespace;
	155
	156	return unless exists $namespace->{$name};
	157
	158	my $entry_ref = \$namespace->{$name};
	159	if (reftype($entry_ref) eq 'GLOB') {
	160	if ( $type eq 'SCALAR' ) {
	161	return defined ${ *{$entry_ref}{SCALAR} };
	162	}
	163	else {
	164	return defined *{$entry_ref}{$type};
	165	}
	166	}
	167	else {
	168	# a symbol table entry can be -1 (stub), string (stub with prototype),
	169	# or reference (constant)
	170	return $type eq 'CODE';
	171	}
	172	}
	173
683542f5	174	=head2 get_package_symbol $variable
	175
	176	Returns the value of the given package variable (including sigil).
	177
	178	=cut
	179
f10f6217	180	sub get_package_symbol {
	181	my ($self, $variable) = @_;
	182
	183	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	184	? @{$variable}{qw[name sigil type]}
	185	: $self->_deconstruct_variable_name($variable);
	186
	187	my $namespace = $self->namespace;
	188
	189	# FIXME
30d1a098	190	if (!exists $namespace->{$name}) {
	191	my $initial = $type eq 'ARRAY' ? []
	192	: $type eq 'HASH' ? {}
	193	: \undef;
	194	$self->add_package_symbol($variable, $initial)
	195	}
f10f6217	196
	197	my $entry_ref = \$namespace->{$name};
	198
	199	if (ref($entry_ref) eq 'GLOB') {
	200	return *{$entry_ref}{$type};
	201	}
	202	else {
	203	if ($type eq 'CODE') {
	204	no strict 'refs';
	205	return \&{ $self->name . '::' . $name };
	206	}
	207	else {
	208	return undef;
	209	}
	210	}
	211	}
	212
683542f5	213	=head2 remove_package_symbol $variable
	214
	215	Removes the package variable described by C<$variable> (which includes the
	216	sigil); other variables with the same name but different sigils will be
	217	untouched.
	218
	219	=cut
	220
f10f6217	221	sub remove_package_symbol {
	222	my ($self, $variable) = @_;
	223
	224	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	225	? @{$variable}{qw[name sigil type]}
	226	: $self->_deconstruct_variable_name($variable);
	227
	228	# FIXME:
	229	# no doubt this is grossly inefficient and
	230	# could be done much easier and faster in XS
	231
b1a00d0e	232	my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
f10f6217	233	{ sigil => '$', type => 'SCALAR', name => $name },
	234	{ sigil => '@', type => 'ARRAY', name => $name },
	235	{ sigil => '%', type => 'HASH', name => $name },
	236	{ sigil => '&', type => 'CODE', name => $name },
b1a00d0e	237	{ sigil => '', type => 'IO', name => $name },
f10f6217	238	);
f10f6217	239
b1a00d0e	240	my ($scalar, $array, $hash, $code, $io);
f10f6217	241	if ($type eq 'SCALAR') {
	242	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	243	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	244	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	245	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	246	}
	247	elsif ($type eq 'ARRAY') {
	248	$scalar = $self->get_package_symbol($scalar_desc) if $self->has_package_symbol($scalar_desc);
	249	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	250	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	251	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	252	}
	253	elsif ($type eq 'HASH') {
	254	$scalar = $self->get_package_symbol($scalar_desc) if $self->has_package_symbol($scalar_desc);
	255	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	256	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	257	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	258	}
	259	elsif ($type eq 'CODE') {
	260	$scalar = $self->get_package_symbol($scalar_desc) if $self->has_package_symbol($scalar_desc);
	261	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	262	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
b1a00d0e	263	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
	264	}
	265	elsif ($type eq 'IO') {
	266	$scalar = $self->get_package_symbol($scalar_desc) if $self->has_package_symbol($scalar_desc);
	267	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	268	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	269	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
f10f6217	270	}
	271	else {
	272	confess "This should never ever ever happen";
	273	}
	274
	275	$self->remove_package_glob($name);
	276
	277	$self->add_package_symbol($scalar_desc => $scalar) if defined $scalar;
	278	$self->add_package_symbol($array_desc => $array) if defined $array;
	279	$self->add_package_symbol($hash_desc => $hash) if defined $hash;
	280	$self->add_package_symbol($code_desc => $code) if defined $code;
b1a00d0e	281	$self->add_package_symbol($io_desc => $io) if defined $io;
f10f6217	282	}
f10f6217	283
683542f5	284	=head2 list_all_package_symbols $type_filter
	285
	286	Returns a list of package variable names in the package, without sigils. If a
	287	C<type_filter> is passed, it is used to select package variables of a given
	288	type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
	289	etc).
	290
	291	=cut
	292
f10f6217	293	sub list_all_package_symbols {
	294	my ($self, $type_filter) = @_;
	295
	296	my $namespace = $self->namespace;
	297	return keys %{$namespace} unless defined $type_filter;
	298
	299	# NOTE:
	300	# or we can filter based on
	301	# type (SCALAR\|ARRAY\|HASH\|CODE)
	302	if ($type_filter eq 'CODE') {
	303	return grep {
	304	(ref($namespace->{$_})
	305	? (ref($namespace->{$_}) eq 'SCALAR')
	306	: (ref(\$namespace->{$_}) eq 'GLOB'
	307	&& defined(*{$namespace->{$_}}{CODE})));
	308	} keys %{$namespace};
	309	} else {
	310	return grep { *{$namespace->{$_}}{$type_filter} } keys %{$namespace};
	311	}
	312	}
f4979588	313
	314	=head1 BUGS
	315
	316	No known bugs.
	317
	318	Please report any bugs through RT: email
	319	C<bug-stash-manip at rt.cpan.org>, or browse to
	320	L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Stash-Manip>.
	321
	322	=head1 SEE ALSO
	323
683542f5	324	L<Class::MOP::Package> - this module is a factoring out of code that used to
683542f5	325	live here
f4979588	326
	327	=head1 SUPPORT
	328
	329	You can find this documentation for this module with the perldoc command.
	330
	331	perldoc Stash::Manip
	332
	333	You can also look for information at:
	334
	335	=over 4
	336
	337	=item * AnnoCPAN: Annotated CPAN documentation
	338
	339	L<http://annocpan.org/dist/Stash-Manip>
	340
	341	=item * CPAN Ratings
	342
	343	L<http://cpanratings.perl.org/d/Stash-Manip>
	344
	345	=item * RT: CPAN's request tracker
	346
	347	L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Stash-Manip>
	348
	349	=item * Search CPAN
	350
	351	L<http://search.cpan.org/dist/Stash-Manip>
	352
	353	=back
	354
	355	=head1 AUTHOR
	356
	357	Jesse Luehrs <doy at tozt dot net>
	358
683542f5	359	Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
	360	Moose Cabal.
	361
f4979588	362	=head1 COPYRIGHT AND LICENSE
	363
	364	This software is copyright (c) 2010 by Jesse Luehrs.
	365
	366	This is free software; you can redistribute it and/or modify it under
	367	the same terms as perl itself.
	368
	369	=cut
	370
	371	1;