Add Log::Message and Log::Message::Simple to the core

[p5sagit/p5-mst-13.2.git] / lib / Log / Message / Item.pm

package Log::Message::Item;\r
\r
use strict;\r
use Params::Check qw[check];\r
use Log::Message::Handlers;\r
\r
### for the messages to store ###\r
use Carp ();\r
\r
BEGIN {\r
    use vars qw[$AUTOLOAD $VERSION];\r
\r
    $VERSION    =   $Log::Message::VERSION;\r
}\r
\r
### create a new item.\r
### note that only an id (position on the stack), message and a reference\r
### to its parent are required. all the other things it can fill in itself\r
sub new {\r
    my $class   = shift;\r
    my %hash    = @_;\r
\r
    my $tmpl = {\r
        when        => { no_override    => 1,   default    => scalar localtime },\r
        id          => { required       => 1    },\r
        message     => { required       => 1    },\r
        parent      => { required        => 1    },\r
        level       => { default        => ''   },      # default may be conf dependant\r
        tag         => { default        => ''   },      # default may be conf dependant\r
        longmess    => { default        => _clean(Carp::longmess()) },\r
        shortmess   => { default        => _clean(Carp::shortmess())},\r
    };\r
\r
    my $args = check($tmpl, \%hash) or return undef;\r
\r
    return bless $args, $class;\r
}\r
\r
sub _clean { map { s/\s*//; chomp; $_ } shift; }\r
\r
sub remove {\r
    my $item = shift;\r
    my $self = $item->parent;\r
\r
    return splice( @{$self->{STACK}}, $item->id, 1, undef );\r
}\r
\r
sub AUTOLOAD {\r
    my $self = $_[0];\r
\r
    $AUTOLOAD =~ s/.+:://;\r
\r
    return $self->{$AUTOLOAD} if exists $self->{$AUTOLOAD};\r
\r
    local $Carp::CarpLevel = $Carp::CarpLevel + 3;\r
\r
    {   no strict 'refs';\r
        return *{"Log::Message::Handlers::${AUTOLOAD}"}->(@_);\r
    }\r
}\r
\r
sub DESTROY { 1 }\r
\r
1;\r
\r
__END__\r
\r
=pod\r
\r
=head1 NAME\r
\r
Log::Message::Item  - Message objects for Log::Message\r
\r
=head1 SYNOPSIS\r
\r
    # Implicitly used by Log::Message to create Log::Message::Item objects\r
\r
    print "this is the message's id: ",     $item->id;\r
\r
    print "this is the message stored: ",   $item->message;\r
\r
    print "this is when it happened: ",     $item->when;\r
\r
    print "the message was tagged: ",       $item->tag;\r
\r
    print "this was the severity level: ",  $item->level;\r
\r
    $item->remove;  # delete the item from the stack it was on\r
\r
    # Besides these methods, you can also call the handlers on\r
    # the object specificallly.\r
    # See the Log::Message::Handlers manpage for documentation on what\r
    # handlers are available by default and how to add your own\r
\r
\r
=head1 DESCRIPTION\r
\r
Log::Message::Item is a class that generates generic Log items.\r
These items are stored on a Log::Message stack, so see the Log::Message\r
manpage about details how to retrieve them.\r
\r
You should probably not create new items by yourself, but use the\r
storing mechanism provided by Log::Message.\r
\r
However, the accessors and handlers are of interest if you want to do\r
fine tuning of how your messages are handled.\r
\r
The accessors and methods are described below, the handlers are\r
documented in the Log::Message::Handlers manpage.\r
\r
=head1 Methods and Accessors\r
\r
=head2 remove\r
\r
Calling remove will remove the object from the stack it was on, so it\r
will not show up any more in subsequent fetches of messages.\r
\r
You can still call accessors and handlers on it however, to handle it\r
as you will.\r
\r
=head2 id\r
\r
Returns the internal ID of the item. This may be useful for comparing\r
since the ID is incremented each time a new item is created.\r
Therefore, an item with ID 4 must have been logged before an item with\r
ID 9.\r
\r
=head2 when\r
\r
Returns the timestamp of when the message was logged\r
\r
=head2 message\r
\r
The actual message that was stored\r
\r
=head2 level\r
\r
The severity type of this message, as well as the name of the handler\r
that was called upon storing it.\r
\r
=head2 tag\r
\r
Returns the identification tag that was put on the message.\r
\r
=head2 shortmess\r
\r
Returns the equivalent of a C<Carp::shortmess> for this item.\r
See the C<Carp> manpage for details.\r
\r
=head2 longmess\r
\r
Returns the equivalent of a C<Carp::longmess> for this item, which\r
is essentially a stack trace.\r
See the C<Carp> manpage for details.\r
\r
=head2 parent\r
\r
Returns a reference to the Log::Message object that stored this item.\r
This is useful if you want to have access to the full stack in a\r
handler.\r
\r
=head1 SEE ALSO\r
\r
L<Log::Message>, L<Log::Message::Handlers>, L<Log::Message::Config>\r
\r
=head1 AUTHOR\r
\r
This module by\r
Jos Boumans E<lt>kane@cpan.orgE<gt>.\r
\r
=head1 Acknowledgements\r
\r
Thanks to Ann Barcomb for her suggestions.\r
\r
=head1 COPYRIGHT\r
\r
This module is\r
copyright (c) 2002 Jos Boumans E<lt>kane@cpan.orgE<gt>.\r
All rights reserved.\r
\r
This library is free software;\r
you may redistribute and/or modify it under the same\r
terms as Perl itself.\r
\r
=cut\r
\r
# Local variables:\r
# c-indentation-style: bsd\r
# c-basic-offset: 4\r
# indent-tabs-mode: nil\r
# End:\r
# vim: expandtab shiftwidth=4:\r