[catagits/Gitalist.git] / lib / Gitalist / Git / Project.pm

use MooseX::Declare;

=head1 NAME

Gitalist::Git::Project - Model of a git repository

=head1 SYNOPSIS

    my $gitrepo = dir('/repo/base/Gitalist');
    my $project = Gitalist::Git::Project->new($gitrepo);
     $project->name;        # 'Gitalist'
     $project->path;        # '/repo/base/Gitalist/.git'
     $project->description; # 'Unnamed repository.'

=head1 DESCRIPTION

This class models a git repository, referred to in Gitalist
as a "Project".

=cut

class Gitalist::Git::Project with Gitalist::Git::HasUtils {
    # FIXME, use Types::Path::Class and coerce
    use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
    use MooseX::Types::Path::Class qw/Dir/;
    use MooseX::Types::Moose qw/Str Maybe Bool HashRef ArrayRef/;
    use List::MoreUtils qw/any zip/;
    use DateTime;
    use aliased 'Gitalist::Git::Object';

    our $SHA1RE = qr/[0-9a-fA-F]{40}/;

    around BUILDARGS (ClassName $class: Dir $dir) {
        # Allows us to be called as Project->new($dir)
        # Last path component becomes $self->name
        # Full path to git objects becomes $self->path
        my $name = $dir->dir_list(-1);
        $dir = $dir->subdir('.git') if (-f $dir->file('.git', 'HEAD'));
        confess("Can't find a git repository at " . $dir)
            unless ( -f $dir->file('HEAD') );
        return $class->$orig(name => $name,
                             path => $dir);
    }

=head1 ATTRIBUTES

=head2 name

The name of the Project.  By default, this is derived from the path to the git repository.

=cut
    has name => ( isa => NonEmptySimpleStr,
                  is => 'ro', required => 1 );

=head2 path

L<Path::Class:Dir> for the location of the git repository.

=cut
    has path => ( isa => Dir,
                  is => 'ro', required => 1);

=head2 description

String containing .git/description

=cut
    has description => ( isa => Str,
                         is => 'ro',
                         lazy_build => 1,
                     );

=head2 owner

Owner of the files on disk.

=cut
    has owner => ( isa => NonEmptySimpleStr,
                   is => 'ro',
                   lazy_build => 1,
               );

=head2 last_change

L<DateTime> for the time of the last update.
undef if the repository has never been used.

=cut
    has last_change => ( isa => Maybe['DateTime'],
                         is => 'ro',
                         lazy_build => 1,
                     );

=head2 is_bare

Bool indicating whether this Project is bare.

=cut
    has is_bare => ( isa => Bool,
                     is => 'ro',
                     lazy => 1,
                     default => sub {
                         -d $_[0]->path->parent->subdir->($_[0]->name)
                             ? 1 : 0
                         },
                     );

=head2 heads

ArrayRef of hashes containing the name and sha1 of all heads.

=cut
    has heads => ( isa => ArrayRef[HashRef],
                   is => 'ro',
                   lazy_build => 1);

=head2 references

Hashref of ArrayRefs for each reference.

=cut
    has references => ( isa => HashRef[ArrayRef[Str]],
                        is => 'ro',
                        lazy_build => 1 );

