[gitmo/Package-Stash.git] / lib / Package / Stash / PP.pm

package Package::Stash::PP;
use strict;
use warnings;
# ABSTRACT: pure perl implementation of the Package::Stash API

use B;
use Carp qw(confess);
use Scalar::Util qw(blessed reftype weaken);
use Symbol;
# before 5.12, assigning to the ISA glob would make it lose its magical ->isa
# powers
use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);
# before 5.10, stashes don't ever seem to drop to a refcount of zero, so
# weakening them isn't helpful
use constant BROKEN_WEAK_STASH     => ($] < 5.010);
# before 5.10, the scalar slot was always treated as existing if the
# glob existed
use constant BROKEN_SCALAR_INITIALIZATION => ($] < 5.010);

=head1 SYNOPSIS

  use Package::Stash;

=head1 DESCRIPTION

This is a backend for L<Package::Stash> implemented in pure perl, for those without a compiler or who would like to use this inline in scripts.

=cut

sub new {
    my $class = shift;
    my ($package) = @_;

    if (!defined($package) || (ref($package) && ref($package) ne 'HASH')) {
        confess "Package::Stash->new must be passed the name of the "
              . "package to access";
    }
    elsif (ref($package) eq 'HASH') {
        confess "The pure perl implementation of Package::Stash doesn't "
              . "currently support anonymous stashes. You should install "
              . "Package::Stash::XS";
    }
    elsif ($package !~ /\A[0-9A-Z_a-z]+(?:::[0-9A-Z_a-z]+)*\z/) {
        confess "$package is not a module name";
    }

    return bless {
        'package' => $package,
    }, $class;
}

sub name {
    confess "Can't call name as a class method"
        unless blessed($_[0]);
    return $_[0]->{package};
}

sub namespace {
    confess "Can't call namespace as a class method"
        unless blessed($_[0]);

    if (BROKEN_WEAK_STASH) {
        no strict 'refs';
        return \%{$_[0]->name . '::'};
    }
    else {
        return $_[0]->{namespace} if defined $_[0]->{namespace};

        {
            no strict 'refs';
            $_[0]->{namespace} = \%{$_[0]->name . '::'};
        }

        weaken($_[0]->{namespace});

        return $_[0]->{namespace};
    }
}

{
    my %SIGIL_MAP = (
        '$' => 'SCALAR',
        '@' => 'ARRAY',
        '%' => 'HASH',
        '&' => 'CODE',
        ''  => 'IO',
    );

    sub _deconstruct_variable_name {
        my ($self, $variable) = @_;

        (defined $variable && length $variable)
            || confess "You must pass a variable name";

        # XXX in pure perl, this will access things in inner packages,
        # in xs, this will segfault - probably look more into this at
        # some point
        ($variable !~ /::/)
            || confess "Variable names may not contain ::";

        my $sigil = substr($variable, 0, 1, '');

        if (exists $SIGIL_MAP{$sigil}) {
            return ($variable, $sigil, $SIGIL_MAP{$sigil});
        }
        else {
            return ("${sigil}${variable}", '', $SIGIL_MAP{''});
        }
    }
}

sub _valid_for_type {
    my $self = shift;
    my ($value, $type) = @_;
    if ($type eq 'HASH' || $type eq 'ARRAY'
     || $type eq 'IO'   || $type eq 'CODE') {
        return reftype($value) eq $type;
    }
    else {
        my $ref = reftype($value);
        return !defined($ref) || $ref eq 'SCALAR' || $ref eq 'REF' || $ref eq 'LVALUE' || $ref eq 'REGEXP' || $ref eq 'VSTRING';
    }
}

sub add_symbol {
    my ($self, $variable, $initial_value, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $pkg = $self->name;

    if (@_ > 2) {
        $self->_valid_for_type($initial_value, $type)
            || confess "$initial_value is not of type $type";

        # cheap fail-fast check for PERLDBf_SUBLINE and '&'
        if ($^P and $^P & 0x10 && $sigil eq '&') {
            my $filename = $opts{filename};
            my $first_line_num = $opts{first_line_num};

            (undef, $filename, $first_line_num) = caller
                if not defined $filename;

            my $last_line_num = $opts{last_line_num} || ($first_line_num ||= 0);

            # http://perldoc.perl.org/perldebguts.html#Debugger-Internals
            $DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
        }
    }

    no strict 'refs';
    no warnings 'redefine', 'misc', 'prototype';
    *{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
}

sub remove_glob {
    my ($self, $name) = @_;
    delete $self->namespace->{$name};
}

sub has_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    return unless exists $namespace->{$name};

    my $entry_ref = \$namespace->{$name};
    if (reftype($entry_ref) eq 'GLOB') {
        if ($type eq 'SCALAR') {
            if (BROKEN_SCALAR_INITIALIZATION) {
                return defined ${ *{$entry_ref}{$type} };
            }
            else {
                return B::svref_2object($entry_ref)->SV->isa('B::SV');
            }
        }
        else {
            return defined *{$entry_ref}{$type};
        }
    }
    else {
        # a symbol table entry can be -1 (stub), string (stub with prototype),
        # or reference (constant)
        return $type eq 'CODE';
    }
}

sub get_symbol {
    my ($self, $variable, %opts) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    my $namespace = $self->namespace;

    if (!exists $namespace->{$name}) {
        if ($opts{vivify}) {
            if ($type eq 'ARRAY') {
                if (BROKEN_ISA_ASSIGNMENT) {
                    $self->add_symbol(
                        $variable,
                        $name eq 'ISA' ? () : ([])
                    );
                }
                else {
                    $self->add_symbol($variable, []);
                }
            }
            elsif ($type eq 'HASH') {
                $self->add_symbol($variable, {});
            }
            elsif ($type eq 'SCALAR') {
                $self->add_symbol($variable);
            }
            elsif ($type eq 'IO') {
                $self->add_symbol($variable, Symbol::geniosym);
            }
            elsif ($type eq 'CODE') {
                confess "Don't know how to vivify CODE variables";
            }
            else {
                confess "Unknown type $type in vivication";
            }
        }
        else {
            return undef;
        }
    }

    my $entry_ref = \$namespace->{$name};

    if (ref($entry_ref) eq 'GLOB') {
        return *{$entry_ref}{$type};
    }
    else {
        if ($type eq 'CODE') {
            no strict 'refs';
            return \&{ $self->name . '::' . $name };
        }
        else {
            return undef;
        }
    }
}

sub get_or_add_symbol {
    my $self = shift;
    $self->get_symbol(@_, vivify => 1);
}

sub remove_symbol {
    my ($self, $variable) = @_;

    my ($name, $sigil, $type) = ref $variable eq 'HASH'
        ? @{$variable}{qw[name sigil type]}
        : $self->_deconstruct_variable_name($variable);

    # FIXME:
    # no doubt this is grossly inefficient and
    # could be done much easier and faster in XS

    my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
        { sigil => '$', type => 'SCALAR', name => $name },
        { sigil => '@', type => 'ARRAY',  name => $name },
        { sigil => '%', type => 'HASH',   name => $name },
        { sigil => '&', type => 'CODE',   name => $name },
        { sigil => '',  type => 'IO',     name => $name },
    );

    my ($scalar, $array, $hash, $code, $io);
    if ($type eq 'SCALAR') {
        $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
        $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
        $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
        $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
    }
    elsif ($type eq 'ARRAY') {
        $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
        $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
        $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
        $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
    }
    elsif ($type eq 'HASH') {
        $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
        $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
        $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
        $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
    }
    elsif ($type eq 'CODE') {
        $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
        $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
        $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
        $io     = $self->get_symbol($io_desc)     if $self->has_symbol($io_desc);
    }
    elsif ($type eq 'IO') {
        $scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) || BROKEN_SCALAR_INITIALIZATION;
        $array  = $self->get_symbol($array_desc)  if $self->has_symbol($array_desc);
        $hash   = $self->get_symbol($hash_desc)   if $self->has_symbol($hash_desc);
        $code   = $self->get_symbol($code_desc)   if $self->has_symbol($code_desc);
    }
    else {
        confess "This should never ever ever happen";
    }

    $self->remove_glob($name);

    $self->add_symbol($scalar_desc => $scalar) if defined $scalar;
    $self->add_symbol($array_desc  => $array)  if defined $array;
    $self->add_symbol($hash_desc   => $hash)   if defined $hash;
    $self->add_symbol($code_desc   => $code)   if defined $code;
    $self->add_symbol($io_desc     => $io)     if defined $io;
}

