[p5sagit/p5-mst-13.2.git] / lib / File / Copy.pm

# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
# source code has been placed in the public domain by the author.
# Please be kind and preserve the documentation.
#
# Additions copyright 1996 by Charles Bailey.  Permission is granted
# to distribute the revised code under the same terms as Perl itself.

package File::Copy;

use 5.005_64;
use strict;
use Carp;
our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
sub copy;
sub syscopy;
sub cp;
sub mv;

# Note that this module implements only *part* of the API defined by
# the File/Copy.pm module of the File-Tools-2.0 package.  However, that
# package has not yet been updated to work with Perl 5.004, and so it
# would be a Bad Thing for the CPAN module to grab it and replace this
# module.  Therefore, we set this module's version higher than 2.0.
$VERSION = '2.03';

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(copy move);
@EXPORT_OK = qw(cp mv);

$Too_Big = 1024 * 1024 * 2;

sub _catname { #  Will be replaced by File::Spec when it arrives
    my($from, $to) = @_;
    if (not defined &basename) {
	require File::Basename;
	import  File::Basename 'basename';
    }
    if ($^O eq 'VMS')  { $to = VMS::Filespec::vmspath($to) . basename($from); }
    elsif ($^O eq 'MacOS') { $to .= ':' . basename($from); }
    elsif ($to =~ m|\\|)   { $to .= '\\' . basename($from); }
    else                   { $to .= '/' . basename($from); }
}

sub copy {
    croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
      unless(@_ == 2 || @_ == 3);

    my $from = shift;
    my $to = shift;

    my $from_a_handle = (ref($from)
			 ? (ref($from) eq 'GLOB'
			    || UNIVERSAL::isa($from, 'GLOB')
                            || UNIVERSAL::isa($from, 'IO::Handle'))
			 : (ref(\$from) eq 'GLOB'));
    my $to_a_handle =   (ref($to)
			 ? (ref($to) eq 'GLOB'
			    || UNIVERSAL::isa($to, 'GLOB')
                            || UNIVERSAL::isa($to, 'IO::Handle'))
			 : (ref(\$to) eq 'GLOB'));

    if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    if (defined &syscopy && !$Syscopy_is_copy
	&& !$to_a_handle
	&& !($from_a_handle && $^O eq 'os2' )	# OS/2 cannot handle handles
	&& !($from_a_handle && $^O eq 'mpeix')	# and neither can MPE/iX.
	&& !($from_a_handle && $^O eq 'MSWin32')
       )
    {
	return syscopy($from, $to);
    }

    my $closefrom = 0;
    my $closeto = 0;
    my ($size, $status, $r, $buf);
    local(*FROM, *TO);
    local($\) = '';

    if ($from_a_handle) {
	*FROM = *$from{FILEHANDLE};
    } else {
	$from = "./$from" if $from =~ /^\s/s;
	open(FROM, "< $from\0") or goto fail_open1;
	binmode FROM or die "($!,$^E)";
	$closefrom = 1;
    }

    if ($to_a_handle) {
	*TO = *$to{FILEHANDLE};
    } else {
	$to = "./$to" if $to =~ /^\s/s;
	open(TO,"> $to\0") or goto fail_open2;
	binmode TO or die "($!,$^E)";
	$closeto = 1;
    }

    if (@_) {
	$size = shift(@_) + 0;
	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
    } else {
	$size = -s FROM;
	$size = 1024 if ($size < 512);
	$size = $Too_Big if ($size > $Too_Big);
    }

    $! = 0;
    for (;;) {
	my ($r, $w, $t);
	defined($r = sysread(FROM, $buf, $size))
	    or goto fail_inner;
	last unless $r;
	for ($w = 0; $w < $r; $w += $t) {
	    $t = syswrite(TO, $buf, $r - $w, $w)
		or goto fail_inner;
	}
    }

    close(TO) || goto fail_open2 if $closeto;
    close(FROM) || goto fail_open1 if $closefrom;

    # Use this idiom to avoid uninitialized value warning.
    return 1;

    # All of these contortions try to preserve error messages...
  fail_inner:
    if ($closeto) {
	$status = $!;
	$! = 0;
	close TO;
	$! = $status unless $!;
    }
  fail_open2:
    if ($closefrom) {
	$status = $!;
	$! = 0;
	close FROM;
	$! = $status unless $!;
    }
  fail_open1:
    return 0;
}

