[dbsrgits/SQL-Translator.git] / lib / SQL / Translator / Producer / GraphViz.pm

package SQL::Translator::Producer::GraphViz;

# -------------------------------------------------------------------
# Copyright (C) 2002-2009 SQLFairy Authors
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; version 2.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
# 02111-1307  USA
# -------------------------------------------------------------------

=pod

=head1 NAME

SQL::Translator::Producer::GraphViz - GraphViz producer for SQL::Translator

=head1 SYNOPSIS

  use SQL::Translator;

  my $trans = new SQL::Translator(
      from => 'MySQL',            # or your db of choice
      to => 'GraphViz',
      producer_args => {
          out_file => 'schema.png',
          add_color => 1,
          show_constraints => 1,
          show_datatypes => 1,
          show_sizes => 1
      }
  ) or die SQL::Translator->error;

  $trans->translate or die $trans->error;

=head1 DESCRIPTION

Creates a graph of a schema using the amazing graphviz
(see http://www.graphviz.org/) application (via
the GraphViz module).  It's nifty--you should try it!

=head1 PRODUCER ARGS

=over 4

=item * out_file

The name of the file where the resulting GraphViz output will be
written. Alternatively an open filehandle can be supplied. If
undefined (the default) - the result is returned as a string.

=item * layout (DEFAULT: 'dot')

determines which layout algorithm GraphViz will use; possible
values are 'dot' (the default GraphViz layout for directed graph
layouts), 'neato' (for undirected graph layouts - spring model)
or 'twopi' (for undirected graph layouts - circular)

=item * node_shape (DEFAULT: 'record')

sets the node shape of each table in the graph; this can be
one of 'record', 'plaintext', 'ellipse', 'circle', 'egg',
'triangle', 'box', 'diamond', 'trapezium', 'parallelogram',
'house', 'hexagon', or 'octagon'

=item * output_type (DEFAULT: 'png')

sets the file type of the output graphic; possible values are
'ps', 'hpgl', 'pcl', 'mif', 'pic', 'gd', 'gd2', 'gif', 'jpeg',
'png', 'wbmp', 'cmap', 'ismap', 'imap', 'vrml', 'vtx', 'mp',
'fig', 'svg', 'canon', 'plain' or 'text' (see GraphViz for
details on each of these)

=item * width (DEFAULT: 8.5)

width (in inches) of the output graphic

=item * height (DEFAULT: 11)

height (in inches) of the output grahic

=item * fontsize

custom font size for node and edge labels (note that arbitrarily large
sizes may be ignored due to page size or graph size constraints)

=item * fontname

custom font name (or full path to font file) for node, edge, and graph
labels

=item * nodeattrs

reference to a hash of node attribute names and their values; these
may override general fontname or fontsize parameter

=item * edgeattrs

reference to a hash of edge attribute names and their values; these
may override general fontname or fontsize parameter

=item * graphattrs

reference to a hash of graph attribute names and their values; these
may override the general fontname parameter

=item * show_fields (DEFAULT: true)

if set to a true value, the names of the colums in a table will
be displayed in each table's node

=item * show_fk_only

if set to a true value, only columns which are foreign keys
will be displayed in each table's node

=item * show_datatypes

if set to a true value, the datatype of each column will be
displayed next to each column's name; this option will have no
effect if the value of show_fields is set to false

=item * show_sizes

if set to a true value, the size (in bytes) of each CHAR and
VARCHAR column will be displayed in parentheses next to the
column's name; this option will have no effect if the value of
show_fields is set to false

=item * show_constraints

if set to a true value, a field's constraints (i.e., its
primary-key-ness, its foreign-key-ness and/or its uniqueness)
will appear as a comma-separated list in brackets next to the
field's name; this option will have no effect if the value of
show_fields is set to false

=item * add_color

if set to a true value, the graphic will have a background
color of 'lightgoldenrodyellow'; otherwise the background
color will be white

=item * natural_join

if set to a true value, the make_natural_join method of
SQL::Translator::Schema will be called before generating the
graph; a true value for join_pk_only (see below) implies a
true value for this option

=item * join_pk_only

the value of this option will be passed as the value of the
like-named argument in the make_natural_join method (see
natural_join above) of SQL::Translator::Schema, if either the
value of this option or the natural_join option is set to true

=item * skip_fields

the value of this option will be passed as the value of the
like-named argument in the make_natural_join method (see
natural_join above) of SQL::Translator::Schema, if either
the natural_join or join_pk_only options has a true value

=item * skip_tables

A comma-separated list of table names that should be skipped.

=item * skip_tables_like

A comma-separated list of regular expressions describing table names
that should be skipped.

=item * show_indexes

if set to a true value, each record will also show the indexes
set on each table. it describes the index types along with
which columns are included in the index. this option requires
that show_fields is a true value as well

=item * show_index_names

if show_indexes is set to a true value, then the value of this
parameter determines whether or not to print names of indexes.
if show_index_names is false, then a list of indexed columns
will appear below the field list. otherwise, it will be a list
prefixed with the name of each index. it defaults to true.

=item * friendly_ints

if set to a true value, each integer type field will be displayed
as a smallint, integer or bigint depending on the field's
associated size parameter. this only applies for the 'integer'
type (and not the lowercase 'int' type, which is assumed to be a
32-bit integer).

