[gitmo/MooseX-Storage.git] / lib / MooseX / Storage / Engine.pm


package MooseX::Storage::Engine;
use Moose;

our $VERSION = '0.02';

# the class marker when 
# serializing an object. 
our $CLASS_MARKER = '__CLASS__';

has 'storage' => (
    is      => 'ro',
    isa     => 'HashRef',
    default => sub {{}}
);

has 'seen' => (
    is      => 'ro',
    isa     => 'HashRef',
    default => sub {{}}
);

has 'object' => (is => 'rw', isa => 'Object');
has 'class'  => (is => 'rw', isa => 'Str');

## this is the API used by other modules ...

sub collapse_object {
	my $self = shift;

	# NOTE:
	# mark the root object as seen ...
	$self->seen->{$self->object} = undef;
	
    $self->map_attributes('collapse_attribute');
    $self->storage->{$CLASS_MARKER} = $self->object->meta->name;    
	return $self->storage;
}

sub expand_object {
    my ($self, $data) = @_;
    
	# NOTE:
	# mark the root object as seen ...
	$self->seen->{$data} = undef;    
    
    $self->map_attributes('expand_attribute', $data);
	return $self->storage;    
}

## this is the internal API ...

sub collapse_attribute {
    my ($self, $attr)  = @_;
    $self->storage->{$attr->name} = $self->collapse_attribute_value($attr) || return;
}

sub expand_attribute {
    my ($self, $attr, $data)  = @_;
    $self->storage->{$attr->name} = $self->expand_attribute_value($attr, $data->{$attr->name}) || return;
}

sub collapse_attribute_value {
    my ($self, $attr)  = @_;
	my $value = $attr->get_value($self->object);
	
	# NOTE:
	# this might not be enough, we might 
	# need to make it possible for the 
	# cycle checker to return the value
    $self->check_for_cycle_in_collapse($attr, $value) 
        if ref $value;
	
    if (defined $value && $attr->has_type_constraint) {
        my $type_converter = $self->find_type_handler($attr->type_constraint);
        (defined $type_converter)
            || confess "Cannot convert " . $attr->type_constraint->name;
        $value = $type_converter->{collapse}->($value);
    }
	return $value;
}

sub expand_attribute_value {
    my ($self, $attr, $value)  = @_;

	# NOTE:
	# (see comment in method above ^^)
    $self->check_for_cycle_in_expansion($attr, $value) 
        if ref $value;    
    
    if (defined $value && $attr->has_type_constraint) {
        my $type_converter = $self->find_type_handler($attr->type_constraint);
        $value = $type_converter->{expand}->($value);
    }
	return $value;
}

# NOTE:
# possibly these two methods will 
# be used by a cycle supporting 
# engine. However, I am not sure 
# if I can make a cycle one work 
# anyway.

sub check_for_cycle_in_collapse {
    my ($self, $attr, $value) = @_;
    (!exists $self->seen->{$value})
        || confess "Basic Engine does not support cycles in class(" 
                 . ($attr->associated_metaclass->name) . ").attr("
                 . ($attr->name) . ") with $value";
    $self->seen->{$value} = undef;
}

sub check_for_cycle_in_expansion {
    my ($self, $attr, $value) = @_;
    (!exists $self->seen->{$value})
    || confess "Basic Engine does not support cycles in class(" 
             . ($attr->associated_metaclass->name) . ").attr("
             . ($attr->name) . ") with $value";
    $self->seen->{$value} = undef;
}

# util methods ...

sub map_attributes {
    my ($self, $method_name, @args) = @_;
    map { 
        $self->$method_name($_, @args) 
    } grep {
        # Skip our special skip attribute :)
        !$_->isa('MooseX::Storage::Meta::Attribute::DoNotSerialize')
    } ($self->object || $self->class)->meta->compute_all_applicable_attributes;
}

## ------------------------------------------------------------------
## This is all the type handler stuff, it is in a state of flux
## right now, so this may change, or it may just continue to be 
## improved upon. Comments and suggestions are welcomed.
## ------------------------------------------------------------------

# NOTE:
# these are needed by the 
# ArrayRef and HashRef handlers
# below, so I need easy access 
my %OBJECT_HANDLERS = (
    expand => sub {
        my $data = shift;   
        (exists $data->{$CLASS_MARKER})
            || confess "Serialized item has no class marker";
        $data->{$CLASS_MARKER}->unpack($data);
    },
    collapse => sub {
        my $obj = shift;
        ($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
            || confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
        $obj->pack();
    },
);


my %TYPES = (
    # These are boring ones, so they use the identity function ...
    'Int'      => { expand => sub { shift }, collapse => sub { shift } },
    'Num'      => { expand => sub { shift }, collapse => sub { shift } },
    'Str'      => { expand => sub { shift }, collapse => sub { shift } },
    # These are the trickier ones, (see notes)
    # NOTE:
    # Because we are nice guys, we will check 
    # your ArrayRef and/or HashRef one level 
    # down and inflate any objects we find. 
    # But this is where it ends, it is too
    # expensive to try and do this any more  
    # recursively, when it is probably not 
    # nessecary in most of the use cases.
    # However, if you need more then this, subtype 
    # and add a custom handler.    
    'ArrayRef' => { 
        expand => sub {
            my $array = shift;
            foreach my $i (0 .. $#{$array}) {
                next unless ref($array->[$i]) eq 'HASH' 
                         && exists $array->[$i]->{$CLASS_MARKER};
                $array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i])
            }
            $array;
        }, 
        collapse => sub { 
            my $array = shift;   
            # NOTE:         
            # we need to make a copy cause
            # otherwise it will affect the 
            # other real version.
            [ map {
                blessed($_)
                    ? $OBJECT_HANDLERS{collapse}->($_)
                    : $_
            } @$array ] 
        } 
    },
    'HashRef'  => { 
        expand   => sub {
            my $hash = shift;
            foreach my $k (keys %$hash) {
                next unless ref($hash->{$k}) eq 'HASH' 
                         && exists $hash->{$k}->{$CLASS_MARKER};
                $hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k})
            }
            $hash;            
        }, 
        collapse => sub {
            my $hash = shift;   
            # NOTE:         
            # we need to make a copy cause
            # otherwise it will affect the 
            # other real version.
            +{ map {
                blessed($hash->{$_})
                    ? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}))
                    : ($_ => $hash->{$_})
            } keys %$hash }            
        } 
    },
    'Object'   => \%OBJECT_HANDLERS,
    # NOTE:
    # The sanity of enabling this feature by 
    # default is very questionable.
    # - SL
    #'CodeRef' => {
    #    expand   => sub {}, # use eval ...
    #    collapse => sub {}, # use B::Deparse ...        
    #} 
);

sub add_custom_type_handler {
    my ($class, $type_name, %handlers) = @_;
    (exists $handlers{expand} && exists $handlers{collapse})
        || confess "Custom type handlers need an expand *and* a collapse method";
    $TYPES{$type_name} = \%handlers;
}

sub remove_custom_type_handler {
    my ($class, $type_name) = @_;
    delete $TYPES{$type_name} if exists $TYPES{$type_name};
}

sub find_type_handler {
    my ($self, $type_constraint) = @_;
    
    # this should handle most type usages
    # since they they are usually just 
    # the standard set of built-ins
    return $TYPES{$type_constraint->name} 
        if exists $TYPES{$type_constraint->name};
      
    # the next possibility is they are 
    # a subtype of the built-in types, 
    # in which case this will DWIM in 
    # most cases. It is probably not 
    # 100% ideal though, but until I 
    # come up with a decent test case 
    # it will do for now.
    foreach my $type (keys %TYPES) {
        return $TYPES{$type} 
            if $type_constraint->is_subtype_of($type);
    }
    
    # NOTE:
    # the reason the above will work has to 
    # do with the fact that custom subtypes
    # are mostly used for validation of 
    # the guts of a type, and not for some
    # weird structural thing which would 
    # need to be accomidated by the serializer.
    # Of course, mst or phaylon will probably  
    # do something to throw this assumption 
    # totally out the door ;)
    # - SL
    
    # NOTE:
    # if this method hasnt returned by now
    # then we have no been able to find a 
    # type constraint handler to match 
    confess "Cannot handle type constraint (" . $type_constraint->name . ")";    
}

1;

__END__

=pod

=head1 NAME

MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects

=head1 DESCRIPTION

No user serviceable parts inside. If you really want to know, read the source :)

=head1 METHODS

=head2 Accessors

=over 4

=item B<class>

=item B<object>

=item B<storage>

=item B<seen>

=back

=head2 API

=over 4

=item B<expand_object>

=item B<collapse_object>

=back

=head2 ...

=over 4

=item B<collapse_attribute>

=item B<collapse_attribute_value>

=item B<expand_attribute>

=item B<expand_attribute_value>

=item B<check_for_cycle_in_collapse>

=item B<check_for_cycle_in_expansion>

=item B<map_attributes>

=back

=head2 Type Constraint Handlers

=over 4

=item B<find_type_handler>

=item B<add_custom_type_handler>

=item B<remove_custom_type_handler>

=back

=head2 Introspection