sub move {
    my($from,$to) = @_;
    my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);

    if (-d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    ($tosz1,$tomt1) = (stat($to))[7,9];
    $fromsz = -s $from;
    if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
      # will not rename with overwrite
      unlink $to;
    }
    return 1 if rename $from, $to;

    ($sts,$ossts) = ($! + 0, $^E + 0);
    # Did rename return an error even though it succeeded, because $to
    # is on a remote NFS file system, and NFS lost the server's ack?
    return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
                (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
                ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
                $tosz2 == $fromsz;                         # it's all there

    ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
    return 1 if ($copied = copy($from,$to)) && unlink($from);

    ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
    unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
    ($!,$^E) = ($sts,$ossts);
    return 0;
}

*cp = \&copy;
*mv = \&move;

# &syscopy is an XSUB under OS/2
unless (defined &syscopy) {
    if ($^O eq 'VMS') {
	*syscopy = \&rmscopy;
    } elsif ($^O eq 'mpeix') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    # Use the MPE cp program in order to
	    # preserve MPE file attributes.
	    return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	};
    } elsif ($^O eq 'MSWin32') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    return Win32::CopyFile(@_, 1);
	};
    } else {
	$Syscopy_is_copy = 1;
	*syscopy = \&copy;
    }
}

1;

__END__

=head1 NAME

File::Copy - Copy files or filehandles

=head1 SYNOPSIS

  	use File::Copy;

	copy("file1","file2");
  	copy("Copy.pm",\*STDOUT);'
	move("/dev1/fileA","/dev2/fileB");

  	use POSIX;
	use File::Copy cp;

	$n = FileHandle->new("/a/file","r");
	cp($n,"x");'

=head1 DESCRIPTION

The File::Copy module provides two basic functions, C<copy> and
C<move>, which are useful for getting the contents of a file from
one place to another.

=over 4

=item *

The C<copy> function takes two
parameters: a file to copy from and a file to copy to. Either
argument may be a string, a FileHandle reference or a FileHandle
glob. Obviously, if the first argument is a filehandle of some
sort, it will be read from, and if it is a file I<name> it will
be opened for reading. Likewise, the second argument will be
written to (and created if need be).

B<Note that passing in
files as handles instead of names may lead to loss of information
on some operating systems; it is recommended that you use file
names whenever possible.>  Files are opened in binary mode where
applicable.  To get a consistent behaviour when copying from a
filehandle to a file, use C<binmode> on the filehandle.

An optional third parameter can be used to specify the buffer
size used for copying. This is the number of bytes from the
first file, that wil be held in memory at any given time, before
being written to the second file. The default buffer size depends
upon the file, but will generally be the whole file (up to 2Mb), or
1k for filehandles that do not reference files (eg. sockets).

You may use the syntax C<use File::Copy "cp"> to get at the
"cp" alias for this function. The syntax is I<exactly> the same.

=item *

The C<move> function also takes two parameters: the current name
and the intended name of the file to be moved.  If the destination
already exists and is a directory, and the source is not a
directory, then the source file will be renamed into the directory
specified by the destination.

If possible, move() will simply rename the file.  Otherwise, it copies
the file to the new location and deletes the original.  If an error occurs
during this copy-and-delete process, you may be left with a (possibly partial)
copy of the file under the destination name.

You may use the "mv" alias for this function in the same way that
you may use the "cp" alias for C<copy>.

=back

File::Copy also provides the C<syscopy> routine, which copies the
file specified in the first parameter to the file specified in the
second parameter, preserving OS-specific attributes and file
structure.  For Unix systems, this is equivalent to the simple
C<copy> routine.  For VMS systems, this calls the C<rmscopy>
routine (see below).  For OS/2 systems, this calls the C<syscopy>
XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.

=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)

If both arguments to C<copy> are not file handles,
then C<copy> will perform a "system copy" of
the input file to a new output file, in order to preserve file
attributes, indexed file structure, I<etc.>  The buffer size
parameter is ignored.  If either argument to C<copy> is a
handle to an opened file, then data is copied using Perl
operators, and no effort is made to preserve file attributes
or record structure.

