[p5sagit/p5-mst-13.2.git] / lib / File / Copy.pm

# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
# source code has been placed in the public domain by the author.
# Please be kind and preserve the documentation.
#
# Additions copyright 1996 by Charles Bailey.  Permission is granted
# to distribute the revised code under the same terms as Perl itself.

package File::Copy;

use 5.006;
use strict;
use warnings;
use File::Spec;
use Config;
our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
sub copy;
sub syscopy;
sub cp;
sub mv;

# Note that this module implements only *part* of the API defined by
# the File/Copy.pm module of the File-Tools-2.0 package.  However, that
# package has not yet been updated to work with Perl 5.004, and so it
# would be a Bad Thing for the CPAN module to grab it and replace this
# module.  Therefore, we set this module's version higher than 2.0.
$VERSION = '2.08_01';

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(copy move);
@EXPORT_OK = qw(cp mv);

$Too_Big = 1024 * 1024 * 2;

sub croak {
    require Carp;
    goto &Carp::croak;
}

my $macfiles;
if ($^O eq 'MacOS') {
	$macfiles = eval { require Mac::MoreFiles };
	warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
		if $@ && $^W;
}

sub _catname {
    my($from, $to) = @_;
    if (not defined &basename) {
	require File::Basename;
	import  File::Basename 'basename';
    }

    if ($^O eq 'MacOS') {
	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	$to = ':' . $to if $to !~ /:/;
    }

    return File::Spec->catfile($to, basename($from));
}

sub copy {
    croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
      unless(@_ == 2 || @_ == 3);

    my $from = shift;
    my $to = shift;

    my $from_a_handle = (ref($from)
			 ? (ref($from) eq 'GLOB'
			    || UNIVERSAL::isa($from, 'GLOB')
                            || UNIVERSAL::isa($from, 'IO::Handle'))
			 : (ref(\$from) eq 'GLOB'));
    my $to_a_handle =   (ref($to)
			 ? (ref($to) eq 'GLOB'
			    || UNIVERSAL::isa($to, 'GLOB')
                            || UNIVERSAL::isa($to, 'IO::Handle'))
			 : (ref(\$to) eq 'GLOB'));

    if ($from eq $to) { # works for references, too
	croak("'$from' and '$to' are identical (not copied)");
    }

    if ((($Config{d_symlink} && $Config{d_readlink}) || $Config{d_link}) &&
	!($^O eq 'MSWin32' || $^O eq 'os2' || $^O eq 'vms')) {
	my @fs = stat($from);
	if (@fs) {
	    my @ts = stat($to);
	    if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
		croak("'$from' and '$to' are identical (not copied)");
	    }
	}
    }

    if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    if (defined &syscopy && !$Syscopy_is_copy
	&& !$to_a_handle
	&& !($from_a_handle && $^O eq 'os2' )	# OS/2 cannot handle handles
	&& !($from_a_handle && $^O eq 'mpeix')	# and neither can MPE/iX.
	&& !($from_a_handle && $^O eq 'MSWin32')
	&& !($from_a_handle && $^O eq 'MacOS')
	&& !($from_a_handle && $^O eq 'NetWare')
       )
    {
	return syscopy($from, $to);
    }

    my $closefrom = 0;
    my $closeto = 0;
    my ($size, $status, $r, $buf);
    local($\) = '';

    my $from_h;
    if ($from_a_handle) {
       $from_h = $from;
    } else {
	$from = _protect($from) if $from =~ /^\s/s;
       $from_h = \do { local *FH };
       open($from_h, "< $from\0") or goto fail_open1;
       binmode $from_h or die "($!,$^E)";
	$closefrom = 1;
    }

    my $to_h;
    if ($to_a_handle) {
       $to_h = $to;
    } else {
	$to = _protect($to) if $to =~ /^\s/s;
       $to_h = \do { local *FH };
       open($to_h,"> $to\0") or goto fail_open2;
       binmode $to_h or die "($!,$^E)";
	$closeto = 1;
    }

    if (@_) {
	$size = shift(@_) + 0;
	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
    } else {
	$size = tied(*$from_h) ? 0 : -s $from_h || 0;
	$size = 1024 if ($size < 512);
	$size = $Too_Big if ($size > $Too_Big);
    }

    $! = 0;
    for (;;) {
	my ($r, $w, $t);
       defined($r = sysread($from_h, $buf, $size))
	    or goto fail_inner;
	last unless $r;
	for ($w = 0; $w < $r; $w += $t) {
           $t = syswrite($to_h, $buf, $r - $w, $w)
		or goto fail_inner;
	}
    }

    close($to_h) || goto fail_open2 if $closeto;
    close($from_h) || goto fail_open1 if $closefrom;

    # Use this idiom to avoid uninitialized value warning.
    return 1;

    # All of these contortions try to preserve error messages...
  fail_inner:
    if ($closeto) {
	$status = $!;
	$! = 0;
       close $to_h;
	$! = $status unless $!;
    }
  fail_open2:
    if ($closefrom) {
	$status = $!;
	$! = 0;
       close $from_h;
	$! = $status unless $!;
    }
  fail_open1:
    return 0;
}