sub list_all_symbols {
    my ($self, $type_filter) = @_;

    my $namespace = $self->namespace;
    return keys %{$namespace} unless defined $type_filter;

    # NOTE:
    # or we can filter based on
    # type (SCALAR|ARRAY|HASH|CODE)
    if ($type_filter eq 'CODE') {
        return grep {
            # any non-typeglob in the symbol table is a constant or stub
            ref(\$namespace->{$_}) ne 'GLOB'
                # regular subs are stored in the CODE slot of the typeglob
                || defined(*{$namespace->{$_}}{CODE})
        } keys %{$namespace};
    }
    elsif ($type_filter eq 'SCALAR') {
        return grep {
            BROKEN_SCALAR_INITIALIZATION
                ? (ref(\$namespace->{$_}) eq 'GLOB'
                      && defined(${*{$namespace->{$_}}{'SCALAR'}}))
                : (do {
                      my $entry = \$namespace->{$_};
                      ref($entry) eq 'GLOB'
                          && B::svref_2object($entry)->SV->isa('B::SV')
                  })
        } keys %{$namespace};
    }
    else {
        return grep {
            ref(\$namespace->{$_}) eq 'GLOB'
                && defined(*{$namespace->{$_}}{$type_filter})
        } keys %{$namespace};
    }
}

sub get_all_symbols {
    my ($self, $type_filter) = @_;

    my $namespace = $self->namespace;
    return { %{$namespace} } unless defined $type_filter;

    return {
        map { $_ => $self->get_symbol({name => $_, type => $type_filter}) }
            $self->list_all_symbols($type_filter)
    }
}

=head1 BUGS

=over 4

=item * remove_symbol also replaces the associated typeglob

This can cause unexpected behavior when doing manipulation at compile time -
removing subroutines will still allow them to be called from within the package
as subroutines (although they will not be available as methods). This can be
considered a feature in some cases (this is how L<namespace::clean> works, for
instance), but should not be relied upon - use C<remove_glob> directly if you
want this behavior.

=item * Some minor memory leaks

The pure perl implementation has a couple minor memory leaks (see the TODO
tests in t/20-leaks.t) that I'm having a hard time tracking down - these may be
core perl bugs, it's hard to tell.

=back

Please report any bugs through RT: email
C<bug-package-stash at rt.cpan.org>, or browse to
L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.

=head1 SEE ALSO

=over 4

=item * L<Class::MOP::Package>

This module is a factoring out of code that used to live here

=back

=head1 SUPPORT

You can find this documentation for this module with the perldoc command.

    perldoc Package::Stash

You can also look for information at:

=over 4

=item * AnnoCPAN: Annotated CPAN documentation

L<http://annocpan.org/dist/Package-Stash>

=item * CPAN Ratings

L<http://cpanratings.perl.org/d/Package-Stash>

=item * RT: CPAN's request tracker

L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>

=item * Search CPAN

L<http://search.cpan.org/dist/Package-Stash>

=back

=head1 AUTHOR

Jesse Luehrs <doy at tozt dot net>

Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
Moose Cabal.

=begin Pod::Coverage

BROKEN_ISA_ASSIGNMENT
add_symbol
get_all_symbols
get_or_add_symbol
get_symbol
has_symbol
list_all_symbols
name
namespace
new
remove_glob

=end Pod::Coverage

=cut

1;
Commit	Line	Data
2905fb35	1	package Package::Stash::PP;
f10f6217	2	use strict;
f10f6217	3	use warnings;
2905fb35	4	# ABSTRACT: pure perl implementation of the Package::Stash API
f10f6217	5
7ef54f40	6	use B;
f10f6217	7	use Carp qw(confess);
eb53b1bd	8	use Scalar::Util qw(blessed reftype weaken);
dc378b60	9	use Symbol;
	10	# before 5.12, assigning to the ISA glob would make it lose its magical ->isa
	11	# powers
	12	use constant BROKEN_ISA_ASSIGNMENT => ($] < 5.012);
36cbfbad	13	# before 5.10, stashes don't ever seem to drop to a refcount of zero, so
	14	# weakening them isn't helpful
	15	use constant BROKEN_WEAK_STASH => ($] < 5.010);
7ef54f40	16	# before 5.10, the scalar slot was always treated as existing if the
	17	# glob existed
	18	use constant BROKEN_SCALAR_INITIALIZATION => ($] < 5.010);
f4979588	19
f4979588	20	=head1 SYNOPSIS
f4979588	21
2905fb35	22	use Package::Stash;
f4979588	23
	24	=head1 DESCRIPTION
	25
2905fb35	26	This is a backend for L<Package::Stash> implemented in pure perl, for those without a compiler or who would like to use this inline in scripts.
f4979588	27
	28	=cut
	29
f10f6217	30	sub new {
f10f6217	31	my $class = shift;
e55970bc	32	my ($package) = @_;
774f4f10	33
	34	if (!defined($package) \|\| (ref($package) && ref($package) ne 'HASH')) {
	35	confess "Package::Stash->new must be passed the name of the "
	36	. "package to access";
	37	}
	38	elsif (ref($package) eq 'HASH') {
	39	confess "The pure perl implementation of Package::Stash doesn't "
	40	. "currently support anonymous stashes. You should install "
	41	. "Package::Stash::XS";
	42	}
12b5662c	43	elsif ($package !~ /\A[0-9A-Z_a-z]+(?:::[0-9A-Z_a-z]+)*\z/) {
ed131e41	44	confess "$package is not a module name";
ed131e41	45	}
774f4f10	46
e55970bc	47	return bless {
eb53b1bd	48	'package' => $package,
e55970bc	49	}, $class;
f10f6217	50	}
	51
	52	sub name {
2905fb35	53	confess "Can't call name as a class method"
2905fb35	54	unless blessed($_[0]);
f10f6217	55	return $_[0]->{package};
	56	}
	57
	58	sub namespace {
2905fb35	59	confess "Can't call namespace as a class method"
2905fb35	60	unless blessed($_[0]);
eb53b1bd	61
36cbfbad	62	if (BROKEN_WEAK_STASH) {
eb53b1bd	63	no strict 'refs';
36cbfbad	64	return \%{$_[0]->name . '::'};
eb53b1bd	65	}
36cbfbad	66	else {
36cbfbad	67	return $_[0]->{namespace} if defined $_[0]->{namespace};
eb53b1bd	68
36cbfbad	69	{
	70	no strict 'refs';
	71	$_[0]->{namespace} = \%{$_[0]->name . '::'};
	72	}
	73
	74	weaken($_[0]->{namespace});
eb53b1bd	75
36cbfbad	76	return $_[0]->{namespace};
36cbfbad	77	}
f10f6217	78	}
	79
	80	{
	81	my %SIGIL_MAP = (
	82	'$' => 'SCALAR',
	83	'@' => 'ARRAY',
	84	'%' => 'HASH',
	85	'&' => 'CODE',
56a29840	86	'' => 'IO',
f10f6217	87	);
	88
	89	sub _deconstruct_variable_name {
	90	my ($self, $variable) = @_;
	91
56a29840	92	(defined $variable && length $variable)
f10f6217	93	\|\| confess "You must pass a variable name";
f10f6217	94
875d2d1d	95	# XXX in pure perl, this will access things in inner packages,
	96	# in xs, this will segfault - probably look more into this at
	97	# some point
	98	($variable !~ /::/)
	99	\|\| confess "Variable names may not contain ::";
	100
f10f6217	101	my $sigil = substr($variable, 0, 1, '');
f10f6217	102
56a29840	103	if (exists $SIGIL_MAP{$sigil}) {
	104	return ($variable, $sigil, $SIGIL_MAP{$sigil});
	105	}
	106	else {
	107	return ("${sigil}${variable}", '', $SIGIL_MAP{''});
	108	}
f10f6217	109	}
	110	}
	111