    method BUILD {
        $self->$_() for qw/last_change owner description/; # Ensure to build early.
    }

=head1 METHODS

=head2 head_hash ($head?)

Return the sha1 for HEAD, or any specified head.

=cut
    method head_hash (Str $head?) {
        my $output = $self->run_cmd(qw/rev-parse --verify/, $head || 'HEAD' );
        confess("No such head: " . $head) unless defined $output;

        my($sha1) = $output =~ /^($SHA1RE)$/;
        return $sha1;
    }

=head2 list_tree ($sha1?)

Return an array of contents for a given tree.
The tree is specified by sha1, and defaults to HEAD.
Each item is a L<Gitalist::Git::Object>.

=cut
    method list_tree (Str $sha1?) {
        $sha1 ||= $self->head_hash;

        my $output = $self->run_cmd(qw/ls-tree -z/, $sha1);
        return unless defined $output;

        my @ret;
        for my $line (split /\0/, $output) {
            my ($mode, $type, $object, $file) = split /\s+/, $line, 4;
            push @ret, Object->new( mode => oct $mode,
                                    type => $type,
                                    sha1 => $object,
                                    file => $file,
                                    project => $self,
                                  );
        }
        return @ret;
    }

=head2 get_object ($sha1)

Return a L<Gitalist::Git::Object> for the given sha1.

=cut
    method get_object (NonEmptySimpleStr $sha1) {
        unless ( $self->_is_valid_rev($sha1) ) {
            $sha1 = $self->head_hash($sha1);
        }
        return Object->new(
            project => $self,
            sha1 => $sha1,
        );
    }

=head2 hash_by_path($sha1, $path, $type?)

Returns the sha1 for a given path, optionally limited by type.

=cut
    method hash_by_path ($base, $path = '', $type?) {
        $path =~ s{/+$}();
        # FIXME should this really just take the first result?
        my @paths = $self->run_cmd('ls-tree', $base, '--', $path)
            or return;
        my $line = $paths[0];

        #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa	panic.c'
        $line =~ m/^([0-9]+) (.+) ($SHA1RE)\t/;
        return defined $type && $type ne $2
            ? ()
                : $3;
    }

=head2 list_revs($sha1, $count?, $skip?, \%search?, $file?)

Returns a list of revs for the given head ($sha1).

=cut
    method list_revs ( NonEmptySimpleStr :$sha1!,
                       Int :$count?,
                       Int :$skip?,
                       HashRef :$search?,
                       NonEmptySimpleStr :$file?
                   ) {
        $sha1 = $self->head_hash($sha1)
            if !$sha1 || $sha1 !~ $SHA1RE;

	my @search_opts;
        if($search) {
            $search->{type} = 'grep'
                if $search->{type} eq 'commit';
            @search_opts = (
                # This seems a little fragile ...
                qq[--$search->{type}=$search->{text}],
                '--regexp-ignore-case',
                $search->{regexp} ? '--extended-regexp' : '--fixed-strings'
            );
        }

        my $output = $self->run_cmd(
            'rev-list',
            '--header',
            (defined $count ? "--max-count=$count" : ()),
            (defined $skip ? "--skip=$skip"       : ()),
            @search_opts,
            $sha1,
            '--',
            ($file ? $file : ()),
        );
        return unless $output;

        my @revs = $self->_parse_rev_list($output);

        return @revs;
    }

=head2 diff($commit, $patch?, $parent?, $file?)

Generate a diff.

FIXME this should be a method on the commit object.

=cut

    # XXX Ideally this would return a wee object instead of ad hoc structures.
    method diff ( Gitalist::Git::Object :$commit!,
                  Bool :$patch?,
                  Maybe[NonEmptySimpleStr] :$parent?,
                  NonEmptySimpleStr :$file? ) {
        # Use parent if specifed, else take the parent from the commit
        # if there is only one, otherwise it was a merge commit.
        $parent = $parent
            ? $parent
            : $commit->parents <= 1
            ? $commit->parent_sha1
            : '-c';
        my @etc = (
            ( $file  ? ('--', $file) : () ),
        );

        my @out = $self->_raw_diff(
            ( $patch ? '--patch-with-raw' : () ),
            ( $parent ? $parent : () ),
            $commit->sha1, @etc,
        );

        # XXX Yes, there is much wrongness having _parse_diff_tree be destructive.
        my @difftree = $self->_parse_diff_tree(\@out);

        return \@difftree
            unless $patch;

        # The blank line between the tree and the patch.
        shift @out;

        # XXX And no I'm not happy about having diff return tree + patch.
        return \@difftree, [$self->_parse_diff(@out)];
    }

=head2 reflog(@lorgargs)

Return a list of hashes representing each reflog entry.

FIXME Should this return objects?

=cut
    method reflog (@logargs) {
        my @entries
            =  $self->run_cmd(qw(log -g), @logargs)
                =~ /(^commit.+?(?:(?=^commit)|(?=\z)))/msg;

#  commit 02526fc15beddf2c64798a947fecdd8d11bf993d
#  Reflog: HEAD@{14} (The Git Server <git@git.dev.venda.com>)
#  Reflog message: push
#  Author: Foo Barsby <fbarsby@example.com>
#  Date:   Thu Sep 17 12:26:05 2009 +0100
#
#      Merge branch 'abc123'

        return map {
            # XXX Stuff like this makes me want to switch to Git::PurePerl
            my($sha1, $type, $author, $date)
                = m{
                       ^ commit \s+ ($SHA1RE)$
                       .*?
                       Reflog[ ]message: \s+ (.+?)$ \s+
                     Author: \s+ ([^<]+) <.*?$ \s+
                   Date: \s+ (.+?)$
               }xms;

            pos($_) = index($_, $date) + length $date;

            # Yeah, I just did that.
            my($msg) = /\G\s+(\S.*)/sg;
            {
                hash    => $sha1,
                type    => $type,
                author  => $author,

                # XXX Add DateTime goodness.
                date    => $date,
                message => $msg,
            }
            ;
        } @entries;
    }

    ## BUILDERS
    method _build__util {
        Gitalist::Git::Util->new(
            project => $self,
        );
    }

    method _build_description {
        return $self->gpp->description;
    }

    method _build_owner {
        my ($gecos, $name) = (getpwuid $self->path->stat->uid)[6,0];
        $gecos =~ s/,+$//;
        return length($gecos) ? $gecos : $name;
    }

    method _build_last_change {
        my $last_change;
        my $output = $self->run_cmd(
            qw{ for-each-ref --format=%(committer)
                --sort=-committerdate --count=1 refs/heads
          });
        if (my ($epoch, $tz) = $output =~ /\s(\d+)\s+([+-]\d+)$/) {
            my $dt = DateTime->from_epoch(epoch => $epoch);
            $dt->set_time_zone($tz);
            $last_change = $dt;
        }
        return $last_change;
    }

    method _build_heads {
        my @revlines = $self->run_cmd_list(qw/for-each-ref --sort=-committerdate /, '--format=%(objectname)%00%(refname)%00%(committer)', 'refs/heads');
        my @ret;
        for my $line (@revlines) {
            my ($rev, $head, $commiter) = split /\0/, $line, 3;
            $head =~ s!^refs/heads/!!;

            push @ret, { sha1 => $rev, name => $head };

            #FIXME: That isn't the time I'm looking for..
            if (my ($epoch, $tz) = $line =~ /\s(\d+)\s+([+-]\d+)$/) {
                my $dt = DateTime->from_epoch(epoch => $epoch);
                $dt->set_time_zone($tz);
                $ret[-1]->{last_change} = $dt;
            }
        }

        return \@ret;
    }

    method _build_references {
    	# 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
    	# c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
    	my @reflist = $self->run_cmd_list(qw(show-ref --dereference))
	    	or return;
        my %refs;
	    for(@reflist) {
		    push @{$refs{$1}}, $2
			    if m!^($SHA1RE)\srefs/(.*)$!;
	    }

	    return \%refs;
    }

    ## Private methods
    method _is_valid_rev (Str $rev) {
        return ($rev =~ /^($SHA1RE)$/);
    }

    method _parse_rev_list ($output) {
        return
            map  $self->get_gpp_object($_),
                grep $self->_is_valid_rev($_),
                    map  split(/\n/, $_, 6), split /\0/, $output;
    }

    method _parse_diff_tree ($diff) {
        my @keys = qw(modesrc modedst sha1src sha1dst status src dst);
        my @ret;
        while (@$diff and $diff->[0] =~ /^:\d+/) {
            my $line = shift @$diff;
            # see. man git-diff-tree for more info
            # mode src, mode dst, sha1 src, sha1 dst, status, src[, dst]
            my @vals = $line =~ /^:(\d+) (\d+) ($SHA1RE) ($SHA1RE) ([ACDMRTUX]\d*)\t([^\t]+)(?:\t([^\n]+))?$/;
            my %line = zip @keys, @vals;
            # Some convenience keys
            $line{file}   = $line{src};
            $line{sha1}   = $line{sha1dst};
            $line{is_new} = $line{sha1src} =~ /^0+$/
		if $line{sha1src};
            @line{qw/status sim/} = $line{status} =~ /(R)(\d+)/
                if $line{status} =~ /^R/;
            push @ret, \%line;
        }

        return @ret;
    }
    method _parse_diff (@diff) {
        my @ret;
        for (@diff) {
            # This regex is a little pathological.
            if(m{^diff --git (a/(.*?)) (b/\2)}) {
                push @ret, {
                    head => $_,
                    a    => $1,
                    b    => $3,
                    file => $2,
                    diff => '',
                };
                next;
            }

            if(/^index (\w+)\.\.(\w+) (\d+)$/) {
                @{$ret[-1]}{qw(index src dst mode)} = ($_, $1, $2, $3);
                next
            }

            # XXX Somewhat hacky. Ahem.
            $ret[@ret ? -1 : 0]{diff} .= "$_\n";
        }

        return @ret;
    }

