[gitmo/MooseX-Storage.git] / lib / MooseX / Storage / Engine.pm


package MooseX::Storage::Engine;
use Moose;
use Scalar::Util qw(refaddr);

our $VERSION   = '0.18';
our $AUTHORITY = 'cpan:STEVAN';

# the class marker when 
# serializing an object. 
our $CLASS_MARKER = '__CLASS__';

has 'storage' => (
    is      => 'ro',
    isa     => 'HashRef',
    default => sub {{}}
);

has 'seen' => (
    is      => 'ro',
    isa     => 'HashRef[Int]', # int is the refaddr
    default => sub {{}}
);

has 'object' => (is => 'rw', isa => 'Object');
has 'class'  => (is => 'rw', isa => 'Str');

## this is the API used by other modules ...

sub collapse_object {
    my ( $self, %options ) = @_;

	# NOTE:
	# mark the root object as seen ...
	$self->seen->{refaddr $self->object} = undef;
	
    $self->map_attributes('collapse_attribute', \%options);
    $self->storage->{$CLASS_MARKER} = $self->object->meta->identifier;    
	return $self->storage;
}

sub expand_object {
    my ($self, $data, %options) = @_;
    
    $options{check_version}       = 1 unless exists $options{check_version};
    $options{check_authority}     = 1 unless exists $options{check_authority};   

	# NOTE:
	# mark the root object as seen ...
	$self->seen->{refaddr $data} = undef;    
    
    $self->map_attributes('expand_attribute', $data, \%options);
	return $self->storage;    
}

## this is the internal API ...

sub collapse_attribute {
    my ($self, $attr, $options)  = @_;
    my $value = $self->collapse_attribute_value($attr, $options);
    return if !defined($value);
    $self->storage->{$attr->name} = $value;
}

sub expand_attribute {
    my ($self, $attr, $data, $options)  = @_;
    my $value = $self->expand_attribute_value($attr, $data->{$attr->name}, $options);
    $self->storage->{$attr->name} = defined $value ? $value : return;
}

sub collapse_attribute_value {
    my ($self, $attr, $options)  = @_;
    # Faster, but breaks attributes without readers, do we care?
	#my $value = $attr->get_read_method_ref->($self->object);
	my $value = $attr->get_value($self->object);

	# NOTE:
	# this might not be enough, we might
	# need to make it possible for the
	# cycle checker to return the value
    $self->check_for_cycle_in_collapse($attr, $value)
        if ref $value;

    if (defined $value && $attr->has_type_constraint) {
        my $type_converter = $self->find_type_handler($attr->type_constraint);
        (defined $type_converter)
            || confess "Cannot convert " . $attr->type_constraint->name;
        $value = $type_converter->{collapse}->($value, $options);
    }
	return $value;
}

sub expand_attribute_value {
    my ($self, $attr, $value, $options)  = @_;

	# NOTE:
	# (see comment in method above ^^)
    if( ref $value and not(
        $options->{disable_cycle_check} or
        $self->class->does('MooseX::Storage::Traits::DisableCycleDetection')
    )) {        
        $self->check_for_cycle_in_collapse($attr, $value)
    }
    
    if (defined $value && $attr->has_type_constraint) {
        my $type_converter = $self->find_type_handler($attr->type_constraint);
        $value = $type_converter->{expand}->($value, $options);
    }
	return $value;
}

# NOTE:
# possibly these two methods will 
# be used by a cycle supporting 
# engine. However, I am not sure 
# if I can make a cycle one work 
# anyway.

sub check_for_cycle_in_collapse {
    my ($self, $attr, $value) = @_;
    (!exists $self->seen->{refaddr $value})
        || confess "Basic Engine does not support cycles in class(" 
                 . ($attr->associated_class->name) . ").attr("
                 . ($attr->name) . ") with $value";
    $self->seen->{refaddr $value} = undef;
}

sub check_for_cycle_in_expansion {
    my ($self, $attr, $value) = @_;
    (!exists $self->seen->{refaddr $value})
    || confess "Basic Engine does not support cycles in class(" 
             . ($attr->associated_class->name) . ").attr("
             . ($attr->name) . ") with $value";
    $self->seen->{refaddr $value} = undef;
}

# util methods ...

sub map_attributes {
    my ($self, $method_name, @args) = @_;
    map { 
        $self->$method_name($_, @args) 
    } grep {
        # Skip our special skip attribute :)
        !$_->does('MooseX::Storage::Meta::Attribute::Trait::DoNotSerialize') 
    } ($self->object || $self->class)->meta->get_all_attributes;
}

## ------------------------------------------------------------------
## This is all the type handler stuff, it is in a state of flux
## right now, so this may change, or it may just continue to be 
## improved upon. Comments and suggestions are welcomed.
## ------------------------------------------------------------------

# NOTE:
# these are needed by the 
# ArrayRef and HashRef handlers
# below, so I need easy access 
my %OBJECT_HANDLERS = (
    expand => sub {
        my ($data, $options) = @_;   
        (exists $data->{$CLASS_MARKER})
            || confess "Serialized item has no class marker";
        # check the class more thoroughly here ...
        my ($class, $version, $authority) = (split '-' => $data->{$CLASS_MARKER});
        my $meta = eval { $class->meta };
        confess "Class ($class) is not loaded, cannot unpack" if $@;     
        
        if ($options->{check_version}) {
            my $meta_version = $meta->version;
            if (defined $meta_version && $version) {            
                if ($options->{check_version} eq 'allow_less_than') {
                    ($meta_version <= $version)
                        || confess "Class ($class) versions is not less than currently available." 
                                 . " got=($version) available=($meta_version)";                
                }
                elsif ($options->{check_version} eq 'allow_greater_than') {
                    ($meta->version >= $version)
                        || confess "Class ($class) versions is not greater than currently available." 
                                 . " got=($version) available=($meta_version)";                
                }            
                else {
                    ($meta->version == $version)
                        || confess "Class ($class) versions don't match." 
                                 . " got=($version) available=($meta_version)";
                }
            }
        }
        
        if ($options->{check_authority}) {
            my $meta_authority = $meta->authority;
            ($meta->authority eq $authority)
                || confess "Class ($class) authorities don't match." 
                         . " got=($authority) available=($meta_authority)"
                if defined $meta_authority && defined $authority;            
        }
            
        # all is well ...
        $class->unpack($data, %$options);
    },
    collapse => sub {
        my ( $obj, $options ) = @_;
#        ($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
#            || confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
        ($obj->can('pack'))
            || confess "Object ($obj) does not have a &pack method, cannot collapse";
        $obj->pack(%$options);
    },
);


my %TYPES = (
    # NOTE:
    # we need to make sure that we properly numify the numbers 
    # before and after them being futzed with, because some of 
    # the JSON engines are stupid/annoying/frustrating
    'Int'      => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
    'Num'      => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
    # These are boring ones, so they use the identity function ...    
    'Str'      => { expand => sub { shift }, collapse => sub { shift } },
    'Bool'     => { expand => sub { shift }, collapse => sub { shift } },
    # These are the trickier ones, (see notes)
    # NOTE:
    # Because we are nice guys, we will check 
    # your ArrayRef and/or HashRef one level 
    # down and inflate any objects we find. 
    # But this is where it ends, it is too
    # expensive to try and do this any more  
    # recursively, when it is probably not 
    # nessecary in most of the use cases.
    # However, if you need more then this, subtype 
    # and add a custom handler.    
    'ArrayRef' => { 
        expand => sub {
            my ( $array, @args ) = @_;
            foreach my $i (0 .. $#{$array}) {
                next unless ref($array->[$i]) eq 'HASH' 
                         && exists $array->[$i]->{$CLASS_MARKER};
                $array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i], @args);
            }
            $array;
        }, 
        collapse => sub {
            my ( $array, @args ) = @_;
            # NOTE:         
            # we need to make a copy cause
            # otherwise it will affect the 
            # other real version.
            [ map {
                blessed($_)
                    ? $OBJECT_HANDLERS{collapse}->($_, @args)
                    : $_
            } @$array ] 
        } 
    },
    'HashRef'  => { 
        expand   => sub {
            my ( $hash, @args ) = @_;
            foreach my $k (keys %$hash) {
                next unless ref($hash->{$k}) eq 'HASH' 
                         && exists $hash->{$k}->{$CLASS_MARKER};
                $hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k}, @args);
            }
            $hash;            
        }, 
        collapse => sub {
            my ( $hash, @args ) = @_;
            # NOTE:         
            # we need to make a copy cause
            # otherwise it will affect the 
            # other real version.
            +{ map {
                blessed($hash->{$_})
                    ? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}, @args))
                    : ($_ => $hash->{$_})
            } keys %$hash }            
        } 
    },
    'Object'   => \%OBJECT_HANDLERS,
    # NOTE:
    # The sanity of enabling this feature by 
    # default is very questionable.
    # - SL
    #'CodeRef' => {
    #    expand   => sub {}, # use eval ...
    #    collapse => sub {}, # use B::Deparse ...        
    #} 
);

sub add_custom_type_handler {
    my ($class, $type_name, %handlers) = @_;
    (exists $handlers{expand} && exists $handlers{collapse})
        || confess "Custom type handlers need an expand *and* a collapse method";
    $TYPES{$type_name} = \%handlers;
}

sub remove_custom_type_handler {
    my ($class, $type_name) = @_;
    delete $TYPES{$type_name} if exists $TYPES{$type_name};
}

sub find_type_handler {
    my ($self, $type_constraint) = @_;
    
    # check if the type is a Maybe and
    # if its parent is not parameterized.
    # If both is true recurse this method
    # using ->type_parameter.
    return $self->find_type_handler($type_constraint->type_parameter)
        if $type_constraint->parent eq 'Maybe'
          and not $type_constraint->parent->can('type_parameter');

    # this should handle most type usages
    # since they they are usually just 
    # the standard set of built-ins
    return $TYPES{$type_constraint->name} 
        if exists $TYPES{$type_constraint->name};
      
    # the next possibility is they are 
    # a subtype of the built-in types, 
    # in which case this will DWIM in 
    # most cases. It is probably not 
    # 100% ideal though, but until I 
    # come up with a decent test case 
    # it will do for now.
    foreach my $type (keys %TYPES) {
        return $TYPES{$type} 
            if $type_constraint->is_subtype_of($type);
    }
    
    # NOTE:
    # the reason the above will work has to 
    # do with the fact that custom subtypes
    # are mostly used for validation of 
    # the guts of a type, and not for some
    # weird structural thing which would 
    # need to be accomidated by the serializer.
    # Of course, mst or phaylon will probably  
    # do something to throw this assumption 
    # totally out the door ;)
    # - SL
    
    # NOTE:
    # if this method hasnt returned by now
    # then we have no been able to find a 
    # type constraint handler to match 
    confess "Cannot handle type constraint (" . $type_constraint->name . ")";    
}

sub find_type_handler_for {
    my ($self, $type_handler_name) = @_;
    $TYPES{$type_handler_name}
}

1;

__END__

=pod

=head1 NAME

MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects

=head1 DESCRIPTION

No user serviceable parts inside. If you really want to know, read the source :)

=head1 METHODS

=head2 Accessors

=over 4

=item B<class>

=item B<object>

=item B<storage>

=item B<seen>

=back

=head2 API

=over 4

=item B<expand_object>

=item B<collapse_object>

=back

=head2 ...

=over 4

=item B<collapse_attribute>

=item B<collapse_attribute_value>

=item B<expand_attribute>

=item B<expand_attribute_value>

=item B<check_for_cycle_in_collapse>

=item B<check_for_cycle_in_expansion>

=item B<map_attributes>

=back

=head2 Type Constraint Handlers

=over 4

=item B<find_type_handler ($type)>

=item B<find_type_handler_for ($name)>

=item B<add_custom_type_handler ($name, %handlers)>

=item B<remove_custom_type_handler ($name)>

=back

=head2 Introspection

=over 4

=item B<meta>

=back

=head1 BUGS

All complex software has bugs lurking in it, and this module is no 
exception. If you find a bug please either email me, or add the bug
to cpan-RT.

=head1 AUTHOR

Chris Prather E<lt>chris.prather@iinteractive.comE<gt>

Stevan Little E<lt>stevan.little@iinteractive.comE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2008 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut
Commit	Line	Data
e59193fb	1
	2	package MooseX::Storage::Engine;
	3	use Moose;
ec73712a	4	use Scalar::Util qw(refaddr);
e59193fb	5
5ca52230	6	our $VERSION = '0.18';
69b45b7d	7	our $AUTHORITY = 'cpan:STEVAN';
ba5bba75	8
	9	# the class marker when
	10	# serializing an object.
	11	our $CLASS_MARKER = '__CLASS__';
	12
e59193fb	13	has 'storage' => (
7eb5dc63	14	is => 'ro',
	15	isa => 'HashRef',
	16	default => sub {{}}
	17	);
	18
	19	has 'seen' => (
	20	is => 'ro',
ec73712a	21	isa => 'HashRef[Int]', # int is the refaddr
e59193fb	22	default => sub {{}}
	23	);
	24
e9739624	25	has 'object' => (is => 'rw', isa => 'Object');
e9739624	26	has 'class' => (is => 'rw', isa => 'Str');
e59193fb	27
e9739624	28	## this is the API used by other modules ...
e59193fb	29
e59193fb	30	sub collapse_object {
34dcaa5d	31	my ( $self, %options ) = @_;
7eb5dc63	32
	33	# NOTE:
	34	# mark the root object as seen ...
ec73712a	35	$self->seen->{refaddr $self->object} = undef;
7eb5dc63	36
34dcaa5d	37	$self->map_attributes('collapse_attribute', \%options);
c1830046	38	$self->storage->{$CLASS_MARKER} = $self->object->meta->identifier;
e59193fb	39	return $self->storage;
	40	}
	41
e9739624	42	sub expand_object {
219c1cc5	43	my ($self, $data, %options) = @_;
219c1cc5	44
5b7ea1fd	45	$options{check_version} = 1 unless exists $options{check_version};
	46	$options{check_authority} = 1 unless exists $options{check_authority};
	47
7eb5dc63	48	# NOTE:
7eb5dc63	49	# mark the root object as seen ...
ec73712a	50	$self->seen->{refaddr $data} = undef;
7eb5dc63	51
219c1cc5	52	$self->map_attributes('expand_attribute', $data, \%options);
e9739624	53	return $self->storage;
e59193fb	54	}
e59193fb	55
e9739624	56	## this is the internal API ...
	57
	58	sub collapse_attribute {
f6e1331f	59	my ($self, $attr, $options) = @_;
eea0dfae	60	my $value = $self->collapse_attribute_value($attr, $options);
	61	return if !defined($value);
	62	$self->storage->{$attr->name} = $value;
e9739624	63	}
	64
	65	sub expand_attribute {
219c1cc5	66	my ($self, $attr, $data, $options) = @_;
14b0a4dc	67	my $value = $self->expand_attribute_value($attr, $data->{$attr->name}, $options);
14b0a4dc	68	$self->storage->{$attr->name} = defined $value ? $value : return;
e59193fb	69	}
e59193fb	70
e9739624	71	sub collapse_attribute_value {
f6e1331f	72	my ($self, $attr, $options) = @_;
f4ffa4ef	73	# Faster, but breaks attributes without readers, do we care?
f4ffa4ef	74	#my $value = $attr->get_read_method_ref->($self->object);
e9739624	75	my $value = $attr->get_value($self->object);
f4ffa4ef	76
b430caa3	77	# NOTE:
f4ffa4ef	78	# this might not be enough, we might
f4ffa4ef	79	# need to make it possible for the
b430caa3	80	# cycle checker to return the value
3513de05	81	$self->check_for_cycle_in_collapse($attr, $value)
3513de05	82	if ref $value;
f4ffa4ef	83
e9739624	84	if (defined $value && $attr->has_type_constraint) {
3db8f791	85	my $type_converter = $self->find_type_handler($attr->type_constraint);
e9739624	86	(defined $type_converter)
e9739624	87	\|\| confess "Cannot convert " . $attr->type_constraint->name;
f6e1331f	88	$value = $type_converter->{collapse}->($value, $options);
e9739624	89	}
	90	return $value;
	91	}
	92
	93	sub expand_attribute_value {
219c1cc5	94	my ($self, $attr, $value, $options) = @_;
7eb5dc63	95
b430caa3	96	# NOTE:
b430caa3	97	# (see comment in method above ^^)
5b7ea1fd	98	if( ref $value and not(
	99	$options->{disable_cycle_check} or
	100	$self->class->does('MooseX::Storage::Traits::DisableCycleDetection')
	101	)) {
	102	$self->check_for_cycle_in_collapse($attr, $value)
	103	}
7eb5dc63	104
e9739624	105	if (defined $value && $attr->has_type_constraint) {
3db8f791	106	my $type_converter = $self->find_type_handler($attr->type_constraint);
219c1cc5	107	$value = $type_converter->{expand}->($value, $options);
e9739624	108	}
	109	return $value;
	110	}
	111
b430caa3	112	# NOTE:
	113	# possibly these two methods will
	114	# be used by a cycle supporting
	115	# engine. However, I am not sure
	116	# if I can make a cycle one work
	117	# anyway.
e9739624	118
7eb5dc63	119	sub check_for_cycle_in_collapse {
45d9a73c	120	my ($self, $attr, $value) = @_;
ec73712a	121	(!exists $self->seen->{refaddr $value})
45d9a73c	122	\|\| confess "Basic Engine does not support cycles in class("
c1830046	123	. ($attr->associated_class->name) . ").attr("
45d9a73c	124	. ($attr->name) . ") with $value";
ec73712a	125	$self->seen->{refaddr $value} = undef;
7eb5dc63	126	}
	127
	128	sub check_for_cycle_in_expansion {
45d9a73c	129	my ($self, $attr, $value) = @_;
ec73712a	130	(!exists $self->seen->{refaddr $value})
45d9a73c	131	\|\| confess "Basic Engine does not support cycles in class("
c1830046	132	. ($attr->associated_class->name) . ").attr("
45d9a73c	133	. ($attr->name) . ") with $value";
ec73712a	134	$self->seen->{refaddr $value} = undef;
7eb5dc63	135	}
7eb5dc63	136
b430caa3	137	# util methods ...
b430caa3	138
e9739624	139	sub map_attributes {
e9739624	140	my ($self, $method_name, @args) = @_;
4eafd265	141	map {
	142	$self->$method_name($_, @args)
	143	} grep {
b430caa3	144	# Skip our special skip attribute :)
4eafd265	145	!$_->does('MooseX::Storage::Meta::Attribute::Trait::DoNotSerialize')
4eafd265	146	} ($self->object \|\| $self->class)->meta->get_all_attributes;
e59193fb	147	}
e59193fb	148
913d96dd	149	## ------------------------------------------------------------------
3db8f791	150	## This is all the type handler stuff, it is in a state of flux
	151	## right now, so this may change, or it may just continue to be
	152	## improved upon. Comments and suggestions are welcomed.
913d96dd	153	## ------------------------------------------------------------------
	154
	155	# NOTE:
	156	# these are needed by the
	157	# ArrayRef and HashRef handlers
	158	# below, so I need easy access
	159	my %OBJECT_HANDLERS = (
	160	expand => sub {
219c1cc5	161	my ($data, $options) = @_;
ba5bba75	162	(exists $data->{$CLASS_MARKER})
913d96dd	163	\|\| confess "Serialized item has no class marker";
c1830046	164	# check the class more thoroughly here ...
	165	my ($class, $version, $authority) = (split '-' => $data->{$CLASS_MARKER});
	166	my $meta = eval { $class->meta };
219c1cc5	167	confess "Class ($class) is not loaded, cannot unpack" if $@;
	168
	169	if ($options->{check_version}) {
	170	my $meta_version = $meta->version;
	171	if (defined $meta_version && $version) {
	172	if ($options->{check_version} eq 'allow_less_than') {
	173	($meta_version <= $version)
	174	\|\| confess "Class ($class) versions is not less than currently available."
	175	. " got=($version) available=($meta_version)";
	176	}
	177	elsif ($options->{check_version} eq 'allow_greater_than') {
	178	($meta->version >= $version)
	179	\|\| confess "Class ($class) versions is not greater than currently available."
	180	. " got=($version) available=($meta_version)";
	181	}
	182	else {
	183	($meta->version == $version)
	184	\|\| confess "Class ($class) versions don't match."
	185	. " got=($version) available=($meta_version)";
	186	}
	187	}
	188	}
	189
	190	if ($options->{check_authority}) {
	191	my $meta_authority = $meta->authority;
	192	($meta->authority eq $authority)
	193	\|\| confess "Class ($class) authorities don't match."
	194	. " got=($authority) available=($meta_authority)"
	195	if defined $meta_authority && defined $authority;
	196	}
	197
c1830046	198	# all is well ...
34dcaa5d	199	$class->unpack($data, %$options);
913d96dd	200	},
913d96dd	201	collapse => sub {
34dcaa5d	202	my ( $obj, $options ) = @_;
c4a322ec	203	# ($obj->can('does') && $obj->does('MooseX::Storage::Basic'))
c4a322ec	204	# \|\| confess "Bad object ($obj) does not do MooseX::Storage::Basic role";
1c6ac775	205	($obj->can('pack'))
3defafb9	206	\|\| confess "Object ($obj) does not have a &pack method, cannot collapse";
34dcaa5d	207	$obj->pack(%$options);
913d96dd	208	},
	209	);
	210
	211
e59193fb	212	my %TYPES = (
cfee09ad	213	# NOTE:
	214	# we need to make sure that we properly numify the numbers
	215	# before and after them being futzed with, because some of
	216	# the JSON engines are stupid/annoying/frustrating
	217	'Int' => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
	218	'Num' => { expand => sub { $_[0] + 0 }, collapse => sub { $_[0] + 0 } },
	219	# These are boring ones, so they use the identity function ...
e9739624	220	'Str' => { expand => sub { shift }, collapse => sub { shift } },
d691721b	221	'Bool' => { expand => sub { shift }, collapse => sub { shift } },
3db8f791	222	# These are the trickier ones, (see notes)
	223	# NOTE:
	224	# Because we are nice guys, we will check
	225	# your ArrayRef and/or HashRef one level
	226	# down and inflate any objects we find.
	227	# But this is where it ends, it is too
	228	# expensive to try and do this any more
	229	# recursively, when it is probably not
	230	# nessecary in most of the use cases.
	231	# However, if you need more then this, subtype
	232	# and add a custom handler.
913d96dd	233	'ArrayRef' => {
e9739624	234	expand => sub {
34dcaa5d	235	my ( $array, @args ) = @_;
913d96dd	236	foreach my $i (0 .. $#{$array}) {
913d96dd	237	next unless ref($array->[$i]) eq 'HASH'
ba5bba75	238	&& exists $array->[$i]->{$CLASS_MARKER};
34dcaa5d	239	$array->[$i] = $OBJECT_HANDLERS{expand}->($array->[$i], @args);
913d96dd	240	}
	241	$array;
	242	},
34dcaa5d	243	collapse => sub {
34dcaa5d	244	my ( $array, @args ) = @_;
913d96dd	245	# NOTE:
	246	# we need to make a copy cause
	247	# otherwise it will affect the
	248	# other real version.
	249	[ map {
	250	blessed($_)
34dcaa5d	251	? $OBJECT_HANDLERS{collapse}->($_, @args)
913d96dd	252	: $_
	253	} @$array ]
	254	}
	255	},
	256	'HashRef' => {
3db8f791	257	expand => sub {
34dcaa5d	258	my ( $hash, @args ) = @_;
3db8f791	259	foreach my $k (keys %$hash) {
3db8f791	260	next unless ref($hash->{$k}) eq 'HASH'
ba5bba75	261	&& exists $hash->{$k}->{$CLASS_MARKER};
34dcaa5d	262	$hash->{$k} = $OBJECT_HANDLERS{expand}->($hash->{$k}, @args);
3db8f791	263	}
	264	$hash;
	265	},
	266	collapse => sub {
34dcaa5d	267	my ( $hash, @args ) = @_;
3db8f791	268	# NOTE:
	269	# we need to make a copy cause
	270	# otherwise it will affect the
	271	# other real version.
	272	+{ map {
95f31c36	273	blessed($hash->{$_})
f6e1331f	274	? ($_ => $OBJECT_HANDLERS{collapse}->($hash->{$_}, @args))
3db8f791	275	: ($_ => $hash->{$_})
	276	} keys %$hash }
	277	}
e1bb45ff	278	},
913d96dd	279	'Object' => \%OBJECT_HANDLERS,
e1bb45ff	280	# NOTE:
	281	# The sanity of enabling this feature by
	282	# default is very questionable.
	283	# - SL
	284	#'CodeRef' => {
	285	# expand => sub {}, # use eval ...
	286	# collapse => sub {}, # use B::Deparse ...
7eb5dc63	287	#}
e59193fb	288	);
e59193fb	289
3db8f791	290	sub add_custom_type_handler {
	291	my ($class, $type_name, %handlers) = @_;
	292	(exists $handlers{expand} && exists $handlers{collapse})
	293	\|\| confess "Custom type handlers need an expand and a collapse method";
	294	$TYPES{$type_name} = \%handlers;
	295	}
	296
	297	sub remove_custom_type_handler {
	298	my ($class, $type_name) = @_;
	299	delete $TYPES{$type_name} if exists $TYPES{$type_name};
	300	}
	301
	302	sub find_type_handler {
e59193fb	303	my ($self, $type_constraint) = @_;
e1bb45ff	304
ef87e4a6	305	# check if the type is a Maybe and
	306	# if its parent is not parameterized.
	307	# If both is true recurse this method
	308	# using ->type_parameter.
	309	return $self->find_type_handler($type_constraint->type_parameter)
	310	if $type_constraint->parent eq 'Maybe'
	311	and not $type_constraint->parent->can('type_parameter');
	312
e1bb45ff	313	# this should handle most type usages
	314	# since they they are usually just
	315	# the standard set of built-ins
	316	return $TYPES{$type_constraint->name}
	317	if exists $TYPES{$type_constraint->name};
	318
	319	# the next possibility is they are
	320	# a subtype of the built-in types,
	321	# in which case this will DWIM in
	322	# most cases. It is probably not
	323	# 100% ideal though, but until I
	324	# come up with a decent test case
	325	# it will do for now.
e59193fb	326	foreach my $type (keys %TYPES) {
	327	return $TYPES{$type}
	328	if $type_constraint->is_subtype_of($type);
	329	}
e1bb45ff	330
	331	# NOTE:
	332	# the reason the above will work has to
	333	# do with the fact that custom subtypes
	334	# are mostly used for validation of
	335	# the guts of a type, and not for some
	336	# weird structural thing which would
	337	# need to be accomidated by the serializer.
	338	# Of course, mst or phaylon will probably
	339	# do something to throw this assumption
	340	# totally out the door ;)
	341	# - SL
	342
e9739624	343	# NOTE:
	344	# if this method hasnt returned by now
	345	# then we have no been able to find a
	346	# type constraint handler to match
	347	confess "Cannot handle type constraint (" . $type_constraint->name . ")";
e59193fb	348	}
e59193fb	349
3defafb9	350	sub find_type_handler_for {
	351	my ($self, $type_handler_name) = @_;
	352	$TYPES{$type_handler_name}
	353	}
	354