3634ce60	112	sub _valid_for_type {
	113	my $self = shift;
	114	my ($value, $type) = @_;
	115	if ($type eq 'HASH' \|\| $type eq 'ARRAY'
	116	\|\| $type eq 'IO' \|\| $type eq 'CODE') {
	117	return reftype($value) eq $type;
	118	}
	119	else {
	120	my $ref = reftype($value);
d173d3a3	121	return !defined($ref) \|\| $ref eq 'SCALAR' \|\| $ref eq 'REF' \|\| $ref eq 'LVALUE' \|\| $ref eq 'REGEXP' \|\| $ref eq 'VSTRING';
3634ce60	122	}
	123	}
	124
2905fb35	125	sub add_symbol {
640de369	126	my ($self, $variable, $initial_value, %opts) = @_;
f10f6217	127
	128	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	129	? @{$variable}{qw[name sigil type]}
	130	: $self->_deconstruct_variable_name($variable);
	131
4ada57e0	132	my $pkg = $self->name;
4ada57e0	133
3634ce60	134	if (@_ > 2) {
	135	$self->_valid_for_type($initial_value, $type)
	136	\|\| confess "$initial_value is not of type $type";
3634ce60	137
4ada57e0	138	# cheap fail-fast check for PERLDBf_SUBLINE and '&'
4ada57e0	139	if ($^P and $^P & 0x10 && $sigil eq '&') {
640de369	140	my $filename = $opts{filename};
640de369	141	my $first_line_num = $opts{first_line_num};
4ada57e0	142
640de369	143	(undef, $filename, $first_line_num) = caller
4ada57e0	144	if not defined $filename;
640de369	145
640de369	146	my $last_line_num = $opts{last_line_num} \|\| ($first_line_num \|\|= 0);
4ada57e0	147
4ada57e0	148	# http://perldoc.perl.org/perldebguts.html#Debugger-Internals
640de369	149	$DB::sub{$pkg . '::' . $name} = "$filename:$first_line_num-$last_line_num";
4ada57e0	150	}
4ada57e0	151	}
f10f6217	152
	153	no strict 'refs';
	154	no warnings 'redefine', 'misc', 'prototype';
	155	*{$pkg . '::' . $name} = ref $initial_value ? $initial_value : \$initial_value;
	156	}
	157
2905fb35	158	sub remove_glob {
f10f6217	159	my ($self, $name) = @_;
65b8253b	160	delete $self->namespace->{$name};
f10f6217	161	}
f10f6217	162
2905fb35	163	sub has_symbol {
f10f6217	164	my ($self, $variable) = @_;
	165
	166	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	167	? @{$variable}{qw[name sigil type]}
	168	: $self->_deconstruct_variable_name($variable);
	169
	170	my $namespace = $self->namespace;
	171
	172	return unless exists $namespace->{$name};
	173
	174	my $entry_ref = \$namespace->{$name};
	175	if (reftype($entry_ref) eq 'GLOB') {
f7543739	176	if ($type eq 'SCALAR') {
7ef54f40	177	if (BROKEN_SCALAR_INITIALIZATION) {
	178	return defined ${ *{$entry_ref}{$type} };
	179	}
	180	else {
	181	return B::svref_2object($entry_ref)->SV->isa('B::SV');
	182	}
f7543739	183	}
	184	else {
	185	return defined *{$entry_ref}{$type};
	186	}
f10f6217	187	}
	188	else {
	189	# a symbol table entry can be -1 (stub), string (stub with prototype),
	190	# or reference (constant)
	191	return $type eq 'CODE';
	192	}
	193	}
	194
