Just haven't commited this yet, and it has a lot of work in it.

[gitmo/MooseX-AttributeHelpers.git] / lib / MooseX / AttributeHelpers / Base.pm

package MooseX::AttributeHelpers::Base;
use Moose;
use Moose::Util::TypeConstraints;
use MooseX::AttributeHelpers::Meta::Method::Provided;

our $VERSION   = '0.04';
our $AUTHORITY = 'cpan:STEVAN';

extends 'Moose::Meta::Attribute';

# this is the method map you define ...
has 'provides' => (
    is      => 'ro',
    isa     => 'HashRef',
    default => sub {{}}
);

# these next two are the possible methods
# you can use in the 'provides' map.

# provide a Class or Role which we can
# collect the method providers from
has 'method_provider' => (
    is        => 'ro',
    isa       => 'ClassName',
    predicate => 'has_method_provider',
);

# or you can provide a HASH ref of anon subs
# yourself. This will also collect and store
# the methods from a method_provider as well
has 'method_constructors' => (
    is      => 'ro',
    isa     => 'HashRef',
    lazy    => 1,
    default => sub {
        my $self = shift;
        return +{} unless $self->has_method_provider;
        # or grab them from the role/class
        my $method_provider = $self->method_provider->meta;
        return +{
            map {
                $_ => $method_provider->get_method($_)
            } $method_provider->get_method_list
        };
    },
);

# extend the parents stuff to make sure
# certain bits are now required ...
has '+$!default'       => (required => 1);
has '+type_constraint' => (required => 1);

## Methods called prior to instantiation

# (overridden by Sugar or plain subclasses)
sub helper_type {()}
sub default_options {}
sub auto_provide {0}

sub process_options_for_provides {
    my ($self, $options) = @_;

    if (my $defaults = $self->default_options) {
        foreach my $key (keys %$defaults) {
            $options->{$key} = $defaults->{$key} 
                unless exists $options->{$key};
        }
    }

    if (my $type = $self->helper_type) {
        $options->{isa} = $type unless exists $options->{isa};

        my $isa = $options->{isa};

        unless (blessed($isa) && $isa->isa('Moose::Meta::TypeConstraint')) {
            $isa = Moose::Util::TypeConstraints::find_or_create_type_constraint($isa);
        }

        ($isa->is_a_type_of($type))
            || confess "The type constraint for a $type ($options->{isa}) must be a subtype of $type";
    }
}

before '_process_options' => sub {
    my ($self, $name, $options) = @_;
    $self->process_options_for_provides($options, $name);
};

## methods called after instantiation

# this confirms that provides has
# all valid possibilities in it
sub check_provides_values {
    my $self = shift;

    my $method_constructors = $self->method_constructors;

    foreach my $key (keys %{$self->provides}) {
        (exists $method_constructors->{$key})
            || confess "$key is an unsupported method type";
    }

    my $provides = $self->provides;
    if (keys %$provides == 0 and $self->auto_provide) {
        my $attr_name = $self->name;

        foreach my $method (keys %$method_constructors) {
          $provides->{$method} = "${method}_${attr_name}";
        }
    }
}

after 'install_accessors' => sub {
    my $attr  = shift;
    my $class = $attr->associated_class;

    # grab the reader and writer methods
    # as well, this will be useful for
    # our method provider constructors
    my $attr_reader = $attr->get_read_method_ref;
    my $attr_writer = $attr->get_write_method_ref;


    # before we install them, lets
    # make sure they are valid
    $attr->check_provides_values;

    my $method_constructors = $attr->method_constructors;

    foreach my $key (keys %{$attr->provides}) {

        my $method_name = $attr->provides->{$key};

        if ($class->has_method($method_name)) {
            confess "The method ($method_name) already exists in class (" . $class->name . ")";
        }

        my $method = MooseX::AttributeHelpers::Meta::Method::Provided->wrap(
            $method_constructors->{$key}->(
                $attr,
                $attr_reader,
                $attr_writer,
            )
        );
        
        $attr->associate_method($method);
        $class->add_method($method_name => $method);
    }
};

after 'remove_accessors' => sub {
    my $attr  = shift;
    my $class = $attr->associated_class;
    foreach my $key (keys %{$attr->provides}) {
        my $method_name = $attr->provides->{$key};
        my $method = $class->get_method($method_name);
        $class->remove_method($method_name)
            if blessed($method) &&
               $method->isa('MooseX::AttributeHelpers::Meta::Method::Provided');
    }
};

no Moose;
no Moose::Util::TypeConstraints;

1;

__END__

=pod

=head1 NAME

MooseX::AttributeHelpers::Base - Base class for attribute helpers

=head1 DESCRIPTION

This class is what you inherit from when you want to make a new
AttributeHelper.  Unless you are doing something quite fancy, your needs
should be met by L<MooseX::AttributeHelpers::Sugar>, which has a nice, terse
syntax and some convenience, but you should still subclass this class.

=head1 ATTRIBUTES

=over 4

=item B<provides>

This is the map of metaclass methods to methods that will be installed in your
class, e.g. add => 'add_to_number'.

=item B<method_provider>

The name of a class or role to be used as source material for the above map.
In the above example, the method provider's "add" method would be used to
construct a method to install into the attribute holder's class.

=item B<method_constructors>

You can optionally supply a hashref of names to subs instead of a class to be
used as method constructors, but by default this is pulled from
method_provider.

=back

=head1 EXTENDED ATTRIBUTES

=over 4

=item B<$!default>

C<$!default> is now required.

=item B<type_constraint>

C<type_constraint> is now required.

=back

=head1 METHODS

=over 4

=item B<meta>

=item B<auto_provide>

If this method returns a true value, all available method constructors will be
provided in the format $method_$attribute_name e.g. inc_counter.  This is
intended to be overridden in subclasses.

=item B<default_options>

Returns a Maybe[Hashref] of attribution specifications to fill in if they are
not overridden by the implementing attribute.  This is intended to be
overridden in subclasses.

=item B<helper_type>

This forces all attributes using this metaclass to be a subtype of
helper_type.  This is intended to be overridden in subclasses.

=item B<check_provides_values>

=item B<has_method_provider>

=item B<install_accessors>

=item B<remove_accessors>

=item B<process_options_for_provides>

=back

=head1 BUGS

All complex software has bugs lurking in it, and this module is no
exception. If you find a bug please either email me, or add the bug
to cpan-RT.

=head1 AUTHOR

Stevan Little E<lt>stevan@iinteractive.comE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2008 by Infinity Interactive, Inc.

L<http://www.iinteractive.com>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut