Composite now implemented.

[gitmo/MooseX-AttributeHelpers.git] / lib / MooseX / AttributeHelpers / MethodProvider / List.pm

package MooseX::AttributeHelpers::MethodProvider::List;
use Moose::Role;

our $VERSION   = '0.01';
our $AUTHORITY = 'cpan:STEVAN';
 
sub count : method {
    my ($attr, $reader, $writer) = @_;
    return sub { scalar @{$reader->($_[0])} };        
}

# Deprecated.  The author was thinking backwardsly when this was written.
sub empty : method {
    my ($attr, $reader, $writer) = @_;
    return sub { scalar @{$reader->($_[0])} ? 1 : 0 };
}

sub is_empty : method {
    my ($attr, $reader, $writer) = @_;
    return sub { @{ $reader->($_[0]) } == 0 };
}

sub has_items : method {
    my ($attr, $reader, $writer) = @_;
    return sub { @{ $reader->($_[0]) } > 0 };
}

sub find : method {
    my ($attr, $reader, $writer) = @_;
    return sub {
        my ($instance, $predicate) = @_;
        foreach my $val (@{$reader->($instance)}) {
            return $val if $predicate->($val);
        }
        return;
    };
}

sub map : method {
    my ($attr, $reader, $writer) = @_;
    return sub {
        my ($instance, $f) = @_;
        CORE::map { $f->($_) } @{$reader->($instance)}
    };
}

sub grep : method {
    my ($attr, $reader, $writer) = @_;
    return sub {
        my ($instance, $predicate) = @_;
        CORE::grep { $predicate->($_) } @{$reader->($instance)}
    };
}

1;

__END__

=pod

=head1 NAME

MooseX::AttributeHelpers::MethodProvider::List
  
=head1 DESCRIPTION

This is a role which provides the method generators for 
L<MooseX::AttributeHelpers::Collection::List>.

=head1 PROVIDED METHODS

=over 4

=item B<count>

Returns the number of items in the list.

=item B<empty>

DEPRECATED.  This was a misleading name for what it does (returns a boolean
indicating whether the list is NOT empty), but we're keeping it for backwards
compatibility.  Do not use it in new code.  Use is_empty or has_items instead,
depending on what you meant.

=item B<is_empty>

Returns a boolean which is true if and only if the list has no items in it.

=item B<has_items>

Returns a boolean which is true if and only if the list has at least one item.

=item B<find($predicate)>

Returns the first item in the list that satisfies $predicate.

=item B<grep>

L<perlfunc/grep>

=item B<map>

L<perlfunc/map>

=back

=head1 BUGS

All complex software has bugs lurking in it, and this module is no 
exception. If you find a bug please either email me, or add the bug
to cpan-RT.

=head1 AUTHOR

Stevan Little E<lt>stevan@iinteractive.comE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2008 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut