[gitmo/Package-Stash-XS.git] / lib / Package / Stash.pm

package Package::Stash;
use strict;
use warnings;
# ABSTRACT: routines for manipulating stashes

use Carp qw(confess);
use Scalar::Util qw(reftype);
use Symbol;

use XSLoader;
XSLoader::load(
    __PACKAGE__,
    # we need to be careful not to touch $VERSION at compile time, otherwise
    # DynaLoader will assume it's set and check against it, which will cause
    # fail when being run in the checkout without dzil having set the actual
    # $VERSION
    exists $Package::Stash::{VERSION}
        ? ${ $Package::Stash::{VERSION} } : (),
);

# before 5.12, assigning to the ISA glob would make it lose its magical ->isa
# powers
use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);

=head1 SYNOPSIS

  my $stash = Package::Stash->new('Foo');
  $stash->add_package_symbol('%foo', {bar => 1});
  # $Foo::foo{bar} == 1
  $stash->has_package_symbol('$foo') # false
  my $namespace = $stash->namespace;
  *{ $namespace->{foo} }{HASH} # {bar => 1}

=head1 DESCRIPTION

Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
incredibly messy, and easy to get wrong. This module hides all of that behind a
simple API.

NOTE: Most methods in this class require a variable specification that includes
a sigil. If this sigil is absent, it is assumed to represent the IO slot.

=method new $package_name

Creates a new C<Package::Stash> object, for the package given as the only
argument.

=method name

Returns the name of the package that this object represents.

=method namespace

Returns the raw stash itself.

=cut

{
    my %SIGIL_MAP = (
        '$' => 'SCALAR',
        '@' => 'ARRAY',
        '%' => 'HASH',
        '&' => 'CODE',
        ''  => 'IO',
    );

    sub _deconstruct_variable_name {
        my ($self, $variable) = @_;

        (defined $variable && length $variable)
            || confess "You must pass a variable name";

        my $sigil = substr($variable, 0, 1, '');

        if (exists $SIGIL_MAP{$sigil}) {
            return ($variable, $sigil, $SIGIL_MAP{$sigil});
        }
        else {
            return ("${sigil}${variable}", '', $SIGIL_MAP{''});
        }
    }
}

=method add_package_symbol $variable $value %opts

Adds a new package symbol, for the symbol given as C<$variable>, and optionally
gives it an initial value of C<$value>. C<$variable> should be the name of
variable including the sigil, so

  Package::Stash->new('Foo')->add_package_symbol('%foo')

will create C<%Foo::foo>.

Valid options (all optional) are C<filename>, C<first_line_num>, and
C<last_line_num>.

C<$opts{filename}>, C<$opts{first_line_num}>, and C<$opts{last_line_num}> can
be used to indicate where the symbol should be regarded as having been defined.
Currently these values are only used if the symbol is a subroutine ('C<&>'
sigil) and only if C<$^P & 0x10> is true, in which case the special C<%DB::sub>
hash is updated to record the values of C<filename>, C<first_line_num>, and
C<last_line_num> for the subroutine. If these are not passed, their values are
inferred (as much as possible) from C<caller> information.

This is especially useful for debuggers and profilers, which use C<%DB::sub> to
determine where the source code for a subroutine can be found.  See
L<http://perldoc.perl.org/perldebguts.html#Debugger-Internals> for more
information about C<%DB::sub>.

=cut

sub _valid_for_type {
    my $self = shift;
    my ($value, $type) = @_;
    if ($type eq 'HASH' || $type eq 'ARRAY'
     || $type eq 'IO'   || $type eq 'CODE') {
        return reftype($value) eq $type;
    }
    else {
        my $ref = reftype($value);
        return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE';
    }
}

sub add_package_symbol {
    my ($self, $variable, $initial_value, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $pkg = $self->name;

    if (@_ > 2) {
        $self->_valid_for_type($initial_value, $type)
            || confess "$initial_value is not of type $type";

        # cheap fail-fast check for PERLDBf_SUBLINE and '&'
        if ($^P and $^P & 0x10 && $sigil eq '&') {
            my $filename = $opts{filename};
            my $first_line_num = $opts{first_line_num};

            (undef, $filename, $first_line_num) = caller
                if not defined $filename;

            my $last_line_num = $opts{last_line_num} || ($first_line_num ||= 0);

            # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
            $DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
        }
    }

    no strict 'refs';
    no warnings 'redefine', 'misc', 'prototype';
    *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
}

=method remove_package_glob $name

Removes all package variables with the given name, regardless of sigil.

=method has_package_symbol $variable

Returns whether or not the given package variable (including sigil) exists.

=cut

sub has_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    return unless exists $namespace->{$name};

    my $entry_ref = \$namespace->{$name};
    if (reftype($entry_ref) eq 'GLOB') {
        # XXX: assigning to any typeglob slot also initializes the SCALAR slot,
        # and saying that an undef scalar variable doesn't exist is probably
        # vaguely less surprising than a scalar variable popping into existence
        # without anyone defining it
        if ($type eq 'SCALAR') {
            return defined ${ *{$entry_ref}{$type} };
        }
        else {
            return defined *{$entry_ref}{$type};
        }
    }
    else {
        # a symbol table entry can be -1 (stub), string (stub with prototype),
        # or reference (constant)
        return $type eq 'CODE';
    }
}

=method get_package_symbol $variable

Returns the value of the given package variable (including sigil).

=cut

sub get_package_symbol {
    my ($self, $variable, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    if (!exists $namespace->{$name}) {
        if ($opts{vivify}) {
            if ($type eq 'ARRAY') {
                if (BROKEN_ISA_ASSIGNMENT) {
                    $self->add_package_symbol(
                        $variable,
                        $name eq 'ISA' ? () : ([])
                    );
                }
                else {
                    $self->add_package_symbol($variable, []);
                }
            }
            elsif ($type eq 'HASH') {
                $self->add_package_symbol($variable, {});
            }
            elsif ($type eq 'SCALAR') {
                $self->add_package_symbol($variable);
            }
            elsif ($type eq 'IO') {
                $self->add_package_symbol($variable, Symbol::geniosym);
            }
            elsif ($type eq 'CODE') {
                confess "Don't know how to vivify CODE variables";
            }
            else {
                confess "Unknown type $type in vivication";
            }
        }
        else {
            if ($type eq 'CODE') {
                # this effectively "de-vivifies" the code slot. if we don't do
                # this, referencing the coderef at the end of this function
                # will cause perl to auto-vivify a stub coderef in the slot,
                # which isn't what we want
                $self->add_package_symbol($variable);
            }
        }
    }

    my $entry_ref = \$namespace->{$name};

    if (ref($entry_ref) eq 'GLOB') {
        return *{$entry_ref}{$type};
    }
    else {
        if ($type eq 'CODE') {
            no strict 'refs';
            return \&{ $self->name . '::' . $name };
        }
        else {
            return undef;
        }
    }
}

=method get_or_add_package_symbol $variable

Like C<get_package_symbol>, except that it will return an empty hashref or
arrayref if the variable doesn't exist.

=cut

sub get_or_add_package_symbol {
    my $self = shift;
    $self->get_package_symbol(@_, vivify => 1);
}

=method remove_package_symbol $variable

Removes the package variable described by C<$variable> (which includes the
sigil); other variables with the same name but different sigils will be
untouched.

=cut

sub remove_package_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    # FIXME:
    # no doubt this is grossly inefficient and
    # could be done much easier and faster in XS

    my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
        { sigil => '$', type => 'SCALAR', name => $name },
        { sigil => '@', type => 'ARRAY',  name => $name },
        { sigil => '%', type => 'HASH',   name => $name },
        { sigil => '&', type => 'CODE',   name => $name },
        { sigil => '',  type => 'IO',     name => $name },
    );

    my ($scalar, $array, $hash, $code, $io);
    if ($type eq 'SCALAR') {
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'ARRAY') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'HASH') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'CODE') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $io     = $self->get_package_symbol($io_desc)     if $self->has_package_symbol($io_desc);
    }
    elsif ($type eq 'IO') {
        $scalar = $self->get_package_symbol($scalar_desc);
        $array  = $self->get_package_symbol($array_desc)  if $self->has_package_symbol($array_desc);
        $hash   = $self->get_package_symbol($hash_desc)   if $self->has_package_symbol($hash_desc);
        $code   = $self->get_package_symbol($code_desc)   if $self->has_package_symbol($code_desc);
    }
    else {
        confess "This should never ever ever happen";
    }

    $self->remove_package_glob($name);

    $self->add_package_symbol($scalar_desc => $scalar);
    $self->add_package_symbol($array_desc  => $array)  if defined $array;
    $self->add_package_symbol($hash_desc   => $hash)   if defined $hash;
    $self->add_package_symbol($code_desc   => $code)   if defined $code;
    $self->add_package_symbol($io_desc     => $io)     if defined $io;
}

=method list_all_package_symbols $type_filter

Returns a list of package variable names in the package, without sigils. If a
C<type_filter> is passed, it is used to select package variables of a given
type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
etc). Note that if the package contained any C<BEGIN> blocks, perl will leave
an empty typeglob in the C<BEGIN> slot, so this will show up if no filter is
used (and similarly for C<INIT>, C<END>, etc).

=head1 BUGS

No known bugs.

Please report any bugs through RT: email
C<bug-package-stash at rt.cpan.org>, or browse to
L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.

=head1 SEE ALSO

=over 4

=item * L<Class::MOP::Package>

This module is a factoring out of code that used to live here

=back

=head1 SUPPORT

You can find this documentation for this module with the perldoc command.

    perldoc Package::Stash

You can also look for information at:

=over 4

=item * AnnoCPAN: Annotated CPAN documentation

L<http://annocpan.org/dist/Package-Stash>

=item * CPAN Ratings

L<http://cpanratings.perl.org/d/Package-Stash>

=item * RT: CPAN's request tracker

L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>

=item * Search CPAN

L<http://search.cpan.org/dist/Package-Stash>

=back

=head1 AUTHOR

Jesse Luehrs <doy at tozt dot net>

Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
Moose Cabal.

=cut

1;
Commit	Line	Data
e94260da	1	package Package::Stash;
f10f6217	2	use strict;
f10f6217	3	use warnings;
988beb41	4	# ABSTRACT: routines for manipulating stashes
f10f6217	5
	6	use Carp qw(confess);
	7	use Scalar::Util qw(reftype);
dc378b60	8	use Symbol;
59017825	9
	10	use XSLoader;
	11	XSLoader::load(
	12	__PACKAGE__,
	13	# we need to be careful not to touch $VERSION at compile time, otherwise
	14	# DynaLoader will assume it's set and check against it, which will cause
	15	# fail when being run in the checkout without dzil having set the actual
	16	# $VERSION
	17	exists $Package::Stash::{VERSION}
	18	? ${ $Package::Stash::{VERSION} } : (),
	19	);
	20
dc378b60	21	# before 5.12, assigning to the ISA glob would make it lose its magical ->isa
	22	# powers
	23	use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);
f4979588	24
f4979588	25	=head1 SYNOPSIS
f4979588	26
e94260da	27	my $stash = Package::Stash->new('Foo');
683542f5	28	$stash->add_package_symbol('%foo', {bar => 1});
	29	# $Foo::foo{bar} == 1
	30	$stash->has_package_symbol('$foo') # false
	31	my $namespace = $stash->namespace;
	32	*{ $namespace->{foo} }{HASH} # {bar => 1}
f4979588	33
	34	=head1 DESCRIPTION
	35
