[gitmo/MooseX-Storage.git] / lib / MooseX / Storage / Engine.pm


package MooseX::Storage::Engine;
use Moose;
use Scalar::Util qw(refaddr);

our $VERSION   = '0.17';
our $AUTHORITY = 'cpan:STEVAN';

# the class marker when 
# serializing an object. 
our $CLASS_MARKER = '__CLASS__';

has 'storage' => (
    is      => 'ro',
    isa     => 'HashRef',
    default => sub {{}}
);

has 'seen' => (
    is      => 'ro',
    isa     => 'HashRef[Int]', # int is the refaddr
    default => sub {{}}
);

has 'object' => (is => 'rw', isa => 'Object');
has 'class'  => (is => 'rw', isa => 'Str');

## this is the API used by other modules ...

sub collapse_object {
    my ( $self, %options ) = @_;

	# NOTE:
	# mark the root object as seen ...
	$self->seen->{refaddr $self->object} = undef;
	
    $self->map_attributes('collapse_attribute', \%options);
    $self->storage->{$CLASS_MARKER} = $self->object->meta->identifier;    
	return $self->storage;
}

sub expand_object {
    my ($self, $data, %options) = @_;
    
    $options{check_version}   = 1 unless exists $options{check_version};
    $options{check_authority} = 1 unless exists $options{check_authority};   
    
	# NOTE:
	# mark the root object as seen ...
	$self->seen->{refaddr $data} = undef;    
    
    $self->map_attributes('expand_attribute', $data, \%options);
	return $self->storage;    
}

## this is the internal API ...

sub collapse_attribute {
    my ($self, $attr, $options)  = @_;
    my $value = $self->collapse_attribute_value($attr, $options);
    return if !defined($value);
    $self->storage->{$attr->name} = $value;
}

sub expand_attribute {
    my ($self, $attr, $data, $options)  = @_;
    my $value = $self->expand_attribute_value($attr, $data->{$attr->name}, $options);
    $self->storage->{$attr->name} = defined $value ? $value : return;
}

sub collapse_attribute_value {
    my ($self, $attr, $options)  = @_;
    # Faster, but breaks attributes without readers, do we care?
	#my $value = $attr->get_read_method_ref->($self->object);
	my $value = $attr->get_value($self->object);

	# NOTE:
	# this might not be enough, we might
	# need to make it possible for the
	# cycle checker to return the value
    $self->check_for_cycle_in_collapse($attr, $value)
        if ref $value;

    if (defined $value && $attr->has_type_constraint) {
        my $type_converter = $self->find_type_handler($attr->type_constraint);
        (defined $type_converter)
            || confess "Cannot convert " . $attr->type_constraint->name;
        $value = $type_converter->{collapse}->($value, $options);
    }
	return $value;
}

sub expand_attribute_value {
    my ($self, $attr, $value, $options)  = @_;

	# NOTE:
	# (see comment in method above ^^)
    $self->check_for_cycle_in_expansion($attr, $value) 
        if ref $value;    
    
    if (defined $value && $attr->has_type_constraint) {
        my $type_converter = $self->find_type_handler($attr->type_constraint);
        $value = $type_converter->{expand}->($value, $options);
    }
	return $value;
}

# NOTE:
# possibly these two methods will 
# be used by a cycle supporting 
# engine. However, I am not sure 
# if I can make a cycle one work 
# anyway.

sub check_for_cycle_in_collapse {
    my ($self, $attr, $value) = @_;
    (!exists $self->seen->{refaddr $value})
        || confess "Basic Engine does not support cycles in class(" 
                 . ($attr->associated_class->name) . ").attr("
                 . ($attr->name) . ") with $value";
    $self->seen->{refaddr $value} = undef;
}

sub check_for_cycle_in_expansion {
    my ($self, $attr, $value) = @_;
    (!exists $self->seen->{refaddr $value})
    || confess "Basic Engine does not support cycles in class(" 
             . ($attr->associated_class->name) . ").attr("
             . ($attr->name) . ") with $value";
    $self->seen->{refaddr $value} = undef;
}

# util methods ...

sub map_attributes {
    my ($self, $method_name, @args) = @_;
    map { 
        $self->$method_name($_, @args) 
    } grep {
        # Skip our special skip attribute :)
        !$_->does('MooseX::Storage::Meta::Attribute::Trait::DoNotSerialize') 
    } ($self->object || $self->class)->meta->get_all_attributes;
}

## ------------------------------------------------------------------
## This is all the type handler stuff, it is in a state of flux
## right now, so this may change, or it may just continue to be 
## improved upon. Comments and suggestions are welcomed.
## ------------------------------------------------------------------

# NOTE:
# these are needed by the 
# ArrayRef and HashRef handlers
# below, so I need easy access 
my %OBJECT_HANDLERS = (
    expand => sub {
        my ($data, $options) = @_;   
        (exists $data->{$CLASS_MARKER})
            || confess "Serialized item has no class marker";
        # check the class more thoroughly here ...
        my ($class, $version, $authority) = (split '-' => $data->{$CLASS_MARKER});
        my $meta = eval { $class->meta };
        confess "Class ($class) is not loaded, cannot unpack" if $@;     
        
        if ($options->{check_version}) {
            my $meta_version = $meta->version;
            if (defined $meta_version && $version) {            
                if ($options->{check_version} eq 'allow_less_than') {
                    ($meta_version <= $version)
                        || confess "Class ($class) versions is not less than currently available." 
                                 . " got=($version) available=($meta_version)";                
                }
                elsif ($options->{check_version} eq 'allow_greater_than') {
                    ($meta->version >= $version)
                        || confess "Class ($class) versions is not greater than currently available." 
                                 . " got=($version) available=($meta_version)";                
                }            
                else {
                    ($meta->version == $version)
                        || confess "Class ($class) versions don't match." 
                                 . " got=($version) available=($meta_version)";
                }
            }
        }
        
        if ($options->{check_authority}) {
            my $meta_authority = $meta->authority;
            ($meta->authority eq $authority)
                || confess "Class ($class) authorities don't match." 
                         . " got=($authority) available=($meta_authority)"
                if defined $meta_authority && defined $authority;            
        }
            
        # all is well ...
        $class->unpack($data, %$options);
    },
    collapse => sub {
        my ( $obj, $options ) = @_;
#        ($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
#            || confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
        ($obj->can('pack'))
            || confess "Object ($obj) does not have a &pack method, cannot collapse";
        $obj->pack(%$options);
    },
);


my %TYPES = (
    # NOTE:
    # we need to make sure that we properly numify the numbers 
    # before and after them being futzed with, because some of 
    # the JSON engines are stupid/annoying/frustrating
    'Int'      => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
    'Num'      => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
    # These are boring ones, so they use the identity function ...    
    'Str'      => { expand => sub { shift }, collapse => sub { shift } },
    'Bool'     => { expand => sub { shift }, collapse => sub { shift } },
    # These are the trickier ones, (see notes)
    # NOTE:
    # Because we are nice guys, we will check 
    # your ArrayRef and/or HashRef one level 
    # down and inflate any objects we find. 
    # But this is where it ends, it is too
    # expensive to try and do this any more  
    # recursively, when it is probably not 
    # nessecary in most of the use cases.
    # However, if you need more then this, subtype 
    # and add a custom handler.    
    'ArrayRef' => { 
        expand => sub {
            my ( $array, @args ) = @_;
            foreach my $i (0 .. $#{$array}) {
                next unless ref($array->[$i]) eq 'HASH' 
                         && exists $array->[$i]->{$CLASS_MARKER};
                $array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i], @args);
            }
            $array;
        }, 
        collapse => sub {
            my ( $array, @args ) = @_;
            # NOTE:         
            # we need to make a copy cause
            # otherwise it will affect the 
            # other real version.
            [ map {
                blessed($_)
                    ? $OBJECT_HANDLERS{collapse}->($_, @args)
                    : $_
            } @$array ] 
        } 
    },
    'HashRef'  => { 
        expand   => sub {
            my ( $hash, @args ) = @_;
            foreach my $k (keys %$hash) {
                next unless ref($hash->{$k}) eq 'HASH' 
                         && exists $hash->{$k}->{$CLASS_MARKER};
                $hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k}, @args);
            }
            $hash;            
        }, 
        collapse => sub {
            my ( $hash, @args ) = @_;
            # NOTE:         
            # we need to make a copy cause
            # otherwise it will affect the 
            # other real version.
            +{ map {
                blessed($hash->{$_})
                    ? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}, @args))
                    : ($_ => $hash->{$_})
            } keys %$hash }            
        } 
    },
    'Object'   => \%OBJECT_HANDLERS,
    # NOTE:
    # The sanity of enabling this feature by 
    # default is very questionable.
    # - SL
    #'CodeRef' => {
    #    expand   => sub {}, # use eval ...
    #    collapse => sub {}, # use B::Deparse ...        
    #} 
);