    # gitweb uses the following sort of command for diffing merges:
# /home/dbrook/apps/bin/git --git-dir=/home/dbrook/dev/app/.git diff-tree -r -M --no-commit-id --patch-with-raw --full-index --cc 316cf158df3f6207afbae7270bcc5ba0 --
# and for regular diffs
# /home/dbrook/apps/bin/git --git-dir=/home/dbrook/dev/app/.git diff-tree -r -M --no-commit-id --patch-with-raw --full-index 2e3454ca0749641b42f063730b0090e1 316cf158df3f6207afbae7270bcc5ba0 --
    method _raw_diff (@args) {
        return $self->run_cmd_list(
            qw(diff-tree -r -M --no-commit-id --full-index),
            @args
        );
    }

=head1 SEE ALSO

L<Gitalist::Git::Util> L<Gitalist::Git::Object>

=head1 AUTHORS AND COPYRIGHT

  Catalyst application:
    (C) 2009 Venda Ltd and Dan Brook <dbrook@venda.com>

  Original gitweb.cgi from which this was derived:
    (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
    (C) 2005, Christian Gierke

=head1 LICENSE

FIXME - Is this going to be GPLv2 as per gitweb? If so this is broken..

This library is free software. You can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

} # end class
Commit	Line	Data
56b6dbe6	1	use MooseX::Declare;
56b6dbe6	2
b5b638f7	3	=head1 NAME
b5b638f7	4
894bff59	5	Gitalist::Git::Project - Model of a git repository
b5b638f7	6
	7	=head1 SYNOPSIS
	8
561a3f14	9	my $gitrepo = dir('/repo/base/Gitalist');
	10	my $project = Gitalist::Git::Project->new($gitrepo);
	11	$project->name; # 'Gitalist'
	12	$project->path; # '/repo/base/Gitalist/.git'
	13	$project->description; # 'Unnamed repository.'
b5b638f7	14
	15	=head1 DESCRIPTION
	16
	17	This class models a git repository, referred to in Gitalist
	18	as a "Project".
	19
	20	=cut
	21
38b9e5c8	22	class Gitalist::Git::Project with Gitalist::Git::HasUtils {
56b6dbe6	23	# FIXME, use Types::Path::Class and coerce
56b6dbe6	24	use MooseX::Types::Common::String qw/NonEmptySimpleStr/;
84f31a44	25	use MooseX::Types::Path::Class qw/Dir/;
829d41ed	26	use MooseX::Types::Moose qw/Str Maybe Bool HashRef ArrayRef/;
77edf882	27	use List::MoreUtils qw/any zip/;
b5b638f7	28	use DateTime;
a8a8f8f9	29	use aliased 'Gitalist::Git::Object';
56b6dbe6	30
32a371cc	31	our $SHA1RE = qr/[0-9a-fA-F]{40}/;
	32
	33	around BUILDARGS (ClassName $class: Dir $dir) {
4b6bcf44	34	# Allows us to be called as Project->new($dir)
	35	# Last path component becomes $self->name
	36	# Full path to git objects becomes $self->path
32a371cc	37	my $name = $dir->dir_list(-1);
	38	$dir = $dir->subdir('.git') if (-f $dir->file('.git', 'HEAD'));
	39	confess("Can't find a git repository at " . $dir)
	40	unless ( -f $dir->file('HEAD') );
	41	return $class->$orig(name => $name,
	42	path => $dir);
	43	}
	44
b5b638f7	45	=head1 ATTRIBUTES
	46
	47	=head2 name
	48
cc88eca5	49	The name of the Project. By default, this is derived from the path to the git repository.
29debefd	50
cc88eca5	51	=cut
56b6dbe6	52	has name => ( isa => NonEmptySimpleStr,
01ced85b	53	is => 'ro', required => 1 );
b5b638f7	54
	55	=head2 path
	56
	57	L<Path::Class:Dir> for the location of the git repository.
	58
	59	=cut
84f31a44	60	has path => ( isa => Dir,
01ced85b	61	is => 'ro', required => 1);
56b6dbe6	62
b5b638f7	63	=head2 description
	64
	65	String containing .git/description
	66
	67	=cut
0617cbd0	68	has description => ( isa => Str,
56b6dbe6	69	is => 'ro',
	70	lazy_build => 1,
	71	);
b5b638f7	72
	73	=head2 owner
	74
	75	Owner of the files on disk.
	76
	77	=cut
56b6dbe6	78	has owner => ( isa => NonEmptySimpleStr,
	79	is => 'ro',
	80	lazy_build => 1,
	81	);
b5b638f7	82
	83	=head2 last_change
	84
	85	L<DateTime> for the time of the last update.
	86	undef if the repository has never been used.
	87
	88	=cut
0617cbd0	89	has last_change => ( isa => Maybe['DateTime'],
56b6dbe6	90	is => 'ro',
	91	lazy_build => 1,
	92	);
	93
b5b638f7	94	=head2 is_bare
	95
	96	Bool indicating whether this Project is bare.
	97
	98	=cut
b5b638f7	99	has is_bare => ( isa => Bool,
	100	is => 'ro',
	101	lazy => 1,
	102	default => sub {
	103	-d $_[0]->path->parent->subdir->($_[0]->name)
	104	? 1 : 0
	105	},
	106	);
84f31a44	107
cc88eca5	108	=head2 heads
	109
	110	ArrayRef of hashes containing the name and sha1 of all heads.
	111
	112	=cut
	113	has heads => ( isa => ArrayRef[HashRef],
	114	is => 'ro',
	115	lazy_build => 1);
	116
	117	=head2 references
	118
	119	Hashref of ArrayRefs for each reference.
	120
	121	=cut
	122	has references => ( isa => HashRef[ArrayRef[Str]],
	123	is => 'ro',
	124	lazy_build => 1 );
	125
01ced85b	126	method BUILD {
38b9e5c8	127	$self->$_() for qw/last_change owner description/; # Ensure to build early.
01ced85b	128	}
01ced85b	129
32a371cc	130	=head1 METHODS
8dbe8024	131
cc88eca5	132	=head2 head_hash ($head?)
894bff59	133
32a371cc	134	Return the sha1 for HEAD, or any specified head.
894bff59	135
32a371cc	136	=cut
32a371cc	137	method head_hash (Str $head?) {
	138	my $output = $self->run_cmd(qw/rev-parse --verify/, $head \|\| 'HEAD' );
	139	confess("No such head: " . $head) unless defined $output;
29debefd	140
32a371cc	141	my($sha1) = $output =~ /^($SHA1RE)$/;
32a371cc	142	return $sha1;
56b6dbe6	143	}
56b6dbe6	144
cc88eca5	145	=head2 list_tree ($sha1?)
a8a8f8f9	146
	147	Return an array of contents for a given tree.
	148	The tree is specified by sha1, and defaults to HEAD.
cc88eca5	149	Each item is a L<Gitalist::Git::Object>.
a8a8f8f9	150
a8a8f8f9	151	=cut
a8a8f8f9	152	method list_tree (Str $sha1?) {
	153	$sha1 \|\|= $self->head_hash;
	154
	155	my $output = $self->run_cmd(qw/ls-tree -z/, $sha1);
	156	return unless defined $output;
	157
	158	my @ret;
	159	for my $line (split /\0/, $output) {
	160	my ($mode, $type, $object, $file) = split /\s+/, $line, 4;
	161	push @ret, Object->new( mode => oct $mode,
	162	type => $type,
	163	sha1 => $object,
	164	file => $file,
50394a3e	165	project => $self,
a8a8f8f9	166	);
	167	}
	168	return @ret;
	169	}
	170
cc88eca5	171	=head2 get_object ($sha1)
	172
	173	Return a L<Gitalist::Git::Object> for the given sha1.
	174
	175	=cut
8bb7649b	176	method get_object (NonEmptySimpleStr $sha1) {
894bff59	177	unless ( $self->_is_valid_rev($sha1) ) {
8bb7649b	178	$sha1 = $self->head_hash($sha1);
8bb7649b	179	}
77edf882	180	return Object->new(
54368e9d	181	project => $self,
	182	sha1 => $sha1,
	183	);
	184	}
8bb7649b	185
cc88eca5	186	=head2 hash_by_path($sha1, $path, $type?)
894bff59	187
cc88eca5	188	Returns the sha1 for a given path, optionally limited by type.
	189
	190	=cut
fc11c7f1	191	method hash_by_path ($base, $path = '', $type?) {
54368e9d	192	$path =~ s{/+$}();
32a371cc	193	# FIXME should this really just take the first result?
32a371cc	194	my @paths = $self->run_cmd('ls-tree', $base, '--', $path)
54368e9d	195	or return;
32a371cc	196	my $line = $paths[0];
54368e9d	197
	198	#'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
	199	$line =~ m/^([0-9]+) (.+) ($SHA1RE)\t/;
	200	return defined $type && $type ne $2
	201	? ()
	202	: $3;
	203	}
	204
cc88eca5	205	=head2 list_revs($sha1, $count?, $skip?, \%search?, $file?)
	206
	207	Returns a list of revs for the given head ($sha1).
	208
	209	=cut
4111e151	210	method list_revs ( NonEmptySimpleStr :$sha1!,
	211	Int :$count?,
	212	Int :$skip?,
	213	HashRef :$search?,
	214	NonEmptySimpleStr :$file?
	215	) {
	216	$sha1 = $self->head_hash($sha1)
	217	if !$sha1 \|\| $sha1 !~ $SHA1RE;
	218
	219	my @search_opts;
	220	if($search) {
	221	$search->{type} = 'grep'
	222	if $search->{type} eq 'commit';
	223	@search_opts = (
	224	# This seems a little fragile ...
	225	qq[--$search->{type}=$search->{text}],
	226	'--regexp-ignore-case',
	227	$search->{regexp} ? '--extended-regexp' : '--fixed-strings'
	228	);
	229	}
	230
	231	my $output = $self->run_cmd(
	232	'rev-list',
	233	'--header',
	234	(defined $count ? "--max-count=$count" : ()),
	235	(defined $skip ? "--skip=$skip" : ()),
	236	@search_opts,
	237	$sha1,
	238	'--',
	239	($file ? $file : ()),
	240	);
	241	return unless $output;
	242
cc88eca5	243	my @revs = $self->_parse_rev_list($output);
4111e151	244
	245	return @revs;
	246	}
	247
cc88eca5	248	=head2 diff($commit, $patch?, $parent?, $file?)
	249
	250	Generate a diff.
	251
	252	FIXME this should be a method on the commit object.
	253
	254	=cut
54368e9d	255
77edf882	256	# XXX Ideally this would return a wee object instead of ad hoc structures.
cc88eca5	257	method diff ( Gitalist::Git::Object :$commit!,
77edf882	258	Bool :$patch?,
fc948aee	259	Maybe[NonEmptySimpleStr] :$parent?,
77edf882	260	NonEmptySimpleStr :$file? ) {
	261	# Use parent if specifed, else take the parent from the commit
	262	# if there is only one, otherwise it was a merge commit.
	263	$parent = $parent
	264	? $parent
	265	: $commit->parents <= 1
	266	? $commit->parent_sha1
	267	: '-c';
	268	my @etc = (
	269	( $file ? ('--', $file) : () ),
	270	);
	271
cc88eca5	272	my @out = $self->_raw_diff(
ba65bc52	273	( $patch ? '--patch-with-raw' : () ),
66a82e01	274	( $parent ? $parent : () ),
66a82e01	275	$commit->sha1, @etc,
77edf882	276	);
77edf882	277
cc88eca5	278	# XXX Yes, there is much wrongness having _parse_diff_tree be destructive.
cc88eca5	279	my @difftree = $self->_parse_diff_tree(\@out);
77edf882	280
	281	return \@difftree
	282	unless $patch;
	283
	284	# The blank line between the tree and the patch.
	285	shift @out;
	286
	287	# XXX And no I'm not happy about having diff return tree + patch.
cc88eca5	288	return \@difftree, [$self->_parse_diff(@out)];
77edf882	289	}
77edf882	290
cc88eca5	291	=head2 reflog(@lorgargs)
77edf882	292
cc88eca5	293	Return a list of hashes representing each reflog entry.
77edf882	294
cc88eca5	295	FIXME Should this return objects?
54368e9d	296
cc88eca5	297	=cut
d8abdf1c	298	method reflog (@logargs) {
	299	my @entries
	300	= $self->run_cmd(qw(log -g), @logargs)
	301	=~ /(^commit.+?(?:(?=^commit)\|(?=\z)))/msg;
	302
b719ff6a	303	# commit 02526fc15beddf2c64798a947fecdd8d11bf993d
	304	# Reflog: HEAD@{14} (The Git Server <git@git.dev.venda.com>)
	305	# Reflog message: push
	306	# Author: Foo Barsby <fbarsby@example.com>
	307	# Date: Thu Sep 17 12:26:05 2009 +0100
	308	#
	309	# Merge branch 'abc123'
d8abdf1c	310
	311	return map {
	312	# XXX Stuff like this makes me want to switch to Git::PurePerl
	313	my($sha1, $type, $author, $date)
	314	= m{
	315	^ commit \s+ ($SHA1RE)$
	316	.*?
	317	Reflog[ ]message: \s+ (.+?)$ \s+
	318	Author: \s+ ([^<]+) <.*?$ \s+
	319	Date: \s+ (.+?)$
	320	}xms;
	321
	322	pos($_) = index($_, $date) + length $date;
	323
	324	# Yeah, I just did that.
	325	my($msg) = /\G\s+(\S.*)/sg;
	326	{
	327	hash => $sha1,
	328	type => $type,
	329	author => $author,
	330
	331	# XXX Add DateTime goodness.
	332	date => $date,
	333	message => $msg,
	334	}
	335	;
	336	} @entries;
	337	}
	338
cc88eca5	339	## BUILDERS
32a371cc	340	method _build__util {
	341	Gitalist::Git::Util->new(
	342	project => $self,
	343	);
	344	}
	345
	346	method _build_description {
b9ef23a5	347	return $self->gpp->description;
32a371cc	348	}
	349
	350	method _build_owner {
	351	my ($gecos, $name) = (getpwuid $self->path->stat->uid)[6,0];
	352	$gecos =~ s/,+$//;
	353	return length($gecos) ? $gecos : $name;
	354	}
	355
	356	method _build_last_change {
	357	my $last_change;
	358	my $output = $self->run_cmd(
	359	qw{ for-each-ref --format=%(committer)
	360	--sort=-committerdate --count=1 refs/heads
	361	});
	362	if (my ($epoch, $tz) = $output =~ /\s(\d+)\s+([+-]\d+)$/) {
	363	my $dt = DateTime->from_epoch(epoch => $epoch);
	364	$dt->set_time_zone($tz);
	365	$last_change = $dt;
	366	}
	367	return $last_change;
	368	}
	369
cc88eca5	370	method _build_heads {
	371	my @revlines = $self->run_cmd_list(qw/for-each-ref --sort=-committerdate /, '--format=%(objectname)%00%(refname)%00%(committer)', 'refs/heads');
	372	my @ret;
	373	for my $line (@revlines) {
	374	my ($rev, $head, $commiter) = split /\0/, $line, 3;
	375	$head =~ s!^refs/heads/!!;
	376
	377	push @ret, { sha1 => $rev, name => $head };
	378
	379	#FIXME: That isn't the time I'm looking for..
	380	if (my ($epoch, $tz) = $line =~ /\s(\d+)\s+([+-]\d+)$/) {
	381	my $dt = DateTime->from_epoch(epoch => $epoch);
	382	$dt->set_time_zone($tz);
	383	$ret[-1]->{last_change} = $dt;
	384	}
	385	}
	386
	387	return \@ret;
	388	}
	389
	390	method _build_references {
	391	# 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
	392	# c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
	393	my @reflist = $self->run_cmd_list(qw(show-ref --dereference))
	394	or return;
	395	my %refs;
	396	for(@reflist) {
	397	push @{$refs{$1}}, $2
	398	if m!^($SHA1RE)\srefs/(.*)$!;
	399	}
	400
	401	return \%refs;
	402	}
	403
	404	## Private methods
	405	method _is_valid_rev (Str $rev) {
	406	return ($rev =~ /^($SHA1RE)$/);
	407	}
	408
	409	method _parse_rev_list ($output) {
	410	return
	411	map $self->get_gpp_object($_),
	412	grep $self->_is_valid_rev($_),
	413	map split(/\n/, $_, 6), split /\0/, $output;
	414	}
	415
	416	method _parse_diff_tree ($diff) {
	417	my @keys = qw(modesrc modedst sha1src sha1dst status src dst);
	418	my @ret;
	419	while (@$diff and $diff->[0] =~ /^:\d+/) {
	420	my $line = shift @$diff;
	421	# see. man git-diff-tree for more info
	422	# mode src, mode dst, sha1 src, sha1 dst, status, src[, dst]
	423	my @vals = $line =~ /^:(\d+) (\d+) ($SHA1RE) ($SHA1RE) ([ACDMRTUX]\d*)\t([^\t]+)(?:\t([^\n]+))?$/;
	424	my %line = zip @keys, @vals;
	425	# Some convenience keys
	426	$line{file} = $line{src};
	427	$line{sha1} = $line{sha1dst};
	428	$line{is_new} = $line{sha1src} =~ /^0+$/
	429	if $line{sha1src};
	430	@line{qw/status sim/} = $line{status} =~ /(R)(\d+)/
	431	if $line{status} =~ /^R/;
	432	push @ret, \%line;
	433	}
434
435	return @ret;
436	}
437	method _parse_diff (@diff) {
438	my @ret;
439	for (@diff) {
440	# This regex is a little pathological.
441	if(m{^diff --git (a/(.*?)) (b/\2)}) {
442	push @ret, {
443	head => $_,
444	a => $1,
445	b => $3,
446	file => $2,
447	diff => '',
448	};
449	next;
450	}
451
452	if(/^index (\w+)\.\.(\w+) (\d+)$/) {
453	@{$ret[-1]}{qw(index src dst mode)} = ($_, $1, $2, $3);
454	next
455	}
456
457	# XXX Somewhat hacky. Ahem.
458	$ret[@ret ? -1 : 0]{diff} .= "$_\n";
459	}
460
461	return @ret;
462	}
463
464	# gitweb uses the following sort of command for diffing merges:
465	# /home/dbrook/apps/bin/git --git-dir=/home/dbrook/dev/app/.git diff-tree -r -M --no-commit-id --patch-with-raw --full-index --cc 316cf158df3f6207afbae7270bcc5ba0 --
466	# and for regular diffs
467	# /home/dbrook/apps/bin/git --git-dir=/home/dbrook/dev/app/.git diff-tree -r -M --no-commit-id --patch-with-raw --full-index 2e3454ca0749641b42f063730b0090e1 316cf158df3f6207afbae7270bcc5ba0 --
468	method _raw_diff (@args) {
469	return $self->run_cmd_list(
470	qw(diff-tree -r -M --no-commit-id --full-index),
471	@args
472	);
473	}
474
b5b638f7	475	=head1 SEE ALSO
	476
	477	L<Gitalist::Git::Util> L<Gitalist::Git::Object>
	478
	479	=head1 AUTHORS AND COPYRIGHT
	480
	481	Catalyst application:
	482	(C) 2009 Venda Ltd and Dan Brook <dbrook@venda.com>
	483
	484	Original gitweb.cgi from which this was derived:
	485	(C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
	486	(C) 2005, Christian Gierke
	487
	488	=head1 LICENSE
	489
	490	FIXME - Is this going to be GPLv2 as per gitweb? If so this is broken..
	491
	492	This library is free software. You can redistribute it and/or modify
	493	it under the same terms as Perl itself.
	494
	495	=cut
	496
56b6dbe6	497	} # end class