sub move {
    my($from,$to) = @_;
    my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);

    if (-d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    ($tosz1,$tomt1) = (stat($to))[7,9];
    $fromsz = -s $from;
    if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
      # will not rename with overwrite
      unlink $to;
    }
    return 1 if rename $from, $to;

    # Did rename return an error even though it succeeded, because $to
    # is on a remote NFS file system, and NFS lost the server's ack?
    return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
                (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
                ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
                $tosz2 == $fromsz;                         # it's all there

    ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
    return 1 if copy($from,$to) && unlink($from);
    ($sts,$ossts) = ($! + 0, $^E + 0);

    ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
    unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
    ($!,$^E) = ($sts,$ossts);
    return 0;
}

*cp = \&copy;
*mv = \&move;


if ($^O eq 'MacOS') {
    *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
} else {
    *_protect = sub { "./$_[0]" };
}

# &syscopy is an XSUB under OS/2
unless (defined &syscopy) {
    if ($^O eq 'VMS') {
	*syscopy = \&rmscopy;
    } elsif ($^O eq 'mpeix') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    # Use the MPE cp program in order to
	    # preserve MPE file attributes.
	    return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	};
    } elsif ($^O eq 'MSWin32') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    return Win32::CopyFile(@_, 1);
	};
    } elsif ($macfiles) {
	*syscopy = sub {
	    my($from, $to) = @_;
	    my($dir, $toname);

	    return 0 unless -e $from;

	    if ($to =~ /(.*:)([^:]+):?$/) {
		($dir, $toname) = ($1, $2);
	    } else {
		($dir, $toname) = (":", $to);
	    }

	    unlink($to);
	    Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	};
    } else {
	$Syscopy_is_copy = 1;
	*syscopy = \&copy;
    }
}

1;

__END__

=head1 NAME

File::Copy - Copy files or filehandles

=head1 SYNOPSIS

	use File::Copy;

	copy("file1","file2") or die "Copy failed: $!";
	copy("Copy.pm",\*STDOUT);
	move("/dev1/fileA","/dev2/fileB");

	use File::Copy "cp";

	$n = FileHandle->new("/a/file","r");
	cp($n,"x");

=head1 DESCRIPTION

The File::Copy module provides two basic functions, C<copy> and
C<move>, which are useful for getting the contents of a file from
one place to another.

=over 4

=item *

The C<copy> function takes two
parameters: a file to copy from and a file to copy to. Either
argument may be a string, a FileHandle reference or a FileHandle
glob. Obviously, if the first argument is a filehandle of some
sort, it will be read from, and if it is a file I<name> it will
be opened for reading. Likewise, the second argument will be
written to (and created if need be).  Trying to copy a file on top
of itself is a fatal error.

B<Note that passing in
files as handles instead of names may lead to loss of information
on some operating systems; it is recommended that you use file
names whenever possible.>  Files are opened in binary mode where
applicable.  To get a consistent behaviour when copying from a
filehandle to a file, use C<binmode> on the filehandle.

An optional third parameter can be used to specify the buffer
size used for copying. This is the number of bytes from the
first file, that wil be held in memory at any given time, before
being written to the second file. The default buffer size depends
upon the file, but will generally be the whole file (up to 2Mb), or
1k for filehandles that do not reference files (eg. sockets).

You may use the syntax C<use File::Copy "cp"> to get at the
"cp" alias for this function. The syntax is I<exactly> the same.

=item *

The C<move> function also takes two parameters: the current name
and the intended name of the file to be moved.  If the destination
already exists and is a directory, and the source is not a
directory, then the source file will be renamed into the directory
specified by the destination.

If possible, move() will simply rename the file.  Otherwise, it copies
the file to the new location and deletes the original.  If an error occurs
during this copy-and-delete process, you may be left with a (possibly partial)
copy of the file under the destination name.

You may use the "mv" alias for this function in the same way that
you may use the "cp" alias for C<copy>.

=back

File::Copy also provides the C<syscopy> routine, which copies the
file specified in the first parameter to the file specified in the
second parameter, preserving OS-specific attributes and file
structure.  For Unix systems, this is equivalent to the simple
C<copy> routine, which doesn't preserve OS-specific attributes.  For
VMS systems, this calls the C<rmscopy> routine (see below).  For OS/2
systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
this calls C<Win32::CopyFile>.

On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
if available.

=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)

If both arguments to C<copy> are not file handles,
then C<copy> will perform a "system copy" of
the input file to a new output file, in order to preserve file
attributes, indexed file structure, I<etc.>  The buffer size
parameter is ignored.  If either argument to C<copy> is a
handle to an opened file, then data is copied using Perl
operators, and no effort is made to preserve file attributes
or record structure.

The system copy routine may also be called directly under VMS and OS/2
as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
is the routine that does the actual work for syscopy).

=over 4

=item rmscopy($from,$to[,$date_flag])

The first and second arguments may be strings, typeglobs, typeglob
references, or objects inheriting from IO::Handle;
they are used in all cases to obtain the
I<filespec> of the input and output files, respectively.  The
name and type of the input file are used as defaults for the
output file, if necessary.

A new version of the output file is always created, which
inherits the structure and RMS attributes of the input file,
except for owner and protections (and possibly timestamps;
see below).  All data from the input file is copied to the
output file; if either of the first two parameters to C<rmscopy>
is a file handle, its position is unchanged.  (Note that this
means a file handle pointing to the output file will be
associated with an old version of that file after C<rmscopy>
returns, not the newly created version.)

The third parameter is an integer flag, which tells C<rmscopy>
how to handle timestamps.  If it is E<lt> 0, none of the input file's
timestamps are propagated to the output file.  If it is E<gt> 0, then
it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
timestamps other than the revision date are propagated; if bit 1
is set, the revision date is propagated.  If the third parameter
to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
if the name or type of the output file was explicitly specified,
then no timestamps are propagated, but if they were taken implicitly
from the input filespec, then all timestamps other than the
revision date are propagated.  If this parameter is not supplied,
it defaults to 0.

Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
it sets C<$!>, deletes the output file, and returns 0.

=back

=head1 RETURN

All functions return 1 on success, 0 on failure.
$! will be set if an error was encountered.

=head1 NOTES

=over 4

=item *

On Mac OS (Classic), the path separator is ':', not '/', and the 
current directory is denoted as ':', not '.'. You should be careful 
about specifying relative pathnames. While a full path always begins 
with a volume name, a relative pathname should always begin with a 
':'.  If specifying a volume name only, a trailing ':' is required.

E.g.

  copy("file1", "tmp");        # creates the file 'tmp' in the current directory
  copy("file1", ":tmp:");      # creates :tmp:file1
  copy("file1", ":tmp");       # same as above
  copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do   
                               # that, since it may cause confusion, see example #1)
  copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
  copy("file1", ":tmp:file1"); # ok, partial path
  copy("file1", "DataHD:");    # creates DataHD:file1
  
  move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one 
                                             # volume to another

=back

=head1 AUTHOR

File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.

=cut
Commit	Line	Data
f716a1dd	1	# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
	2	# source code has been placed in the public domain by the author.
	3	# Please be kind and preserve the documentation.
	4	#
71be2cbc	5	# Additions copyright 1996 by Charles Bailey. Permission is granted
71be2cbc	6	# to distribute the revised code under the same terms as Perl itself.
f716a1dd	7
	8	package File::Copy;
	9
3b825e41	10	use 5.006;
71be2cbc	11	use strict;
b395063c	12	use warnings;
6c254d95	13	use File::Spec;
96a91e01	14	use Config;
17f410f9	15	our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
	16	sub copy;
	17	sub syscopy;
	18	sub cp;
	19	sub mv;
71be2cbc	20
	21	# Note that this module implements only part of the API defined by
	22	# the File/Copy.pm module of the File-Tools-2.0 package. However, that
	23	# package has not yet been updated to work with Perl 5.004, and so it
	24	# would be a Bad Thing for the CPAN module to grab it and replace this
	25	# module. Therefore, we set this module's version higher than 2.0.