sub add_custom_type_handler {
    my ($class, $type_name, %handlers) = @_;
    (exists $handlers{expand} && exists $handlers{collapse})
        || confess "Custom type handlers need an expand *and* a collapse method";
    $TYPES{$type_name} = \%handlers;
}

sub remove_custom_type_handler {
    my ($class, $type_name) = @_;
    delete $TYPES{$type_name} if exists $TYPES{$type_name};
}

sub find_type_handler {
    my ($self, $type_constraint) = @_;
    
    # check if the type is a Maybe and
    # if its parent is not parameterized.
    # If both is true recurse this method
    # using ->type_parameter.
    return $self->find_type_handler($type_constraint->type_parameter)
        if $type_constraint->parent eq 'Maybe'
          and not $type_constraint->parent->can('type_parameter');

    # this should handle most type usages
    # since they they are usually just 
    # the standard set of built-ins
    return $TYPES{$type_constraint->name} 
        if exists $TYPES{$type_constraint->name};
      
    # the next possibility is they are 
    # a subtype of the built-in types, 
    # in which case this will DWIM in 
    # most cases. It is probably not 
    # 100% ideal though, but until I 
    # come up with a decent test case 
    # it will do for now.
    foreach my $type (keys %TYPES) {
        return $TYPES{$type} 
            if $type_constraint->is_subtype_of($type);
    }
    
    # NOTE:
    # the reason the above will work has to 
    # do with the fact that custom subtypes
    # are mostly used for validation of 
    # the guts of a type, and not for some
    # weird structural thing which would 
    # need to be accomidated by the serializer.
    # Of course, mst or phaylon will probably  
    # do something to throw this assumption 
    # totally out the door ;)
    # - SL
    
    # NOTE:
    # if this method hasnt returned by now
    # then we have no been able to find a 
    # type constraint handler to match 
    confess "Cannot handle type constraint (" . $type_constraint->name . ")";    
}

sub find_type_handler_for {
    my ($self, $type_handler_name) = @_;
    $TYPES{$type_handler_name}
}

1;

__END__

=pod

=head1 NAME

MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects

=head1 DESCRIPTION

No user serviceable parts inside. If you really want to know, read the source :)

=head1 METHODS

=head2 Accessors

=over 4

=item B<class>

=item B<object>

=item B<storage>

=item B<seen>

=back

=head2 API

=over 4

=item B<expand_object>

=item B<collapse_object>

=back

=head2 ...

=over 4

=item B<collapse_attribute>

=item B<collapse_attribute_value>

=item B<expand_attribute>

=item B<expand_attribute_value>

=item B<check_for_cycle_in_collapse>

=item B<check_for_cycle_in_expansion>

=item B<map_attributes>

=back

=head2 Type Constraint Handlers

=over 4

=item B<find_type_handler ($type)>

=item B<find_type_handler_for ($name)>

=item B<add_custom_type_handler ($name, %handlers)>

=item B<remove_custom_type_handler ($name)>

=back

=head2 Introspection

=over 4

=item B<meta>

=back

=head1 BUGS

All complex software has bugs lurking in it, and this module is no 
exception. If you find a bug please either email me, or add the bug
to cpan-RT.

=head1 AUTHOR

Chris Prather E<lt>chris.prather@iinteractive.comE<gt>

Stevan Little E<lt>stevan.little@iinteractive.comE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2008 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut
Commit	Line	Data
e59193fb	1
	2	package MooseX::Storage::Engine;
	3	use Moose;
ec73712a	4	use Scalar::Util qw(refaddr);
e59193fb	5
f4ffa4ef	6	our $VERSION = '0.17';
69b45b7d	7	our $AUTHORITY = 'cpan:STEVAN';
ba5bba75	8
	9	# the class marker when
	10	# serializing an object.
	11	our $CLASS_MARKER = '__CLASS__';
	12
