[p5sagit/p5-mst-13.2.git] / lib / File / Copy.pm

# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
# source code has been placed in the public domain by the author.
# Please be kind and preserve the documentation.
#
# Additions copyright 1996 by Charles Bailey.  Permission is granted
# to distribute the revised code under the same terms as Perl itself.

package File::Copy;

use 5.6.0;
use strict;
use warnings;
use Carp;
use File::Spec;
our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
sub copy;
sub syscopy;
sub cp;
sub mv;

# Note that this module implements only *part* of the API defined by
# the File/Copy.pm module of the File-Tools-2.0 package.  However, that
# package has not yet been updated to work with Perl 5.004, and so it
# would be a Bad Thing for the CPAN module to grab it and replace this
# module.  Therefore, we set this module's version higher than 2.0.
$VERSION = '2.04';

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(copy move);
@EXPORT_OK = qw(cp mv);

$Too_Big = 1024 * 1024 * 2;

sub _catname {
    my($from, $to) = @_;
    if (not defined &basename) {
	require File::Basename;
	import  File::Basename 'basename';
    }

    if ($^O eq 'MacOS') {
	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	$to = ':' . $to if $to !~ /:/;
    }

    return File::Spec->catfile($to, basename($from));
}

sub copy {
    croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
      unless(@_ == 2 || @_ == 3);

    my $from = shift;
    my $to = shift;

    my $from_a_handle = (ref($from)
			 ? (ref($from) eq 'GLOB'
			    || UNIVERSAL::isa($from, 'GLOB')
                            || UNIVERSAL::isa($from, 'IO::Handle'))
			 : (ref(\$from) eq 'GLOB'));
    my $to_a_handle =   (ref($to)
			 ? (ref($to) eq 'GLOB'
			    || UNIVERSAL::isa($to, 'GLOB')
                            || UNIVERSAL::isa($to, 'IO::Handle'))
			 : (ref(\$to) eq 'GLOB'));

    if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    if (defined &syscopy && !$Syscopy_is_copy
	&& !$to_a_handle
	&& !($from_a_handle && $^O eq 'os2' )	# OS/2 cannot handle handles
	&& !($from_a_handle && $^O eq 'mpeix')	# and neither can MPE/iX.
	&& !($from_a_handle && $^O eq 'MSWin32')
	&& !($from_a_handle && $^O eq 'MacOS')
	&& !($from_a_handle && $^O eq 'NetWare')
       )
    {
	return syscopy($from, $to);
    }

    my $closefrom = 0;
    my $closeto = 0;
    my ($size, $status, $r, $buf);
    local($\) = '';

    my $from_h;
    if ($from_a_handle) {
       $from_h = $from;
    } else {
	$from = _protect($from) if $from =~ /^\s/s;
       $from_h = \do { local *FH };
       open($from_h, "< $from\0") or goto fail_open1;
       binmode $from_h or die "($!,$^E)";
	$closefrom = 1;
    }

    my $to_h;
    if ($to_a_handle) {
       $to_h = $to;
    } else {
	$to = _protect($to) if $to =~ /^\s/s;
       $to_h = \do { local *FH };
       open($to_h,"> $to\0") or goto fail_open2;
       binmode $to_h or die "($!,$^E)";
	$closeto = 1;
    }

    if (@_) {
	$size = shift(@_) + 0;
	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
    } else {
       no warnings 'uninitialized';
       $size = -s $from_h;
	$size = 1024 if ($size < 512);
	$size = $Too_Big if ($size > $Too_Big);
    }

    $! = 0;
    for (;;) {
	my ($r, $w, $t);
       defined($r = sysread($from_h, $buf, $size))
	    or goto fail_inner;
	last unless $r;
	for ($w = 0; $w < $r; $w += $t) {
           $t = syswrite($to_h, $buf, $r - $w, $w)
		or goto fail_inner;
	}
    }

    close($to_h) || goto fail_open2 if $closeto;
    close($from_h) || goto fail_open1 if $closefrom;

    # Use this idiom to avoid uninitialized value warning.
    return 1;

    # All of these contortions try to preserve error messages...
  fail_inner:
    if ($closeto) {
	$status = $!;
	$! = 0;
       close $to_h;
	$! = $status unless $!;
    }
  fail_open2:
    if ($closefrom) {
	$status = $!;
	$! = 0;
       close $from_h;
	$! = $status unless $!;
    }
  fail_open1:
    return 0;
}

sub move {
    my($from,$to) = @_;
    my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);

    if (-d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    ($tosz1,$tomt1) = (stat($to))[7,9];
    $fromsz = -s $from;
    if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
      # will not rename with overwrite
      unlink $to;
    }
    return 1 if rename $from, $to;

    ($sts,$ossts) = ($! + 0, $^E + 0);
    # Did rename return an error even though it succeeded, because $to
    # is on a remote NFS file system, and NFS lost the server's ack?
    return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
                (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
                ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
                $tosz2 == $fromsz;                         # it's all there

    ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
    return 1 if ($copied = copy($from,$to)) && unlink($from);

    ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
    unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
    ($!,$^E) = ($sts,$ossts);
    return 0;
}

*cp = \&copy;
*mv = \&move;


if ($^O eq 'MacOS') {
    *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
} else {
    *_protect = sub { "./$_[0]" };
}

# &syscopy is an XSUB under OS/2
unless (defined &syscopy) {
    if ($^O eq 'VMS') {
	*syscopy = \&rmscopy;
    } elsif ($^O eq 'mpeix') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    # Use the MPE cp program in order to
	    # preserve MPE file attributes.
	    return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	};
    } elsif ($^O eq 'MSWin32') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    return Win32::CopyFile(@_, 1);
	};
    } elsif ($^O eq 'MacOS') {
	require Mac::MoreFiles;
	*syscopy = sub {
	    my($from, $to) = @_;
	    my($dir, $toname);

	    return 0 unless -e $from;

	    if ($to =~ /(.*:)([^:]+):?$/) {
		($dir, $toname) = ($1, $2);
	    } else {
		($dir, $toname) = (":", $to);
	    }

	    unlink($to);
	    Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	};
    } else {
	$Syscopy_is_copy = 1;
	*syscopy = \&copy;
    }
}

1;

__END__

=head1 NAME

File::Copy - Copy files or filehandles

=head1 SYNOPSIS

  	use File::Copy;

	copy("file1","file2");
  	copy("Copy.pm",\*STDOUT);'
	move("/dev1/fileA","/dev2/fileB");

  	use POSIX;
	use File::Copy cp;

	$n = FileHandle->new("/a/file","r");
	cp($n,"x");'

=head1 DESCRIPTION

The File::Copy module provides two basic functions, C<copy> and
C<move>, which are useful for getting the contents of a file from
one place to another.

=over 4

=item *

The C<copy> function takes two
parameters: a file to copy from and a file to copy to. Either
argument may be a string, a FileHandle reference or a FileHandle
glob. Obviously, if the first argument is a filehandle of some
sort, it will be read from, and if it is a file I<name> it will
be opened for reading. Likewise, the second argument will be
written to (and created if need be).

B<Note that passing in
files as handles instead of names may lead to loss of information
on some operating systems; it is recommended that you use file
names whenever possible.>  Files are opened in binary mode where
applicable.  To get a consistent behaviour when copying from a
filehandle to a file, use C<binmode> on the filehandle.

An optional third parameter can be used to specify the buffer
size used for copying. This is the number of bytes from the
first file, that wil be held in memory at any given time, before
being written to the second file. The default buffer size depends
upon the file, but will generally be the whole file (up to 2Mb), or
1k for filehandles that do not reference files (eg. sockets).

You may use the syntax C<use File::Copy "cp"> to get at the
"cp" alias for this function. The syntax is I<exactly> the same.

=item *

The C<move> function also takes two parameters: the current name
and the intended name of the file to be moved.  If the destination
already exists and is a directory, and the source is not a
directory, then the source file will be renamed into the directory
specified by the destination.

If possible, move() will simply rename the file.  Otherwise, it copies
the file to the new location and deletes the original.  If an error occurs
during this copy-and-delete process, you may be left with a (possibly partial)
copy of the file under the destination name.