The system copy routine may also be called directly under VMS and OS/2
as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
is the routine that does the actual work for syscopy).

=over 4

=item rmscopy($from,$to[,$date_flag])

The first and second arguments may be strings, typeglobs, typeglob
references, or objects inheriting from IO::Handle;
they are used in all cases to obtain the
I<filespec> of the input and output files, respectively.  The
name and type of the input file are used as defaults for the
output file, if necessary.

A new version of the output file is always created, which
inherits the structure and RMS attributes of the input file,
except for owner and protections (and possibly timestamps;
see below).  All data from the input file is copied to the
output file; if either of the first two parameters to C<rmscopy>
is a file handle, its position is unchanged.  (Note that this
means a file handle pointing to the output file will be
associated with an old version of that file after C<rmscopy>
returns, not the newly created version.)

The third parameter is an integer flag, which tells C<rmscopy>
how to handle timestamps.  If it is E<lt> 0, none of the input file's
timestamps are propagated to the output file.  If it is E<gt> 0, then
it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
timestamps other than the revision date are propagated; if bit 1
is set, the revision date is propagated.  If the third parameter
to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
if the name or type of the output file was explicitly specified,
then no timestamps are propagated, but if they were taken implicitly
from the input filespec, then all timestamps other than the
revision date are propagated.  If this parameter is not supplied,
it defaults to 0.

Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
it sets C<$!>, deletes the output file, and returns 0.

=back

=head1 RETURN

All functions return 1 on success, 0 on failure.
$! will be set if an error was encountered.

=head1 AUTHOR

File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.

=cut
Commit	Line	Data
f716a1dd	1	# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
	2	# source code has been placed in the public domain by the author.
	3	# Please be kind and preserve the documentation.
	4	#
71be2cbc	5	# Additions copyright 1996 by Charles Bailey. Permission is granted
71be2cbc	6	# to distribute the revised code under the same terms as Perl itself.
f716a1dd	7
	8	package File::Copy;
	9
17f410f9	10	use 5.005_64;
71be2cbc	11	use strict;
f716a1dd	12	use Carp;
17f410f9	13	our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
	14	sub copy;
	15	sub syscopy;
	16	sub cp;
	17	sub mv;
71be2cbc	18
	19	# Note that this module implements only part of the API defined by
	20	# the File/Copy.pm module of the File-Tools-2.0 package. However, that
	21	# package has not yet been updated to work with Perl 5.004, and so it
	22	# would be a Bad Thing for the CPAN module to grab it and replace this
	23	# module. Therefore, we set this module's version higher than 2.0.
1a04d035	24	$VERSION = '2.03';
f716a1dd	25
71be2cbc	26	require Exporter;
	27	@ISA = qw(Exporter);
	28	@EXPORT = qw(copy move);
	29	@EXPORT_OK = qw(cp mv);
f716a1dd	30
441496b2	31	$Too_Big = 1024 * 1024 * 2;
f716a1dd	32
71be2cbc	33	sub _catname { # Will be replaced by File::Spec when it arrives
	34	my($from, $to) = @_;
	35	if (not defined &basename) {
	36	require File::Basename;
	37	import File::Basename 'basename';
	38	}
	39	if ($^O eq 'VMS') { $to = VMS::Filespec::vmspath($to) . basename($from); }
	40	elsif ($^O eq 'MacOS') { $to .= ':' . basename($from); }
	41	elsif ($to =~ m\|\\\|) { $to .= '\\' . basename($from); }
	42	else { $to .= '/' . basename($from); }
f716a1dd	43	}
	44
	45	sub copy {
71be2cbc	46	croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
f716a1dd	47	unless(@_ == 2 \|\| @_ == 3);
	48
	49	my $from = shift;
	50	my $to = shift;
71be2cbc	51
	52	my $from_a_handle = (ref($from)
	53	? (ref($from) eq 'GLOB'
d704f39a	54	\|\| UNIVERSAL::isa($from, 'GLOB')
d704f39a	55	\|\| UNIVERSAL::isa($from, 'IO::Handle'))
71be2cbc	56	: (ref(\$from) eq 'GLOB'));
	57	my $to_a_handle = (ref($to)
	58	? (ref($to) eq 'GLOB'
d704f39a	59	\|\| UNIVERSAL::isa($to, 'GLOB')
d704f39a	60	\|\| UNIVERSAL::isa($to, 'IO::Handle'))
71be2cbc	61	: (ref(\$to) eq 'GLOB'));
	62
	63	if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	64	$to = _catname($from, $to);
	65	}
	66