e59193fb	13	has 'storage' => (
7eb5dc63	14	is => 'ro',
	15	isa => 'HashRef',
	16	default => sub {{}}
	17	);
	18
	19	has 'seen' => (
	20	is => 'ro',
ec73712a	21	isa => 'HashRef[Int]', # int is the refaddr
e59193fb	22	default => sub {{}}
	23	);
	24
e9739624	25	has 'object' => (is => 'rw', isa => 'Object');
e9739624	26	has 'class' => (is => 'rw', isa => 'Str');
e59193fb	27
e9739624	28	## this is the API used by other modules ...
e59193fb	29
e59193fb	30	sub collapse_object {
34dcaa5d	31	my ( $self, %options ) = @_;
7eb5dc63	32
	33	# NOTE:
	34	# mark the root object as seen ...
ec73712a	35	$self->seen->{refaddr $self->object} = undef;
7eb5dc63	36
34dcaa5d	37	$self->map_attributes('collapse_attribute', \%options);
c1830046	38	$self->storage->{$CLASS_MARKER} = $self->object->meta->identifier;
e59193fb	39	return $self->storage;
	40	}
	41
e9739624	42	sub expand_object {
219c1cc5	43	my ($self, $data, %options) = @_;
	44
	45	$options{check_version} = 1 unless exists $options{check_version};
	46	$options{check_authority} = 1 unless exists $options{check_authority};
7eb5dc63	47
	48	# NOTE:
	49	# mark the root object as seen ...
ec73712a	50	$self->seen->{refaddr $data} = undef;
7eb5dc63	51
219c1cc5	52	$self->map_attributes('expand_attribute', $data, \%options);
e9739624	53	return $self->storage;
e59193fb	54	}
e59193fb	55
e9739624	56	## this is the internal API ...
	57
	58	sub collapse_attribute {
f6e1331f	59	my ($self, $attr, $options) = @_;
eea0dfae	60	my $value = $self->collapse_attribute_value($attr, $options);
	61	return if !defined($value);
	62	$self->storage->{$attr->name} = $value;
e9739624	63	}
	64
	65	sub expand_attribute {
219c1cc5	66	my ($self, $attr, $data, $options) = @_;
14b0a4dc	67	my $value = $self->expand_attribute_value($attr, $data->{$attr->name}, $options);
14b0a4dc	68	$self->storage->{$attr->name} = defined $value ? $value : return;
e59193fb	69	}
e59193fb	70
e9739624	71	sub collapse_attribute_value {
f6e1331f	72	my ($self, $attr, $options) = @_;
f4ffa4ef	73	# Faster, but breaks attributes without readers, do we care?
f4ffa4ef	74	#my $value = $attr->get_read_method_ref->($self->object);
e9739624	75	my $value = $attr->get_value($self->object);
f4ffa4ef	76
b430caa3	77	# NOTE:
f4ffa4ef	78	# this might not be enough, we might
f4ffa4ef	79	# need to make it possible for the
b430caa3	80	# cycle checker to return the value
34dcaa5d	81	$self->check_for_cycle_in_collapse($attr, $value)
7eb5dc63	82	if ref $value;
f4ffa4ef	83
e9739624	84	if (defined $value && $attr->has_type_constraint) {
3db8f791	85	my $type_converter = $self->find_type_handler($attr->type_constraint);
e9739624	86	(defined $type_converter)
e9739624	87	\|\| confess "Cannot convert " . $attr->type_constraint->name;
f6e1331f	88	$value = $type_converter->{collapse}->($value, $options);
e9739624	89	}
	90	return $value;
	91	}
	92
	93	sub expand_attribute_value {
219c1cc5	94	my ($self, $attr, $value, $options) = @_;
7eb5dc63	95
b430caa3	96	# NOTE:
b430caa3	97	# (see comment in method above ^^)
45d9a73c	98	$self->check_for_cycle_in_expansion($attr, $value)
7eb5dc63	99	if ref $value;
7eb5dc63	100
e9739624	101	if (defined $value && $attr->has_type_constraint) {
3db8f791	102	my $type_converter = $self->find_type_handler($attr->type_constraint);
219c1cc5	103	$value = $type_converter->{expand}->($value, $options);
e9739624	104	}
	105	return $value;
	106	}
	107