You may use the "mv" alias for this function in the same way that
you may use the "cp" alias for C<copy>.

=back

File::Copy also provides the C<syscopy> routine, which copies the
file specified in the first parameter to the file specified in the
second parameter, preserving OS-specific attributes and file
structure.  For Unix systems, this is equivalent to the simple
C<copy> routine.  For VMS systems, this calls the C<rmscopy>
routine (see below).  For OS/2 systems, this calls the C<syscopy>
XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.

=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)

If both arguments to C<copy> are not file handles,
then C<copy> will perform a "system copy" of
the input file to a new output file, in order to preserve file
attributes, indexed file structure, I<etc.>  The buffer size
parameter is ignored.  If either argument to C<copy> is a
handle to an opened file, then data is copied using Perl
operators, and no effort is made to preserve file attributes
or record structure.

The system copy routine may also be called directly under VMS and OS/2
as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
is the routine that does the actual work for syscopy).

=over 4

=item rmscopy($from,$to[,$date_flag])

The first and second arguments may be strings, typeglobs, typeglob
references, or objects inheriting from IO::Handle;
they are used in all cases to obtain the
I<filespec> of the input and output files, respectively.  The
name and type of the input file are used as defaults for the
output file, if necessary.

A new version of the output file is always created, which
inherits the structure and RMS attributes of the input file,
except for owner and protections (and possibly timestamps;
see below).  All data from the input file is copied to the
output file; if either of the first two parameters to C<rmscopy>
is a file handle, its position is unchanged.  (Note that this
means a file handle pointing to the output file will be
associated with an old version of that file after C<rmscopy>
returns, not the newly created version.)

The third parameter is an integer flag, which tells C<rmscopy>
how to handle timestamps.  If it is E<lt> 0, none of the input file's
timestamps are propagated to the output file.  If it is E<gt> 0, then
it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
timestamps other than the revision date are propagated; if bit 1
is set, the revision date is propagated.  If the third parameter
to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
if the name or type of the output file was explicitly specified,
then no timestamps are propagated, but if they were taken implicitly
from the input filespec, then all timestamps other than the
revision date are propagated.  If this parameter is not supplied,
it defaults to 0.

Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
it sets C<$!>, deletes the output file, and returns 0.

=back

=head1 RETURN

All functions return 1 on success, 0 on failure.
$! will be set if an error was encountered.

=head1 NOTES

=over 4

=item *

On Mac OS (Classic), the path separator is ':', not '/', and the 
current directory is denoted as ':', not '.'. You should be careful 
about specifying relative pathnames. While a full path always begins 
with a volume name, a relative pathname should always begin with a 
':'.  If specifying a volume name only, a trailing ':' is required.

E.g.

  copy("file1", "tmp");        # creates the file 'tmp' in the current directory
  copy("file1", ":tmp:");      # creates :tmp:file1
  copy("file1", ":tmp");       # same as above
  copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do   
                               # that, since it may cause confusion, see example #1)
  copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
  copy("file1", ":tmp:file1"); # ok, partial path
  copy("file1", "DataHD:");    # creates DataHD:file1
  
  move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one 
                                             # volume to another

=back

=head1 AUTHOR

File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.

=cut
Commit	Line	Data
f716a1dd	1	# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
	2	# source code has been placed in the public domain by the author.
	3	# Please be kind and preserve the documentation.
	4	#
71be2cbc	5	# Additions copyright 1996 by Charles Bailey. Permission is granted
71be2cbc	6	# to distribute the revised code under the same terms as Perl itself.
f716a1dd	7
	8	package File::Copy;
	9
b395063c	10	use 5.6.0;
71be2cbc	11	use strict;
b395063c	12	use warnings;
f716a1dd	13	use Carp;
6c254d95	14	use File::Spec;
17f410f9	15	our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
	16	sub copy;
	17	sub syscopy;
	18	sub cp;
	19	sub mv;