=item * friendly_ints_extended

if set to a true value, the friendly ints displayed will take into
account the non-standard types, 'tinyint' and 'mediumint' (which,
as far as I am aware, is only implemented in MySQL)

=back

=cut

use strict;
use GraphViz;
use SQL::Translator::Schema::Constants;
use SQL::Translator::Utils qw(debug);
use Scalar::Util qw/openhandle/;

use vars qw[ $VERSION $DEBUG ];
$VERSION = '1.59';
$DEBUG   = 0 unless defined $DEBUG;

use constant VALID_LAYOUT => {
    dot   => 1, 
    neato => 1, 
    twopi => 1,
};

use constant VALID_NODE_SHAPE => {
    record        => 1, 
    plaintext     => 1, 
    ellipse       => 1, 
    circle        => 1, 
    egg           => 1, 
    triangle      => 1, 
    box           => 1, 
    diamond       => 1, 
    trapezium     => 1, 
    parallelogram => 1, 
    house         => 1, 
    hexagon       => 1, 
    octagon       => 1, 
};

sub produce {
    my $t          = shift;
    my $schema     = $t->schema;
    my $args       = $t->producer_args;
    local $DEBUG   = $t->debug;

    my $out_file         = $args->{'out_file'}    || '';
    my $layout           = $args->{'layout'}      || 'dot';
    my $node_shape       = $args->{'node_shape'}  || 'record';
    my $output_type      = $args->{'output_type'} || 'png';
    my $width            = defined $args->{'width'} 
                           ? $args->{'width'} : 8.5;
    my $height           = defined $args->{'height'}
                           ? $args->{'height'} : 11;
    my $fontsize         = $args->{'fontsize'};
    my $fontname         = $args->{'fontname'};
    my $edgeattrs        = $args->{'edgeattrs'} || {};
    my $graphattrs       = $args->{'graphattrs'} || {};
    my $nodeattrs        = $args->{'nodeattrs'} || {};
    my $show_fields      = defined $args->{'show_fields'} 
                           ? $args->{'show_fields'} : 1;
    my $add_color        = $args->{'add_color'};
    my $natural_join     = $args->{'natural_join'};
    my $show_fk_only     = $args->{'show_fk_only'};
    my $show_datatypes   = $args->{'show_datatypes'};
    my $show_sizes       = $args->{'show_sizes'};
    my $show_indexes     = $args->{'show_indexes'};
    my $show_index_names = defined $args->{'show_index_names'} 
                         ? $args->{'show_index_names'} : 1;
    my $friendly_ints    = $args->{'friendly_ints'};
    my $friendly_ints_ex = $args->{'friendly_ints_extended'};
    my $show_constraints = $args->{'show_constraints'};
    my $join_pk_only     = $args->{'join_pk_only'};
    my $skip_fields      = $args->{'skip_fields'}      || '';
    my $skip_tables      = $args->{'skip_tables'}      || '';
    my $skip_tables_like = $args->{'skip_tables_like'} || '';
    my %skip             = map { s/^\s+|\s+$//g; length $_ ? ($_, 1) : () }
                           split ( /,/, $skip_fields );
    $natural_join      ||= $join_pk_only;

    $schema->make_natural_joins(
        join_pk_only => $join_pk_only,
        skip_fields  => $args->{'skip_fields'},
    ) if $natural_join;

    die "Invalid layout '$layout'" unless VALID_LAYOUT->{ $layout };
    die "Invalid node shape'$node_shape'" 
        unless VALID_NODE_SHAPE->{ $node_shape };

    for ( $height, $width ) {
        $_ = 0 unless $_ =~ /^\d+(.\d)?$/;
        $_ = 0 if $_ < 0;
    }

    my %args = (
        directed      => $natural_join ? 0 : 1,
        layout        => $layout,
        no_overlap    => 1,
        bgcolor       => $add_color ? 'lightgoldenrodyellow' : 'white',
        node          => { 
            shape     => $node_shape, 
            style     => 'filled', 
            fillcolor => 'white',
        },
    );
    $args{'width'}  = $width  if $width;
    $args{'height'} = $height if $height;
    # set fontsize for edge and node labels if specified
    if ($fontsize) {
        $args{'node'}->{'fontsize'} = $fontsize;
        $args{'edge'} = {} unless $args{'edge'};
        $args{'edge'}->{'fontsize'} = $fontsize;        
    }
    # set the font name globally for node, edge, and graph labels if
    # specified (use node, edge, or graph attributes for individual
    # font specification)
    if ($fontname) {
        $args{'node'}->{'fontname'} = $fontname;
        $args{'edge'} = {} unless $args{'edge'};
        $args{'edge'}->{'fontname'} = $fontname;        
        $args{'graph'} = {} unless $args{'graph'};
        $args{'graph'}->{'fontname'} = $fontname;        
    }
    # set additional node, edge, and graph attributes; these may
    # possibly override ones set before
    while (my ($key,$val) = each %$nodeattrs) {
        $args{'node'}->{$key} = $val;
    }
    $args{'edge'} = {} if %$edgeattrs && !$args{'edge'};
    while (my ($key,$val) = each %$edgeattrs) {
        $args{'edge'}->{$key} = $val;
    }
    $args{'graph'} = {} if %$edgeattrs && !$args{'graph'};
    while (my ($key,$val) = each %$graphattrs) {
        $args{'graph'}->{$key} = $val;
    }

    #
    # Create a blank GraphViz object and see if we can produce the output type.
    #
    my $gv = GraphViz->new( %args ) or die "Can't create GraphViz object\n";
    my $output_method = "as_$output_type";

    # the generators are AUTOLOADed so can't use ->can ($output_method) 
    eval { $gv->$output_method };
    die "Invalid output type: '$output_type'" if $@;

    my %skip_table       = map { $_, 1 }  split /\s*,\s*/, $skip_tables;
    my @skip_tables_like = map { qr/$_/ } split /\s*,\s*/, $skip_tables_like;
    my %nj_registry; # for locations of fields for natural joins
    my @fk_registry; # for locations of fields for foreign keys

    TABLE:
    for my $table ( $schema->get_tables ) {
        my $tname = $table->name;

        if ( %skip_table ) {
            next TABLE if $skip_table{ $tname };

            for my $regex ( @skip_tables_like ) {
                next TABLE if $tname =~ $regex;
            }
        }

        my @fields     = $table->get_fields;
        if ( $show_fk_only ) {
            @fields = grep { $_->is_foreign_key } @fields;
        }

        my $field_str = '';
        if ( $show_fields ) {
            my @fmt_fields;
            for my $field ( @fields ) {
                my $field_type;
                if ($show_datatypes) {
                    $field_type = $field->data_type;

                    # For the integer type, transform into different
                    # types based on requested size, if a size is given.
                    if (    $field->size
                        and $friendly_ints
                        and ( lc $field_type ) eq 'integer' 
                    ) {
                        # Automatically translate to int2, int4, int8
                        # Type (Bits)     Max. Signed/Unsigned    Length
                        # tinyint* (8)    128                     3
                        #                 255                     3
                        # smallint (16)   32767                   5
                        #                 65535                   5
                        # mediumint* (24) 8388607                 7
                        #                 16777215                8
                        # int (32)        2147483647              10
                        #                 4294967295              11
                        # bigint (64)     9223372036854775807     19
                        #                 18446744073709551615    20
                        #
                        # * tinyint and mediumint are nonstandard extensions 
                        # which are only available under MySQL (to my knowledge)
                        my $size = $field->size;
                        if ( $size <= 3 and $friendly_ints_ex ) {
                            $field_type = 'tinyint',;
                        }
                        elsif ( $size <= 5 ) {
                            $field_type = 'smallint';
                        }
                        elsif ( $size <= 8 and $friendly_ints_ex ) {
                            $field_type = 'mediumint';
                        }
                        elsif ( $size <= 11 ) {
                            $field_type = 'integer';
                        }
                        else {
                            $field_type = 'bigint';
                        }
                    }

                    if (
                            $show_sizes
                        and $field->size
                        and (  $field_type =~ /^(var)?char2?$/
                            or $field_type eq 'numeric'
                            or $field_type eq 'decimal' )
                    ) {
                        $field_type .= '(' . $field->size . ')';
                    }
                }

                my $constraints;
                if ( $show_constraints ) {
                    my @constraints;

                    push( @constraints, 'PK' ) if $field->is_primary_key;
                    push( @constraints, 'FK' ) if $field->is_foreign_key;
                    push( @constraints, 'U' )  if $field->is_unique;

                    $constraints = join( ',', @constraints );
                }

                # construct the field line from all info gathered so far
                push @fmt_fields, join( ' ',
                    '-', $field->name,
                    $field_type || (),
                    $constraints ? "[$constraints]" : (),
                );
            }

            # join field lines with graphviz formatting
            $field_str = join( '\l', @fmt_fields ) . '\l';
        }

        my $index_str = '';
        if ($show_indexes) {
            my @fmt_indexes;
            for my $index ( $table->get_indices ) {
                next unless $index->is_valid;

                push @fmt_indexes, join( ' ',
                    '*',
                    $show_index_names ? $index->name . ':' : (),
                    join( ', ', $index->fields ),
                    ( $index->type eq 'UNIQUE' ) ? '[U]' : (),
                );
            }

            # join index lines with graphviz formatting (if any indexes at all)
            $index_str = join( '\l', @fmt_indexes ) . '\l' if @fmt_indexes;
        }

        my $table_name = $table->name;
        my $name_str = $table_name . '\n';

        # escape spaces
        for ($name_str, $field_str, $index_str) {
            $_ =~ s/ /\\ /g;
        }


        # only the 'record' type supports nice formatting
        if ( $node_shape eq 'record' ) {
            # the necessity to supply shape => 'record' is a graphviz bug
            $gv->add_node( $table_name,
                shape => 'record',
                label => sprintf( '{%s}',
                    join( '|', $name_str, $field_str || (), $index_str || (), ),
                ),
            );
        }
        else {
            my $sep = sprintf ('%s\n',
                '-' x ( (length $table_name) + 2)
            );

            $gv->add_node( $table_name,
                label => join ($sep,
                    $name_str,
                    $field_str || (),
                    $index_str || (),
                ),
            );
        }

        debug("Processing table '$table_name'");

        debug("Fields = ", join(', ', map { $_->name } @fields));

        for my $f ( @fields ) {
            my $name      = $f->name or next;
            my $is_pk     = $f->is_primary_key;
            my $is_unique = $f->is_unique;

            #
            # Decide if we should skip this field.
            #
            if ( $natural_join ) {
                next unless $is_pk || $f->is_foreign_key;
            }

            my $constraints = $f->{'constraints'};

            if ( $natural_join && !$skip{ $name } ) {
                push @{ $nj_registry{ $name } }, $table_name;
            }
        }

        unless ( $natural_join ) {
            for my $c ( $table->get_constraints ) {
                next unless $c->type eq FOREIGN_KEY;
                my $fk_table = $c->reference_table or next;

                for my $field_name ( $c->fields ) {
                    for my $fk_field ( $c->reference_fields ) {
                        next unless defined $schema->get_table( $fk_table );
                        push @fk_registry, [ $table_name, $fk_table ];
                    }
                }
            }
        }
    }

    #
    # Make the connections.
    #
    my @table_bunches;
    if ( $natural_join ) {
        for my $field_name ( keys %nj_registry ) {
            my @table_names = @{ $nj_registry{ $field_name } || [] } or next;
            next if scalar @table_names == 1;
            push @table_bunches, [ @table_names ];
        }
    }
    else {
        @table_bunches = @fk_registry;
    }

    my %done;
    for my $bunch ( @table_bunches ) {
        my @tables = @$bunch;

        for my $i ( 0 .. $#tables ) {
            my $table1 = $tables[ $i ];
            for my $j ( 0 .. $#tables ) {
                next if $i == $j;
                my $table2 = $tables[ $j ];
                next if $done{ $table1 }{ $table2 };
                $gv->add_edge( $table2, $table1 );
                $done{ $table1 }{ $table2 } = 1;
                $done{ $table2 }{ $table1 } = 1;
            }
        }
    }

    #
    # Print the image.
    #
    if ( $out_file ) {
        if ( openhandle( $out_file ) ) {
            print $out_file $gv->$output_method;
        }
        else {
            open my $fh, ">$out_file" or die "Can't write '$out_file': $!\n";
            binmode $fh;
            print $fh $gv->$output_method;
            close $fh;
        }
    }
    else {
        return $gv->$output_method;
    }
}

1;

# -------------------------------------------------------------------

=pod

=head1 AUTHOR

Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>,
Jonathan Yu E<lt>frequency@cpan.orgE<gt>

=head1 SEE ALSO

SQL::Translator, GraphViz.

=cut
Commit	Line	Data
14d7eb56	1	package SQL::Translator::Producer::GraphViz;
	2
	3	# -------------------------------------------------------------------
6264cdc8	4	# Copyright (C) 2002-2009 SQLFairy Authors
14d7eb56	5	#
	6	# This program is free software; you can redistribute it and/or
	7	# modify it under the terms of the GNU General Public License as
	8	# published by the Free Software Foundation; version 2.
	9	#
	10	# This program is distributed in the hope that it will be useful, but
	11	# WITHOUT ANY WARRANTY; without even the implied warranty of
	12	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
	13	# General Public License for more details.
	14	#
	15	# You should have received a copy of the GNU General Public License
	16	# along with this program; if not, write to the Free Software
	17	# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
	18	# 02111-1307 USA
	19	# -------------------------------------------------------------------
	20
d491c962	21	=pod
	22
	23	=head1 NAME
	24
	25	SQL::Translator::Producer::GraphViz - GraphViz producer for SQL::Translator
	26
	27	=head1 SYNOPSIS
	28
	29	use SQL::Translator;
	30
	31	my $trans = new SQL::Translator(
	32	from => 'MySQL', # or your db of choice
	33	to => 'GraphViz',
	34	producer_args => {
	35	out_file => 'schema.png',
	36	add_color => 1,
	37	show_constraints => 1,
	38	show_datatypes => 1,
9d93edab	39	show_sizes => 1
d491c962	40	}
	41	) or die SQL::Translator->error;
	42
	43	$trans->translate or die $trans->error;
	44
	45	=head1 DESCRIPTION
	46
	47	Creates a graph of a schema using the amazing graphviz
	48	(see http://www.graphviz.org/) application (via
	49	the GraphViz module). It's nifty--you should try it!
	50
	51	=head1 PRODUCER ARGS
	52
	53	=over 4
	54
	55	=item * out_file
	56
d8324f08	57	The name of the file where the resulting GraphViz output will be
	58	written. Alternatively an open filehandle can be supplied. If
	59	undefined (the default) - the result is returned as a string.
d491c962	60
	61	=item * layout (DEFAULT: 'dot')
	62
	63	determines which layout algorithm GraphViz will use; possible
	64	values are 'dot' (the default GraphViz layout for directed graph
	65	layouts), 'neato' (for undirected graph layouts - spring model)
	66	or 'twopi' (for undirected graph layouts - circular)
	67
	68	=item * node_shape (DEFAULT: 'record')
	69
	70	sets the node shape of each table in the graph; this can be
	71	one of 'record', 'plaintext', 'ellipse', 'circle', 'egg',
	72	'triangle', 'box', 'diamond', 'trapezium', 'parallelogram',
	73	'house', 'hexagon', or 'octagon'
	74
	75	=item * output_type (DEFAULT: 'png')
	76
	77	sets the file type of the output graphic; possible values are
	78	'ps', 'hpgl', 'pcl', 'mif', 'pic', 'gd', 'gd2', 'gif', 'jpeg',
	79	'png', 'wbmp', 'cmap', 'ismap', 'imap', 'vrml', 'vtx', 'mp',
	80	'fig', 'svg', 'canon', 'plain' or 'text' (see GraphViz for
	81	details on each of these)
	82
	83	=item * width (DEFAULT: 8.5)
	84
	85	width (in inches) of the output graphic
	86
	87	=item * height (DEFAULT: 11)
	88
	89	height (in inches) of the output grahic
	90
027cebc7	91	=item * fontsize
	92
	93	custom font size for node and edge labels (note that arbitrarily large
	94	sizes may be ignored due to page size or graph size constraints)
	95
9d93edab	96	=item * fontname
027cebc7	97
	98	custom font name (or full path to font file) for node, edge, and graph
	99	labels
	100
9d93edab	101	=item * nodeattrs
027cebc7	102
	103	reference to a hash of node attribute names and their values; these
	104	may override general fontname or fontsize parameter
	105
9d93edab	106	=item * edgeattrs
027cebc7	107
	108	reference to a hash of edge attribute names and their values; these
	109	may override general fontname or fontsize parameter
	110
9d93edab	111	=item * graphattrs
027cebc7	112
	113	reference to a hash of graph attribute names and their values; these
	114	may override the general fontname parameter
	115
d491c962	116	=item * show_fields (DEFAULT: true)
	117
	118	if set to a true value, the names of the colums in a table will
	119	be displayed in each table's node
	120
	121	=item * show_fk_only
	122
	123	if set to a true value, only columns which are foreign keys
	124	will be displayed in each table's node
	125
	126	=item * show_datatypes
	127
	128	if set to a true value, the datatype of each column will be
	129	displayed next to each column's name; this option will have no
	130	effect if the value of show_fields is set to false
	131
9d93edab	132	=item * show_sizes
d491c962	133
	134	if set to a true value, the size (in bytes) of each CHAR and
	135	VARCHAR column will be displayed in parentheses next to the
	136	column's name; this option will have no effect if the value of
	137	show_fields is set to false
	138
	139	=item * show_constraints
	140
	141	if set to a true value, a field's constraints (i.e., its
	142	primary-key-ness, its foreign-key-ness and/or its uniqueness)
	143	will appear as a comma-separated list in brackets next to the
	144	field's name; this option will have no effect if the value of
	145	show_fields is set to false
	146
	147	=item * add_color
	148
	149	if set to a true value, the graphic will have a background
	150	color of 'lightgoldenrodyellow'; otherwise the background
	151	color will be white
	152
	153	=item * natural_join
	154
	155	if set to a true value, the make_natural_join method of
	156	SQL::Translator::Schema will be called before generating the
	157	graph; a true value for join_pk_only (see below) implies a
	158	true value for this option
	159
	160	=item * join_pk_only
	161
	162	the value of this option will be passed as the value of the
	163	like-named argument in the make_natural_join method (see
	164	natural_join above) of SQL::Translator::Schema, if either the
	165	value of this option or the natural_join option is set to true
	166
	167	=item * skip_fields
	168
	169	the value of this option will be passed as the value of the
	170	like-named argument in the make_natural_join method (see
	171	natural_join above) of SQL::Translator::Schema, if either
	172	the natural_join or join_pk_only options has a true value
	173