b430caa3	108	# NOTE:
	109	# possibly these two methods will
	110	# be used by a cycle supporting
	111	# engine. However, I am not sure
	112	# if I can make a cycle one work
	113	# anyway.
e9739624	114
7eb5dc63	115	sub check_for_cycle_in_collapse {
45d9a73c	116	my ($self, $attr, $value) = @_;
ec73712a	117	(!exists $self->seen->{refaddr $value})
45d9a73c	118	\|\| confess "Basic Engine does not support cycles in class("
c1830046	119	. ($attr->associated_class->name) . ").attr("
45d9a73c	120	. ($attr->name) . ") with $value";
ec73712a	121	$self->seen->{refaddr $value} = undef;
7eb5dc63	122	}
	123
	124	sub check_for_cycle_in_expansion {
45d9a73c	125	my ($self, $attr, $value) = @_;
ec73712a	126	(!exists $self->seen->{refaddr $value})
45d9a73c	127	\|\| confess "Basic Engine does not support cycles in class("
c1830046	128	. ($attr->associated_class->name) . ").attr("
45d9a73c	129	. ($attr->name) . ") with $value";
ec73712a	130	$self->seen->{refaddr $value} = undef;
7eb5dc63	131	}
7eb5dc63	132
b430caa3	133	# util methods ...
b430caa3	134
e9739624	135	sub map_attributes {
	136	my ($self, $method_name, @args) = @_;
	137	map {
	138	$self->$method_name($_, @args)
b430caa3	139	} grep {
b430caa3	140	# Skip our special skip attribute :)
04990d7a	141	!$_->does('MooseX::Storage::Meta::Attribute::Trait::DoNotSerialize')
f4ffa4ef	142	} ($self->object \|\| $self->class)->meta->get_all_attributes;
e59193fb	143	}
e59193fb	144
913d96dd	145	## ------------------------------------------------------------------
3db8f791	146	## This is all the type handler stuff, it is in a state of flux
	147	## right now, so this may change, or it may just continue to be
	148	## improved upon. Comments and suggestions are welcomed.
913d96dd	149	## ------------------------------------------------------------------
	150
	151	# NOTE:
	152	# these are needed by the
	153	# ArrayRef and HashRef handlers
	154	# below, so I need easy access
	155	my %OBJECT_HANDLERS = (
	156	expand => sub {
219c1cc5	157	my ($data, $options) = @_;
ba5bba75	158	(exists $data->{$CLASS_MARKER})
913d96dd	159	\|\| confess "Serialized item has no class marker";
c1830046	160	# check the class more thoroughly here ...
	161	my ($class, $version, $authority) = (split '-' => $data->{$CLASS_MARKER});
	162	my $meta = eval { $class->meta };
219c1cc5	163	confess "Class ($class) is not loaded, cannot unpack" if $@;
	164
	165	if ($options->{check_version}) {
	166	my $meta_version = $meta->version;
	167	if (defined $meta_version && $version) {
	168	if ($options->{check_version} eq 'allow_less_than') {
	169	($meta_version <= $version)
	170	\|\| confess "Class ($class) versions is not less than currently available."
	171	. " got=($version) available=($meta_version)";
	172	}
	173	elsif ($options->{check_version} eq 'allow_greater_than') {
	174	($meta->version >= $version)
	175	\|\| confess "Class ($class) versions is not greater than currently available."
	176	. " got=($version) available=($meta_version)";
	177	}
	178	else {
	179	($meta->version == $version)
	180	\|\| confess "Class ($class) versions don't match."
	181	. " got=($version) available=($meta_version)";
	182	}
	183	}
	184	}
	185
	186	if ($options->{check_authority}) {
	187	my $meta_authority = $meta->authority;
	188	($meta->authority eq $authority)
	189	\|\| confess "Class ($class) authorities don't match."
	190	. " got=($authority) available=($meta_authority)"
	191	if defined $meta_authority && defined $authority;
	192	}
	193
c1830046	194	# all is well ...
34dcaa5d	195	$class->unpack($data, %$options);
913d96dd	196	},
913d96dd	197	collapse => sub {
34dcaa5d	198	my ( $obj, $options ) = @_;
c4a322ec	199	# ($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
c4a322ec	200	# \|\| confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
1c6ac775	201	($obj->can('pack'))
3defafb9	202	\|\| confess "Object ($obj) does not have a &pack method, cannot collapse";
34dcaa5d	203	$obj->pack(%$options);
913d96dd	204	},
	205	);
	206
	207
