Commit | Line | Data |
262eb13a |
1 | package File::Temp; |
2 | |
3 | =head1 NAME |
4 | |
5 | File::Temp - return name and handle of a temporary file safely |
6 | |
7 | =head1 SYNOPSIS |
8 | |
9 | use File::Temp qw/ tempfile tempdir /; |
10 | |
11 | $dir = tempdir( CLEANUP => 1 ); |
12 | ($fh, $filename) = tempfile( DIR => $dir ); |
13 | |
14 | ($fh, $filename) = tempfile( $template, DIR => $dir); |
15 | ($fh, $filename) = tempfile( $template, SUFFIX => '.dat'); |
16 | |
17 | $fh = tempfile(); |
18 | |
19 | MkTemp family: |
20 | |
21 | use File::Temp qw/ :mktemp /; |
22 | |
23 | ($fh, $file) = mkstemp( "tmpfileXXXXX" ); |
24 | ($fh, $file) = mkstemps( "tmpfileXXXXXX", $suffix); |
25 | |
26 | $tmpdir = mkdtemp( $template ); |
27 | |
28 | $unopened_file = mktemp( $template ); |
29 | |
30 | POSIX functions: |
31 | |
32 | use File::Temp qw/ :POSIX /; |
33 | |
34 | $file = tmpnam(); |
35 | $fh = tmpfile(); |
36 | |
37 | ($fh, $file) = tmpnam(); |
38 | ($fh, $file) = tmpfile(); |
39 | |
40 | |
41 | Compatibility functions: |
42 | |
43 | $unopened_file = File::Temp::tempnam( $dir, $pfx ); |
44 | |
45 | =begin later |
46 | |
47 | Objects (NOT YET IMPLEMENTED): |
48 | |
49 | require File::Temp; |
50 | |
51 | $fh = new File::Temp($template); |
52 | $fname = $fh->filename; |
53 | |
54 | =end later |
55 | |
56 | =head1 DESCRIPTION |
57 | |
58 | C<File::Temp> can be used to create and open temporary files in a safe way. |
59 | The tempfile() function can be used to return the name and the open |
60 | filehandle of a temporary file. The tempdir() function can |
61 | be used to create a temporary directory. |
62 | |
63 | The security aspect of temporary file creation is emphasized such that |
64 | a filehandle and filename are returned together. This helps guarantee that |
65 | a race condition can not occur where the temporary file is created by another process |
66 | between checking for the existence of the file and its |
67 | opening. Additional security levels are provided to check, for |
68 | example, that the sticky bit is set on world writable directories. |
69 | See L<"safe_level"> for more information. |
70 | |
71 | For compatibility with popular C library functions, Perl implementations of |
72 | the mkstemp() family of functions are provided. These are, mkstemp(), |
73 | mkstemps(), mkdtemp() and mktemp(). |
74 | |
75 | Additionally, implementations of the standard L<POSIX|POSIX> |
76 | tmpnam() and tmpfile() functions are provided if required. |
77 | |
78 | Implementations of mktemp(), tmpnam(), and tempnam() are provided, |
79 | but should be used with caution since they return only a filename |
80 | that was valid when function was called, so cannot guarantee |
81 | that the file will not exist by the time the caller opens the filename. |
82 | |
83 | =cut |
84 | |
85 | # 5.6.0 gives us S_IWOTH, S_IWGRP, our and auto-vivifying filehandls |
86 | # People would like a version on 5.005 so give them what they want :-) |
87 | use 5.005; |
88 | use strict; |
89 | use Carp; |
90 | use File::Spec 0.8; |
91 | use File::Path qw/ rmtree /; |
92 | use Fcntl 1.03; |
93 | use Errno qw( EEXIST ENOENT ENOTDIR EINVAL ); |
94 | |
1c19c868 |
95 | # Need the Symbol package if we are running older perl |
96 | require Symbol if $] < 5.006; |
97 | |
98 | |
262eb13a |
99 | # use 'our' on v5.6.0 |
100 | use vars qw($VERSION @EXPORT_OK %EXPORT_TAGS $DEBUG); |
101 | |
102 | $DEBUG = 0; |
103 | |
104 | # We are exporting functions |
105 | |
262eb13a |
106 | use base qw/Exporter/; |
107 | |
108 | # Export list - to allow fine tuning of export table |
109 | |
110 | @EXPORT_OK = qw{ |
111 | tempfile |
112 | tempdir |
113 | tmpnam |
114 | tmpfile |
115 | mktemp |
116 | mkstemp |
117 | mkstemps |
118 | mkdtemp |
119 | unlink0 |
120 | }; |
121 | |
122 | # Groups of functions for export |
123 | |
124 | %EXPORT_TAGS = ( |
125 | 'POSIX' => [qw/ tmpnam tmpfile /], |
126 | 'mktemp' => [qw/ mktemp mkstemp mkstemps mkdtemp/], |
127 | ); |
128 | |
129 | # add contents of these tags to @EXPORT |
130 | Exporter::export_tags('POSIX','mktemp'); |
131 | |
132 | # Version number |
133 | |
1c19c868 |
134 | $VERSION = '0.08'; |
262eb13a |
135 | |
136 | # This is a list of characters that can be used in random filenames |
137 | |
138 | my @CHARS = (qw/ A B C D E F G H I J K L M N O P Q R S T U V W X Y Z |
139 | a b c d e f g h i j k l m n o p q r s t u v w x y z |
140 | 0 1 2 3 4 5 6 7 8 9 _ |
141 | /); |
142 | |
143 | # Maximum number of tries to make a temp file before failing |
144 | |
145 | use constant MAX_TRIES => 10; |
146 | |
147 | # Minimum number of X characters that should be in a template |
148 | use constant MINX => 4; |
149 | |
150 | # Default template when no template supplied |
151 | |
152 | use constant TEMPXXX => 'X' x 10; |
153 | |
154 | # Constants for the security level |
155 | |
156 | use constant STANDARD => 0; |
157 | use constant MEDIUM => 1; |
158 | use constant HIGH => 2; |
159 | |
1c19c868 |
160 | # OPENFLAGS. If we defined the flag to use with Sysopen here this gives |
161 | # us an optimisation when many temporary files are requested |
162 | |
163 | my $OPENFLAGS = O_CREAT | O_EXCL | O_RDWR; |
164 | |
165 | for my $oflag (qw/FOLLOW BINARY LARGEFILE EXLOCK NOINHERIT TEMPORARY/) { |
166 | my ($bit, $func) = (0, "Fcntl::O_" . $oflag); |
167 | no strict 'refs'; |
168 | $OPENFLAGS |= $bit if eval { $bit = &$func(); 1 }; |
169 | } |
170 | |
171 | |
172 | |
262eb13a |
173 | # INTERNAL ROUTINES - not to be used outside of package |
174 | |
175 | # Generic routine for getting a temporary filename |
176 | # modelled on OpenBSD _gettemp() in mktemp.c |
177 | |
178 | # The template must contain X's that are to be replaced |
179 | # with the random values |
180 | |
181 | # Arguments: |
182 | |
183 | # TEMPLATE - string containing the XXXXX's that is converted |
184 | # to a random filename and opened if required |
185 | |
186 | # Optionally, a hash can also be supplied containing specific options |
187 | # "open" => if true open the temp file, else just return the name |
188 | # default is 0 |
189 | # "mkdir"=> if true, we are creating a temp directory rather than tempfile |
190 | # default is 0 |
191 | # "suffixlen" => number of characters at end of PATH to be ignored. |
192 | # default is 0. |
193 | # "open" and "mkdir" can not both be true |
194 | |
195 | # The default options are equivalent to mktemp(). |
196 | |
197 | # Returns: |
198 | # filehandle - open file handle (if called with doopen=1, else undef) |
199 | # temp name - name of the temp file or directory |
200 | |
201 | # For example: |
202 | # ($fh, $name) = _gettemp($template, "open" => 1); |
203 | |
204 | # for the current version, failures are associated with |
205 | # a carp to give the reason whilst debugging |
206 | |
207 | sub _gettemp { |
208 | |
209 | croak 'Usage: ($fh, $name) = _gettemp($template, OPTIONS);' |
210 | unless scalar(@_) >= 1; |
211 | |
212 | # Default options |
213 | my %options = ( |
214 | "open" => 0, |
215 | "mkdir" => 0, |
216 | "suffixlen" => 0, |
217 | ); |
218 | |
219 | # Read the template |
220 | my $template = shift; |
221 | if (ref($template)) { |
222 | carp "File::Temp::_gettemp: template must not be a reference"; |
223 | return (); |
224 | } |
225 | |
226 | # Check that the number of entries on stack are even |
227 | if (scalar(@_) % 2 != 0) { |
228 | carp "File::Temp::_gettemp: Must have even number of options"; |
229 | return (); |
230 | } |
231 | |
232 | # Read the options and merge with defaults |
233 | %options = (%options, @_) if @_; |
234 | |
235 | # Can not open the file and make a directory in a single call |
236 | if ($options{"open"} && $options{"mkdir"}) { |
237 | carp "File::Temp::_gettemp: doopen and domkdir can not both be true\n"; |
238 | return (); |
239 | } |
240 | |
241 | # Find the start of the end of the Xs (position of last X) |
242 | # Substr starts from 0 |
243 | my $start = length($template) - 1 - $options{"suffixlen"}; |
244 | |
245 | # Check that we have at least MINX x X (eg 'XXXX") at the end of the string |
246 | # (taking suffixlen into account). Any fewer is insecure. |
247 | |
248 | # Do it using substr - no reason to use a pattern match since |
249 | # we know where we are looking and what we are looking for |
250 | |
251 | if (substr($template, $start - MINX + 1, MINX) ne 'X' x MINX) { |
252 | carp "File::Temp::_gettemp: The template must contain at least ". MINX ." 'X' characters\n"; |
253 | return (); |
254 | } |
255 | |
256 | # Replace all the X at the end of the substring with a |
257 | # random character or just all the XX at the end of a full string. |
258 | # Do it as an if, since the suffix adjusts which section to replace |
259 | # and suffixlen=0 returns nothing if used in the substr directly |
260 | # and generate a full path from the template |
261 | |
262 | my $path = _replace_XX($template, $options{"suffixlen"}); |
263 | |
264 | |
265 | # Split the path into constituent parts - eventually we need to check |
266 | # whether the directory exists |
267 | # We need to know whether we are making a temp directory |
268 | # or a tempfile |
269 | |
270 | my ($volume, $directories, $file); |
271 | my $parent; # parent directory |
272 | if ($options{"mkdir"}) { |
273 | # There is no filename at the end |
274 | ($volume, $directories, $file) = File::Spec->splitpath( $path, 1); |
275 | |
276 | # The parent is then $directories without the last directory |
277 | # Split the directory and put it back together again |
278 | my @dirs = File::Spec->splitdir($directories); |
279 | |
280 | # If @dirs only has one entry that means we are in the current |
281 | # directory |
282 | if ($#dirs == 0) { |
283 | $parent = File::Spec->curdir; |
284 | } else { |
285 | |
286 | # Put it back together without the last one |
287 | $parent = File::Spec->catdir(@dirs[0..$#dirs-1]); |
288 | |
289 | # ...and attach the volume (no filename) |
290 | $parent = File::Spec->catpath($volume, $parent, ''); |
291 | |
292 | } |
293 | |
294 | } else { |
295 | |
296 | # Get rid of the last filename (use File::Basename for this?) |
297 | ($volume, $directories, $file) = File::Spec->splitpath( $path ); |
298 | |
299 | # Join up without the file part |
300 | $parent = File::Spec->catpath($volume,$directories,''); |
301 | |
302 | # If $parent is empty replace with curdir |
303 | $parent = File::Spec->curdir |
304 | unless $directories ne ''; |
305 | |
306 | } |
307 | |
308 | # Check that the parent directories exist |
309 | # Do this even for the case where we are simply returning a name |
310 | # not a file -- no point returning a name that includes a directory |
311 | # that does not exist or is not writable |
312 | |
313 | unless (-d $parent && -w _) { |
314 | carp "File::Temp::_gettemp: Parent directory ($parent) is not a directory" |
315 | . " or is not writable\n"; |
316 | return (); |
317 | } |
318 | |
319 | # Check the stickiness of the directory and chown giveaway if required |
320 | # If the directory is world writable the sticky bit |
321 | # must be set |
322 | |
323 | if (File::Temp->safe_level == MEDIUM) { |
324 | unless (_is_safe($parent)) { |
325 | carp "File::Temp::_gettemp: Parent directory ($parent) is not safe (sticky bit not set when world writable?)"; |
326 | return (); |
327 | } |
328 | } elsif (File::Temp->safe_level == HIGH) { |
329 | unless (_is_verysafe($parent)) { |
330 | carp "File::Temp::_gettemp: Parent directory ($parent) is not safe (sticky bit not set when world writable?)"; |
331 | return (); |
332 | } |
333 | } |
334 | |
335 | |
336 | # Calculate the flags that we wish to use for the sysopen |
337 | # Some of these are not always available |
1c19c868 |
338 | # my $openflags; |
339 | # if ($options{"open"}) { |
262eb13a |
340 | # Default set |
1c19c868 |
341 | # $openflags = O_CREAT | O_EXCL | O_RDWR; |
262eb13a |
342 | |
1c19c868 |
343 | # for my $oflag (qw/FOLLOW BINARY LARGEFILE EXLOCK NOINHERIT TEMPORARY/) { |
344 | # my ($bit, $func) = (0, "Fcntl::O_" . $oflag); |
345 | # no strict 'refs'; |
346 | # $openflags |= $bit if eval { $bit = &$func(); 1 }; |
347 | # } |
262eb13a |
348 | |
1c19c868 |
349 | # } |
262eb13a |
350 | |
351 | |
352 | # Now try MAX_TRIES time to open the file |
353 | for (my $i = 0; $i < MAX_TRIES; $i++) { |
354 | |
355 | # Try to open the file if requested |
356 | if ($options{"open"}) { |
357 | my $fh; |
358 | |
359 | # If we are running before perl5.6.0 we can not auto-vivify |
360 | if ($] < 5.006) { |
262eb13a |
361 | $fh = &Symbol::gensym; |
362 | } |
363 | |
364 | # Try to make sure this will be marked close-on-exec |
365 | # XXX: Win32 doesn't respect this, nor the proper fcntl, |
366 | # but may have O_NOINHERIT. This may or may not be in Fcntl. |
367 | local $^F = 2; |
368 | |
369 | # Store callers umask |
370 | my $umask = umask(); |
371 | |
372 | # Set a known umask |
373 | umask(066); |
374 | |
375 | # Attempt to open the file |
1c19c868 |
376 | if ( sysopen($fh, $path, $OPENFLAGS, 0600) ) { |
262eb13a |
377 | |
378 | # Reset umask |
379 | umask($umask); |
380 | |
381 | # Opened successfully - return file handle and name |
382 | return ($fh, $path); |
383 | |
384 | } else { |
385 | # Reset umask |
386 | umask($umask); |
387 | |
388 | # Error opening file - abort with error |
389 | # if the reason was anything but EEXIST |
390 | unless ($! == EEXIST) { |
391 | carp "File::Temp: Could not create temp file $path: $!"; |
392 | return (); |
393 | } |
394 | |
395 | # Loop round for another try |
396 | |
397 | } |
398 | } elsif ($options{"mkdir"}) { |
399 | |
400 | # Store callers umask |
401 | my $umask = umask(); |
402 | |
403 | # Set a known umask |
404 | umask(066); |
405 | |
406 | # Open the temp directory |
407 | if (mkdir( $path, 0700)) { |
408 | # created okay |
409 | # Reset umask |
410 | umask($umask); |
411 | |
412 | return undef, $path; |
413 | } else { |
414 | |
415 | # Reset umask |
416 | umask($umask); |
417 | |
418 | # Abort with error if the reason for failure was anything |
419 | # except EEXIST |
420 | unless ($! == EEXIST) { |
421 | carp "File::Temp: Could not create directory $path: $!"; |
422 | return (); |
423 | } |
424 | |
425 | # Loop round for another try |
426 | |
427 | } |
428 | |
429 | } else { |
430 | |
431 | # Return true if the file can not be found |
432 | # Directory has been checked previously |
433 | |
434 | return (undef, $path) unless -e $path; |
435 | |
436 | # Try again until MAX_TRIES |
437 | |
438 | } |
439 | |
440 | # Did not successfully open the tempfile/dir |
441 | # so try again with a different set of random letters |
442 | # No point in trying to increment unless we have only |
443 | # 1 X say and the randomness could come up with the same |
444 | # file MAX_TRIES in a row. |
445 | |
446 | # Store current attempt - in principal this implies that the |
447 | # 3rd time around the open attempt that the first temp file |
448 | # name could be generated again. Probably should store each |
449 | # attempt and make sure that none are repeated |
450 | |
451 | my $original = $path; |
452 | my $counter = 0; # Stop infinite loop |
453 | my $MAX_GUESS = 50; |
454 | |
455 | do { |
456 | |
457 | # Generate new name from original template |
458 | $path = _replace_XX($template, $options{"suffixlen"}); |
459 | |
460 | $counter++; |
461 | |
462 | } until ($path ne $original || $counter > $MAX_GUESS); |
463 | |
464 | # Check for out of control looping |
465 | if ($counter > $MAX_GUESS) { |
1c19c868 |
466 | carp "Tried to get a new temp name different to the previous value $MAX_GUESS times.\nSomething wrong with template?? ($template)"; |
262eb13a |
467 | return (); |
468 | } |
469 | |
470 | } |
471 | |
472 | # If we get here, we have run out of tries |
473 | carp "Have exceeded the maximum number of attempts (".MAX_TRIES . |
474 | ") to open temp file/dir"; |
475 | |
476 | return (); |
477 | |
478 | } |
479 | |
480 | # Internal routine to return a random character from the |
481 | # character list. Does not do an srand() since rand() |
482 | # will do one automatically |
483 | |
484 | # No arguments. Return value is the random character |
485 | |
1c19c868 |
486 | # No longer called since _replace_XX runs a few percent faster if |
487 | # I inline the code. This is important if we are creating thousands of |
488 | # temporary files. |
489 | |
262eb13a |
490 | sub _randchar { |
491 | |
492 | $CHARS[ int( rand( $#CHARS ) ) ]; |
493 | |
494 | } |
495 | |
496 | # Internal routine to replace the XXXX... with random characters |
497 | # This has to be done by _gettemp() every time it fails to |
498 | # open a temp file/dir |
499 | |
500 | # Arguments: $template (the template with XXX), |
501 | # $ignore (number of characters at end to ignore) |
502 | |
503 | # Returns: modified template |
504 | |
505 | sub _replace_XX { |
506 | |
507 | croak 'Usage: _replace_XX($template, $ignore)' |
508 | unless scalar(@_) == 2; |
509 | |
510 | my ($path, $ignore) = @_; |
511 | |
512 | # Do it as an if, since the suffix adjusts which section to replace |
513 | # and suffixlen=0 returns nothing if used in the substr directly |
514 | # Alternatively, could simply set $ignore to length($path)-1 |
515 | # Don't want to always use substr when not required though. |
516 | |
517 | if ($ignore) { |
1c19c868 |
518 | substr($path, 0, - $ignore) =~ s/X(?=X*\z)/$CHARS[ int( rand( $#CHARS ) ) ]/ge; |
262eb13a |
519 | } else { |
1c19c868 |
520 | $path =~ s/X(?=X*\z)/$CHARS[ int( rand( $#CHARS ) ) ]/ge; |
262eb13a |
521 | } |
522 | |
523 | return $path; |
524 | } |
525 | |
526 | # internal routine to check to see if the directory is safe |
527 | # First checks to see if the directory is not owned by the |
528 | # current user or root. Then checks to see if anyone else |
529 | # can write to the directory and if so, checks to see if |
530 | # it has the sticky bit set |
531 | |
532 | # Will not work on systems that do not support sticky bit |
533 | |
534 | #Args: directory path to check |
535 | # Returns true if the path is safe and false otherwise. |
536 | # Returns undef if can not even run stat() on the path |
537 | |
538 | # This routine based on version written by Tom Christiansen |
539 | |
540 | # Presumably, by the time we actually attempt to create the |
541 | # file or directory in this directory, it may not be safe |
542 | # anymore... Have to run _is_safe directly after the open. |
543 | |
544 | sub _is_safe { |
545 | |
546 | my $path = shift; |
547 | |
548 | # Stat path |
549 | my @info = stat($path); |
550 | return 0 unless scalar(@info); |
551 | |
552 | # Check to see whether owner is neither superuser (or a system uid) nor me |
553 | # Use the real uid from the $< variable |
554 | # UID is in [4] |
555 | if ( $info[4] > File::Temp->top_system_uid() && $info[4] != $<) { |
556 | carp "Directory owned neither by root nor the current user"; |
557 | return 0; |
558 | } |
559 | |
560 | # check whether group or other can write file |
561 | # use 066 to detect either reading or writing |
562 | # use 022 to check writability |
563 | # Do it with S_IWOTH and S_IWGRP for portability (maybe) |
564 | # mode is in info[2] |
565 | if (($info[2] & &Fcntl::S_IWGRP) || # Is group writable? |
566 | ($info[2] & &Fcntl::S_IWOTH) ) { # Is world writable? |
567 | return 0 unless -d _; # Must be a directory |
568 | return 0 unless -k _; # Must be sticky |
569 | } |
570 | |
571 | return 1; |
572 | } |
573 | |
574 | # Internal routine to check whether a directory is safe |
575 | # for temp files. Safer than _is_safe since it checks for |
576 | # the possibility of chown giveaway and if that is a possibility |
577 | # checks each directory in the path to see if it is safe (with _is_safe) |
578 | |
579 | # If _PC_CHOWN_RESTRICTED is not set, does the full test of each |
580 | # directory anyway. |
581 | |
582 | sub _is_verysafe { |
583 | |
584 | # Need POSIX - but only want to bother if really necessary due to overhead |
585 | require POSIX; |
586 | |
587 | my $path = shift; |
588 | |
589 | # Should Get the value of _PC_CHOWN_RESTRICTED if it is defined |
590 | # and If it is not there do the extensive test |
591 | my $chown_restricted; |
592 | $chown_restricted = &POSIX::_PC_CHOWN_RESTRICTED() |
593 | if eval { &POSIX::_PC_CHOWN_RESTRICTED(); 1}; |
594 | |
595 | # If chown_resticted is set to some value we should test it |
596 | if (defined $chown_restricted) { |
597 | |
598 | # Return if the current directory is safe |
599 | return _is_safe($path) if POSIX::sysconf( $chown_restricted ); |
600 | |
601 | } |
602 | |
603 | # To reach this point either, the _PC_CHOWN_RESTRICTED symbol |
604 | # was not avialable or the symbol was there but chown giveaway |
605 | # is allowed. Either way, we now have to test the entire tree for |
606 | # safety. |
607 | |
608 | # Convert path to an absolute directory if required |
609 | unless (File::Spec->file_name_is_absolute($path)) { |
610 | $path = File::Spec->rel2abs($path); |
611 | } |
612 | |
613 | # Split directory into components - assume no file |
614 | my ($volume, $directories, undef) = File::Spec->splitpath( $path, 1); |
615 | |
616 | # Slightly less efficient than having a a function in File::Spec |
617 | # to chop off the end of a directory or even a function that |
618 | # can handle ../ in a directory tree |
619 | # Sometimes splitdir() returns a blank at the end |
620 | # so we will probably check the bottom directory twice in some cases |
621 | my @dirs = File::Spec->splitdir($directories); |
622 | |
623 | # Concatenate one less directory each time around |
624 | foreach my $pos (0.. $#dirs) { |
625 | # Get a directory name |
626 | my $dir = File::Spec->catpath($volume, |
627 | File::Spec->catdir(@dirs[0.. $#dirs - $pos]), |
628 | '' |
629 | ); |
630 | |
631 | print "TESTING DIR $dir\n" if $DEBUG; |
632 | |
633 | # Check the directory |
634 | return 0 unless _is_safe($dir); |
635 | |
636 | } |
637 | |
638 | return 1; |
639 | } |
640 | |
641 | |
642 | |
643 | # internal routine to determine whether unlink works on this |
644 | # platform for files that are currently open. |
645 | # Returns true if we can, false otherwise. |
646 | |
1c19c868 |
647 | # Currently WinNT and OS/2 can not unlink an opened file |
262eb13a |
648 | |
649 | sub _can_unlink_opened_file { |
650 | |
1c19c868 |
651 | if ($^O eq 'MSWin32' || $^O eq 'os2') { |
652 | return 0; |
653 | } else { |
654 | return 1; |
655 | } |
262eb13a |
656 | |
657 | } |
658 | |
1c19c868 |
659 | # internal routine to decide which security levels are allowed |
660 | # see safe_level() for more information on this |
661 | |
662 | # Controls whether the supplied security level is allowed |
663 | |
664 | # $cando = _can_do_level( $level ) |
665 | |
666 | sub _can_do_level { |
667 | |
668 | # Get security level |
669 | my $level = shift; |
670 | |
671 | # Always have to be able to do STANDARD |
672 | return 1 if $level == STANDARD; |
673 | |
674 | # Currently, the systems that can do HIGH or MEDIUM are identical |
675 | if ( $^O eq 'MSWin32' ) { |
676 | return 0; |
677 | } else { |
678 | return 1; |
679 | } |
680 | |
681 | } |
262eb13a |
682 | |
683 | # This routine sets up a deferred unlinking of a specified |
684 | # filename and filehandle. It is used in the following cases: |
685 | # - Called by unlink0 if an opend file can not be unlinked |
686 | # - Called by tempfile() if files are to be removed on shutdown |
687 | # - Called by tempdir() if directories are to be removed on shutdown |
688 | |
689 | # Arguments: |
690 | # _deferred_unlink( $fh, $fname, $isdir ); |
691 | # |
692 | # - filehandle (so that it can be expclicitly closed if open |
693 | # - filename (the thing we want to remove) |
694 | # - isdir (flag to indicate that we are being given a directory) |
695 | # [and hence no filehandle] |
696 | |
1c19c868 |
697 | # Status is not referred to since all the magic is done with and END block |
262eb13a |
698 | |
1c19c868 |
699 | { |
700 | # Will set up two lexical variables to contain all the files to be |
701 | # removed. One array for files, another for directories |
702 | # They will only exist in this block |
703 | # This means we only have to set up a single END block to remove all files |
704 | # @files_to_unlink contains an array ref with the filehandle and filename |
705 | my (@files_to_unlink, @dirs_to_unlink); |
706 | |
707 | # Set up an end block to use these arrays |
708 | END { |
709 | # Files |
710 | foreach my $file (@files_to_unlink) { |
711 | # close the filehandle without checking its state |
712 | # in order to make real sure that this is closed |
713 | # if its already closed then I dont care about the answer |
714 | # probably a better way to do this |
715 | close($file->[0]); # file handle is [0] |
716 | |
717 | if (-f $file->[1]) { # file name is [1] |
718 | unlink $file->[1] or warn "Error removing ".$file->[1]; |
719 | } |
720 | } |
721 | # Dirs |
722 | foreach my $dir (@dirs_to_unlink) { |
723 | if (-d $dir) { |
724 | rmtree($dir, $DEBUG, 1); |
725 | } |
726 | } |
262eb13a |
727 | |
262eb13a |
728 | |
1c19c868 |
729 | } |
262eb13a |
730 | |
1c19c868 |
731 | # This is the sub called to register a file for deferred unlinking |
732 | # This could simply store the input parameters and defer everything |
733 | # until the END block. For now we do a bit of checking at this |
734 | # point in order to make sure that (1) we have a file/dir to delete |
735 | # and (2) we have been called with the correct arguments. |
736 | sub _deferred_unlink { |
737 | |
738 | croak 'Usage: _deferred_unlink($fh, $fname, $isdir)' |
739 | unless scalar(@_) == 3; |
740 | |
741 | my ($fh, $fname, $isdir) = @_; |
262eb13a |
742 | |
1c19c868 |
743 | warn "Setting up deferred removal of $fname\n" |
744 | if $DEBUG; |
745 | |
746 | # If we have a directory, check that it is a directory |
747 | if ($isdir) { |
262eb13a |
748 | |
1c19c868 |
749 | if (-d $fname) { |
262eb13a |
750 | |
1c19c868 |
751 | # Directory exists so store it |
752 | push (@dirs_to_unlink, $fname); |
262eb13a |
753 | |
1c19c868 |
754 | } else { |
755 | carp "Request to remove directory $fname could not be completed since it does not exists!\n"; |
756 | } |
757 | |
758 | |
262eb13a |
759 | } else { |
262eb13a |
760 | |
1c19c868 |
761 | if (-f $fname) { |
262eb13a |
762 | |
1c19c868 |
763 | # file exists so store handle and name for later removal |
764 | push(@files_to_unlink, [$fh, $fname]); |
262eb13a |
765 | |
1c19c868 |
766 | } else { |
767 | carp "Request to remove file $fname could not be completed since it is not there!\n"; |
768 | } |
262eb13a |
769 | |
262eb13a |
770 | } |
771 | |
262eb13a |
772 | } |
773 | |
262eb13a |
774 | |
1c19c868 |
775 | } |
262eb13a |
776 | |
777 | =head1 FUNCTIONS |
778 | |
779 | This section describes the recommended interface for generating |
780 | temporary files and directories. |
781 | |
782 | =over 4 |
783 | |
784 | =item B<tempfile> |
785 | |
786 | This is the basic function to generate temporary files. |
787 | The behaviour of the file can be changed using various options: |
788 | |
789 | ($fh, $filename) = tempfile(); |
790 | |
791 | Create a temporary file in the directory specified for temporary |
792 | files, as specified by the tmpdir() function in L<File::Spec>. |
793 | |
794 | ($fh, $filename) = tempfile($template); |
795 | |
796 | Create a temporary file in the current directory using the supplied |
797 | template. Trailing `X' characters are replaced with random letters to |
798 | generate the filename. At least four `X' characters must be present |
799 | in the template. |
800 | |
801 | ($fh, $filename) = tempfile($template, SUFFIX => $suffix) |
802 | |
803 | Same as previously, except that a suffix is added to the template |
804 | after the `X' translation. Useful for ensuring that a temporary |
805 | filename has a particular extension when needed by other applications. |
806 | But see the WARNING at the end. |
807 | |
808 | ($fh, $filename) = tempfile($template, DIR => $dir); |
809 | |
810 | Translates the template as before except that a directory name |
811 | is specified. |
812 | |
813 | If the template is not specified, a template is always |
814 | automatically generated. This temporary file is placed in tmpdir() |
815 | (L<File::Spec>) unless a directory is specified explicitly with the |
816 | DIR option. |
817 | |
818 | $fh = tempfile( $template, DIR => $dir ); |
819 | |
820 | If called in scalar context, only the filehandle is returned |
821 | and the file will automatically be deleted when closed (see |
822 | the description of tmpfile() elsewhere in this document). |
823 | This is the preferred mode of operation, as if you only |
824 | have a filehandle, you can never create a race condition |
825 | by fumbling with the filename. On systems that can not unlink |
826 | an open file (for example, Windows NT) the file is marked for |
827 | deletion when the program ends (equivalent to setting UNLINK to 1). |
828 | |
829 | (undef, $filename) = tempfile($template, OPEN => 0); |
830 | |
831 | This will return the filename based on the template but |
832 | will not open this file. Cannot be used in conjunction with |
833 | UNLINK set to true. Default is to always open the file |
834 | to protect from possible race conditions. A warning is issued |
835 | if warnings are turned on. Consider using the tmpnam() |
836 | and mktemp() functions described elsewhere in this document |
837 | if opening the file is not required. |
838 | |
839 | =cut |
840 | |
841 | sub tempfile { |
842 | |
843 | # Can not check for argument count since we can have any |
844 | # number of args |
845 | |
846 | # Default options |
847 | my %options = ( |
848 | "DIR" => undef, # Directory prefix |
849 | "SUFFIX" => '', # Template suffix |
850 | "UNLINK" => 0, # Unlink file on exit |
851 | "OPEN" => 1, # Do not open file |
852 | ); |
853 | |
854 | # Check to see whether we have an odd or even number of arguments |
855 | my $template = (scalar(@_) % 2 == 1 ? shift(@_) : undef); |
856 | |
857 | # Read the options and merge with defaults |
858 | %options = (%options, @_) if @_; |
859 | |
860 | # First decision is whether or not to open the file |
861 | if (! $options{"OPEN"}) { |
862 | |
863 | warn "tempfile(): temporary filename requested but not opened.\nPossibly unsafe, consider using tempfile() with OPEN set to true\n" |
864 | if $^W; |
865 | |
866 | } |
867 | |
868 | # Construct the template |
869 | |
870 | # Have a choice of trying to work around the mkstemp/mktemp/tmpnam etc |
871 | # functions or simply constructing a template and using _gettemp() |
872 | # explicitly. Go for the latter |
873 | |
874 | # First generate a template if not defined and prefix the directory |
875 | # If no template must prefix the temp directory |
876 | if (defined $template) { |
877 | if ($options{"DIR"}) { |
878 | |
879 | $template = File::Spec->catfile($options{"DIR"}, $template); |
880 | |
881 | } |
882 | |
883 | } else { |
884 | |
885 | if ($options{"DIR"}) { |
886 | |
887 | $template = File::Spec->catfile($options{"DIR"}, TEMPXXX); |
888 | |
889 | } else { |
890 | |
891 | $template = File::Spec->catfile(File::Spec->tmpdir, TEMPXXX); |
892 | |
893 | } |
894 | |
895 | } |
896 | |
897 | # Now add a suffix |
898 | $template .= $options{"SUFFIX"}; |
899 | |
900 | # Create the file |
901 | my ($fh, $path); |
902 | croak "Error in tempfile() using $template" |
903 | unless (($fh, $path) = _gettemp($template, |
904 | "open" => $options{'OPEN'}, |
905 | "mkdir"=> 0 , |
906 | "suffixlen" => length($options{'SUFFIX'}), |
907 | ) ); |
908 | |
909 | # Set up an exit handler that can do whatever is right for the |
910 | # system. Do not check return status since this is all done with |
911 | # END blocks |
912 | _deferred_unlink($fh, $path, 0) if $options{"UNLINK"}; |
913 | |
914 | # Return |
915 | if (wantarray()) { |
916 | |
917 | if ($options{'OPEN'}) { |
918 | return ($fh, $path); |
919 | } else { |
920 | return (undef, $path); |
921 | } |
922 | |
923 | } else { |
924 | |
925 | # Unlink the file. It is up to unlink0 to decide what to do with |
926 | # this (whether to unlink now or to defer until later) |
927 | unlink0($fh, $path) or croak "Error unlinking file $path using unlink0"; |
928 | |
929 | # Return just the filehandle. |
930 | return $fh; |
931 | } |
932 | |
933 | |
934 | } |
935 | |
936 | =item B<tempdir> |
937 | |
938 | This is the recommended interface for creation of temporary directories. |
939 | The behaviour of the function depends on the arguments: |
940 | |
941 | $tempdir = tempdir(); |
942 | |
943 | Create a directory in tmpdir() (see L<File::Spec|File::Spec>). |
944 | |
945 | $tempdir = tempdir( $template ); |
946 | |
947 | Create a directory from the supplied template. This template is |
948 | similar to that described for tempfile(). `X' characters at the end |
949 | of the template are replaced with random letters to construct the |
950 | directory name. At least four `X' characters must be in the template. |
951 | |
952 | $tempdir = tempdir ( DIR => $dir ); |
953 | |
954 | Specifies the directory to use for the temporary directory. |
955 | The temporary directory name is derived from an internal template. |
956 | |
957 | $tempdir = tempdir ( $template, DIR => $dir ); |
958 | |
959 | Prepend the supplied directory name to the template. The template |
960 | should not include parent directory specifications itself. Any parent |
961 | directory specifications are removed from the template before |
962 | prepending the supplied directory. |
963 | |
964 | $tempdir = tempdir ( $template, TMPDIR => 1 ); |
965 | |
966 | Using the supplied template, creat the temporary directory in |
967 | a standard location for temporary files. Equivalent to doing |
968 | |
969 | $tempdir = tempdir ( $template, DIR => File::Spec->tmpdir); |
970 | |
971 | but shorter. Parent directory specifications are stripped from the |
972 | template itself. The C<TMPDIR> option is ignored if C<DIR> is set |
973 | explicitly. Additionally, C<TMPDIR> is implied if neither a template |
974 | nor a directory are supplied. |
975 | |
976 | $tempdir = tempdir( $template, CLEANUP => 1); |
977 | |
978 | Create a temporary directory using the supplied template, but |
979 | attempt to remove it (and all files inside it) when the program |
980 | exits. Note that an attempt will be made to remove all files from |
981 | the directory even if they were not created by this module (otherwise |
982 | why ask to clean it up?). The directory removal is made with |
983 | the rmtree() function from the L<File::Path|File::Path> module. |
984 | Of course, if the template is not specified, the temporary directory |
985 | will be created in tmpdir() and will also be removed at program exit. |
986 | |
987 | =cut |
988 | |
989 | # ' |
990 | |
991 | sub tempdir { |
992 | |
993 | # Can not check for argument count since we can have any |
994 | # number of args |
995 | |
996 | # Default options |
997 | my %options = ( |
998 | "CLEANUP" => 0, # Remove directory on exit |
999 | "DIR" => '', # Root directory |
1000 | "TMPDIR" => 0, # Use tempdir with template |
1001 | ); |
1002 | |
1003 | # Check to see whether we have an odd or even number of arguments |
1004 | my $template = (scalar(@_) % 2 == 1 ? shift(@_) : undef ); |
1005 | |
1006 | # Read the options and merge with defaults |
1007 | %options = (%options, @_) if @_; |
1008 | |
1009 | # Modify or generate the template |
1010 | |
1011 | # Deal with the DIR and TMPDIR options |
1012 | if (defined $template) { |
1013 | |
1014 | # Need to strip directory path if using DIR or TMPDIR |
1015 | if ($options{'TMPDIR'} || $options{'DIR'}) { |
1016 | |
1017 | # Strip parent directory from the filename |
1018 | # |
1019 | # There is no filename at the end |
1020 | my ($volume, $directories, undef) = File::Spec->splitpath( $template, 1); |
1021 | |
1022 | # Last directory is then our template |
1023 | $template = (File::Spec->splitdir($directories))[-1]; |
1024 | |
1025 | # Prepend the supplied directory or temp dir |
1026 | if ($options{"DIR"}) { |
1027 | |
1028 | $template = File::Spec->catfile($options{"DIR"}, $template); |
1029 | |
1030 | } elsif ($options{TMPDIR}) { |
1031 | |
1032 | # Prepend tmpdir |
1033 | $template = File::Spec->catdir(File::Spec->tmpdir, $template); |
1034 | |
1035 | } |
1036 | |
1037 | } |
1038 | |
1039 | } else { |
1040 | |
1041 | if ($options{"DIR"}) { |
1042 | |
1043 | $template = File::Spec->catdir($options{"DIR"}, TEMPXXX); |
1044 | |
1045 | } else { |
1046 | |
1047 | $template = File::Spec->catdir(File::Spec->tmpdir, TEMPXXX); |
1048 | |
1049 | } |
1050 | |
1051 | } |
1052 | |
1053 | # Create the directory |
1054 | my $tempdir; |
1055 | croak "Error in tempdir() using $template" |
1056 | unless ((undef, $tempdir) = _gettemp($template, |
1057 | "open" => 0, |
1058 | "mkdir"=> 1 , |
1059 | "suffixlen" => 0, |
1060 | ) ); |
1061 | |
1062 | # Install exit handler; must be dynamic to get lexical |
1063 | if ( $options{'CLEANUP'} && -d $tempdir) { |
1064 | _deferred_unlink(undef, $tempdir, 1); |
1065 | } |
1066 | |
1067 | # Return the dir name |
1068 | return $tempdir; |
1069 | |
1070 | } |
1071 | |
1072 | =back |
1073 | |
1074 | =head1 MKTEMP FUNCTIONS |
1075 | |
1076 | The following functions are Perl implementations of the |
1077 | mktemp() family of temp file generation system calls. |
1078 | |
1079 | =over 4 |
1080 | |
1081 | =item B<mkstemp> |
1082 | |
1083 | Given a template, returns a filehandle to the temporary file and the name |
1084 | of the file. |
1085 | |
1086 | ($fh, $name) = mkstemp( $template ); |
1087 | |
1088 | In scalar context, just the filehandle is returned. |
1089 | |
1090 | The template may be any filename with some number of X's appended |
1091 | to it, for example F</tmp/temp.XXXX>. The trailing X's are replaced |
1092 | with unique alphanumeric combinations. |
1093 | |
1094 | =cut |
1095 | |
1096 | |
1097 | |
1098 | sub mkstemp { |
1099 | |
1100 | croak "Usage: mkstemp(template)" |
1101 | if scalar(@_) != 1; |
1102 | |
1103 | my $template = shift; |
1104 | |
1105 | my ($fh, $path); |
1106 | croak "Error in mkstemp using $template" |
1107 | unless (($fh, $path) = _gettemp($template, |
1108 | "open" => 1, |
1109 | "mkdir"=> 0 , |
1110 | "suffixlen" => 0, |
1111 | ) ); |
1112 | |
1113 | if (wantarray()) { |
1114 | return ($fh, $path); |
1115 | } else { |
1116 | return $fh; |
1117 | } |
1118 | |
1119 | } |
1120 | |
1121 | |
1122 | =item B<mkstemps> |
1123 | |
1124 | Similar to mkstemp(), except that an extra argument can be supplied |
1125 | with a suffix to be appended to the template. |
1126 | |
1127 | ($fh, $name) = mkstemps( $template, $suffix ); |
1128 | |
1129 | For example a template of C<testXXXXXX> and suffix of C<.dat> |
1130 | would generate a file similar to F<testhGji_w.dat>. |
1131 | |
1132 | Returns just the filehandle alone when called in scalar context. |
1133 | |
1134 | =cut |
1135 | |
1136 | sub mkstemps { |
1137 | |
1138 | croak "Usage: mkstemps(template, suffix)" |
1139 | if scalar(@_) != 2; |
1140 | |
1141 | |
1142 | my $template = shift; |
1143 | my $suffix = shift; |
1144 | |
1145 | $template .= $suffix; |
1146 | |
1147 | my ($fh, $path); |
1148 | croak "Error in mkstemps using $template" |
1149 | unless (($fh, $path) = _gettemp($template, |
1150 | "open" => 1, |
1151 | "mkdir"=> 0 , |
1152 | "suffixlen" => length($suffix), |
1153 | ) ); |
1154 | |
1155 | if (wantarray()) { |
1156 | return ($fh, $path); |
1157 | } else { |
1158 | return $fh; |
1159 | } |
1160 | |
1161 | } |
1162 | |
1163 | =item B<mkdtemp> |
1164 | |
1165 | Create a directory from a template. The template must end in |
1166 | X's that are replaced by the routine. |
1167 | |
1168 | $tmpdir_name = mkdtemp($template); |
1169 | |
1170 | Returns the name of the temporary directory created. |
1171 | Returns undef on failure. |
1172 | |
1173 | Directory must be removed by the caller. |
1174 | |
1175 | =cut |
1176 | |
1177 | #' # for emacs |
1178 | |
1179 | sub mkdtemp { |
1180 | |
1181 | croak "Usage: mkdtemp(template)" |
1182 | if scalar(@_) != 1; |
1183 | |
1184 | my $template = shift; |
1185 | |
1186 | my ($junk, $tmpdir); |
1187 | croak "Error creating temp directory from template $template\n" |
1188 | unless (($junk, $tmpdir) = _gettemp($template, |
1189 | "open" => 0, |
1190 | "mkdir"=> 1 , |
1191 | "suffixlen" => 0, |
1192 | ) ); |
1193 | |
1194 | return $tmpdir; |
1195 | |
1196 | } |
1197 | |
1198 | =item B<mktemp> |
1199 | |
1200 | Returns a valid temporary filename but does not guarantee |
1201 | that the file will not be opened by someone else. |
1202 | |
1203 | $unopened_file = mktemp($template); |
1204 | |
1205 | Template is the same as that required by mkstemp(). |
1206 | |
1207 | =cut |
1208 | |
1209 | sub mktemp { |
1210 | |
1211 | croak "Usage: mktemp(template)" |
1212 | if scalar(@_) != 1; |
1213 | |
1214 | my $template = shift; |
1215 | |
1216 | my ($tmpname, $junk); |
1217 | croak "Error getting name to temp file from template $template\n" |
1218 | unless (($junk, $tmpname) = _gettemp($template, |
1219 | "open" => 0, |
1220 | "mkdir"=> 0 , |
1221 | "suffixlen" => 0, |
1222 | ) ); |
1223 | |
1224 | return $tmpname; |
1225 | } |
1226 | |
1227 | =back |
1228 | |
1229 | =head1 POSIX FUNCTIONS |
1230 | |
1231 | This section describes the re-implementation of the tmpnam() |
1232 | and tmpfile() functions described in L<POSIX> |
1233 | using the mkstemp() from this module. |
1234 | |
1235 | Unlike the L<POSIX|POSIX> implementations, the directory used |
1236 | for the temporary file is not specified in a system include |
1237 | file (C<P_tmpdir>) but simply depends on the choice of tmpdir() |
1238 | returned by L<File::Spec|File::Spec>. On some implementations this |
1239 | location can be set using the C<TMPDIR> environment variable, which |
1240 | may not be secure. |
1241 | If this is a problem, simply use mkstemp() and specify a template. |
1242 | |
1243 | =over 4 |
1244 | |
1245 | =item B<tmpnam> |
1246 | |
1247 | When called in scalar context, returns the full name (including path) |
1248 | of a temporary file (uses mktemp()). The only check is that the file does |
1249 | not already exist, but there is no guarantee that that condition will |
1250 | continue to apply. |
1251 | |
1252 | $file = tmpnam(); |
1253 | |
1254 | When called in list context, a filehandle to the open file and |
1255 | a filename are returned. This is achieved by calling mkstemp() |
1256 | after constructing a suitable template. |
1257 | |
1258 | ($fh, $file) = tmpnam(); |
1259 | |
1260 | If possible, this form should be used to prevent possible |
1261 | race conditions. |
1262 | |
1263 | See L<File::Spec/tmpdir> for information on the choice of temporary |
1264 | directory for a particular operating system. |
1265 | |
1266 | =cut |
1267 | |
1268 | sub tmpnam { |
1269 | |
1270 | # Retrieve the temporary directory name |
1271 | my $tmpdir = File::Spec->tmpdir; |
1272 | |
1273 | croak "Error temporary directory is not writable" |
1274 | if $tmpdir eq ''; |
1275 | |
1276 | # Use a ten character template and append to tmpdir |
1277 | my $template = File::Spec->catfile($tmpdir, TEMPXXX); |
1278 | |
1279 | if (wantarray() ) { |
1280 | return mkstemp($template); |
1281 | } else { |
1282 | return mktemp($template); |
1283 | } |
1284 | |
1285 | } |
1286 | |
1287 | =item B<tmpfile> |
1288 | |
1289 | In scalar context, returns the filehandle of a temporary file. |
1290 | |
1291 | $fh = tmpfile(); |
1292 | |
1293 | The file is removed when the filehandle is closed or when the program |
1294 | exits. No access to the filename is provided. |
1295 | |
1296 | =cut |
1297 | |
1298 | sub tmpfile { |
1299 | |
1300 | # Simply call tmpnam() in an array context |
1301 | my ($fh, $file) = tmpnam(); |
1302 | |
1303 | # Make sure file is removed when filehandle is closed |
1304 | unlink0($fh, $file) or croak "Unable to unlink temporary file: $!"; |
1305 | |
1306 | return $fh; |
1307 | |
1308 | } |
1309 | |
1310 | =back |
1311 | |
1312 | =head1 ADDITIONAL FUNCTIONS |
1313 | |
1314 | These functions are provided for backwards compatibility |
1315 | with common tempfile generation C library functions. |
1316 | |
1317 | They are not exported and must be addressed using the full package |
1318 | name. |
1319 | |
1320 | =over 4 |
1321 | |
1322 | =item B<tempnam> |
1323 | |
1324 | Return the name of a temporary file in the specified directory |
1325 | using a prefix. The file is guaranteed not to exist at the time |
1326 | the function was called, but such guarantees are good for one |
1327 | clock tick only. Always use the proper form of C<sysopen> |
1328 | with C<O_CREAT | O_EXCL> if you must open such a filename. |
1329 | |
1330 | $filename = File::Temp::tempnam( $dir, $prefix ); |
1331 | |
1332 | Equivalent to running mktemp() with $dir/$prefixXXXXXXXX |
1333 | (using unix file convention as an example) |
1334 | |
1335 | Because this function uses mktemp(), it can suffer from race conditions. |
1336 | |
1337 | =cut |
1338 | |
1339 | sub tempnam { |
1340 | |
1341 | croak 'Usage tempnam($dir, $prefix)' unless scalar(@_) == 2; |
1342 | |
1343 | my ($dir, $prefix) = @_; |
1344 | |
1345 | # Add a string to the prefix |
1346 | $prefix .= 'XXXXXXXX'; |
1347 | |
1348 | # Concatenate the directory to the file |
1349 | my $template = File::Spec->catfile($dir, $prefix); |
1350 | |
1351 | return mktemp($template); |
1352 | |
1353 | } |
1354 | |
1355 | =back |
1356 | |
1357 | =head1 UTILITY FUNCTIONS |
1358 | |
1359 | Useful functions for dealing with the filehandle and filename. |
1360 | |
1361 | =over 4 |
1362 | |
1363 | =item B<unlink0> |
1364 | |
1365 | Given an open filehandle and the associated filename, make a safe |
1366 | unlink. This is achieved by first checking that the filename and |
1367 | filehandle initially point to the same file and that the number of |
1368 | links to the file is 1 (all fields returned by stat() are compared). |
1369 | Then the filename is unlinked and the filehandle checked once again to |
1370 | verify that the number of links on that file is now 0. This is the |
1371 | closest you can come to making sure that the filename unlinked was the |
1372 | same as the file whose descriptor you hold. |
1373 | |
1374 | unlink0($fh, $path) or die "Error unlinking file $path safely"; |
1375 | |
1376 | Returns false on error. The filehandle is not closed since on some |
1377 | occasions this is not required. |
1378 | |
1379 | On some platforms, for example Windows NT, it is not possible to |
1380 | unlink an open file (the file must be closed first). On those |
1c19c868 |
1381 | platforms, the actual unlinking is deferred until the program ends and |
1382 | good status is returned. A check is still performed to make sure that |
1383 | the filehandle and filename are pointing to the same thing (but not at |
1384 | the time the end block is executed since the deferred removal may not |
1385 | have access to the filehandle). |
262eb13a |
1386 | |
1387 | Additionally, on Windows NT not all the fields returned by stat() can |
1388 | be compared. For example, the C<dev> and C<rdev> fields seem to be different |
1389 | and also. Also, it seems that the size of the file returned by stat() |
1390 | does not always agree, with C<stat(FH)> being more accurate than |
1391 | C<stat(filename)>, presumably because of caching issues even when |
1392 | using autoflush (this is usually overcome by waiting a while after |
1393 | writing to the tempfile before attempting to C<unlink0> it). |
1394 | |
1c19c868 |
1395 | Finally, on NFS file systems the link count of the file handle does |
1396 | not always go to zero immediately after unlinking. Currently, this |
1397 | command is expected to fail on NFS disks. |
1398 | |
262eb13a |
1399 | =cut |
1400 | |
1401 | sub unlink0 { |
1402 | |
1403 | croak 'Usage: unlink0(filehandle, filename)' |
1404 | unless scalar(@_) == 2; |
1405 | |
1406 | # Read args |
1407 | my ($fh, $path) = @_; |
1408 | |
1409 | warn "Unlinking $path using unlink0\n" |
1410 | if $DEBUG; |
1411 | |
1412 | # Stat the filehandle |
1413 | my @fh = stat $fh; |
1414 | |
1415 | if ($fh[3] > 1 && $^W) { |
1416 | carp "unlink0: fstat found too many links; SB=@fh"; |
1417 | } |
1418 | |
1419 | # Stat the path |
1420 | my @path = stat $path; |
1421 | |
1422 | unless (@path) { |
1423 | carp "unlink0: $path is gone already" if $^W; |
1424 | return; |
1425 | } |
1426 | |
1427 | # this is no longer a file, but may be a directory, or worse |
1428 | unless (-f _) { |
1429 | confess "panic: $path is no longer a file: SB=@fh"; |
1430 | } |
1431 | |
1432 | # Do comparison of each member of the array |
1433 | # On WinNT dev and rdev seem to be different |
1434 | # depending on whether it is a file or a handle. |
1435 | # Cannot simply compare all members of the stat return |
1436 | # Select the ones we can use |
1437 | my @okstat = (0..$#fh); # Use all by default |
1438 | if ($^O eq 'MSWin32') { |
1439 | @okstat = (1,2,3,4,5,7,8,9,10); |
1440 | } |
1441 | |
1442 | # Now compare each entry explicitly by number |
1443 | for (@okstat) { |
1444 | print "Comparing: $_ : $fh[$_] and $path[$_]\n" if $DEBUG; |
1445 | unless ($fh[$_] == $path[$_]) { |
1446 | warn "Did not match $_ element of stat\n" if $DEBUG; |
1447 | return 0; |
1448 | } |
1449 | } |
1450 | |
1451 | # attempt remove the file (does not work on some platforms) |
1452 | if (_can_unlink_opened_file()) { |
1453 | # XXX: do *not* call this on a directory; possible race |
1454 | # resulting in recursive removal |
1455 | croak "unlink0: $path has become a directory!" if -d $path; |
1456 | unlink($path) or return 0; |
1457 | |
1458 | # Stat the filehandle |
1459 | @fh = stat $fh; |
1460 | |
1461 | print "Link count = $fh[3] \n" if $DEBUG; |
1462 | |
1463 | # Make sure that the link count is zero |
1464 | return ( $fh[3] == 0 ? 1 : 0); |
1465 | |
1466 | } else { |
1467 | _deferred_unlink($fh, $path, 0); |
1468 | return 1; |
1469 | } |
1470 | |
1471 | } |
1472 | |
1473 | =back |
1474 | |
1475 | =head1 PACKAGE VARIABLES |
1476 | |
1477 | These functions control the global state of the package. |
1478 | |
1479 | =over 4 |
1480 | |
1481 | =item B<safe_level> |
1482 | |
1483 | Controls the lengths to which the module will go to check the safety of the |
1484 | temporary file or directory before proceeding. |
1485 | Options are: |
1486 | |
1487 | =over 8 |
1488 | |
1489 | =item STANDARD |
1490 | |
1491 | Do the basic security measures to ensure the directory exists and |
1492 | is writable, that the umask() is fixed before opening of the file, |
1493 | that temporary files are opened only if they do not already exist, and |
1494 | that possible race conditions are avoided. Finally the L<unlink0|"unlink0"> |
1495 | function is used to remove files safely. |
1496 | |
1497 | =item MEDIUM |
1498 | |
1499 | In addition to the STANDARD security, the output directory is checked |
1500 | to make sure that it is owned either by root or the user running the |
1501 | program. If the directory is writable by group or by other, it is then |
1502 | checked to make sure that the sticky bit is set. |
1503 | |
1504 | Will not work on platforms that do not support the C<-k> test |
1505 | for sticky bit. |
1506 | |
1507 | =item HIGH |
1508 | |
1509 | In addition to the MEDIUM security checks, also check for the |
1510 | possibility of ``chown() giveaway'' using the L<POSIX|POSIX> |
1511 | sysconf() function. If this is a possibility, each directory in the |
1512 | path is checked in turn for safeness, recursively walking back to the |
1513 | root directory. |
1514 | |
1515 | For platforms that do not support the L<POSIX|POSIX> |
1516 | C<_PC_CHOWN_RESTRICTED> symbol (for example, Windows NT) it is |
1517 | assumed that ``chown() giveaway'' is possible and the recursive test |
1518 | is performed. |
1519 | |
1520 | =back |
1521 | |
1522 | The level can be changed as follows: |
1523 | |
1524 | File::Temp->safe_level( File::Temp::HIGH ); |
1525 | |
1526 | The level constants are not exported by the module. |
1527 | |
1528 | Currently, you must be running at least perl v5.6.0 in order to |
1529 | run with MEDIUM or HIGH security. This is simply because the |
1530 | safety tests use functions from L<Fcntl|Fcntl> that are not |
1531 | available in older versions of perl. The problem is that the version |
1532 | number for Fcntl is the same in perl 5.6.0 and in 5.005_03 even though |
1c19c868 |
1533 | they are different versions. |
1534 | |
1535 | On systems that do not support the HIGH or MEDIUM safety levels |
1536 | (for example Win NT or OS/2) any attempt to change the level will |
1537 | be ignored. The decision to ignore rather than raise an exception |
1538 | allows portable programs to be written with high security in mind |
1539 | for the systems that can support this without those programs failing |
1540 | on systems where the extra tests are irrelevant. |
1541 | |
1542 | If you really need to see whether the change has been accepted |
1543 | simply examine the return value of C<safe_level>. |
1544 | |
1545 | $newlevel = File::Temp->safe_level( File::Temp::HIGH ); |
1546 | die "Could not change to high security" |
1547 | if $newlevel != File::Temp::HIGH; |
262eb13a |
1548 | |
1549 | =cut |
1550 | |
1551 | { |
1552 | # protect from using the variable itself |
1553 | my $LEVEL = STANDARD; |
1554 | sub safe_level { |
1555 | my $self = shift; |
1556 | if (@_) { |
1557 | my $level = shift; |
1558 | if (($level != STANDARD) && ($level != MEDIUM) && ($level != HIGH)) { |
1559 | carp "safe_level: Specified level ($level) not STANDARD, MEDIUM or HIGH - ignoring\n"; |
1560 | } else { |
1c19c868 |
1561 | # Dont allow this on perl 5.005 or earlier |
262eb13a |
1562 | if ($] < 5.006 && $level != STANDARD) { |
1563 | # Cant do MEDIUM or HIGH checks |
1564 | croak "Currently requires perl 5.006 or newer to do the safe checks"; |
1565 | } |
1c19c868 |
1566 | # Check that we are allowed to change level |
1567 | # Silently ignore if we can not. |
1568 | $LEVEL = $level if _can_do_level($level); |
262eb13a |
1569 | } |
1570 | } |
1571 | return $LEVEL; |
1572 | } |
1573 | } |
1574 | |
1575 | =item TopSystemUID |
1576 | |
1577 | This is the highest UID on the current system that refers to a root |
1578 | UID. This is used to make sure that the temporary directory is |
1579 | owned by a system UID (C<root>, C<bin>, C<sys> etc) rather than |
1580 | simply by root. |
1581 | |
1582 | This is required since on many unix systems C</tmp> is not owned |
1583 | by root. |
1584 | |
1585 | Default is to assume that any UID less than or equal to 10 is a root |
1586 | UID. |
1587 | |
1588 | File::Temp->top_system_uid(10); |
1589 | my $topid = File::Temp->top_system_uid; |
1590 | |
1591 | This value can be adjusted to reduce security checking if required. |
1592 | The value is only relevant when C<safe_level> is set to MEDIUM or higher. |
1593 | |
1594 | =back |
1595 | |
1596 | =cut |
1597 | |
1598 | { |
1599 | my $TopSystemUID = 10; |
1600 | sub top_system_uid { |
1601 | my $self = shift; |
1602 | if (@_) { |
1603 | my $newuid = shift; |
1604 | croak "top_system_uid: UIDs should be numeric" |
1605 | unless $newuid =~ /^\d+$/s; |
1606 | $TopSystemUID = $newuid; |
1607 | } |
1608 | return $TopSystemUID; |
1609 | } |
1610 | } |
1611 | |
1612 | =head1 WARNING |
1613 | |
1614 | For maximum security, endeavour always to avoid ever looking at, |
1615 | touching, or even imputing the existence of the filename. You do not |
1616 | know that that filename is connected to the same file as the handle |
1617 | you have, and attempts to check this can only trigger more race |
1618 | conditions. It's far more secure to use the filehandle alone and |
1619 | dispense with the filename altogether. |
1620 | |
1621 | If you need to pass the handle to something that expects a filename |
1622 | then, on a unix system, use C<"/dev/fd/" . fileno($fh)> for arbitrary |
1623 | programs, or more generally C<< "+<=&" . fileno($fh) >> for Perl |
1624 | programs. You will have to clear the close-on-exec bit on that file |
1625 | descriptor before passing it to another process. |
1626 | |
1627 | use Fcntl qw/F_SETFD F_GETFD/; |
1628 | fcntl($tmpfh, F_SETFD, 0) |
1629 | or die "Can't clear close-on-exec flag on temp fh: $!\n"; |
1630 | |
1631 | =head1 HISTORY |
1632 | |
1633 | Originally began life in May 1999 as an XS interface to the system |
1634 | mkstemp() function. In March 2000, the mkstemp() code was |
1635 | translated to Perl for total control of the code's |
1636 | security checking, to ensure the presence of the function regardless of |
1637 | operating system and to help with portability. |
1638 | |
1639 | =head1 SEE ALSO |
1640 | |
1641 | L<POSIX/tmpnam>, L<POSIX/tmpfile>, L<File::Spec>, L<File::Path> |
1642 | |
1643 | See L<File::MkTemp> for a different implementation of temporary |
1644 | file handling. |
1645 | |
1646 | =head1 AUTHOR |
1647 | |
1648 | Tim Jenness E<lt>t.jenness@jach.hawaii.eduE<gt> |
1649 | |
1650 | Copyright (C) 1999, 2000 Tim Jenness and the UK Particle Physics and |
1651 | Astronomy Research Council. All Rights Reserved. This program is free |
1652 | software; you can redistribute it and/or modify it under the same |
1653 | terms as Perl itself. |
1654 | |
1655 | Original Perl implementation loosely based on the OpenBSD C code for |
1656 | mkstemp(). Thanks to Tom Christiansen for suggesting that this module |
1657 | should be written and providing ideas for code improvements and |
1658 | security enhancements. |
1659 | |
1660 | =cut |
1661 | |
1662 | |
1663 | 1; |