71be2cbc	20
	21	# Note that this module implements only part of the API defined by
	22	# the File/Copy.pm module of the File-Tools-2.0 package. However, that
	23	# package has not yet been updated to work with Perl 5.004, and so it
	24	# would be a Bad Thing for the CPAN module to grab it and replace this
	25	# module. Therefore, we set this module's version higher than 2.0.
6c254d95	26	$VERSION = '2.04';
f716a1dd	27
71be2cbc	28	require Exporter;
	29	@ISA = qw(Exporter);
	30	@EXPORT = qw(copy move);
	31	@EXPORT_OK = qw(cp mv);
f716a1dd	32
441496b2	33	$Too_Big = 1024 * 1024 * 2;
f716a1dd	34
6c254d95	35	sub _catname {
71be2cbc	36	my($from, $to) = @_;
	37	if (not defined &basename) {
	38	require File::Basename;
	39	import File::Basename 'basename';
	40	}
6c254d95	41
	42	if ($^O eq 'MacOS') {
	43	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	44	$to = ':' . $to if $to !~ /:/;
	45	}
	46
	47	return File::Spec->catfile($to, basename($from));
f716a1dd	48	}
	49
	50	sub copy {
71be2cbc	51	croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
f716a1dd	52	unless(@_ == 2 \|\| @_ == 3);
	53
	54	my $from = shift;
	55	my $to = shift;
71be2cbc	56
	57	my $from_a_handle = (ref($from)
	58	? (ref($from) eq 'GLOB'
d704f39a	59	\|\| UNIVERSAL::isa($from, 'GLOB')
d704f39a	60	\|\| UNIVERSAL::isa($from, 'IO::Handle'))
71be2cbc	61	: (ref(\$from) eq 'GLOB'));
	62	my $to_a_handle = (ref($to)
	63	? (ref($to) eq 'GLOB'
d704f39a	64	\|\| UNIVERSAL::isa($to, 'GLOB')
d704f39a	65	\|\| UNIVERSAL::isa($to, 'IO::Handle'))
71be2cbc	66	: (ref(\$to) eq 'GLOB'));
	67
	68	if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	69	$to = _catname($from, $to);
	70	}
	71
1a04d035	72	if (defined &syscopy && !$Syscopy_is_copy
e6434134	73	&& !$to_a_handle
1d84e8df	74	&& !($from_a_handle && $^O eq 'os2' ) # OS/2 cannot handle handles
1d84e8df	75	&& !($from_a_handle && $^O eq 'mpeix') # and neither can MPE/iX.
7509b657	76	&& !($from_a_handle && $^O eq 'MSWin32')
fa648be5	77	&& !($from_a_handle && $^O eq 'MacOS')
2986a63f	78	&& !($from_a_handle && $^O eq 'NetWare')
1a04d035	79	)
71be2cbc	80	{
	81	return syscopy($from, $to);
	82	}
	83
	84	my $closefrom = 0;
	85	my $closeto = 0;
