redispatch /-foo/ style static URLs

[scpubgit/SCS.git] / lib / SCSite / FeedGenerator.pm

package SCSite::FeedGenerator;

use Moo;
no warnings 'once';

has id_prefix => (is => 'ro', required => 1);
has pages => (is => 'ro', required => 1);

sub feed_http_response {
  my ($self, $code, $feed_config) = @_;
  $self->_feed_response(
    $code, $self->_config_to_data($feed_config)
  );
}

sub _config_to_data {
  my ($self, $config) = @_;
  my $base_page = $self->pages->get({ path => $config->{base} });
  my @entry_pages = $base_page->children(%{$config->{entries}})
                              ->latest(10)->flatten;
  my $updated = (sort map $_->created, @entry_pages)[-1];
  +{
     %$config,
     id => $self->_id_for($base_page->path),
     web_url => $base_page->path.'/',
     feed_url => "/feed/${\$config->{base}}/",
     updated => join('T', split(' ',$updated)).'Z',
     entries => [ map +{
       title => $_->title,
       summary_html => do {
         use HTML::Tags;
         join '', HTML::Tags::to_html_string(<p>, $_->description, </p>)
       },
       content_html => $_->body,
       created => join('T', split(' ',$_->created)).'Z',
       web_url => $_->path,
     }, @entry_pages ],
  }
}

sub _id_for {
  my ($self, $for) = @_;
  join '', $self->id_prefix, $for;
}

sub _feed_response {
  my ($self, $code, $data) = @_;
  [ $code,
    [ 'Content-type' => 'application/atom+xml' ],
    [ $self->_feed_string($data) ]
  ]
}

sub _feed_string {
  my ($self, $data) = @_;
  XML::Tags::to_xml_string(
    $self->_feed_data_to_tags($data)
  );
}

sub _feed_data_to_tags {
  my ($self, $data) = @_;
  use XML::Tags qw(
    feed title subtitle link id
  );
  my ($web_url, $feed_url) = @{$data}{qw(web_url feed_url)};
  (\'<?xml version="1.0" encoding="UTF-8"?>', "\n",
  <feed xmlns="http://www.w3.org/2005/Atom">, "\n",
    '  ', <title type="text">, $data->{title}, </title>, "\n",
    ($data->{subtitle}
      ? ('  ', <subtitle type="text">, $data->{subtitle}, </subtitle>, "\n",)
      : ()),
    '  ', <link rel="alternate" type="text/html" href="${web_url}" />, "\n",
    '  ', <link rel="self" type="application/atom+xml" href="${feed_url}" />, "\n",
    '  ', <updated>, $data->{updated}, </updated>, "\n",
    '  ', <id>, $data->{id}, </id>, "\n",
    (map $self->_entry_data_to_tags($_), @{$data->{entries}}),
  </feed>);
}

sub _entry_data_to_tags {
  my ($self, $data) = @_;
  use XML::Tags qw(
    entry title author name link id published updated summary content
  );
  my $web_url = $data->{web_url};
  '  ', <entry>, "\n",
    '    ', <title>, $data->{title}, </title>, "\n",
    '    ', <author>, <name>, "Shadowcat Staff", </name>, </author>, "\n",
    '    ', <link href="${web_url}" />, "\n",
    '    ', <id>, $self->_id_for($data->{web_url}), </id>, "\n",
    '    ', <published>, $data->{created}, </published>, "\n",
    '    ', <updated>, ($data->{created}||$data->{updated}), </updated>, "\n",
    ($data->{summary_html}
      ? ('    ', <summary type="html">, \('<![CDATA['.$data->{summary_html}.']]>'), </summary>, "\n")
      : ()
    ),
    '    ', <content type="html">, \('<![CDATA['.$data->{content_html}.']]>'), </content>, "\n",
  '  ', </entry>, "\n";
}

1;