[gitmo/Package-Stash.git] / lib / Package / Stash.pm

package Package::Stash;
use strict;
use warnings;
# ABSTRACT: routines for manipulating stashes

use Carp qw(confess);
use Scalar::Util qw(reftype);

=head1 SYNOPSIS

  my $stash = Package::Stash->new('Foo');
  $stash->add_package_symbol('%foo', {bar => 1});
  # $Foo::foo{bar} == 1
  $stash->has_package_symbol('$foo') # false
  my $namespace = $stash->namespace;
  *{ $namespace->{foo} }{HASH} # {bar => 1}

=head1 DESCRIPTION

Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
incredibly messy, and easy to get wrong. This module hides all of that behind a
simple API.

NOTE: Most methods in this class require a variable specification that includes
a sigil. If this sigil is absent, it is assumed to represent the IO slot.

=method new $package_name

Creates a new C<Package::Stash> object, for the package given as the only
argument.

=cut

sub new {
    my $class = shift;
    my ($package) = @_;
    my $namespace;
    {
        no strict 'refs';
        # supposedly this caused a bug in earlier perls, but I can't reproduce
        # it, so re-enabling the caching
        $namespace = \%{$package . '::'};
    }
    return bless {
        'package'   => $package,
        'namespace' => $namespace,
    }, $class;
}

=method name

Returns the name of the package that this object represents.

=cut

sub name {
    return $_[0]->{package};
}

=method namespace

Returns the raw stash itself.

=cut

sub namespace {
    return $_[0]->{namespace};
}

{
    my %SIGIL_MAP = (
        '$' => 'SCALAR',
        '@' => 'ARRAY',
        '%' => 'HASH',
        '&' => 'CODE',
        ''  => 'IO',
    );

    sub _deconstruct_variable_name {
        my ($self, $variable) = @_;

        (defined $variable && length $variable)
            || confess "You must pass a variable name";

        my $sigil = substr($variable, 0, 1, '');

        if (exists $SIGIL_MAP{$sigil}) {
            return ($variable, $sigil, $SIGIL_MAP{$sigil});
        }
        else {
            return ("${sigil}${variable}", '', $SIGIL_MAP{''});
        }
    }
}

=method add_package_symbol $variable $value %opts

Adds a new package symbol, for the symbol given as C<$variable>, and optionally
gives it an initial value of C<$value>. C<$variable> should be the name of
variable including the sigil, so

  Package::Stash->new('Foo')->add_package_symbol('%foo')

will create C<%Foo::foo>.

Valid options (all optional) are C<filename>, C<first_line_num>, and
C<last_line_num>.

C<$opts{filename}>, C<$opts{first_line_num}>, and C<$opts{last_line_num}> can
be used to indicate where the symbol should be regarded as having been defined.
Currently these values are only used if the symbol is a subroutine ('C<&>'
sigil) and only if C<$^P & 0x10> is true, in which case the special C<%DB::sub>
hash is updated to record the values of C<filename>, C<first_line_num>, and
C<last_line_num> for the subroutine. If these are not passed, their values are
inferred (as much as possible) from C<caller> information.

This is especially useful for debuggers and profilers, which use C<%DB::sub> to
determine where the source code for a subroutine can be found.  See
L<http://perldoc.perl.org/perldebguts.html#Debugger-Internals> for more
information about C<%DB::sub>.

=cut

sub _valid_for_type {
    my $self = shift;
    my ($value, $type) = @_;
    if ($type eq 'HASH' || $type eq 'ARRAY'
     || $type eq 'IO'   || $type eq 'CODE') {
        return reftype($value) eq $type;
    }
    else {
        my $ref = reftype($value);
        return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE';
    }
}

sub add_package_symbol {
    my ($self, $variable, $initial_value, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $pkg = $self->name;

    if (@_ > 2) {
        $self->_valid_for_type($initial_value, $type)
            || confess "$initial_value is not of type $type";

        # cheap fail-fast check for PERLDBf_SUBLINE and '&'
        if ($^P and $^P & 0x10 && $sigil eq '&') {
            my $filename = $opts{filename};
            my $first_line_num = $opts{first_line_num};

            (undef, $filename, $first_line_num) = caller
                if not defined $filename;

            my $last_line_num = $opts{last_line_num} || ($first_line_num ||= 0);

            # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
            $DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
        }
    }

    no strict 'refs';
    no warnings 'redefine', 'misc', 'prototype';
    *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
}

=method remove_package_glob $name

Removes all package variables with the given name, regardless of sigil.

=cut

sub remove_package_glob {
    my ($self, $name) = @_;
    no strict 'refs';
    delete ${$self->name . '::'}{$name};
}

# ... these functions deal with stuff on the namespace level

=method has_package_symbol $variable

Returns whether or not the given package variable (including sigil) exists.

=cut

sub has_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    return unless exists $namespace->{$name};

    my $entry_ref = \$namespace->{$name};
    if (reftype($entry_ref) eq 'GLOB') {
        if ( $type eq 'SCALAR' ) {
            return defined ${ *{$entry_ref}{SCALAR} };
        }
        else {
            return defined *{$entry_ref}{$type};
        }
    }
    else {
        # a symbol table entry can be -1 (stub), string (stub with prototype),
        # or reference (constant)
        return $type eq 'CODE';
    }
}

=method get_package_symbol $variable

Returns the value of the given package variable (including sigil).

=cut

sub get_package_symbol {
    my ($self, $variable, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    if ($opts{vivify} && !exists $namespace->{$name}) {
        if ($type eq 'ARRAY') {
            $self->add_package_symbol(
                $variable,
                # setting our own arrayref manually loses the magicalness or
                # something
                $name eq 'ISA' ? () : ([])
            );
        }
        elsif ($type eq 'HASH') {
            $self->add_package_symbol($variable, {});
        }
        else {
            # FIXME
            $self->add_package_symbol($variable)
        }
    }

    my $entry_ref = \$namespace->{$name};

    if (ref($entry_ref) eq 'GLOB') {
        return *{$entry_ref}{$type};
    }
    else {
        if ($type eq 'CODE') {
            no strict 'refs';
            return \&{ $self->name . '::' . $name };
        }
        else {
            return undef;
        }
    }
}

=method get_or_add_package_symbol $variable

Like C<get_package_symbol>, except that it will return an empty hashref or
arrayref if the variable doesn't exist.

=cut

sub get_or_add_package_symbol {
    my $self = shift;
    $self->get_package_symbol(@_, vivify => 1);
}

=method remove_package_symbol $variable

Removes the package variable described by C<$variable> (which includes the
sigil); other variables with the same name but different sigils will be
untouched.

=cut

sub remove_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    # FIXME:
    # no doubt this is grossly inefficient and
    # could be done much easier and faster in XS

    my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
        { sigil => '$', type => 'SCALAR', name => $name },
        { sigil => '@', type => 'ARRAY',  name => $name },
        { sigil => '%', type => 'HASH',   name => $name },
        { sigil => '&', type => 'CODE',   name => $name },
        { sigil => '',  type => 'IO',     name => $name },
    );

    my ($scalar, $array, $hash, $code, $io);
    if ($type eq 'SCALAR') {
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'ARRAY') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'HASH') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'CODE') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'IO') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
    }
    else {
        confess "This should never ever ever happen";
    }

    $self->remove_package_glob($name);

    $self->add_package_symbol($scalar_desc => $scalar);
    $self->add_package_symbol($array_desc  => $array)  if defined $array;
    $self->add_package_symbol($hash_desc   => $hash)   if defined $hash;
    $self->add_package_symbol($code_desc   => $code)   if defined $code;
    $self->add_package_symbol($io_desc     => $io)     if defined $io;
}

=method list_all_package_symbols $type_filter

Returns a list of package variable names in the package, without sigils. If a
C<type_filter> is passed, it is used to select package variables of a given
type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
etc).

=cut

sub list_all_package_symbols {
    my ($self, $type_filter) = @_;

    my $namespace = $self->namespace;
    return keys %{$namespace} unless defined $type_filter;

    # NOTE:
    # or we can filter based on
    # type (SCALAR|ARRAY|HASH|CODE)
    if ($type_filter eq 'CODE') {
        return grep {
            (ref($namespace->{$_})
                ? (ref($namespace->{$_}) eq 'SCALAR')
                : (ref(\$namespace->{$_}) eq 'GLOB'
                   && defined(*{$namespace->{$_}}{CODE})));
        } keys %{$namespace};
    } else {
        return grep { *{$namespace->{$_}}{$type_filter} } keys %{$namespace};
    }
}

=head1 BUGS

No known bugs.

Please report any bugs through RT: email
C<bug-package-stash at rt.cpan.org>, or browse to
L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.

=head1 SEE ALSO

=over 4

=item * L<Class::MOP::Package>

This module is a factoring out of code that used to live here

=back

=head1 SUPPORT

You can find this documentation for this module with the perldoc command.

    perldoc Package::Stash

You can also look for information at:

=over 4

=item * AnnoCPAN: Annotated CPAN documentation

L<http://annocpan.org/dist/Package-Stash>

=item * CPAN Ratings

L<http://cpanratings.perl.org/d/Package-Stash>

=item * RT: CPAN's request tracker

L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>

=item * Search CPAN

L<http://search.cpan.org/dist/Package-Stash>

=back

=head1 AUTHOR

Jesse Luehrs <doy at tozt dot net>

Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
Moose Cabal.

=cut

1;
Commit	Line	Data
e94260da	1	package Package::Stash;
f10f6217	2	use strict;
f10f6217	3	use warnings;
988beb41	4	# ABSTRACT: routines for manipulating stashes
f10f6217	5
	6	use Carp qw(confess);
	7	use Scalar::Util qw(reftype);
f4979588	8
f4979588	9	=head1 SYNOPSIS
f4979588	10
e94260da	11	my $stash = Package::Stash->new('Foo');
683542f5	12	$stash->add_package_symbol('%foo', {bar => 1});
	13	# $Foo::foo{bar} == 1
	14	$stash->has_package_symbol('$foo') # false
	15	my $namespace = $stash->namespace;
	16	*{ $namespace->{foo} }{HASH} # {bar => 1}
f4979588	17
	18	=head1 DESCRIPTION
	19
683542f5	20	Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
	21	incredibly messy, and easy to get wrong. This module hides all of that behind a
	22	simple API.
	23
56a29840	24	NOTE: Most methods in this class require a variable specification that includes
	25	a sigil. If this sigil is absent, it is assumed to represent the IO slot.
	26
988beb41	27	=method new $package_name
683542f5	28
e94260da	29	Creates a new C<Package::Stash> object, for the package given as the only
683542f5	30	argument.
f4979588	31
	32	=cut
	33
f10f6217	34	sub new {
f10f6217	35	my $class = shift;
e55970bc	36	my ($package) = @_;
	37	my $namespace;
	38	{
	39	no strict 'refs';
	40	# supposedly this caused a bug in earlier perls, but I can't reproduce
	41	# it, so re-enabling the caching
	42	$namespace = \%{$package . '::'};
	43	}
	44	return bless {
	45	'package' => $package,
	46	'namespace' => $namespace,
	47	}, $class;
f10f6217	48	}
f10f6217	49
988beb41	50	=method name
683542f5	51
	52	Returns the name of the package that this object represents.
	53
	54	=cut
	55
f10f6217	56	sub name {
	57	return $_[0]->{package};
	58	}
	59
988beb41	60	=method namespace
683542f5	61
	62	Returns the raw stash itself.
	63
	64	=cut
	65
f10f6217	66	sub namespace {
e55970bc	67	return $_[0]->{namespace};
f10f6217	68	}
	69
	70	{
	71	my %SIGIL_MAP = (
	72	'$' => 'SCALAR',
	73	'@' => 'ARRAY',
	74	'%' => 'HASH',
	75	'&' => 'CODE',
56a29840	76	'' => 'IO',
f10f6217	77	);
	78
	79	sub _deconstruct_variable_name {
	80	my ($self, $variable) = @_;
	81
56a29840	82	(defined $variable && length $variable)
f10f6217	83	\|\| confess "You must pass a variable name";
	84
	85	my $sigil = substr($variable, 0, 1, '');
	86
56a29840	87	if (exists $SIGIL_MAP{$sigil}) {
	88	return ($variable, $sigil, $SIGIL_MAP{$sigil});
	89	}
	90	else {
	91	return ("${sigil}${variable}", '', $SIGIL_MAP{''});
	92	}
f10f6217	93	}
	94	}
	95
988beb41	96	=method add_package_symbol $variable $value %opts
683542f5	97
	98	Adds a new package symbol, for the symbol given as C<$variable>, and optionally
	99	gives it an initial value of C<$value>. C<$variable> should be the name of
	100	variable including the sigil, so
	101
e94260da	102	Package::Stash->new('Foo')->add_package_symbol('%foo')
683542f5	103
	104	will create C<%Foo::foo>.
	105
c61010aa	106	Valid options (all optional) are C<filename>, C<first_line_num>, and
	107	C<last_line_num>.
	108
	109	C<$opts{filename}>, C<$opts{first_line_num}>, and C<$opts{last_line_num}> can
	110	be used to indicate where the symbol should be regarded as having been defined.
4ada57e0	111	Currently these values are only used if the symbol is a subroutine ('C<&>'
c61010aa	112	sigil) and only if C<$^P & 0x10> is true, in which case the special C<%DB::sub>
	113	hash is updated to record the values of C<filename>, C<first_line_num>, and
	114	C<last_line_num> for the subroutine. If these are not passed, their values are
	115	inferred (as much as possible) from C<caller> information.
4ada57e0	116
	117	This is especially useful for debuggers and profilers, which use C<%DB::sub> to
	118	determine where the source code for a subroutine can be found. See
	119	L<http://perldoc.perl.org/perldebguts.html#Debugger-Internals> for more
	120	information about C<%DB::sub>.
	121
683542f5	122	=cut
683542f5	123
3634ce60	124	sub _valid_for_type {
	125	my $self = shift;
	126	my ($value, $type) = @_;
	127	if ($type eq 'HASH' \|\| $type eq 'ARRAY'
	128	\|\| $type eq 'IO' \|\| $type eq 'CODE') {
	129	return reftype($value) eq $type;
	130	}
	131	else {
	132	my $ref = reftype($value);
	133	return !defined($ref) \|\| $ref eq 'SCALAR' \|\| $ref eq 'REF' \|\| $ref eq 'LVALUE';
	134	}
	135	}
	136