8878f897	26	$VERSION = '2.08_01';
f716a1dd	27
71be2cbc	28	require Exporter;
	29	@ISA = qw(Exporter);
	30	@EXPORT = qw(copy move);
	31	@EXPORT_OK = qw(cp mv);
f716a1dd	32
441496b2	33	$Too_Big = 1024 * 1024 * 2;
f716a1dd	34
8878f897	35	sub croak {
	36	require Carp;
	37	goto &Carp::croak;
	38	}
	39
bcdb689b	40	my $macfiles;
	41	if ($^O eq 'MacOS') {
	42	$macfiles = eval { require Mac::MoreFiles };
	43	warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
3a2263fe	44	if $@ && $^W;
bcdb689b	45	}
bcdb689b	46
6c254d95	47	sub _catname {
71be2cbc	48	my($from, $to) = @_;
	49	if (not defined &basename) {
	50	require File::Basename;
	51	import File::Basename 'basename';
	52	}
6c254d95	53
	54	if ($^O eq 'MacOS') {
	55	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	56	$to = ':' . $to if $to !~ /:/;
	57	}
	58
	59	return File::Spec->catfile($to, basename($from));
f716a1dd	60	}
	61
	62	sub copy {
71be2cbc	63	croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
f716a1dd	64	unless(@_ == 2 \|\| @_ == 3);
	65
	66	my $from = shift;
	67	my $to = shift;
71be2cbc	68
	69	my $from_a_handle = (ref($from)
	70	? (ref($from) eq 'GLOB'
d704f39a	71	\|\| UNIVERSAL::isa($from, 'GLOB')
d704f39a	72	\|\| UNIVERSAL::isa($from, 'IO::Handle'))
71be2cbc	73	: (ref(\$from) eq 'GLOB'));
	74	my $to_a_handle = (ref($to)
	75	? (ref($to) eq 'GLOB'
d704f39a	76	\|\| UNIVERSAL::isa($to, 'GLOB')
d704f39a	77	\|\| UNIVERSAL::isa($to, 'IO::Handle'))
71be2cbc	78	: (ref(\$to) eq 'GLOB'));
71be2cbc	79
96a91e01	80	if ($from eq $to) { # works for references, too
	81	croak("'$from' and '$to' are identical (not copied)");
	82	}
	83
ac7b122d	84	if ((($Config{d_symlink} && $Config{d_readlink}) \|\| $Config{d_link}) &&
b8ccb221	85	!($^O eq 'MSWin32' \|\| $^O eq 'os2' \|\| $^O eq 'vms')) {
ac7b122d	86	my @fs = stat($from);
ac7b122d	87	if (@fs) {
96a91e01	88	my @ts = stat($to);
ac7b122d	89	if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
96a91e01	90	croak("'$from' and '$to' are identical (not copied)");
	91	}
	92	}
	93	}
	94
71be2cbc	95	if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	96	$to = _catname($from, $to);
	97	}
	98
1a04d035	99	if (defined &syscopy && !$Syscopy_is_copy
e6434134	100	&& !$to_a_handle
1d84e8df	101	&& !($from_a_handle && $^O eq 'os2' ) # OS/2 cannot handle handles
1d84e8df	102	&& !($from_a_handle && $^O eq 'mpeix') # and neither can MPE/iX.
7509b657	103	&& !($from_a_handle && $^O eq 'MSWin32')
fa648be5	104	&& !($from_a_handle && $^O eq 'MacOS')
2986a63f	105	&& !($from_a_handle && $^O eq 'NetWare')
1a04d035	106	)
71be2cbc	107	{
	108	return syscopy($from, $to);
	109	}
	110
	111	my $closefrom = 0;
	112	my $closeto = 0;