f716a1dd	86	my ($size, $status, $r, $buf);
48a5c399	87	local($\) = '';
f716a1dd	88
23ba2776	89	my $from_h;
71be2cbc	90	if ($from_a_handle) {
23ba2776	91	$from_h = $from;
f716a1dd	92	} else {
fa648be5	93	$from = _protect($from) if $from =~ /^\s/s;
23ba2776	94	$from_h = \do { local *FH };
	95	open($from_h, "< $from\0") or goto fail_open1;
	96	binmode $from_h or die "($!,$^E)";
f716a1dd	97	$closefrom = 1;
1a04d035	98	}
1a04d035	99
23ba2776	100	my $to_h;
71be2cbc	101	if ($to_a_handle) {
23ba2776	102	$to_h = $to;
1a04d035	103	} else {
fa648be5	104	$to = _protect($to) if $to =~ /^\s/s;
23ba2776	105	$to_h = \do { local *FH };
	106	open($to_h,"> $to\0") or goto fail_open2;
	107	binmode $to_h or die "($!,$^E)";
71be2cbc	108	$closeto = 1;
1a04d035	109	}
f716a1dd	110
	111	if (@_) {
	112	$size = shift(@_) + 0;
	113	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
	114	} else {
23ba2776	115	no warnings 'uninitialized';
23ba2776	116	$size = -s $from_h;
f716a1dd	117	$size = 1024 if ($size < 512);
441496b2	118	$size = $Too_Big if ($size > $Too_Big);
f716a1dd	119	}
f716a1dd	120
71be2cbc	121	$! = 0;
	122	for (;;) {
	123	my ($r, $w, $t);
23ba2776	124	defined($r = sysread($from_h, $buf, $size))
71be2cbc	125	or goto fail_inner;
	126	last unless $r;
	127	for ($w = 0; $w < $r; $w += $t) {
23ba2776	128	$t = syswrite($to_h, $buf, $r - $w, $w)
71be2cbc	129	or goto fail_inner;
f716a1dd	130	}
f716a1dd	131	}
71be2cbc	132
23ba2776	133	close($to_h) \|\| goto fail_open2 if $closeto;
23ba2776	134	close($from_h) \|\| goto fail_open1 if $closefrom;
71be2cbc	135
48a5c399	136	# Use this idiom to avoid uninitialized value warning.
f716a1dd	137	return 1;
1a04d035	138
f716a1dd	139	# All of these contortions try to preserve error messages...
	140	fail_inner:
	141	if ($closeto) {
	142	$status = $!;
	143	$! = 0;
23ba2776	144	close $to_h;
f716a1dd	145	$! = $status unless $!;
	146	}
	147	fail_open2:
	148	if ($closefrom) {
	149	$status = $!;
	150	$! = 0;
23ba2776	151	close $from_h;
f716a1dd	152	$! = $status unless $!;
	153	}
	154	fail_open1:
f716a1dd	155	return 0;
f716a1dd	156	}
9b957b78	157
441496b2	158	sub move {
71be2cbc	159	my($from,$to) = @_;
71be2cbc	160	my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
441496b2	161
71be2cbc	162	if (-d $to && ! -d $from) {
	163	$to = _catname($from, $to);
	164	}
	165
	166	($tosz1,$tomt1) = (stat($to))[7,9];
	167	$fromsz = -s $from;
e6434134	168	if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
	169	# will not rename with overwrite
	170	unlink $to;
	171	}
71be2cbc	172	return 1 if rename $from, $to;
	173
	174	($sts,$ossts) = ($! + 0, $^E + 0);
	175	# Did rename return an error even though it succeeded, because $to
	176	# is on a remote NFS file system, and NFS lost the server's ack?
	177	return 1 if defined($fromsz) && !-e $from && # $from disappeared
	178	(($tosz2,$tomt2) = (stat($to))[7,9]) && # $to's there
	179	($tosz1 != $tosz2 or $tomt1 != $tomt2) && # and changed
	180	$tosz2 == $fromsz; # it's all there
1a04d035	181
71be2cbc	182	($tosz1,$tomt1) = (stat($to))[7,9]; # just in case rename did something
71be2cbc	183	return 1 if ($copied = copy($from,$to)) && unlink($from);
1a04d035	184
71be2cbc	185	($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
	186	unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
	187	($!,$^E) = ($sts,$ossts);
	188	return 0;
441496b2	189	}
9b957b78	190
71be2cbc	191	*cp = \©
	192	*mv = \&move;
	193
fa648be5	194
	195	if ($^O eq 'MacOS') {
	196	*_protect = sub { MacPerl::MakeFSSpec($_[0]) };
	197	} else {
	198	*_protect = sub { "./$_[0]" };
	199	}
	200
9b957b78	201	# &syscopy is an XSUB under OS/2
1d84e8df	202	unless (defined &syscopy) {
	203	if ($^O eq 'VMS') {
	204	*syscopy = \&rmscopy;
	205	} elsif ($^O eq 'mpeix') {
	206	*syscopy = sub {
3f5ee302	207	return 0 unless @_ == 2;
1d84e8df	208	# Use the MPE cp program in order to
	209	# preserve MPE file attributes.
	210	return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	211	};
7509b657	212	} elsif ($^O eq 'MSWin32') {
	213	*syscopy = sub {
	214	return 0 unless @_ == 2;
	215	return Win32::CopyFile(@_, 1);
	216	};
fa648be5	217	} elsif ($^O eq 'MacOS') {
	218	require Mac::MoreFiles;
	219	*syscopy = sub {
	220	my($from, $to) = @_;
	221	my($dir, $toname);
	222
	223	return 0 unless -e $from;
	224
	225	if ($to =~ /(.*:)([^:]+):?$/) {
	226	($dir, $toname) = ($1, $2);
	227	} else {
	228	($dir, $toname) = (":", $to);
	229	}
	230
	231	unlink($to);
	232	Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	233	};
1d84e8df	234	} else {
1a04d035	235	$Syscopy_is_copy = 1;
1d84e8df	236	*syscopy = \©
	237	}
	238	}
f716a1dd	239
	240	1;
	241
	242	__END__
a5f75d66	243
f716a1dd	244	=head1 NAME
	245
	246	File::Copy - Copy files or filehandles
	247
a5f75d66	248	=head1 SYNOPSIS
f716a1dd	249
	250	use File::Copy;
	251
	252	copy("file1","file2");
	253	copy("Copy.pm",\*STDOUT);'
441496b2	254	move("/dev1/fileA","/dev2/fileB");
f716a1dd	255
	256	use POSIX;
	257	use File::Copy cp;
	258
23f3aea0	259	$n = FileHandle->new("/a/file","r");
f716a1dd	260	cp($n,"x");'
	261
	262	=head1 DESCRIPTION
	263
441496b2	264	The File::Copy module provides two basic functions, C<copy> and
	265	C<move>, which are useful for getting the contents of a file from
	266	one place to another.
	267
	268	=over 4
	269
	270	=item *
	271
	272	The C<copy> function takes two
f716a1dd	273	parameters: a file to copy from and a file to copy to. Either
	274	argument may be a string, a FileHandle reference or a FileHandle
	275	glob. Obviously, if the first argument is a filehandle of some
	276	sort, it will be read from, and if it is a file I<name> it will
	277	be opened for reading. Likewise, the second argument will be
e6434134	278	written to (and created if need be).
71be2cbc	279
71be2cbc	280	B<Note that passing in
9b957b78	281	files as handles instead of names may lead to loss of information
9b957b78	282	on some operating systems; it is recommended that you use file
e6434134	283	names whenever possible.> Files are opened in binary mode where
8dcee03e	284	applicable. To get a consistent behaviour when copying from a
e6434134	285	filehandle to a file, use C<binmode> on the filehandle.
f716a1dd	286
	287	An optional third parameter can be used to specify the buffer
	288	size used for copying. This is the number of bytes from the
	289	first file, that wil be held in memory at any given time, before
	290	being written to the second file. The default buffer size depends
	291	upon the file, but will generally be the whole file (up to 2Mb), or
	292	1k for filehandles that do not reference files (eg. sockets).
	293
	294	You may use the syntax C<use File::Copy "cp"> to get at the
	295	"cp" alias for this function. The syntax is I<exactly> the same.
	296
441496b2	297	=item *
	298
	299	The C<move> function also takes two parameters: the current name
71be2cbc	300	and the intended name of the file to be moved. If the destination
	301	already exists and is a directory, and the source is not a
	302	directory, then the source file will be renamed into the directory
	303	specified by the destination.
	304
	305	If possible, move() will simply rename the file. Otherwise, it copies
	306	the file to the new location and deletes the original. If an error occurs
	307	during this copy-and-delete process, you may be left with a (possibly partial)
441496b2	308	copy of the file under the destination name.
	309
	310	You may use the "mv" alias for this function in the same way that
	311	you may use the "cp" alias for C<copy>.
	312
	313	=back
	314
9b957b78	315	File::Copy also provides the C<syscopy> routine, which copies the
	316	file specified in the first parameter to the file specified in the
	317	second parameter, preserving OS-specific attributes and file
	318	structure. For Unix systems, this is equivalent to the simple
	319	C<copy> routine. For VMS systems, this calls the C<rmscopy>
	320	routine (see below). For OS/2 systems, this calls the C<syscopy>
7509b657	321	XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.
9b957b78	322
7509b657	323	=head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
9b957b78	324
71be2cbc	325	If both arguments to C<copy> are not file handles,
71be2cbc	326	then C<copy> will perform a "system copy" of
9b957b78	327	the input file to a new output file, in order to preserve file
9b957b78	328	attributes, indexed file structure, I<etc.> The buffer size
71be2cbc	329	parameter is ignored. If either argument to C<copy> is a
71be2cbc	330	handle to an opened file, then data is copied using Perl
9b957b78	331	operators, and no effort is made to preserve file attributes
	332	or record structure.
	333
55497cff	334	The system copy routine may also be called directly under VMS and OS/2
55497cff	335	as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
71be2cbc	336	is the routine that does the actual work for syscopy).
9b957b78	337
441496b2	338	=over 4
55497cff	339
9b957b78	340	=item rmscopy($from,$to[,$date_flag])
9b957b78	341
71be2cbc	342	The first and second arguments may be strings, typeglobs, typeglob
	343	references, or objects inheriting from IO::Handle;
	344	they are used in all cases to obtain the
9b957b78	345	I<filespec> of the input and output files, respectively. The
	346	name and type of the input file are used as defaults for the
	347	output file, if necessary.
	348
	349	A new version of the output file is always created, which
	350	inherits the structure and RMS attributes of the input file,
	351	except for owner and protections (and possibly timestamps;
	352	see below). All data from the input file is copied to the
	353	output file; if either of the first two parameters to C<rmscopy>
	354	is a file handle, its position is unchanged. (Note that this
	355	means a file handle pointing to the output file will be
	356	associated with an old version of that file after C<rmscopy>
	357	returns, not the newly created version.)
	358
	359	The third parameter is an integer flag, which tells C<rmscopy>
1fef88e7	360	how to handle timestamps. If it is E<lt> 0, none of the input file's
1fef88e7	361	timestamps are propagated to the output file. If it is E<gt> 0, then
9b957b78	362	it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
	363	timestamps other than the revision date are propagated; if bit 1
	364	is set, the revision date is propagated. If the third parameter
	365	to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
	366	if the name or type of the output file was explicitly specified,
	367	then no timestamps are propagated, but if they were taken implicitly
	368	from the input filespec, then all timestamps other than the
	369	revision date are propagated. If this parameter is not supplied,
	370	it defaults to 0.
	371
	372	Like C<copy>, C<rmscopy> returns 1 on success. If an error occurs,
	373	it sets C<$!>, deletes the output file, and returns 0.
	374
55497cff	375	=back
55497cff	376
f716a1dd	377	=head1 RETURN
f716a1dd	378
441496b2	379	All functions return 1 on success, 0 on failure.
441496b2	380	$! will be set if an error was encountered.
f716a1dd	381
6c254d95	382	=head1 NOTES
	383
	384	=over 4
	385
	386	=item *
	387
	388	On Mac OS (Classic), the path separator is ':', not '/', and the
	389	current directory is denoted as ':', not '.'. You should be careful
	390	about specifying relative pathnames. While a full path always begins
	391	with a volume name, a relative pathname should always begin with a
	392	':'. If specifying a volume name only, a trailing ':' is required.
	393
	394	E.g.
	395
	396	copy("file1", "tmp"); # creates the file 'tmp' in the current directory
	397	copy("file1", ":tmp:"); # creates :tmp:file1
	398	copy("file1", ":tmp"); # same as above
	399	copy("file1", "tmp"); # same as above, if 'tmp' is a directory (but don't do
	400	# that, since it may cause confusion, see example #1)
	401	copy("file1", "tmp:file1"); # error, since 'tmp:' is not a volume
	402	copy("file1", ":tmp:file1"); # ok, partial path
	403	copy("file1", "DataHD:"); # creates DataHD:file1
	404
	405	move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
	406	# volume to another
	407
	408	=back
	409
f716a1dd	410	=head1 AUTHOR
f716a1dd	411
441496b2	412	File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
bd3fa61c	413	and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
f716a1dd	414
f716a1dd	415	=cut
441496b2	416