f10f6217	137	sub add_package_symbol {
640de369	138	my ($self, $variable, $initial_value, %opts) = @_;
f10f6217	139
	140	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	141	? @{$variable}{qw[name sigil type]}
	142	: $self->_deconstruct_variable_name($variable);
	143
4ada57e0	144	my $pkg = $self->name;
4ada57e0	145
3634ce60	146	if (@_ > 2) {
	147	$self->_valid_for_type($initial_value, $type)
	148	\|\| confess "$initial_value is not of type $type";
3634ce60	149
4ada57e0	150	# cheap fail-fast check for PERLDBf_SUBLINE and '&'
4ada57e0	151	if ($^P and $^P & 0x10 && $sigil eq '&') {
640de369	152	my $filename = $opts{filename};
640de369	153	my $first_line_num = $opts{first_line_num};
4ada57e0	154
640de369	155	(undef, $filename, $first_line_num) = caller
4ada57e0	156	if not defined $filename;
640de369	157
640de369	158	my $last_line_num = $opts{last_line_num} \|\| ($first_line_num \|\|= 0);
4ada57e0	159
4ada57e0	160	# http://perldoc.perl.org/perldebguts.html#Debugger-Internals
640de369	161	$DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
4ada57e0	162	}
4ada57e0	163	}
f10f6217	164
	165	no strict 'refs';
	166	no warnings 'redefine', 'misc', 'prototype';
	167	*{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
	168	}
	169
988beb41	170	=method remove_package_glob $name
683542f5	171
	172	Removes all package variables with the given name, regardless of sigil.
	173
	174	=cut
	175
f10f6217	176	sub remove_package_glob {
	177	my ($self, $name) = @_;
	178	no strict 'refs';
	179	delete ${$self->name . '::'}{$name};
	180	}
	181
	182	# ... these functions deal with stuff on the namespace level
	183
988beb41	184	=method has_package_symbol $variable
683542f5	185
	186	Returns whether or not the given package variable (including sigil) exists.
	187
	188	=cut
	189
f10f6217	190	sub has_package_symbol {
	191	my ($self, $variable) = @_;
	192
	193	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	194	? @{$variable}{qw[name sigil type]}
	195	: $self->_deconstruct_variable_name($variable);
	196
	197	my $namespace = $self->namespace;
	198
	199	return unless exists $namespace->{$name};
	200
	201	my $entry_ref = \$namespace->{$name};
	202	if (reftype($entry_ref) eq 'GLOB') {
	203	if ( $type eq 'SCALAR' ) {
	204	return defined ${ *{$entry_ref}{SCALAR} };
	205	}
	206	else {
	207	return defined *{$entry_ref}{$type};
	208	}
	209	}
	210	else {
	211	# a symbol table entry can be -1 (stub), string (stub with prototype),
	212	# or reference (constant)
	213	return $type eq 'CODE';
	214	}
	215	}
	216
988beb41	217	=method get_package_symbol $variable
683542f5	218
	219	Returns the value of the given package variable (including sigil).
	220
	221	=cut
	222
f10f6217	223	sub get_package_symbol {
e55803fc	224	my ($self, $variable, %opts) = @_;
f10f6217	225
	226	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	227	? @{$variable}{qw[name sigil type]}
	228	: $self->_deconstruct_variable_name($variable);
	229
	230	my $namespace = $self->namespace;
	231
f8e7797c	232	if ($opts{vivify} && !exists $namespace->{$name}) {
	233	if ($type eq 'ARRAY') {
	234	$self->add_package_symbol(
	235	$variable,
	236	# setting our own arrayref manually loses the magicalness or
	237	# something
	238	$name eq 'ISA' ? () : ([])
	239	);
e55803fc	240	}
f8e7797c	241	elsif ($type eq 'HASH') {
e55803fc	242	$self->add_package_symbol($variable, {});
	243	}
	244	else {
	245	# FIXME
	246	$self->add_package_symbol($variable)
	247	}
30d1a098	248	}
f10f6217	249
	250	my $entry_ref = \$namespace->{$name};
	251
	252	if (ref($entry_ref) eq 'GLOB') {
	253	return *{$entry_ref}{$type};
	254	}
	255	else {
	256	if ($type eq 'CODE') {
	257	no strict 'refs';
	258	return \&{ $self->name . '::' . $name };
	259	}
	260	else {
	261	return undef;
	262	}
	263	}
	264	}
	265
988beb41	266	=method get_or_add_package_symbol $variable
e55803fc	267
	268	Like C<get_package_symbol>, except that it will return an empty hashref or
	269	arrayref if the variable doesn't exist.
	270
	271	=cut
	272
	273	sub get_or_add_package_symbol {
	274	my $self = shift;
	275	$self->get_package_symbol(@_, vivify => 1);
	276	}
	277
988beb41	278	=method remove_package_symbol $variable
683542f5	279
	280	Removes the package variable described by C<$variable> (which includes the
	281	sigil); other variables with the same name but different sigils will be
	282	untouched.
	283
	284	=cut
	285
f10f6217	286	sub remove_package_symbol {
	287	my ($self, $variable) = @_;
	288
	289	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	290	? @{$variable}{qw[name sigil type]}
	291	: $self->_deconstruct_variable_name($variable);
	292
	293	# FIXME:
9a3d1390	294	# no doubt this is grossly inefficient and
f10f6217	295	# could be done much easier and faster in XS
f10f6217	296
b1a00d0e	297	my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
f10f6217	298	{ sigil => '$', type => 'SCALAR', name => $name },
	299	{ sigil => '@', type => 'ARRAY', name => $name },
	300	{ sigil => '%', type => 'HASH', name => $name },
	301	{ sigil => '&', type => 'CODE', name => $name },
b1a00d0e	302	{ sigil => '', type => 'IO', name => $name },
f10f6217	303	);
f10f6217	304
b1a00d0e	305	my ($scalar, $array, $hash, $code, $io);
f10f6217	306	if ($type eq 'SCALAR') {
	307	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	308	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	309	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	310	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	311	}
f10f6217	312	elsif ($type eq 'ARRAY') {
42fa5cfc	313	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	314	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
f10f6217	315	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	316	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	317	}
f10f6217	318	elsif ($type eq 'HASH') {
42fa5cfc	319	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	320	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
f10f6217	321	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	322	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	323	}
f10f6217	324	elsif ($type eq 'CODE') {
42fa5cfc	325	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	326	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
f10f6217	327	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
b1a00d0e	328	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
	329	}
	330	elsif ($type eq 'IO') {
42fa5cfc	331	$scalar = $self->get_package_symbol($scalar_desc);
b1a00d0e	332	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	333	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	334	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
f10f6217	335	}
	336	else {
	337	confess "This should never ever ever happen";
	338	}
	339
	340	$self->remove_package_glob($name);
	341
42fa5cfc	342	$self->add_package_symbol($scalar_desc => $scalar);
f10f6217	343	$self->add_package_symbol($array_desc => $array) if defined $array;
	344	$self->add_package_symbol($hash_desc => $hash) if defined $hash;
	345	$self->add_package_symbol($code_desc => $code) if defined $code;
b1a00d0e	346	$self->add_package_symbol($io_desc => $io) if defined $io;
f10f6217	347	}
f10f6217	348
988beb41	349	=method list_all_package_symbols $type_filter
683542f5	350
	351	Returns a list of package variable names in the package, without sigils. If a
	352	C<type_filter> is passed, it is used to select package variables of a given
	353	type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
	354	etc).
	355
	356	=cut
	357