44435b87	174	=item * skip_tables
44435b87	175
818e0d98	176	A comma-separated list of table names that should be skipped.
	177
	178	=item * skip_tables_like
	179
	180	A comma-separated list of regular expressions describing table names
	181	that should be skipped.
44435b87	182
b7478526	183	=item * show_indexes
	184
	185	if set to a true value, each record will also show the indexes
	186	set on each table. it describes the index types along with
	187	which columns are included in the index. this option requires
	188	that show_fields is a true value as well
	189
4d5d28cb	190	=item * show_index_names
d6d6b205	191
	192	if show_indexes is set to a true value, then the value of this
	193	parameter determines whether or not to print names of indexes.
d8324f08	194	if show_index_names is false, then a list of indexed columns
d6d6b205	195	will appear below the field list. otherwise, it will be a list
	196	prefixed with the name of each index. it defaults to true.
	197
b7478526	198	=item * friendly_ints
	199
	200	if set to a true value, each integer type field will be displayed
d44b5f54	201	as a smallint, integer or bigint depending on the field's
b7478526	202	associated size parameter. this only applies for the 'integer'
	203	type (and not the lowercase 'int' type, which is assumed to be a
	204	32-bit integer).
	205
d44b5f54	206	=item * friendly_ints_extended
	207
	208	if set to a true value, the friendly ints displayed will take into
	209	account the non-standard types, 'tinyint' and 'mediumint' (which,
	210	as far as I am aware, is only implemented in MySQL)
	211