1a04d035	67	if (defined &syscopy && !$Syscopy_is_copy
e6434134	68	&& !$to_a_handle
1d84e8df	69	&& !($from_a_handle && $^O eq 'os2' ) # OS/2 cannot handle handles
1d84e8df	70	&& !($from_a_handle && $^O eq 'mpeix') # and neither can MPE/iX.
7509b657	71	&& !($from_a_handle && $^O eq 'MSWin32')
1a04d035	72	)
71be2cbc	73	{
	74	return syscopy($from, $to);
	75	}
	76
	77	my $closefrom = 0;
	78	my $closeto = 0;
f716a1dd	79	my ($size, $status, $r, $buf);
f716a1dd	80	local(FROM, TO);
48a5c399	81	local($\) = '';
f716a1dd	82
71be2cbc	83	if ($from_a_handle) {
71be2cbc	84	FROM = $from{FILEHANDLE};
f716a1dd	85	} else {
1b1e14d3	86	$from = "./$from" if $from =~ /^\s/s;
71be2cbc	87	open(FROM, "< $from\0") or goto fail_open1;
71be2cbc	88	binmode FROM or die "($!,$^E)";
f716a1dd	89	$closefrom = 1;
1a04d035	90	}
1a04d035	91
71be2cbc	92	if ($to_a_handle) {
71be2cbc	93	TO = $to{FILEHANDLE};
1a04d035	94	} else {
1b1e14d3	95	$to = "./$to" if $to =~ /^\s/s;
71be2cbc	96	open(TO,"> $to\0") or goto fail_open2;
	97	binmode TO or die "($!,$^E)";
	98	$closeto = 1;
1a04d035	99	}
f716a1dd	100
	101	if (@_) {
	102	$size = shift(@_) + 0;
	103	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
	104	} else {
	105	$size = -s FROM;
	106	$size = 1024 if ($size < 512);
441496b2	107	$size = $Too_Big if ($size > $Too_Big);
f716a1dd	108	}
f716a1dd	109
71be2cbc	110	$! = 0;
	111	for (;;) {
	112	my ($r, $w, $t);
	113	defined($r = sysread(FROM, $buf, $size))
	114	or goto fail_inner;
	115	last unless $r;
	116	for ($w = 0; $w < $r; $w += $t) {
	117	$t = syswrite(TO, $buf, $r - $w, $w)
	118	or goto fail_inner;
f716a1dd	119	}
f716a1dd	120	}
71be2cbc	121
f716a1dd	122	close(TO) \|\| goto fail_open2 if $closeto;
f716a1dd	123	close(FROM) \|\| goto fail_open1 if $closefrom;
71be2cbc	124
48a5c399	125	# Use this idiom to avoid uninitialized value warning.
f716a1dd	126	return 1;
1a04d035	127
f716a1dd	128	# All of these contortions try to preserve error messages...
	129	fail_inner:
	130	if ($closeto) {
	131	$status = $!;
	132	$! = 0;
	133	close TO;
	134	$! = $status unless $!;
	135	}
	136	fail_open2:
	137	if ($closefrom) {
	138	$status = $!;
	139	$! = 0;
	140	close FROM;
	141	$! = $status unless $!;
	142	}
	143	fail_open1:
f716a1dd	144	return 0;
f716a1dd	145	}
9b957b78	146
441496b2	147	sub move {
71be2cbc	148	my($from,$to) = @_;
71be2cbc	149	my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
441496b2	150
71be2cbc	151	if (-d $to && ! -d $from) {
	152	$to = _catname($from, $to);
	153	}
	154
	155	($tosz1,$tomt1) = (stat($to))[7,9];
	156	$fromsz = -s $from;
e6434134	157	if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
	158	# will not rename with overwrite
	159	unlink $to;
	160	}