f10f6217	358	sub list_all_package_symbols {
	359	my ($self, $type_filter) = @_;
	360
	361	my $namespace = $self->namespace;
	362	return keys %{$namespace} unless defined $type_filter;
	363
	364	# NOTE:
9a3d1390	365	# or we can filter based on
f10f6217	366	# type (SCALAR\|ARRAY\|HASH\|CODE)
	367	if ($type_filter eq 'CODE') {
	368	return grep {
	369	(ref($namespace->{$_})
	370	? (ref($namespace->{$_}) eq 'SCALAR')
	371	: (ref(\$namespace->{$_}) eq 'GLOB'
	372	&& defined(*{$namespace->{$_}}{CODE})));
	373	} keys %{$namespace};
	374	} else {
	375	return grep { *{$namespace->{$_}}{$type_filter} } keys %{$namespace};
	376	}
	377	}
f4979588	378
0992f4ec	379	=head1 BUGS
	380
	381	No known bugs.
	382
	383	Please report any bugs through RT: email
	384	C<bug-package-stash at rt.cpan.org>, or browse to
	385	L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
	386
f4979588	387	=head1 SEE ALSO
f4979588	388
f4979588	389	=over 4
f4979588	390
988beb41	391	=item * L<Class::MOP::Package>
f4979588	392
988beb41	393	This module is a factoring out of code that used to live here
f4979588	394
	395	=back
	396
0992f4ec	397	=head1 SUPPORT
	398
	399	You can find this documentation for this module with the perldoc command.
	400
	401	perldoc Package::Stash
	402
	403	You can also look for information at:
	404
	405	=over 4
	406
	407	=item * AnnoCPAN: Annotated CPAN documentation
	408
	409	L<http://annocpan.org/dist/Package-Stash>
	410
	411	=item * CPAN Ratings
	412
	413	L<http://cpanratings.perl.org/d/Package-Stash>
	414
	415	=item * RT: CPAN's request tracker
	416
	417	L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
	418
	419	=item * Search CPAN
	420
	421	L<http://search.cpan.org/dist/Package-Stash>
	422
	423	=back
	424
	425	=head1 AUTHOR
	426
	427	Jesse Luehrs <doy at tozt dot net>
	428
	429	Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
	430	Moose Cabal.
	431
f4979588	432	=cut
	433
	434	1;