e59193fb	208	my %TYPES = (
cfee09ad	209	# NOTE:
	210	# we need to make sure that we properly numify the numbers
	211	# before and after them being futzed with, because some of
	212	# the JSON engines are stupid/annoying/frustrating
	213	'Int' => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
	214	'Num' => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
	215	# These are boring ones, so they use the identity function ...
e9739624	216	'Str' => { expand => sub { shift }, collapse => sub { shift } },
d691721b	217	'Bool' => { expand => sub { shift }, collapse => sub { shift } },
3db8f791	218	# These are the trickier ones, (see notes)
	219	# NOTE:
	220	# Because we are nice guys, we will check
	221	# your ArrayRef and/or HashRef one level
	222	# down and inflate any objects we find.
	223	# But this is where it ends, it is too
	224	# expensive to try and do this any more
	225	# recursively, when it is probably not
	226	# nessecary in most of the use cases.
	227	# However, if you need more then this, subtype
	228	# and add a custom handler.
913d96dd	229	'ArrayRef' => {
e9739624	230	expand => sub {
34dcaa5d	231	my ( $array, @args ) = @_;
913d96dd	232	foreach my $i (0 .. $#{$array}) {
913d96dd	233	next unless ref($array->[$i]) eq 'HASH'
ba5bba75	234	&& exists $array->[$i]->{$CLASS_MARKER};
34dcaa5d	235	$array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i], @args);
913d96dd	236	}
	237	$array;
	238	},
34dcaa5d	239	collapse => sub {
34dcaa5d	240	my ( $array, @args ) = @_;
913d96dd	241	# NOTE:
	242	# we need to make a copy cause
	243	# otherwise it will affect the
	244	# other real version.
	245	[ map {
	246	blessed($_)
34dcaa5d	247	? $OBJECT_HANDLERS{collapse}->($_, @args)
913d96dd	248	: $_
	249	} @$array ]
	250	}
	251	},
	252	'HashRef' => {
3db8f791	253	expand => sub {
34dcaa5d	254	my ( $hash, @args ) = @_;
3db8f791	255	foreach my $k (keys %$hash) {
3db8f791	256	next unless ref($hash->{$k}) eq 'HASH'
ba5bba75	257	&& exists $hash->{$k}->{$CLASS_MARKER};
34dcaa5d	258	$hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k}, @args);
3db8f791	259	}
	260	$hash;
	261	},
	262	collapse => sub {
34dcaa5d	263	my ( $hash, @args ) = @_;
3db8f791	264	# NOTE:
	265	# we need to make a copy cause
	266	# otherwise it will affect the
	267	# other real version.
	268	+{ map {
95f31c36	269	blessed($hash->{$_})
f6e1331f	270	? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}, @args))
3db8f791	271	: ($_ => $hash->{$_})
	272	} keys %$hash }
	273	}
e1bb45ff	274	},
913d96dd	275	'Object' => \%OBJECT_HANDLERS,
e1bb45ff	276	# NOTE:
	277	# The sanity of enabling this feature by
	278	# default is very questionable.
	279	# - SL
	280	#'CodeRef' => {
	281	# expand => sub {}, # use eval ...
	282	# collapse => sub {}, # use B::Deparse ...