71be2cbc	161	return 1 if rename $from, $to;
	162
	163	($sts,$ossts) = ($! + 0, $^E + 0);
	164	# Did rename return an error even though it succeeded, because $to
	165	# is on a remote NFS file system, and NFS lost the server's ack?
	166	return 1 if defined($fromsz) && !-e $from && # $from disappeared
	167	(($tosz2,$tomt2) = (stat($to))[7,9]) && # $to's there
	168	($tosz1 != $tosz2 or $tomt1 != $tomt2) && # and changed
	169	$tosz2 == $fromsz; # it's all there
1a04d035	170
71be2cbc	171	($tosz1,$tomt1) = (stat($to))[7,9]; # just in case rename did something
71be2cbc	172	return 1 if ($copied = copy($from,$to)) && unlink($from);
1a04d035	173
71be2cbc	174	($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
	175	unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
	176	($!,$^E) = ($sts,$ossts);
	177	return 0;
441496b2	178	}
9b957b78	179
71be2cbc	180	*cp = \©
	181	*mv = \&move;
	182
9b957b78	183	# &syscopy is an XSUB under OS/2
1d84e8df	184	unless (defined &syscopy) {
	185	if ($^O eq 'VMS') {
	186	*syscopy = \&rmscopy;
	187	} elsif ($^O eq 'mpeix') {
	188	*syscopy = sub {
3f5ee302	189	return 0 unless @_ == 2;
1d84e8df	190	# Use the MPE cp program in order to
	191	# preserve MPE file attributes.
	192	return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	193	};
7509b657	194	} elsif ($^O eq 'MSWin32') {
	195	*syscopy = sub {
	196	return 0 unless @_ == 2;
	197	return Win32::CopyFile(@_, 1);
	198	};
1d84e8df	199	} else {
1a04d035	200	$Syscopy_is_copy = 1;
1d84e8df	201	*syscopy = \©
	202	}
	203	}
f716a1dd	204
	205	1;
	206
	207	__END__
a5f75d66	208
f716a1dd	209	=head1 NAME
	210
	211	File::Copy - Copy files or filehandles
	212
a5f75d66	213	=head1 SYNOPSIS
f716a1dd	214
	215	use File::Copy;
	216
	217	copy("file1","file2");
	218	copy("Copy.pm",\*STDOUT);'
441496b2	219	move("/dev1/fileA","/dev2/fileB");
f716a1dd	220
	221	use POSIX;
	222	use File::Copy cp;
	223
23f3aea0	224	$n = FileHandle->new("/a/file","r");
f716a1dd	225	cp($n,"x");'
	226
	227	=head1 DESCRIPTION
	228
441496b2	229	The File::Copy module provides two basic functions, C<copy> and
	230	C<move>, which are useful for getting the contents of a file from
	231	one place to another.
	232
	233	=over 4
	234
	235	=item *
	236
	237	The C<copy> function takes two
f716a1dd	238	parameters: a file to copy from and a file to copy to. Either
	239	argument may be a string, a FileHandle reference or a FileHandle
	240	glob. Obviously, if the first argument is a filehandle of some
	241	sort, it will be read from, and if it is a file I<name> it will
	242	be opened for reading. Likewise, the second argument will be
e6434134	243	written to (and created if need be).
71be2cbc	244
71be2cbc	245	B<Note that passing in
9b957b78	246	files as handles instead of names may lead to loss of information
9b957b78	247	on some operating systems; it is recommended that you use file
e6434134	248	names whenever possible.> Files are opened in binary mode where
8dcee03e	249	applicable. To get a consistent behaviour when copying from a
e6434134	250	filehandle to a file, use C<binmode> on the filehandle.
f716a1dd	251
	252	An optional third parameter can be used to specify the buffer
	253	size used for copying. This is the number of bytes from the
	254	first file, that wil be held in memory at any given time, before
	255	being written to the second file. The default buffer size depends
	256	upon the file, but will generally be the whole file (up to 2Mb), or
	257	1k for filehandles that do not reference files (eg. sockets).
	258
	259	You may use the syntax C<use File::Copy "cp"> to get at the
	260	"cp" alias for this function. The syntax is I<exactly> the same.
	261