f716a1dd	113	my ($size, $status, $r, $buf);
48a5c399	114	local($\) = '';
f716a1dd	115
23ba2776	116	my $from_h;
71be2cbc	117	if ($from_a_handle) {
23ba2776	118	$from_h = $from;
f716a1dd	119	} else {
fa648be5	120	$from = _protect($from) if $from =~ /^\s/s;
23ba2776	121	$from_h = \do { local *FH };
	122	open($from_h, "< $from\0") or goto fail_open1;
	123	binmode $from_h or die "($!,$^E)";
f716a1dd	124	$closefrom = 1;
1a04d035	125	}
1a04d035	126
23ba2776	127	my $to_h;
71be2cbc	128	if ($to_a_handle) {
23ba2776	129	$to_h = $to;
1a04d035	130	} else {
fa648be5	131	$to = _protect($to) if $to =~ /^\s/s;
23ba2776	132	$to_h = \do { local *FH };
	133	open($to_h,"> $to\0") or goto fail_open2;
	134	binmode $to_h or die "($!,$^E)";
71be2cbc	135	$closeto = 1;
1a04d035	136	}
f716a1dd	137
	138	if (@_) {
	139	$size = shift(@_) + 0;
	140	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
	141	} else {
025a6ea3	142	$size = tied(*$from_h) ? 0 : -s $from_h \|\| 0;
f716a1dd	143	$size = 1024 if ($size < 512);
441496b2	144	$size = $Too_Big if ($size > $Too_Big);
f716a1dd	145	}
f716a1dd	146
71be2cbc	147	$! = 0;
	148	for (;;) {
	149	my ($r, $w, $t);
23ba2776	150	defined($r = sysread($from_h, $buf, $size))
71be2cbc	151	or goto fail_inner;
	152	last unless $r;
	153	for ($w = 0; $w < $r; $w += $t) {
23ba2776	154	$t = syswrite($to_h, $buf, $r - $w, $w)
71be2cbc	155	or goto fail_inner;
f716a1dd	156	}
f716a1dd	157	}
71be2cbc	158
23ba2776	159	close($to_h) \|\| goto fail_open2 if $closeto;
23ba2776	160	close($from_h) \|\| goto fail_open1 if $closefrom;
71be2cbc	161
48a5c399	162	# Use this idiom to avoid uninitialized value warning.
f716a1dd	163	return 1;
1a04d035	164
f716a1dd	165	# All of these contortions try to preserve error messages...
	166	fail_inner:
	167	if ($closeto) {
	168	$status = $!;
	169	$! = 0;
23ba2776	170	close $to_h;
f716a1dd	171	$! = $status unless $!;
	172	}
	173	fail_open2:
	174	if ($closefrom) {
	175	$status = $!;
	176	$! = 0;
23ba2776	177	close $from_h;
f716a1dd	178	$! = $status unless $!;
	179	}
	180	fail_open1:
f716a1dd	181	return 0;
f716a1dd	182	}
9b957b78	183
441496b2	184	sub move {
71be2cbc	185	my($from,$to) = @_;
fa76202e	186	my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
441496b2	187
71be2cbc	188	if (-d $to && ! -d $from) {
	189	$to = _catname($from, $to);
	190	}
	191
	192	($tosz1,$tomt1) = (stat($to))[7,9];
	193	$fromsz = -s $from;
e6434134	194	if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
	195	# will not rename with overwrite
	196	unlink $to;
	197	}
71be2cbc	198	return 1 if rename $from, $to;
71be2cbc	199
71be2cbc	200	# Did rename return an error even though it succeeded, because $to
	201	# is on a remote NFS file system, and NFS lost the server's ack?
	202	return 1 if defined($fromsz) && !-e $from && # $from disappeared
	203	(($tosz2,$tomt2) = (stat($to))[7,9]) && # $to's there
	204	($tosz1 != $tosz2 or $tomt1 != $tomt2) && # and changed
	205	$tosz2 == $fromsz; # it's all there
1a04d035	206
71be2cbc	207	($tosz1,$tomt1) = (stat($to))[7,9]; # just in case rename did something
fa76202e	208	return 1 if copy($from,$to) && unlink($from);
fa76202e	209	($sts,$ossts) = ($! + 0, $^E + 0);
1a04d035	210
71be2cbc	211	($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
	212	unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
	213	($!,$^E) = ($sts,$ossts);
	214	return 0;
441496b2	215	}
9b957b78	216
71be2cbc	217	*cp = \©
	218	*mv = \&move;
	219
fa648be5	220
	221	if ($^O eq 'MacOS') {
	222	*_protect = sub { MacPerl::MakeFSSpec($_[0]) };
	223	} else {
	224	*_protect = sub { "./$_[0]" };
	225	}
	226
9b957b78	227	# &syscopy is an XSUB under OS/2
1d84e8df	228	unless (defined &syscopy) {
	229	if ($^O eq 'VMS') {
	230	*syscopy = \&rmscopy;
	231	} elsif ($^O eq 'mpeix') {
	232	*syscopy = sub {
3f5ee302	233	return 0 unless @_ == 2;
1d84e8df	234	# Use the MPE cp program in order to
	235	# preserve MPE file attributes.
	236	return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	237	};
7509b657	238	} elsif ($^O eq 'MSWin32') {
	239	*syscopy = sub {
	240	return 0 unless @_ == 2;
	241	return Win32::CopyFile(@_, 1);
	242	};
bcdb689b	243	} elsif ($macfiles) {
fa648be5	244	*syscopy = sub {
	245	my($from, $to) = @_;
	246	my($dir, $toname);
	247
	248	return 0 unless -e $from;
	249
	250	if ($to =~ /(.*:)([^:]+):?$/) {
	251	($dir, $toname) = ($1, $2);
	252	} else {
	253	($dir, $toname) = (":", $to);
	254	}
	255
	256	unlink($to);
	257	Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	258	};
1d84e8df	259	} else {
1a04d035	260	$Syscopy_is_copy = 1;
1d84e8df	261	*syscopy = \©
	262	}
	263	}
f716a1dd	264
	265	1;
	266
	267	__END__
a5f75d66	268
f716a1dd	269	=head1 NAME
	270
	271	File::Copy - Copy files or filehandles
	272
a5f75d66	273	=head1 SYNOPSIS
f716a1dd	274
5ce10329	275	use File::Copy;
f716a1dd	276
5ce10329	277	copy("file1","file2") or die "Copy failed: $!";
5ce10329	278	copy("Copy.pm",\*STDOUT);
441496b2	279	move("/dev1/fileA","/dev2/fileB");
f716a1dd	280
78e38bb6	281	use File::Copy "cp";
f716a1dd	282
23f3aea0	283	$n = FileHandle->new("/a/file","r");
c6dfe06b	284	cp($n,"x");
f716a1dd	285
	286	=head1 DESCRIPTION
	287
441496b2	288	The File::Copy module provides two basic functions, C<copy> and
	289	C<move>, which are useful for getting the contents of a file from
	290	one place to another.
	291
	292	=over 4
	293
	294	=item *
	295
	296	The C<copy> function takes two
f716a1dd	297	parameters: a file to copy from and a file to copy to. Either
	298	argument may be a string, a FileHandle reference or a FileHandle
	299	glob. Obviously, if the first argument is a filehandle of some
	300	sort, it will be read from, and if it is a file I<name> it will
	301	be opened for reading. Likewise, the second argument will be
96a91e01	302	written to (and created if need be). Trying to copy a file on top
96a91e01	303	of itself is a fatal error.
71be2cbc	304
71be2cbc	305	B<Note that passing in
9b957b78	306	files as handles instead of names may lead to loss of information
9b957b78	307	on some operating systems; it is recommended that you use file
e6434134	308	names whenever possible.> Files are opened in binary mode where
8dcee03e	309	applicable. To get a consistent behaviour when copying from a
e6434134	310	filehandle to a file, use C<binmode> on the filehandle.
f716a1dd	311
	312	An optional third parameter can be used to specify the buffer
	313	size used for copying. This is the number of bytes from the
	314	first file, that wil be held in memory at any given time, before
	315	being written to the second file. The default buffer size depends
	316	upon the file, but will generally be the whole file (up to 2Mb), or
	317	1k for filehandles that do not reference files (eg. sockets).
	318
	319	You may use the syntax C<use File::Copy "cp"> to get at the
	320	"cp" alias for this function. The syntax is I<exactly> the same.
	321
441496b2	322	=item *
	323
	324	The C<move> function also takes two parameters: the current name
71be2cbc	325	and the intended name of the file to be moved. If the destination
	326	already exists and is a directory, and the source is not a
	327	directory, then the source file will be renamed into the directory
	328	specified by the destination.
	329
	330	If possible, move() will simply rename the file. Otherwise, it copies
	331	the file to the new location and deletes the original. If an error occurs
	332	during this copy-and-delete process, you may be left with a (possibly partial)
441496b2	333	copy of the file under the destination name.
	334
	335	You may use the "mv" alias for this function in the same way that
	336	you may use the "cp" alias for C<copy>.
	337
	338	=back
	339
9b957b78	340	File::Copy also provides the C<syscopy> routine, which copies the
	341	file specified in the first parameter to the file specified in the
	342	second parameter, preserving OS-specific attributes and file
	343	structure. For Unix systems, this is equivalent to the simple
f1442e8b	344	C<copy> routine, which doesn't preserve OS-specific attributes. For
	345	VMS systems, this calls the C<rmscopy> routine (see below). For OS/2
	346	systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
	347	this calls C<Win32::CopyFile>.
9b957b78	348
bcdb689b	349	On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
	350	if available.
	351
7509b657	352	=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
9b957b78	353
71be2cbc	354	If both arguments to C<copy> are not file handles,
71be2cbc	355	then C<copy> will perform a "system copy" of
9b957b78	356	the input file to a new output file, in order to preserve file
9b957b78	357	attributes, indexed file structure, I<etc.> The buffer size
71be2cbc	358	parameter is ignored. If either argument to C<copy> is a
71be2cbc	359	handle to an opened file, then data is copied using Perl
9b957b78	360	operators, and no effort is made to preserve file attributes
	361	or record structure.
	362
55497cff	363	The system copy routine may also be called directly under VMS and OS/2
55497cff	364	as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
71be2cbc	365	is the routine that does the actual work for syscopy).
9b957b78	366
441496b2	367	=over 4
55497cff	368
9b957b78	369	=item rmscopy($from,$to[,$date_flag])
9b957b78	370
71be2cbc	371	The first and second arguments may be strings, typeglobs, typeglob
	372	references, or objects inheriting from IO::Handle;
	373	they are used in all cases to obtain the
9b957b78	374	I<filespec> of the input and output files, respectively. The
	375	name and type of the input file are used as defaults for the
	376	output file, if necessary.
	377
	378	A new version of the output file is always created, which
	379	inherits the structure and RMS attributes of the input file,
	380	except for owner and protections (and possibly timestamps;
	381	see below). All data from the input file is copied to the
	382	output file; if either of the first two parameters to C<rmscopy>
	383	is a file handle, its position is unchanged. (Note that this
	384	means a file handle pointing to the output file will be
	385	associated with an old version of that file after C<rmscopy>
	386	returns, not the newly created version.)
	387
	388	The third parameter is an integer flag, which tells C<rmscopy>
1fef88e7	389	how to handle timestamps. If it is E<lt> 0, none of the input file's
1fef88e7	390	timestamps are propagated to the output file. If it is E<gt> 0, then
9b957b78	391	it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
	392	timestamps other than the revision date are propagated; if bit 1
	393	is set, the revision date is propagated. If the third parameter
	394	to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
	395	if the name or type of the output file was explicitly specified,
	396	then no timestamps are propagated, but if they were taken implicitly
	397	from the input filespec, then all timestamps other than the
	398	revision date are propagated. If this parameter is not supplied,
	399	it defaults to 0.
	400
	401	Like C<copy>, C<rmscopy> returns 1 on success. If an error occurs,
	402	it sets C<$!>, deletes the output file, and returns 0.
	403
55497cff	404	=back
55497cff	405
f716a1dd	406	=head1 RETURN
f716a1dd	407
441496b2	408	All functions return 1 on success, 0 on failure.
441496b2	409	$! will be set if an error was encountered.
f716a1dd	410
6c254d95	411	=head1 NOTES
	412
	413	=over 4
	414
	415	=item *
	416
	417	On Mac OS (Classic), the path separator is ':', not '/', and the
	418	current directory is denoted as ':', not '.'. You should be careful
	419	about specifying relative pathnames. While a full path always begins
	420	with a volume name, a relative pathname should always begin with a
	421	':'. If specifying a volume name only, a trailing ':' is required.
	422
	423	E.g.
	424
	425	copy("file1", "tmp"); # creates the file 'tmp' in the current directory
	426	copy("file1", ":tmp:"); # creates :tmp:file1
	427	copy("file1", ":tmp"); # same as above
	428	copy("file1", "tmp"); # same as above, if 'tmp' is a directory (but don't do
	429	# that, since it may cause confusion, see example #1)
	430	copy("file1", "tmp:file1"); # error, since 'tmp:' is not a volume
	431	copy("file1", ":tmp:file1"); # ok, partial path
	432	copy("file1", "DataHD:"); # creates DataHD:file1
	433
	434	move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
	435	# volume to another
	436
	437	=back
	438
f716a1dd	439	=head1 AUTHOR
f716a1dd	440
441496b2	441	File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
bd3fa61c	442	and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
f716a1dd	443
f716a1dd	444	=cut
441496b2	445