d491c962	212	=back
	213
	214	=cut
	215
14d7eb56	216	use strict;
14d7eb56	217	use GraphViz;
997f14b2	218	use SQL::Translator::Schema::Constants;
14d7eb56	219	use SQL::Translator::Utils qw(debug);
d8324f08	220	use Scalar::Util qw/openhandle/;
14d7eb56	221
14d7eb56	222	use vars qw[ $VERSION $DEBUG ];
4ab3763d	223	$VERSION = '1.59';
14d7eb56	224	$DEBUG = 0 unless defined $DEBUG;
	225
	226	use constant VALID_LAYOUT => {
	227	dot => 1,
	228	neato => 1,
	229	twopi => 1,
	230	};
	231
	232	use constant VALID_NODE_SHAPE => {
	233	record => 1,
	234	plaintext => 1,
	235	ellipse => 1,
	236	circle => 1,
	237	egg => 1,
	238	triangle => 1,
	239	box => 1,
	240	diamond => 1,
	241	trapezium => 1,
	242	parallelogram => 1,
	243	house => 1,
	244	hexagon => 1,
	245	octagon => 1,
	246	};
	247
14d7eb56	248	sub produce {
997f14b2	249	my $t = shift;
997f14b2	250	my $schema = $t->schema;
14d7eb56	251	my $args = $t->producer_args;
14d7eb56	252	local $DEBUG = $t->debug;
14d7eb56	253
59cbb03f	254	my $out_file = $args->{'out_file'} \|\| '';
	255	my $layout = $args->{'layout'} \|\| 'dot';
	256	my $node_shape = $args->{'node_shape'} \|\| 'record';
	257	my $output_type = $args->{'output_type'} \|\| 'png';
	258	my $width = defined $args->{'width'}
	259	? $args->{'width'} : 8.5;
	260	my $height = defined $args->{'height'}
	261	? $args->{'height'} : 11;
027cebc7	262	my $fontsize = $args->{'fontsize'};
	263	my $fontname = $args->{'fontname'};
	264	my $edgeattrs = $args->{'edgeattrs'} \|\| {};
	265	my $graphattrs = $args->{'graphattrs'} \|\| {};
	266	my $nodeattrs = $args->{'nodeattrs'} \|\| {};
59cbb03f	267	my $show_fields = defined $args->{'show_fields'}
	268	? $args->{'show_fields'} : 1;
	269	my $add_color = $args->{'add_color'};
	270	my $natural_join = $args->{'natural_join'};
	271	my $show_fk_only = $args->{'show_fk_only'};
	272	my $show_datatypes = $args->{'show_datatypes'};
	273	my $show_sizes = $args->{'show_sizes'};
b7478526	274	my $show_indexes = $args->{'show_indexes'};
818e0d98	275	my $show_index_names = defined $args->{'show_index_names'}
818e0d98	276	? $args->{'show_index_names'} : 1;
b7478526	277	my $friendly_ints = $args->{'friendly_ints'};
d44b5f54	278	my $friendly_ints_ex = $args->{'friendly_ints_extended'};
37ce746e	279	my $show_constraints = $args->{'show_constraints'};
59cbb03f	280	my $join_pk_only = $args->{'join_pk_only'};
818e0d98	281	my $skip_fields = $args->{'skip_fields'} \|\| '';
	282	my $skip_tables = $args->{'skip_tables'} \|\| '';
	283	my $skip_tables_like = $args->{'skip_tables_like'} \|\| '';
9d93edab	284	my %skip = map { s/^\s+\|\s+$//g; length $_ ? ($_, 1) : () }
59cbb03f	285	split ( /,/, $skip_fields );
59cbb03f	286	$natural_join \|\|= $join_pk_only;
14d7eb56	287
997f14b2	288	$schema->make_natural_joins(
	289	join_pk_only => $join_pk_only,
	290	skip_fields => $args->{'skip_fields'},
	291	) if $natural_join;
	292
14d7eb56	293	die "Invalid layout '$layout'" unless VALID_LAYOUT->{ $layout };
14d7eb56	294	die "Invalid node shape'$node_shape'"
	295	unless VALID_NODE_SHAPE->{ $node_shape };
	296
e36752ea	297	for ( $height, $width ) {
	298	$_ = 0 unless $_ =~ /^\d+(.\d)?$/;
	299	$_ = 0 if $_ < 0;
	300	}
	301
e36752ea	302	my %args = (
14d7eb56	303	directed => $natural_join ? 0 : 1,
	304	layout => $layout,
	305	no_overlap => 1,
	306	bgcolor => $add_color ? 'lightgoldenrodyellow' : 'white',
	307	node => {
	308	shape => $node_shape,
	309	style => 'filled',
027cebc7	310	fillcolor => 'white',
027cebc7	311	},
e36752ea	312	);
	313	$args{'width'} = $width if $width;
	314	$args{'height'} = $height if $height;
027cebc7	315	# set fontsize for edge and node labels if specified
	316	if ($fontsize) {
	317	$args{'node'}->{'fontsize'} = $fontsize;
	318	$args{'edge'} = {} unless $args{'edge'};
	319	$args{'edge'}->{'fontsize'} = $fontsize;
	320	}
	321	# set the font name globally for node, edge, and graph labels if
	322	# specified (use node, edge, or graph attributes for individual
	323	# font specification)
	324	if ($fontname) {
	325	$args{'node'}->{'fontname'} = $fontname;
	326	$args{'edge'} = {} unless $args{'edge'};
	327	$args{'edge'}->{'fontname'} = $fontname;
	328	$args{'graph'} = {} unless $args{'graph'};
	329	$args{'graph'}->{'fontname'} = $fontname;
	330	}
	331	# set additional node, edge, and graph attributes; these may
	332	# possibly override ones set before
	333	while (my ($key,$val) = each %$nodeattrs) {
	334	$args{'node'}->{$key} = $val;
	335	}
	336	$args{'edge'} = {} if %$edgeattrs && !$args{'edge'};
	337	while (my ($key,$val) = each %$edgeattrs) {
	338	$args{'edge'}->{$key} = $val;
	339	}
	340	$args{'graph'} = {} if %$edgeattrs && !$args{'graph'};
	341	while (my ($key,$val) = each %$graphattrs) {
	342	$args{'graph'}->{$key} = $val;
	343	}
e36752ea	344
d8324f08	345	#
	346	# Create a blank GraphViz object and see if we can produce the output type.
	347	#
	348	my $gv = GraphViz->new( %args ) or die "Can't create GraphViz object\n";
	349	my $output_method = "as_$output_type";
	350
	351	# the generators are AUTOLOADed so can't use ->can ($output_method)
	352	eval { $gv->$output_method };
	353	die "Invalid output type: '$output_type'" if $@;
	354
818e0d98	355	my %skip_table = map { $_, 1 } split /\s,\s/, $skip_tables;
818e0d98	356	my @skip_tables_like = map { qr/$_/ } split /\s,\s/, $skip_tables_like;
14d7eb56	357	my %nj_registry; # for locations of fields for natural joins
	358	my @fk_registry; # for locations of fields for foreign keys
	359
44435b87	360	TABLE:
997f14b2	361	for my $table ( $schema->get_tables ) {
44435b87	362	my $tname = $table->name;
	363
	364	if ( %skip_table ) {
	365	next TABLE if $skip_table{ $tname };
	366
818e0d98	367	for my $regex ( @skip_tables_like ) {
818e0d98	368	next TABLE if $tname =~ $regex;
44435b87	369	}
	370	}
	371
997f14b2	372	my @fields = $table->get_fields;
	373	if ( $show_fk_only ) {
	374	@fields = grep { $_->is_foreign_key } @fields;
14d7eb56	375	}
14d7eb56	376
6264cdc8	377	my $field_str = '';
818e0d98	378	if ( $show_fields ) {
	379	my @fmt_fields;
	380	for my $field ( @fields ) {
	381	my $field_type;
	382	if ($show_datatypes) {
	383	$field_type = $field->data_type;
	384
	385	# For the integer type, transform into different
	386	# types based on requested size, if a size is given.
	387	if ( $field->size
	388	and $friendly_ints
	389	and ( lc $field_type ) eq 'integer'
	390	) {
	391	# Automatically translate to int2, int4, int8
	392	# Type (Bits) Max. Signed/Unsigned Length
	393	# tinyint* (8) 128 3
	394	# 255 3
	395	# smallint (16) 32767 5
	396	# 65535 5
	397	# mediumint* (24) 8388607 7
	398	# 16777215 8
	399	# int (32) 2147483647 10
	400	# 4294967295 11
	401	# bigint (64) 9223372036854775807 19
	402	# 18446744073709551615 20
	403	#
	404	# * tinyint and mediumint are nonstandard extensions
	405	# which are only available under MySQL (to my knowledge)
	406	my $size = $field->size;
	407	if ( $size <= 3 and $friendly_ints_ex ) {
	408	$field_type = 'tinyint',;
	409	}
	410	elsif ( $size <= 5 ) {
	411	$field_type = 'smallint';
	412	}
	413	elsif ( $size <= 8 and $friendly_ints_ex ) {
	414	$field_type = 'mediumint';
	415	}
	416	elsif ( $size <= 11 ) {
	417	$field_type = 'integer';
	418	}
	419	else {
	420	$field_type = 'bigint';
	421	}
	422	}
	423
	424	if (
	425	$show_sizes
	426	and $field->size
	427	and ( $field_type =~ /^(var)?char2?$/
	428	or $field_type eq 'numeric'
	429	or $field_type eq 'decimal' )
	430	) {
	431	$field_type .= '(' . $field->size . ')';
	432	}
b7478526	433	}
b7478526	434
818e0d98	435	my $constraints;
	436	if ( $show_constraints ) {
	437	my @constraints;
6264cdc8	438
818e0d98	439	push( @constraints, 'PK' ) if $field->is_primary_key;
	440	push( @constraints, 'FK' ) if $field->is_foreign_key;
	441	push( @constraints, 'U' ) if $field->is_unique;
6264cdc8	442
818e0d98	443	$constraints = join( ',', @constraints );
818e0d98	444	}
6264cdc8	445
818e0d98	446	# construct the field line from all info gathered so far
	447	push @fmt_fields, join( ' ',
	448	'-', $field->name,
	449	$field_type \|\| (),
	450	$constraints ? "[$constraints]" : (),
	451	);
	452	}
6264cdc8	453
818e0d98	454	# join field lines with graphviz formatting
818e0d98	455	$field_str = join( '\l', @fmt_fields ) . '\l';
b7478526	456	}
b7478526	457
6264cdc8	458	my $index_str = '';
b7478526	459	if ($show_indexes) {
818e0d98	460	my @fmt_indexes;
	461	for my $index ( $table->get_indices ) {
	462	next unless $index->is_valid;
	463
	464	push @fmt_indexes, join( ' ',
	465	'*',
	466	$show_index_names ? $index->name . ':' : (),
	467	join( ', ', $index->fields ),
	468	( $index->type eq 'UNIQUE' ) ? '[U]' : (),
	469	);
	470	}
6264cdc8	471
818e0d98	472	# join index lines with graphviz formatting (if any indexes at all)
818e0d98	473	$index_str = join( '\l', @fmt_indexes ) . '\l' if @fmt_indexes;
6264cdc8	474	}
	475
	476	my $table_name = $table->name;
	477	my $name_str = $table_name . '\n';
	478
	479	# escape spaces
	480	for ($name_str, $field_str, $index_str) {
818e0d98	481	$_ =~ s/ /\\ /g;
b7478526	482	}
6264cdc8	483
	484
	485	# only the 'record' type supports nice formatting
818e0d98	486	if ( $node_shape eq 'record' ) {
818e0d98	487	# the necessity to supply shape => 'record' is a graphviz bug
6264cdc8	488	$gv->add_node( $table_name,
818e0d98	489	shape => 'record',
	490	label => sprintf( '{%s}',
	491	join( '\|', $name_str, $field_str \|\| (), $index_str \|\| (), ),
6264cdc8	492	),
6264cdc8	493	);
	494	}
	495	else {
	496	my $sep = sprintf ('%s\n',
	497	'-' x ( (length $table_name) + 2)
	498	);
	499
	500	$gv->add_node( $table_name,
	501	label => join ($sep,
	502	$name_str,
	503	$field_str \|\| (),
	504	$index_str \|\| (),
	505	),
	506	);
	507	}
	508
e36752ea	509	debug("Processing table '$table_name'");
e36752ea	510
997f14b2	511	debug("Fields = ", join(', ', map { $_->name } @fields));
14d7eb56	512
14d7eb56	513	for my $f ( @fields ) {
997f14b2	514	my $name = $f->name or next;
	515	my $is_pk = $f->is_primary_key;
	516	my $is_unique = $f->is_unique;
14d7eb56	517
	518	#
	519	# Decide if we should skip this field.
	520	#
	521	if ( $natural_join ) {
997f14b2	522	next unless $is_pk \|\| $f->is_foreign_key;
14d7eb56	523	}
	524
	525	my $constraints = $f->{'constraints'};
	526
	527	if ( $natural_join && !$skip{ $name } ) {
	528	push @{ $nj_registry{ $name } }, $table_name;
	529	}
997f14b2	530	}
	531
	532	unless ( $natural_join ) {
	533	for my $c ( $table->get_constraints ) {
	534	next unless $c->type eq FOREIGN_KEY;
	535	my $fk_table = $c->reference_table or next;
	536
	537	for my $field_name ( $c->fields ) {
	538	for my $fk_field ( $c->reference_fields ) {
	539	next unless defined $schema->get_table( $fk_table );
14d7eb56	540	push @fk_registry, [ $table_name, $fk_table ];
	541	}
	542	}
	543	}
	544	}
	545	}
	546
	547	#
	548	# Make the connections.
	549	#
	550	my @table_bunches;
	551	if ( $natural_join ) {
	552	for my $field_name ( keys %nj_registry ) {
	553	my @table_names = @{ $nj_registry{ $field_name } \|\| [] } or next;
	554	next if scalar @table_names == 1;
	555	push @table_bunches, [ @table_names ];
	556	}
	557	}
	558	else {
	559	@table_bunches = @fk_registry;
	560	}
	561
	562	my %done;
	563	for my $bunch ( @table_bunches ) {
	564	my @tables = @$bunch;
	565
	566	for my $i ( 0 .. $#tables ) {
	567	my $table1 = $tables[ $i ];
	568	for my $j ( 0 .. $#tables ) {
d51a158e	569	next if $i == $j;
14d7eb56	570	my $table2 = $tables[ $j ];
14d7eb56	571	next if $done{ $table1 }{ $table2 };
13811af0	572	$gv->add_edge( $table2, $table1 );
14d7eb56	573	$done{ $table1 }{ $table2 } = 1;
	574	$done{ $table2 }{ $table1 } = 1;
	575	}
	576	}
	577	}
	578
	579	#
	580	# Print the image.
	581	#
14d7eb56	582	if ( $out_file ) {
818e0d98	583	if ( openhandle( $out_file ) ) {
	584	print $out_file $gv->$output_method;
	585	}
	586	else {
	587	open my $fh, ">$out_file" or die "Can't write '$out_file': $!\n";
	588	binmode $fh;
	589	print $fh $gv->$output_method;
	590	close $fh;
	591	}
14d7eb56	592	}
14d7eb56	593	else {
818e0d98	594	return $gv->$output_method;
14d7eb56	595	}
	596	}
	597
	598	1;
	599
977651a5	600	# -------------------------------------------------------------------
977651a5	601
14d7eb56	602	=pod
14d7eb56	603
14d7eb56	604	=head1 AUTHOR
14d7eb56	605
818e0d98	606	Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>,
d44b5f54	607	Jonathan Yu E<lt>frequency@cpan.orgE<gt>
d44b5f54	608
d491c962	609	=head1 SEE ALSO
d491c962	610
818e0d98	611	SQL::Translator, GraphViz.
d491c962	612
14d7eb56	613	=cut