441496b2	262	=item *
	263
	264	The C<move> function also takes two parameters: the current name
71be2cbc	265	and the intended name of the file to be moved. If the destination
	266	already exists and is a directory, and the source is not a
	267	directory, then the source file will be renamed into the directory
	268	specified by the destination.
	269
	270	If possible, move() will simply rename the file. Otherwise, it copies
	271	the file to the new location and deletes the original. If an error occurs
	272	during this copy-and-delete process, you may be left with a (possibly partial)
441496b2	273	copy of the file under the destination name.
	274
	275	You may use the "mv" alias for this function in the same way that
	276	you may use the "cp" alias for C<copy>.
	277
	278	=back
	279
9b957b78	280	File::Copy also provides the C<syscopy> routine, which copies the
	281	file specified in the first parameter to the file specified in the
	282	second parameter, preserving OS-specific attributes and file
	283	structure. For Unix systems, this is equivalent to the simple
	284	C<copy> routine. For VMS systems, this calls the C<rmscopy>
	285	routine (see below). For OS/2 systems, this calls the C<syscopy>
7509b657	286	XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.
9b957b78	287
7509b657	288	=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
9b957b78	289
71be2cbc	290	If both arguments to C<copy> are not file handles,
71be2cbc	291	then C<copy> will perform a "system copy" of
9b957b78	292	the input file to a new output file, in order to preserve file
9b957b78	293	attributes, indexed file structure, I<etc.> The buffer size
71be2cbc	294	parameter is ignored. If either argument to C<copy> is a
71be2cbc	295	handle to an opened file, then data is copied using Perl
9b957b78	296	operators, and no effort is made to preserve file attributes
	297	or record structure.
	298
55497cff	299	The system copy routine may also be called directly under VMS and OS/2
55497cff	300	as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
71be2cbc	301	is the routine that does the actual work for syscopy).
9b957b78	302
441496b2	303	=over 4
55497cff	304
9b957b78	305	=item rmscopy($from,$to[,$date_flag])
9b957b78	306
71be2cbc	307	The first and second arguments may be strings, typeglobs, typeglob
	308	references, or objects inheriting from IO::Handle;
	309	they are used in all cases to obtain the
9b957b78	310	I<filespec> of the input and output files, respectively. The
	311	name and type of the input file are used as defaults for the
	312	output file, if necessary.
	313
	314	A new version of the output file is always created, which
	315	inherits the structure and RMS attributes of the input file,
	316	except for owner and protections (and possibly timestamps;
	317	see below). All data from the input file is copied to the
	318	output file; if either of the first two parameters to C<rmscopy>
	319	is a file handle, its position is unchanged. (Note that this
	320	means a file handle pointing to the output file will be
	321	associated with an old version of that file after C<rmscopy>
	322	returns, not the newly created version.)
	323
	324	The third parameter is an integer flag, which tells C<rmscopy>
1fef88e7	325	how to handle timestamps. If it is E<lt> 0, none of the input file's
1fef88e7	326	timestamps are propagated to the output file. If it is E<gt> 0, then
9b957b78	327	it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
	328	timestamps other than the revision date are propagated; if bit 1
	329	is set, the revision date is propagated. If the third parameter
	330	to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
	331	if the name or type of the output file was explicitly specified,
	332	then no timestamps are propagated, but if they were taken implicitly
	333	from the input filespec, then all timestamps other than the
	334	revision date are propagated. If this parameter is not supplied,
	335	it defaults to 0.
	336
	337	Like C<copy>, C<rmscopy> returns 1 on success. If an error occurs,
	338	it sets C<$!>, deletes the output file, and returns 0.
	339
55497cff	340	=back
55497cff	341
f716a1dd	342	=head1 RETURN
f716a1dd	343
441496b2	344	All functions return 1 on success, 0 on failure.
441496b2	345	$! will be set if an error was encountered.
f716a1dd	346
	347	=head1 AUTHOR
	348
441496b2	349	File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
bd3fa61c	350	and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
f716a1dd	351
f716a1dd	352	=cut
441496b2	353