2905fb35	195	sub get_symbol {
e55803fc	196	my ($self, $variable, %opts) = @_;
f10f6217	197
	198	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	199	? @{$variable}{qw[name sigil type]}
	200	: $self->_deconstruct_variable_name($variable);
	201
	202	my $namespace = $self->namespace;
	203
7486ccf3	204	if (!exists $namespace->{$name}) {
dc378b60	205	if ($opts{vivify}) {
	206	if ($type eq 'ARRAY') {
	207	if (BROKEN_ISA_ASSIGNMENT) {
2905fb35	208	$self->add_symbol(
dc378b60	209	$variable,
	210	$name eq 'ISA' ? () : ([])
	211	);
	212	}
	213	else {
2905fb35	214	$self->add_symbol($variable, []);
dc378b60	215	}
	216	}
	217	elsif ($type eq 'HASH') {
2905fb35	218	$self->add_symbol($variable, {});
dc378b60	219	}
dc378b60	220	elsif ($type eq 'SCALAR') {
2905fb35	221	$self->add_symbol($variable);
dc378b60	222	}
dc378b60	223	elsif ($type eq 'IO') {
2905fb35	224	$self->add_symbol($variable, Symbol::geniosym);
dc378b60	225	}
	226	elsif ($type eq 'CODE') {
	227	confess "Don't know how to vivify CODE variables";
	228	}
	229	else {
	230	confess "Unknown type $type in vivication";
	231	}
5d3589c8	232	}
e55803fc	233	else {
4723417a	234	return undef;
e55803fc	235	}
30d1a098	236	}
f10f6217	237
	238	my $entry_ref = \$namespace->{$name};
	239
	240	if (ref($entry_ref) eq 'GLOB') {
	241	return *{$entry_ref}{$type};
	242	}
	243	else {
	244	if ($type eq 'CODE') {
	245	no strict 'refs';
	246	return \&{ $self->name . '::' . $name };
	247	}
	248	else {
	249	return undef;
	250	}
	251	}
	252	}
	253