683542f5	36	Manipulating stashes (Perl's symbol tables) is occasionally necessary, but
	37	incredibly messy, and easy to get wrong. This module hides all of that behind a
	38	simple API.
	39
56a29840	40	NOTE: Most methods in this class require a variable specification that includes
	41	a sigil. If this sigil is absent, it is assumed to represent the IO slot.
	42
988beb41	43	=method new $package_name
683542f5	44
e94260da	45	Creates a new C<Package::Stash> object, for the package given as the only
683542f5	46	argument.
f4979588	47
988beb41	48	=method name
683542f5	49
	50	Returns the name of the package that this object represents.
	51
988beb41	52	=method namespace
683542f5	53
	54	Returns the raw stash itself.
	55
	56	=cut
	57
f10f6217	58	{
	59	my %SIGIL_MAP = (
	60	'$' => 'SCALAR',
	61	'@' => 'ARRAY',
	62	'%' => 'HASH',
	63	'&' => 'CODE',
56a29840	64	'' => 'IO',
f10f6217	65	);
	66
	67	sub _deconstruct_variable_name {
	68	my ($self, $variable) = @_;
	69
56a29840	70	(defined $variable && length $variable)
f10f6217	71	\|\| confess "You must pass a variable name";
	72
	73	my $sigil = substr($variable, 0, 1, '');
	74
56a29840	75	if (exists $SIGIL_MAP{$sigil}) {
	76	return ($variable, $sigil, $SIGIL_MAP{$sigil});
	77	}
	78	else {
	79	return ("${sigil}${variable}", '', $SIGIL_MAP{''});
	80	}
f10f6217	81	}
	82	}
	83
988beb41	84	=method add_package_symbol $variable $value %opts
683542f5	85
	86	Adds a new package symbol, for the symbol given as C<$variable>, and optionally
	87	gives it an initial value of C<$value>. C<$variable> should be the name of
	88	variable including the sigil, so
	89
e94260da	90	Package::Stash->new('Foo')->add_package_symbol('%foo')
683542f5	91
	92	will create C<%Foo::foo>.
	93
c61010aa	94	Valid options (all optional) are C<filename>, C<first_line_num>, and
	95	C<last_line_num>.
	96
	97	C<$opts{filename}>, C<$opts{first_line_num}>, and C<$opts{last_line_num}> can
	98	be used to indicate where the symbol should be regarded as having been defined.
4ada57e0	99	Currently these values are only used if the symbol is a subroutine ('C<&>'
c61010aa	100	sigil) and only if C<$^P & 0x10> is true, in which case the special C<%DB::sub>
	101	hash is updated to record the values of C<filename>, C<first_line_num>, and
	102	C<last_line_num> for the subroutine. If these are not passed, their values are
	103	inferred (as much as possible) from C<caller> information.
4ada57e0	104
	105	This is especially useful for debuggers and profilers, which use C<%DB::sub> to
	106	determine where the source code for a subroutine can be found. See
	107	L<http://perldoc.perl.org/perldebguts.html#Debugger-Internals> for more
	108	information about C<%DB::sub>.
	109
683542f5	110	=cut
683542f5	111
3634ce60	112	sub _valid_for_type {
	113	my $self = shift;
	114	my ($value, $type) = @_;
	115	if ($type eq 'HASH' \|\| $type eq 'ARRAY'
	116	\|\| $type eq 'IO' \|\| $type eq 'CODE') {
	117	return reftype($value) eq $type;
	118	}
	119	else {
	120	my $ref = reftype($value);
	121	return !defined($ref) \|\| $ref eq 'SCALAR' \|\| $ref eq 'REF' \|\| $ref eq 'LVALUE';
	122	}
	123	}
	124
f10f6217	125	sub add_package_symbol {
640de369	126	my ($self, $variable, $initial_value, %opts) = @_;
f10f6217	127
	128	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	129	? @{$variable}{qw[name sigil type]}
	130	: $self->_deconstruct_variable_name($variable);
	131
4ada57e0	132	my $pkg = $self->name;
4ada57e0	133
3634ce60	134	if (@_ > 2) {
	135	$self->_valid_for_type($initial_value, $type)
	136	\|\| confess "$initial_value is not of type $type";
3634ce60	137
4ada57e0	138	# cheap fail-fast check for PERLDBf_SUBLINE and '&'
4ada57e0	139	if ($^P and $^P & 0x10 && $sigil eq '&') {
640de369	140	my $filename = $opts{filename};
640de369	141	my $first_line_num = $opts{first_line_num};
4ada57e0	142
640de369	143	(undef, $filename, $first_line_num) = caller
4ada57e0	144	if not defined $filename;
640de369	145
640de369	146	my $last_line_num = $opts{last_line_num} \|\| ($first_line_num \|\|= 0);
4ada57e0	147
4ada57e0	148	# http://perldoc.perl.org/perldebguts.html#Debugger-Internals
640de369	149	$DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
4ada57e0	150	}
4ada57e0	151	}
f10f6217	152
	153	no strict 'refs';
	154	no warnings 'redefine', 'misc', 'prototype';
	155	*{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
	156	}
	157
988beb41	158	=method remove_package_glob $name
683542f5	159
	160	Removes all package variables with the given name, regardless of sigil.
	161
988beb41	162	=method has_package_symbol $variable
683542f5	163
	164	Returns whether or not the given package variable (including sigil) exists.
	165
	166	=cut
	167
f10f6217	168	sub has_package_symbol {
	169	my ($self, $variable) = @_;
	170
	171	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	172	? @{$variable}{qw[name sigil type]}
	173	: $self->_deconstruct_variable_name($variable);
	174
	175	my $namespace = $self->namespace;
	176
	177	return unless exists $namespace->{$name};
	178
	179	my $entry_ref = \$namespace->{$name};
	180	if (reftype($entry_ref) eq 'GLOB') {
f7543739	181	# XXX: assigning to any typeglob slot also initializes the SCALAR slot,
	182	# and saying that an undef scalar variable doesn't exist is probably
	183	# vaguely less surprising than a scalar variable popping into existence
	184	# without anyone defining it
	185	if ($type eq 'SCALAR') {
	186	return defined ${ *{$entry_ref}{$type} };
	187	}
	188	else {
	189	return defined *{$entry_ref}{$type};
	190	}
f10f6217	191	}
	192	else {
	193	# a symbol table entry can be -1 (stub), string (stub with prototype),
	194	# or reference (constant)
	195	return $type eq 'CODE';
	196	}
	197	}
	198
988beb41	199	=method get_package_symbol $variable
683542f5	200
	201	Returns the value of the given package variable (including sigil).
	202
	203	=cut
	204
f10f6217	205	sub get_package_symbol {
e55803fc	206	my ($self, $variable, %opts) = @_;
f10f6217	207
	208	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	209	? @{$variable}{qw[name sigil type]}
	210	: $self->_deconstruct_variable_name($variable);
	211
	212	my $namespace = $self->namespace;
	213
7486ccf3	214	if (!exists $namespace->{$name}) {
dc378b60	215	if ($opts{vivify}) {
	216	if ($type eq 'ARRAY') {
	217	if (BROKEN_ISA_ASSIGNMENT) {
	218	$self->add_package_symbol(
	219	$variable,
	220	$name eq 'ISA' ? () : ([])
	221	);
	222	}
	223	else {
	224	$self->add_package_symbol($variable, []);
	225	}
	226	}
	227	elsif ($type eq 'HASH') {
	228	$self->add_package_symbol($variable, {});
	229	}
	230	elsif ($type eq 'SCALAR') {
	231	$self->add_package_symbol($variable);
	232	}
	233	elsif ($type eq 'IO') {
	234	$self->add_package_symbol($variable, Symbol::geniosym);
	235	}
	236	elsif ($type eq 'CODE') {
	237	confess "Don't know how to vivify CODE variables";
	238	}
	239	else {
	240	confess "Unknown type $type in vivication";
	241	}
5d3589c8	242	}
e55803fc	243	else {
dc378b60	244	if ($type eq 'CODE') {
	245	# this effectively "de-vivifies" the code slot. if we don't do
	246	# this, referencing the coderef at the end of this function
	247	# will cause perl to auto-vivify a stub coderef in the slot,
	248	# which isn't what we want
	249	$self->add_package_symbol($variable);
	250	}
e55803fc	251	}
30d1a098	252	}
f10f6217	253
	254	my $entry_ref = \$namespace->{$name};
	255
	256	if (ref($entry_ref) eq 'GLOB') {
	257	return *{$entry_ref}{$type};
	258	}
	259	else {
	260	if ($type eq 'CODE') {
	261	no strict 'refs';
	262	return \&{ $self->name . '::' . $name };
	263	}
	264	else {
	265	return undef;
	266	}
	267	}
	268	}
	269
988beb41	270	=method get_or_add_package_symbol $variable
e55803fc	271
	272	Like C<get_package_symbol>, except that it will return an empty hashref or
	273	arrayref if the variable doesn't exist.
	274
	275	=cut
	276
	277	sub get_or_add_package_symbol {
	278	my $self = shift;
	279	$self->get_package_symbol(@_, vivify => 1);
	280	}
	281
988beb41	282	=method remove_package_symbol $variable
683542f5	283
	284	Removes the package variable described by C<$variable> (which includes the
	285	sigil); other variables with the same name but different sigils will be
	286	untouched.
	287
	288	=cut
	289
f10f6217	290	sub remove_package_symbol {
	291	my ($self, $variable) = @_;
	292
	293	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	294	? @{$variable}{qw[name sigil type]}
	295	: $self->_deconstruct_variable_name($variable);
	296
	297	# FIXME:
9a3d1390	298	# no doubt this is grossly inefficient and
f10f6217	299	# could be done much easier and faster in XS
f10f6217	300
b1a00d0e	301	my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
f10f6217	302	{ sigil => '$', type => 'SCALAR', name => $name },
	303	{ sigil => '@', type => 'ARRAY', name => $name },
	304	{ sigil => '%', type => 'HASH', name => $name },
	305	{ sigil => '&', type => 'CODE', name => $name },
b1a00d0e	306	{ sigil => '', type => 'IO', name => $name },
f10f6217	307	);
f10f6217	308
b1a00d0e	309	my ($scalar, $array, $hash, $code, $io);
f10f6217	310	if ($type eq 'SCALAR') {
	311	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	312	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	313	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	314	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	315	}
f10f6217	316	elsif ($type eq 'ARRAY') {
42fa5cfc	317	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	318	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
f10f6217	319	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	320	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	321	}
f10f6217	322	elsif ($type eq 'HASH') {
42fa5cfc	323	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	324	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
f10f6217	325	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
b1a00d0e	326	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
f10f6217	327	}
f10f6217	328	elsif ($type eq 'CODE') {
42fa5cfc	329	$scalar = $self->get_package_symbol($scalar_desc);
f10f6217	330	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
f10f6217	331	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
b1a00d0e	332	$io = $self->get_package_symbol($io_desc) if $self->has_package_symbol($io_desc);
	333	}
	334	elsif ($type eq 'IO') {
42fa5cfc	335	$scalar = $self->get_package_symbol($scalar_desc);
b1a00d0e	336	$array = $self->get_package_symbol($array_desc) if $self->has_package_symbol($array_desc);
	337	$hash = $self->get_package_symbol($hash_desc) if $self->has_package_symbol($hash_desc);
	338	$code = $self->get_package_symbol($code_desc) if $self->has_package_symbol($code_desc);
f10f6217	339	}
	340	else {
	341	confess "This should never ever ever happen";
	342	}
	343
	344	$self->remove_package_glob($name);
	345
42fa5cfc	346	$self->add_package_symbol($scalar_desc => $scalar);
f10f6217	347	$self->add_package_symbol($array_desc => $array) if defined $array;
	348	$self->add_package_symbol($hash_desc => $hash) if defined $hash;
	349	$self->add_package_symbol($code_desc => $code) if defined $code;
b1a00d0e	350	$self->add_package_symbol($io_desc => $io) if defined $io;
f10f6217	351	}
f10f6217	352
988beb41	353	=method list_all_package_symbols $type_filter
683542f5	354
	355	Returns a list of package variable names in the package, without sigils. If a
	356	C<type_filter> is passed, it is used to select package variables of a given
	357	type, where valid types are the slots of a typeglob ('SCALAR', 'CODE', 'HASH',
d1f721b3	358	etc). Note that if the package contained any C<BEGIN> blocks, perl will leave
	359	an empty typeglob in the C<BEGIN> slot, so this will show up if no filter is
	360	used (and similarly for C<INIT>, C<END>, etc).
683542f5	361
0992f4ec	362	=head1 BUGS
	363
	364	No known bugs.
	365
	366	Please report any bugs through RT: email
	367	C<bug-package-stash at rt.cpan.org>, or browse to
	368	L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
	369
f4979588	370	=head1 SEE ALSO
f4979588	371
f4979588	372	=over 4
f4979588	373
988beb41	374	=item * L<Class::MOP::Package>
f4979588	375
988beb41	376	This module is a factoring out of code that used to live here
f4979588	377
	378	=back
	379
0992f4ec	380	=head1 SUPPORT
	381
	382	You can find this documentation for this module with the perldoc command.
	383
	384	perldoc Package::Stash
	385
	386	You can also look for information at:
	387
	388	=over 4
	389
	390	=item * AnnoCPAN: Annotated CPAN documentation
	391
	392	L<http://annocpan.org/dist/Package-Stash>
	393
	394	=item * CPAN Ratings
	395
	396	L<http://cpanratings.perl.org/d/Package-Stash>
	397
	398	=item * RT: CPAN's request tracker
	399
	400	L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
	401
	402	=item * Search CPAN
	403
	404	L<http://search.cpan.org/dist/Package-Stash>
	405
	406	=back
	407
	408	=head1 AUTHOR
	409
	410	Jesse Luehrs <doy at tozt dot net>
	411
	412	Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
	413	Moose Cabal.
	414
f4979588	415	=cut
	416
	417	1;