e59193fb	355	1;
e9739624	356
	357	__END__
	358
	359	=pod
	360
ec9c1923	361	=head1 NAME
ec9c1923	362
1390c23d	363	MooseX::Storage::Engine - The meta-engine to handle collapsing and expanding objects
ec9c1923	364
	365	=head1 DESCRIPTION
	366
1390c23d	367	No user serviceable parts inside. If you really want to know, read the source :)
1390c23d	368
ec9c1923	369	=head1 METHODS
	370
	371	=head2 Accessors
	372
	373	=over 4
	374
	375	=item B<class>
	376
	377	=item B<object>
	378
	379	=item B<storage>
	380
b430caa3	381	=item B<seen>
b430caa3	382
ec9c1923	383	=back
	384
	385	=head2 API
	386
	387	=over 4
	388
	389	=item B<expand_object>
	390
	391	=item B<collapse_object>
	392
	393	=back
	394
	395	=head2 ...
	396
	397	=over 4
	398
	399	=item B<collapse_attribute>
	400
	401	=item B<collapse_attribute_value>
	402
	403	=item B<expand_attribute>
	404
	405	=item B<expand_attribute_value>
	406
b430caa3	407	=item B<check_for_cycle_in_collapse>
	408
	409	=item B<check_for_cycle_in_expansion>
	410
ec9c1923	411	=item B<map_attributes>
ec9c1923	412
3db8f791	413	=back
	414
	415	=head2 Type Constraint Handlers
	416
	417	=over 4
	418
3defafb9	419	=item B<find_type_handler ($type)>
	420
	421	=item B<find_type_handler_for ($name)>
3db8f791	422
3defafb9	423	=item B<add_custom_type_handler ($name, %handlers)>
3db8f791	424
3defafb9	425	=item B<remove_custom_type_handler ($name)>
ec9c1923	426
	427	=back
	428
	429	=head2 Introspection
	430
	431	=over 4
	432
	433	=item B<meta>
	434
	435	=back
	436
	437	=head1 BUGS
	438
	439	All complex software has bugs lurking in it, and this module is no
	440	exception. If you find a bug please either email me, or add the bug
	441	to cpan-RT.
	442
	443	=head1 AUTHOR
	444
	445	Chris Prather E<lt>chris.prather@iinteractive.comE<gt>
	446
	447	Stevan Little E<lt>stevan.little@iinteractive.comE<gt>
	448
	449	=head1 COPYRIGHT AND LICENSE
	450
1f3074ea	451	Copyright 2007-2008 by Infinity Interactive, Inc.
ec9c1923	452
	453	L<http://www.iinteractive.com>
	454
	455	This library is free software; you can redistribute it and/or modify
	456	it under the same terms as Perl itself.
	457
e9739624	458	=cut
	459
	460
ec9c1923	461