7eb5dc63	283	#}
e59193fb	284	);
e59193fb	285
3db8f791	286	sub add_custom_type_handler {
	287	my ($class, $type_name, %handlers) = @_;
	288	(exists $handlers{expand} && exists $handlers{collapse})
	289	\|\| confess "Custom type handlers need an expand and a collapse method";
	290	$TYPES{$type_name} = \%handlers;
	291	}
	292
	293	sub remove_custom_type_handler {
	294	my ($class, $type_name) = @_;
	295	delete $TYPES{$type_name} if exists $TYPES{$type_name};
	296	}
	297
	298	sub find_type_handler {
e59193fb	299	my ($self, $type_constraint) = @_;
e1bb45ff	300
ef87e4a6	301	# check if the type is a Maybe and
	302	# if its parent is not parameterized.
	303	# If both is true recurse this method
	304	# using ->type_parameter.
	305	return $self->find_type_handler($type_constraint->type_parameter)
	306	if $type_constraint->parent eq 'Maybe'
	307	and not $type_constraint->parent->can('type_parameter');
	308
e1bb45ff	309	# this should handle most type usages
	310	# since they they are usually just
	311	# the standard set of built-ins
	312	return $TYPES{$type_constraint->name}
	313	if exists $TYPES{$type_constraint->name};
	314
	315	# the next possibility is they are
	316	# a subtype of the built-in types,
	317	# in which case this will DWIM in
	318	# most cases. It is probably not
	319	# 100% ideal though, but until I
	320	# come up with a decent test case
	321	# it will do for now.
e59193fb	322	foreach my $type (keys %TYPES) {
	323	return $TYPES{$type}
	324	if $type_constraint->is_subtype_of($type);
	325	}
e1bb45ff	326
	327	# NOTE:
	328	# the reason the above will work has to
	329	# do with the fact that custom subtypes
	330	# are mostly used for validation of
	331	# the guts of a type, and not for some
	332	# weird structural thing which would
	333	# need to be accomidated by the serializer.
	334	# Of course, mst or phaylon will probably
	335	# do something to throw this assumption
	336	# totally out the door ;)
	337	# - SL
	338
e9739624	339	# NOTE:
	340	# if this method hasnt returned by now
	341	# then we have no been able to find a
	342	# type constraint handler to match
	343	confess "Cannot handle type constraint (" . $type_constraint->name . ")";
e59193fb	344	}
e59193fb	345
3defafb9	346	sub find_type_handler_for {
	347	my ($self, $type_handler_name) = @_;
	348	$TYPES{$type_handler_name}
	349	}
	350
e59193fb	351	1;
e9739624	352
	353	__END__
	354
	355	=pod
	356
ec9c1923	357	=head1 NAME
ec9c1923	358
1390c23d	359	MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects
ec9c1923	360
	361	=head1 DESCRIPTION
	362
1390c23d	363	No user serviceable parts inside. If you really want to know, read the source :)
1390c23d	364
ec9c1923	365	=head1 METHODS
	366
	367	=head2 Accessors
	368
	369	=over 4
	370
	371	=item B<class>
	372
	373	=item B<object>
	374
	375	=item B<storage>
	376
b430caa3	377	=item B<seen>
b430caa3	378
ec9c1923	379	=back
	380
	381	=head2 API
	382
	383	=over 4
	384
	385	=item B<expand_object>
	386
	387	=item B<collapse_object>
	388
	389	=back
	390
	391	=head2 ...
	392
	393	=over 4
	394
	395	=item B<collapse_attribute>
	396
	397	=item B<collapse_attribute_value>
	398
	399	=item B<expand_attribute>
	400
	401	=item B<expand_attribute_value>
	402
b430caa3	403	=item B<check_for_cycle_in_collapse>
	404
	405	=item B<check_for_cycle_in_expansion>
	406
ec9c1923	407	=item B<map_attributes>
ec9c1923	408
3db8f791	409	=back
	410
	411	=head2 Type Constraint Handlers
	412
	413	=over 4
	414
3defafb9	415	=item B<find_type_handler ($type)>
	416
	417	=item B<find_type_handler_for ($name)>
3db8f791	418
3defafb9	419	=item B<add_custom_type_handler ($name, %handlers)>
3db8f791	420
3defafb9	421	=item B<remove_custom_type_handler ($name)>
ec9c1923	422
	423	=back
	424
	425	=head2 Introspection
	426
	427	=over 4
	428
	429	=item B<meta>
	430
	431	=back
	432
	433	=head1 BUGS
	434
	435	All complex software has bugs lurking in it, and this module is no
	436	exception. If you find a bug please either email me, or add the bug
	437	to cpan-RT.
	438
	439	=head1 AUTHOR
	440
	441	Chris Prather E<lt>chris.prather@iinteractive.comE<gt>
	442
	443	Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
	444
	445	=head1 COPYRIGHT AND LICENSE
	446
1f3074ea	447	Copyright 2007-2008 by Infinity Interactive, Inc.
ec9c1923	448
	449	L<http://www.iinteractive.com>
	450
	451	This library is free software; you can redistribute it and/or modify
	452	it under the same terms as Perl itself.
	453
e9739624	454	=cut
	455
	456
ec9c1923	457