2905fb35	254	sub get_or_add_symbol {
e55803fc	255	my $self = shift;
2905fb35	256	$self->get_symbol(@_, vivify => 1);
e55803fc	257	}
e55803fc	258
2905fb35	259	sub remove_symbol {
f10f6217	260	my ($self, $variable) = @_;
	261
	262	my ($name, $sigil, $type) = ref $variable eq 'HASH'
	263	? @{$variable}{qw[name sigil type]}
	264	: $self->_deconstruct_variable_name($variable);
	265
	266	# FIXME:
9a3d1390	267	# no doubt this is grossly inefficient and
f10f6217	268	# could be done much easier and faster in XS
f10f6217	269
b1a00d0e	270	my ($scalar_desc, $array_desc, $hash_desc, $code_desc, $io_desc) = (
f10f6217	271	{ sigil => '$', type => 'SCALAR', name => $name },
	272	{ sigil => '@', type => 'ARRAY', name => $name },
	273	{ sigil => '%', type => 'HASH', name => $name },
	274	{ sigil => '&', type => 'CODE', name => $name },
b1a00d0e	275	{ sigil => '', type => 'IO', name => $name },
f10f6217	276	);
f10f6217	277
b1a00d0e	278	my ($scalar, $array, $hash, $code, $io);
f10f6217	279	if ($type eq 'SCALAR') {
2905fb35	280	$array = $self->get_symbol($array_desc) if $self->has_symbol($array_desc);
	281	$hash = $self->get_symbol($hash_desc) if $self->has_symbol($hash_desc);
	282	$code = $self->get_symbol($code_desc) if $self->has_symbol($code_desc);
	283	$io = $self->get_symbol($io_desc) if $self->has_symbol($io_desc);
f10f6217	284	}
f10f6217	285	elsif ($type eq 'ARRAY') {
7ef54f40	286	$scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) \|\| BROKEN_SCALAR_INITIALIZATION;
2905fb35	287	$hash = $self->get_symbol($hash_desc) if $self->has_symbol($hash_desc);
	288	$code = $self->get_symbol($code_desc) if $self->has_symbol($code_desc);
	289	$io = $self->get_symbol($io_desc) if $self->has_symbol($io_desc);
f10f6217	290	}
f10f6217	291	elsif ($type eq 'HASH') {
7ef54f40	292	$scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) \|\| BROKEN_SCALAR_INITIALIZATION;
2905fb35	293	$array = $self->get_symbol($array_desc) if $self->has_symbol($array_desc);
	294	$code = $self->get_symbol($code_desc) if $self->has_symbol($code_desc);
	295	$io = $self->get_symbol($io_desc) if $self->has_symbol($io_desc);
f10f6217	296	}
f10f6217	297	elsif ($type eq 'CODE') {
7ef54f40	298	$scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) \|\| BROKEN_SCALAR_INITIALIZATION;
2905fb35	299	$array = $self->get_symbol($array_desc) if $self->has_symbol($array_desc);
	300	$hash = $self->get_symbol($hash_desc) if $self->has_symbol($hash_desc);
	301	$io = $self->get_symbol($io_desc) if $self->has_symbol($io_desc);
b1a00d0e	302	}
b1a00d0e	303	elsif ($type eq 'IO') {
7ef54f40	304	$scalar = $self->get_symbol($scalar_desc) if $self->has_symbol($scalar_desc) \|\| BROKEN_SCALAR_INITIALIZATION;
2905fb35	305	$array = $self->get_symbol($array_desc) if $self->has_symbol($array_desc);
	306	$hash = $self->get_symbol($hash_desc) if $self->has_symbol($hash_desc);
	307	$code = $self->get_symbol($code_desc) if $self->has_symbol($code_desc);
f10f6217	308	}
	309	else {
	310	confess "This should never ever ever happen";
	311	}
	312
2905fb35	313	$self->remove_glob($name);
f10f6217	314
7ef54f40	315	$self->add_symbol($scalar_desc => $scalar) if defined $scalar;
2905fb35	316	$self->add_symbol($array_desc => $array) if defined $array;
	317	$self->add_symbol($hash_desc => $hash) if defined $hash;
	318	$self->add_symbol($code_desc => $code) if defined $code;
	319	$self->add_symbol($io_desc => $io) if defined $io;