=over 4

=item B<meta>

=back

=head1 BUGS

All complex software has bugs lurking in it, and this module is no 
exception. If you find a bug please either email me, or add the bug
to cpan-RT.

=head1 AUTHOR

Chris Prather E<lt>chris.prather@iinteractive.comE<gt>

Stevan Little E<lt>stevan.little@iinteractive.comE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright 2007 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut
Commit	Line	Data
e59193fb	1
	2	package MooseX::Storage::Engine;
	3	use Moose;
	4
45d9a73c	5	our $VERSION = '0.02';
ba5bba75	6
	7	# the class marker when
	8	# serializing an object.
	9	our $CLASS_MARKER = '__CLASS__';
	10
e59193fb	11	has 'storage' => (
7eb5dc63	12	is => 'ro',
	13	isa => 'HashRef',
	14	default => sub {{}}
	15	);
	16
	17	has 'seen' => (
	18	is => 'ro',
e9739624	19	isa => 'HashRef',
e59193fb	20	default => sub {{}}
	21	);
	22
e9739624	23	has 'object' => (is => 'rw', isa => 'Object');
e9739624	24	has 'class' => (is => 'rw', isa => 'Str');
e59193fb	25
e9739624	26	## this is the API used by other modules ...
e59193fb	27
	28	sub collapse_object {
	29	my $self = shift;
7eb5dc63	30
	31	# NOTE:
	32	# mark the root object as seen ...
	33	$self->seen->{$self->object} = undef;
	34
e9739624	35	$self->map_attributes('collapse_attribute');
ba5bba75	36	$self->storage->{$CLASS_MARKER} = $self->object->meta->name;
e59193fb	37	return $self->storage;
	38	}
	39
e9739624	40	sub expand_object {
e9739624	41	my ($self, $data) = @_;
7eb5dc63	42
	43	# NOTE:
	44	# mark the root object as seen ...
	45	$self->seen->{$data} = undef;
	46
e9739624	47	$self->map_attributes('expand_attribute', $data);
e9739624	48	return $self->storage;
e59193fb	49	}
e59193fb	50
e9739624	51	## this is the internal API ...
	52
	53	sub collapse_attribute {
	54	my ($self, $attr) = @_;
	55	$self->storage->{$attr->name} = $self->collapse_attribute_value($attr) \|\| return;
	56	}
	57
	58	sub expand_attribute {
	59	my ($self, $attr, $data) = @_;
	60	$self->storage->{$attr->name} = $self->expand_attribute_value($attr, $data->{$attr->name}) \|\| return;
e59193fb	61	}
e59193fb	62
e9739624	63	sub collapse_attribute_value {
e59193fb	64	my ($self, $attr) = @_;
e9739624	65	my $value = $attr->get_value($self->object);
7eb5dc63	66
b430caa3	67	# NOTE:
	68	# this might not be enough, we might
	69	# need to make it possible for the
	70	# cycle checker to return the value
45d9a73c	71	$self->check_for_cycle_in_collapse($attr, $value)
7eb5dc63	72	if ref $value;
7eb5dc63	73
e9739624	74	if (defined $value && $attr->has_type_constraint) {
3db8f791	75	my $type_converter = $self->find_type_handler($attr->type_constraint);
e9739624	76	(defined $type_converter)
	77	\|\| confess "Cannot convert " . $attr->type_constraint->name;
	78	$value = $type_converter->{collapse}->($value);
	79	}
	80	return $value;
	81	}
	82
	83	sub expand_attribute_value {
	84	my ($self, $attr, $value) = @_;
7eb5dc63	85
b430caa3	86	# NOTE:
b430caa3	87	# (see comment in method above ^^)
45d9a73c	88	$self->check_for_cycle_in_expansion($attr, $value)
7eb5dc63	89	if ref $value;
7eb5dc63	90
e9739624	91	if (defined $value && $attr->has_type_constraint) {
3db8f791	92	my $type_converter = $self->find_type_handler($attr->type_constraint);
e9739624	93	$value = $type_converter->{expand}->($value);
	94	}
	95	return $value;
	96	}
	97
b430caa3	98	# NOTE:
	99	# possibly these two methods will
	100	# be used by a cycle supporting
	101	# engine. However, I am not sure
	102	# if I can make a cycle one work
	103	# anyway.
e9739624	104
7eb5dc63	105	sub check_for_cycle_in_collapse {
45d9a73c	106	my ($self, $attr, $value) = @_;
7eb5dc63	107	(!exists $self->seen->{$value})
45d9a73c	108	\|\| confess "Basic Engine does not support cycles in class("
	109	. ($attr->associated_metaclass->name) . ").attr("
	110	. ($attr->name) . ") with $value";
7eb5dc63	111	$self->seen->{$value} = undef;
	112	}
	113
	114	sub check_for_cycle_in_expansion {
45d9a73c	115	my ($self, $attr, $value) = @_;
7eb5dc63	116	(!exists $self->seen->{$value})
45d9a73c	117	\|\| confess "Basic Engine does not support cycles in class("
	118	. ($attr->associated_metaclass->name) . ").attr("
	119	. ($attr->name) . ") with $value";
7eb5dc63	120	$self->seen->{$value} = undef;
	121	}
	122
b430caa3	123	# util methods ...
b430caa3	124
e9739624	125	sub map_attributes {
	126	my ($self, $method_name, @args) = @_;
	127	map {
	128	$self->$method_name($_, @args)
b430caa3	129	} grep {
	130	# Skip our special skip attribute :)
	131	!$_->isa('MooseX::Storage::Meta::Attribute::DoNotSerialize')
e9739624	132	} ($self->object \|\| $self->class)->meta->compute_all_applicable_attributes;
e59193fb	133	}
e59193fb	134
913d96dd	135	## ------------------------------------------------------------------
3db8f791	136	## This is all the type handler stuff, it is in a state of flux
	137	## right now, so this may change, or it may just continue to be
	138	## improved upon. Comments and suggestions are welcomed.
913d96dd	139	## ------------------------------------------------------------------
	140
	141	# NOTE:
	142	# these are needed by the
	143	# ArrayRef and HashRef handlers
	144	# below, so I need easy access
	145	my %OBJECT_HANDLERS = (
	146	expand => sub {
	147	my $data = shift;
ba5bba75	148	(exists $data->{$CLASS_MARKER})
913d96dd	149	\|\| confess "Serialized item has no class marker";
ba5bba75	150	$data->{$CLASS_MARKER}->unpack($data);
913d96dd	151	},
	152	collapse => sub {
	153	my $obj = shift;
	154	($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
	155	\|\| confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
	156	$obj->pack();
	157	},
	158	);
	159
	160
e59193fb	161	my %TYPES = (
3db8f791	162	# These are boring ones, so they use the identity function ...
e9739624	163	'Int' => { expand => sub { shift }, collapse => sub { shift } },
	164	'Num' => { expand => sub { shift }, collapse => sub { shift } },
	165	'Str' => { expand => sub { shift }, collapse => sub { shift } },
3db8f791	166	# These are the trickier ones, (see notes)
	167	# NOTE:
	168	# Because we are nice guys, we will check
	169	# your ArrayRef and/or HashRef one level
	170	# down and inflate any objects we find.
	171	# But this is where it ends, it is too
	172	# expensive to try and do this any more
	173	# recursively, when it is probably not
	174	# nessecary in most of the use cases.
	175	# However, if you need more then this, subtype
	176	# and add a custom handler.
913d96dd	177	'ArrayRef' => {
e9739624	178	expand => sub {
913d96dd	179	my $array = shift;
	180	foreach my $i (0 .. $#{$array}) {
	181	next unless ref($array->[$i]) eq 'HASH'
ba5bba75	182	&& exists $array->[$i]->{$CLASS_MARKER};
913d96dd	183	$array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i])
	184	}
	185	$array;
	186	},
	187	collapse => sub {
	188	my $array = shift;
	189	# NOTE:
	190	# we need to make a copy cause
	191	# otherwise it will affect the
	192	# other real version.
	193	[ map {
	194	blessed($_)
	195	? $OBJECT_HANDLERS{collapse}->($_)
	196	: $_
	197	} @$array ]
	198	}
	199	},
	200	'HashRef' => {
3db8f791	201	expand => sub {
	202	my $hash = shift;
	203	foreach my $k (keys %$hash) {
	204	next unless ref($hash->{$k}) eq 'HASH'
ba5bba75	205	&& exists $hash->{$k}->{$CLASS_MARKER};
3db8f791	206	$hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k})
	207	}
	208	$hash;
	209	},
	210	collapse => sub {
	211	my $hash = shift;
	212	# NOTE:
	213	# we need to make a copy cause
	214	# otherwise it will affect the
	215	# other real version.
	216	+{ map {
95f31c36	217	blessed($hash->{$_})
3db8f791	218	? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}))
	219	: ($_ => $hash->{$_})
	220	} keys %$hash }
	221	}
e1bb45ff	222	},
913d96dd	223	'Object' => \%OBJECT_HANDLERS,
e1bb45ff	224	# NOTE:
	225	# The sanity of enabling this feature by
	226	# default is very questionable.
	227	# - SL
	228	#'CodeRef' => {
	229	# expand => sub {}, # use eval ...
	230	# collapse => sub {}, # use B::Deparse ...
7eb5dc63	231	#}
e59193fb	232	);
e59193fb	233
3db8f791	234	sub add_custom_type_handler {
	235	my ($class, $type_name, %handlers) = @_;
	236	(exists $handlers{expand} && exists $handlers{collapse})
	237	\|\| confess "Custom type handlers need an expand and a collapse method";
	238	$TYPES{$type_name} = \%handlers;
	239	}
	240
	241	sub remove_custom_type_handler {
	242	my ($class, $type_name) = @_;
	243	delete $TYPES{$type_name} if exists $TYPES{$type_name};
	244	}
	245
	246	sub find_type_handler {
e59193fb	247	my ($self, $type_constraint) = @_;
e1bb45ff	248
	249	# this should handle most type usages
	250	# since they they are usually just
	251	# the standard set of built-ins
	252	return $TYPES{$type_constraint->name}
	253	if exists $TYPES{$type_constraint->name};
	254
	255	# the next possibility is they are
	256	# a subtype of the built-in types,
	257	# in which case this will DWIM in
	258	# most cases. It is probably not
	259	# 100% ideal though, but until I
	260	# come up with a decent test case
	261	# it will do for now.
e59193fb	262	foreach my $type (keys %TYPES) {
	263	return $TYPES{$type}
	264	if $type_constraint->is_subtype_of($type);
	265	}
e1bb45ff	266
	267	# NOTE:
	268	# the reason the above will work has to
	269	# do with the fact that custom subtypes
	270	# are mostly used for validation of
	271	# the guts of a type, and not for some
	272	# weird structural thing which would
	273	# need to be accomidated by the serializer.
	274	# Of course, mst or phaylon will probably
	275	# do something to throw this assumption
	276	# totally out the door ;)
	277	# - SL
	278
e9739624	279	# NOTE:
	280	# if this method hasnt returned by now
	281	# then we have no been able to find a
	282	# type constraint handler to match
	283	confess "Cannot handle type constraint (" . $type_constraint->name . ")";
e59193fb	284	}
	285
	286	1;
e9739624	287
	288	__END__
	289
	290	=pod
	291
ec9c1923	292	=head1 NAME
ec9c1923	293
1390c23d	294	MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects
ec9c1923	295
	296	=head1 DESCRIPTION
	297
1390c23d	298	No user serviceable parts inside. If you really want to know, read the source :)
1390c23d	299
ec9c1923	300	=head1 METHODS
	301
	302	=head2 Accessors
	303
	304	=over 4
	305
	306	=item B<class>
	307
	308	=item B<object>
	309
	310	=item B<storage>
	311
b430caa3	312	=item B<seen>
b430caa3	313
ec9c1923	314	=back
	315
	316	=head2 API
	317
	318	=over 4
	319
	320	=item B<expand_object>
	321
	322	=item B<collapse_object>
	323
	324	=back
	325
	326	=head2 ...
	327
	328	=over 4
	329
	330	=item B<collapse_attribute>
	331
	332	=item B<collapse_attribute_value>
	333
	334	=item B<expand_attribute>
	335
	336	=item B<expand_attribute_value>
	337
b430caa3	338	=item B<check_for_cycle_in_collapse>
	339
	340	=item B<check_for_cycle_in_expansion>
	341
ec9c1923	342	=item B<map_attributes>
ec9c1923	343
3db8f791	344	=back
	345
	346	=head2 Type Constraint Handlers
	347
	348	=over 4
	349
	350	=item B<find_type_handler>
	351
	352	=item B<add_custom_type_handler>
	353
	354	=item B<remove_custom_type_handler>
ec9c1923	355
	356	=back
	357
	358	=head2 Introspection
	359
	360	=over 4
	361
	362	=item B<meta>
	363
	364	=back
	365
	366	=head1 BUGS
	367
	368	All complex software has bugs lurking in it, and this module is no
	369	exception. If you find a bug please either email me, or add the bug
	370	to cpan-RT.
	371
	372	=head1 AUTHOR
	373
	374	Chris Prather E<lt>chris.prather@iinteractive.comE<gt>
	375
	376	Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
	377
	378	=head1 COPYRIGHT AND LICENSE
	379
	380	Copyright 2007 by Infinity Interactive, Inc.
	381
	382	L<http://www.iinteractive.com>
	383
	384	This library is free software; you can redistribute it and/or modify
	385	it under the same terms as Perl itself.
	386
e9739624	387	=cut
	388
	389
ec9c1923	390