f10f6217	320	}
f10f6217	321
2905fb35	322	sub list_all_symbols {
f10f6217	323	my ($self, $type_filter) = @_;
	324
	325	my $namespace = $self->namespace;
	326	return keys %{$namespace} unless defined $type_filter;
	327
	328	# NOTE:
9a3d1390	329	# or we can filter based on
f10f6217	330	# type (SCALAR\|ARRAY\|HASH\|CODE)
	331	if ($type_filter eq 'CODE') {
	332	return grep {
25c87f5c	333	# any non-typeglob in the symbol table is a constant or stub
	334	ref(\$namespace->{$_}) ne 'GLOB'
	335	# regular subs are stored in the CODE slot of the typeglob
d1f721b3	336	\|\| defined(*{$namespace->{$_}}{CODE})
	337	} keys %{$namespace};
	338	}
	339	elsif ($type_filter eq 'SCALAR') {
	340	return grep {
7ef54f40	341	BROKEN_SCALAR_INITIALIZATION
	342	? (ref(\$namespace->{$_}) eq 'GLOB'
	343	&& defined(${*{$namespace->{$_}}{'SCALAR'}}))
	344	: (do {
	345	my $entry = \$namespace->{$_};
	346	ref($entry) eq 'GLOB'
	347	&& B::svref_2object($entry)->SV->isa('B::SV')
	348	})
d1f721b3	349	} keys %{$namespace};
	350	}
	351	else {
	352	return grep {
	353	ref(\$namespace->{$_}) eq 'GLOB'
	354	&& defined(*{$namespace->{$_}}{$type_filter})
f10f6217	355	} keys %{$namespace};
f10f6217	356	}
f10f6217	357	}
f4979588	358
2905fb35	359	sub get_all_symbols {
	360	my ($self, $type_filter) = @_;
	361
	362	my $namespace = $self->namespace;
	363	return { %{$namespace} } unless defined $type_filter;
	364
	365	return {
	366	map { $_ => $self->get_symbol({name => $_, type => $type_filter}) }
	367	$self->list_all_symbols($type_filter)
	368	}
	369	}
	370
0992f4ec	371	=head1 BUGS
0992f4ec	372
2905fb35	373	=over 4
2905fb35	374
2905fb35	375	=item * remove_symbol also replaces the associated typeglob
	376
	377	This can cause unexpected behavior when doing manipulation at compile time -
	378	removing subroutines will still allow them to be called from within the package
	379	as subroutines (although they will not be available as methods). This can be
	380	considered a feature in some cases (this is how L<namespace::clean> works, for
	381	instance), but should not be relied upon - use C<remove_glob> directly if you
	382	want this behavior.
	383
cdb543b5	384	=item * Some minor memory leaks
	385
	386	The pure perl implementation has a couple minor memory leaks (see the TODO
	387	tests in t/20-leaks.t) that I'm having a hard time tracking down - these may be
	388	core perl bugs, it's hard to tell.
	389
2905fb35	390	=back
0992f4ec	391
	392	Please report any bugs through RT: email
	393	C<bug-package-stash at rt.cpan.org>, or browse to
	394	L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Package-Stash>.
	395
f4979588	396	=head1 SEE ALSO
f4979588	397
f4979588	398	=over 4
f4979588	399
988beb41	400	=item * L<Class::MOP::Package>
f4979588	401
988beb41	402	This module is a factoring out of code that used to live here
f4979588	403
	404	=back
	405
0992f4ec	406	=head1 SUPPORT
	407
	408	You can find this documentation for this module with the perldoc command.
	409
	410	perldoc Package::Stash
	411
	412	You can also look for information at:
	413
	414	=over 4
	415
	416	=item * AnnoCPAN: Annotated CPAN documentation
	417
	418	L<http://annocpan.org/dist/Package-Stash>
	419
	420	=item * CPAN Ratings
	421
	422	L<http://cpanratings.perl.org/d/Package-Stash>
	423
	424	=item * RT: CPAN's request tracker
	425
	426	L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Package-Stash>
	427
	428	=item * Search CPAN
	429
	430	L<http://search.cpan.org/dist/Package-Stash>
	431
	432	=back
	433
	434	=head1 AUTHOR
	435
	436	Jesse Luehrs <doy at tozt dot net>
	437
	438	Mostly copied from code from L<Class::MOP::Package>, by Stevan Little and the
	439	Moose Cabal.
	440
a912fc4b	441	=begin Pod::Coverage
	442
	443	BROKEN_ISA_ASSIGNMENT
	444	add_symbol
	445	get_all_symbols
	446	get_or_add_symbol
	447	get_symbol
	448	has_symbol
	449	list_all_symbols
	450	name
	451	namespace
	452	new
	453	remove_glob
	454
	455	=end Pod::Coverage
	456
f4979588	457	=cut
	458
	459	1;