[p5sagit/p5-mst-13.2.git] / lib / File / Copy.pm

# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
# source code has been placed in the public domain by the author.
# Please be kind and preserve the documentation.
#
# Additions copyright 1996 by Charles Bailey.  Permission is granted
# to distribute the revised code under the same terms as Perl itself.

package File::Copy;

use 5.006;
use strict;
use warnings;
use File::Spec;
use Config;
our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
sub copy;
sub syscopy;
sub cp;
sub mv;

# Note that this module implements only *part* of the API defined by
# the File/Copy.pm module of the File-Tools-2.0 package.  However, that
# package has not yet been updated to work with Perl 5.004, and so it
# would be a Bad Thing for the CPAN module to grab it and replace this
# module.  Therefore, we set this module's version higher than 2.0.
$VERSION = '2.09';

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(copy move);
@EXPORT_OK = qw(cp mv);

$Too_Big = 1024 * 1024 * 2;

sub croak {
    require Carp;
    goto &Carp::croak;
}

sub carp {
    require Carp;
    goto &Carp::carp;
}

my $macfiles;
if ($^O eq 'MacOS') {
	$macfiles = eval { require Mac::MoreFiles };
	warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
		if $@ && $^W;
}

sub _catname {
    my($from, $to) = @_;
    if (not defined &basename) {
	require File::Basename;
	import  File::Basename 'basename';
    }

    if ($^O eq 'MacOS') {
	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	$to = ':' . $to if $to !~ /:/;
    }

    return File::Spec->catfile($to, basename($from));
}

sub copy {
    croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
      unless(@_ == 2 || @_ == 3);

    my $from = shift;
    my $to = shift;

    my $from_a_handle = (ref($from)
			 ? (ref($from) eq 'GLOB'
			    || UNIVERSAL::isa($from, 'GLOB')
                            || UNIVERSAL::isa($from, 'IO::Handle'))
			 : (ref(\$from) eq 'GLOB'));
    my $to_a_handle =   (ref($to)
			 ? (ref($to) eq 'GLOB'
			    || UNIVERSAL::isa($to, 'GLOB')
                            || UNIVERSAL::isa($to, 'IO::Handle'))
			 : (ref(\$to) eq 'GLOB'));

    if ($from eq $to) { # works for references, too
	carp("'$from' and '$to' are identical (not copied)");
        # The "copy" was a success as the source and destination contain
        # the same data.
        return 1;
    }

    if ((($Config{d_symlink} && $Config{d_readlink}) || $Config{d_link}) &&
	!($^O eq 'MSWin32' || $^O eq 'os2' || $^O eq 'vms')) {
	my @fs = stat($from);
	if (@fs) {
	    my @ts = stat($to);
	    if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
		carp("'$from' and '$to' are identical (not copied)");
                return 0;
	    }
	}
    }

    if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    if (defined &syscopy && !$Syscopy_is_copy
	&& !$to_a_handle
	&& !($from_a_handle && $^O eq 'os2' )	# OS/2 cannot handle handles
	&& !($from_a_handle && $^O eq 'mpeix')	# and neither can MPE/iX.
	&& !($from_a_handle && $^O eq 'MSWin32')
	&& !($from_a_handle && $^O eq 'MacOS')
	&& !($from_a_handle && $^O eq 'NetWare')
       )
    {
	return syscopy($from, $to);
    }

    my $closefrom = 0;
    my $closeto = 0;
    my ($size, $status, $r, $buf);
    local($\) = '';

    my $from_h;
    if ($from_a_handle) {
       $from_h = $from;
    } else {
	$from = _protect($from) if $from =~ /^\s/s;
       $from_h = \do { local *FH };
       open($from_h, "< $from\0") or goto fail_open1;
       binmode $from_h or die "($!,$^E)";
	$closefrom = 1;
    }

    my $to_h;
    if ($to_a_handle) {
       $to_h = $to;
    } else {
	$to = _protect($to) if $to =~ /^\s/s;
       $to_h = \do { local *FH };
       open($to_h,"> $to\0") or goto fail_open2;
       binmode $to_h or die "($!,$^E)";
	$closeto = 1;
    }

    if (@_) {
	$size = shift(@_) + 0;
	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
    } else {
	$size = tied(*$from_h) ? 0 : -s $from_h || 0;
	$size = 1024 if ($size < 512);
	$size = $Too_Big if ($size > $Too_Big);
    }

    $! = 0;
    for (;;) {
	my ($r, $w, $t);
       defined($r = sysread($from_h, $buf, $size))
	    or goto fail_inner;
	last unless $r;
	for ($w = 0; $w < $r; $w += $t) {
           $t = syswrite($to_h, $buf, $r - $w, $w)
		or goto fail_inner;
	}
    }

    close($to_h) || goto fail_open2 if $closeto;
    close($from_h) || goto fail_open1 if $closefrom;

    # Use this idiom to avoid uninitialized value warning.
    return 1;

    # All of these contortions try to preserve error messages...
  fail_inner:
    if ($closeto) {
	$status = $!;
	$! = 0;
       close $to_h;
	$! = $status unless $!;
    }
  fail_open2:
    if ($closefrom) {
	$status = $!;
	$! = 0;
       close $from_h;
	$! = $status unless $!;
    }
  fail_open1:
    return 0;
}

sub move {
    croak("Usage: move(FROM, TO) ") unless @_ == 2;

    my($from,$to) = @_;

    my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);

    if (-d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    ($tosz1,$tomt1) = (stat($to))[7,9];
    $fromsz = -s $from;
    if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
      # will not rename with overwrite
      unlink $to;
    }
    return 1 if rename $from, $to;

    # Did rename return an error even though it succeeded, because $to
    # is on a remote NFS file system, and NFS lost the server's ack?
    return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
                (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
                ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
                $tosz2 == $fromsz;                         # it's all there

    ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something

    {
        local $@;
        eval {
            local $SIG{__DIE__};
            copy($from,$to) or die;
            my($atime, $mtime) = (stat($from))[8,9];
            utime($atime, $mtime, $to);
            unlink($from)   or die;
        };
        return 1 unless $@;
    }
    ($sts,$ossts) = ($! + 0, $^E + 0);

    ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
    unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
    ($!,$^E) = ($sts,$ossts);
    return 0;
}

*cp = \&copy;
*mv = \&move;


if ($^O eq 'MacOS') {
    *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
} else {
    *_protect = sub { "./$_[0]" };
}

# &syscopy is an XSUB under OS/2
unless (defined &syscopy) {
    if ($^O eq 'VMS') {
	*syscopy = \&rmscopy;
    } elsif ($^O eq 'mpeix') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    # Use the MPE cp program in order to
	    # preserve MPE file attributes.
	    return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	};
    } elsif ($^O eq 'MSWin32') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    return Win32::CopyFile(@_, 1);
	};
    } elsif ($macfiles) {
	*syscopy = sub {
	    my($from, $to) = @_;
	    my($dir, $toname);

	    return 0 unless -e $from;

	    if ($to =~ /(.*:)([^:]+):?$/) {
		($dir, $toname) = ($1, $2);
	    } else {
		($dir, $toname) = (":", $to);
	    }

	    unlink($to);
	    Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	};
    } else {
	$Syscopy_is_copy = 1;
	*syscopy = \&copy;
    }
}

1;

__END__

=head1 NAME

File::Copy - Copy files or filehandles

=head1 SYNOPSIS

	use File::Copy;

	copy("file1","file2") or die "Copy failed: $!";
	copy("Copy.pm",\*STDOUT);
	move("/dev1/fileA","/dev2/fileB");

	use File::Copy "cp";

	$n = FileHandle->new("/a/file","r");
	cp($n,"x");

=head1 DESCRIPTION

The File::Copy module provides two basic functions, C<copy> and
C<move>, which are useful for getting the contents of a file from
one place to another.

=over 4

=item copy
X<copy> X<cp>

The C<copy> function takes two
parameters: a file to copy from and a file to copy to. Either
argument may be a string, a FileHandle reference or a FileHandle
glob. Obviously, if the first argument is a filehandle of some
sort, it will be read from, and if it is a file I<name> it will
be opened for reading. Likewise, the second argument will be
written to (and created if need be).  Trying to copy a file on top
of itself is a fatal error.

B<Note that passing in
files as handles instead of names may lead to loss of information
on some operating systems; it is recommended that you use file
names whenever possible.>  Files are opened in binary mode where
applicable.  To get a consistent behaviour when copying from a
filehandle to a file, use C<binmode> on the filehandle.

An optional third parameter can be used to specify the buffer
size used for copying. This is the number of bytes from the
first file, that wil be held in memory at any given time, before
being written to the second file. The default buffer size depends
upon the file, but will generally be the whole file (up to 2Mb), or
1k for filehandles that do not reference files (eg. sockets).

You may use the syntax C<use File::Copy "cp"> to get at the
"cp" alias for this function. The syntax is I<exactly> the same.

=item move
X<move> X<mv> X<rename>

The C<move> function also takes two parameters: the current name
and the intended name of the file to be moved.  If the destination
already exists and is a directory, and the source is not a
directory, then the source file will be renamed into the directory
specified by the destination.

If possible, move() will simply rename the file.  Otherwise, it copies
the file to the new location and deletes the original.  If an error occurs
during this copy-and-delete process, you may be left with a (possibly partial)
copy of the file under the destination name.

You may use the "mv" alias for this function in the same way that
you may use the "cp" alias for C<copy>.

=item syscopy
X<syscopy>

File::Copy also provides the C<syscopy> routine, which copies the
file specified in the first parameter to the file specified in the
second parameter, preserving OS-specific attributes and file
structure.  For Unix systems, this is equivalent to the simple
C<copy> routine, which doesn't preserve OS-specific attributes.  For
VMS systems, this calls the C<rmscopy> routine (see below).  For OS/2
systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
this calls C<Win32::CopyFile>.

On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
if available.

B<Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)>

If both arguments to C<copy> are not file handles,
then C<copy> will perform a "system copy" of
the input file to a new output file, in order to preserve file
attributes, indexed file structure, I<etc.>  The buffer size
parameter is ignored.  If either argument to C<copy> is a
handle to an opened file, then data is copied using Perl
operators, and no effort is made to preserve file attributes
or record structure.

The system copy routine may also be called directly under VMS and OS/2
as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
is the routine that does the actual work for syscopy).

=item rmscopy($from,$to[,$date_flag])
X<rmscopy>

The first and second arguments may be strings, typeglobs, typeglob
references, or objects inheriting from IO::Handle;
they are used in all cases to obtain the
I<filespec> of the input and output files, respectively.  The
name and type of the input file are used as defaults for the
output file, if necessary.

A new version of the output file is always created, which
inherits the structure and RMS attributes of the input file,
except for owner and protections (and possibly timestamps;
see below).  All data from the input file is copied to the
output file; if either of the first two parameters to C<rmscopy>
is a file handle, its position is unchanged.  (Note that this
means a file handle pointing to the output file will be
associated with an old version of that file after C<rmscopy>
returns, not the newly created version.)

The third parameter is an integer flag, which tells C<rmscopy>
how to handle timestamps.  If it is E<lt> 0, none of the input file's
timestamps are propagated to the output file.  If it is E<gt> 0, then
it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
timestamps other than the revision date are propagated; if bit 1
is set, the revision date is propagated.  If the third parameter
to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
if the name or type of the output file was explicitly specified,
then no timestamps are propagated, but if they were taken implicitly
from the input filespec, then all timestamps other than the
revision date are propagated.  If this parameter is not supplied,
it defaults to 0.

Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
it sets C<$!>, deletes the output file, and returns 0.

=back

=head1 RETURN

All functions return 1 on success, 0 on failure.
$! will be set if an error was encountered.

=head1 NOTES

=over 4

=item *

On Mac OS (Classic), the path separator is ':', not '/', and the 
current directory is denoted as ':', not '.'. You should be careful 
about specifying relative pathnames. While a full path always begins 
with a volume name, a relative pathname should always begin with a 
':'.  If specifying a volume name only, a trailing ':' is required.

E.g.

  copy("file1", "tmp");        # creates the file 'tmp' in the current directory
  copy("file1", ":tmp:");      # creates :tmp:file1
  copy("file1", ":tmp");       # same as above
  copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
                               # that, since it may cause confusion, see example #1)
  copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
  copy("file1", ":tmp:file1"); # ok, partial path
  copy("file1", "DataHD:");    # creates DataHD:file1

  move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
                                             # volume to another

=back

=head1 AUTHOR

File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.

=cut
Commit	Line	Data
f716a1dd	1	# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
	2	# source code has been placed in the public domain by the author.
	3	# Please be kind and preserve the documentation.
	4	#
71be2cbc	5	# Additions copyright 1996 by Charles Bailey. Permission is granted
71be2cbc	6	# to distribute the revised code under the same terms as Perl itself.
f716a1dd	7
	8	package File::Copy;
	9
3b825e41	10	use 5.006;
71be2cbc	11	use strict;
b395063c	12	use warnings;
6c254d95	13	use File::Spec;
96a91e01	14	use Config;
17f410f9	15	our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
	16	sub copy;
	17	sub syscopy;
	18	sub cp;
	19	sub mv;
71be2cbc	20
	21	# Note that this module implements only part of the API defined by
	22	# the File/Copy.pm module of the File-Tools-2.0 package. However, that
	23	# package has not yet been updated to work with Perl 5.004, and so it
	24	# would be a Bad Thing for the CPAN module to grab it and replace this
	25	# module. Therefore, we set this module's version higher than 2.0.
98225a64	26	$VERSION = '2.09';
f716a1dd	27
71be2cbc	28	require Exporter;
	29	@ISA = qw(Exporter);
	30	@EXPORT = qw(copy move);
	31	@EXPORT_OK = qw(cp mv);
f716a1dd	32
441496b2	33	$Too_Big = 1024 * 1024 * 2;
f716a1dd	34
8878f897	35	sub croak {
	36	require Carp;
	37	goto &Carp::croak;
	38	}
	39
754f2cd0	40	sub carp {
	41	require Carp;
	42	goto &Carp::carp;
	43	}
	44
bcdb689b	45	my $macfiles;
	46	if ($^O eq 'MacOS') {
	47	$macfiles = eval { require Mac::MoreFiles };
	48	warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
3a2263fe	49	if $@ && $^W;
bcdb689b	50	}
bcdb689b	51
6c254d95	52	sub _catname {
71be2cbc	53	my($from, $to) = @_;
	54	if (not defined &basename) {
	55	require File::Basename;
	56	import File::Basename 'basename';
	57	}
6c254d95	58
	59	if ($^O eq 'MacOS') {
	60	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	61	$to = ':' . $to if $to !~ /:/;
	62	}
	63
	64	return File::Spec->catfile($to, basename($from));
f716a1dd	65	}
	66
	67	sub copy {
71be2cbc	68	croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
f716a1dd	69	unless(@_ == 2 \|\| @_ == 3);
	70
	71	my $from = shift;
	72	my $to = shift;
71be2cbc	73
	74	my $from_a_handle = (ref($from)
	75	? (ref($from) eq 'GLOB'
d704f39a	76	\|\| UNIVERSAL::isa($from, 'GLOB')
d704f39a	77	\|\| UNIVERSAL::isa($from, 'IO::Handle'))
71be2cbc	78	: (ref(\$from) eq 'GLOB'));
	79	my $to_a_handle = (ref($to)
	80	? (ref($to) eq 'GLOB'
d704f39a	81	\|\| UNIVERSAL::isa($to, 'GLOB')
d704f39a	82	\|\| UNIVERSAL::isa($to, 'IO::Handle'))
71be2cbc	83	: (ref(\$to) eq 'GLOB'));
71be2cbc	84
96a91e01	85	if ($from eq $to) { # works for references, too
754f2cd0	86	carp("'$from' and '$to' are identical (not copied)");
	87	# The "copy" was a success as the source and destination contain
	88	# the same data.
	89	return 1;
96a91e01	90	}
96a91e01	91
ac7b122d	92	if ((($Config{d_symlink} && $Config{d_readlink}) \|\| $Config{d_link}) &&
b8ccb221	93	!($^O eq 'MSWin32' \|\| $^O eq 'os2' \|\| $^O eq 'vms')) {
ac7b122d	94	my @fs = stat($from);
ac7b122d	95	if (@fs) {
96a91e01	96	my @ts = stat($to);
ac7b122d	97	if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
754f2cd0	98	carp("'$from' and '$to' are identical (not copied)");
754f2cd0	99	return 0;
96a91e01	100	}
	101	}
	102	}
	103
71be2cbc	104	if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	105	$to = _catname($from, $to);
	106	}
	107
1a04d035	108	if (defined &syscopy && !$Syscopy_is_copy
e6434134	109	&& !$to_a_handle
1d84e8df	110	&& !($from_a_handle && $^O eq 'os2' ) # OS/2 cannot handle handles
1d84e8df	111	&& !($from_a_handle && $^O eq 'mpeix') # and neither can MPE/iX.
7509b657	112	&& !($from_a_handle && $^O eq 'MSWin32')
fa648be5	113	&& !($from_a_handle && $^O eq 'MacOS')
2986a63f	114	&& !($from_a_handle && $^O eq 'NetWare')
1a04d035	115	)
71be2cbc	116	{
	117	return syscopy($from, $to);
	118	}
	119
	120	my $closefrom = 0;
	121	my $closeto = 0;
f716a1dd	122	my ($size, $status, $r, $buf);
48a5c399	123	local($\) = '';
f716a1dd	124
23ba2776	125	my $from_h;
71be2cbc	126	if ($from_a_handle) {
23ba2776	127	$from_h = $from;
f716a1dd	128	} else {
fa648be5	129	$from = _protect($from) if $from =~ /^\s/s;
23ba2776	130	$from_h = \do { local *FH };
	131	open($from_h, "< $from\0") or goto fail_open1;
	132	binmode $from_h or die "($!,$^E)";
f716a1dd	133	$closefrom = 1;
1a04d035	134	}
1a04d035	135
23ba2776	136	my $to_h;
71be2cbc	137	if ($to_a_handle) {
23ba2776	138	$to_h = $to;
1a04d035	139	} else {
fa648be5	140	$to = _protect($to) if $to =~ /^\s/s;
23ba2776	141	$to_h = \do { local *FH };
	142	open($to_h,"> $to\0") or goto fail_open2;
	143	binmode $to_h or die "($!,$^E)";
71be2cbc	144	$closeto = 1;
1a04d035	145	}
f716a1dd	146
	147	if (@_) {
	148	$size = shift(@_) + 0;
	149	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
	150	} else {
025a6ea3	151	$size = tied(*$from_h) ? 0 : -s $from_h \|\| 0;
f716a1dd	152	$size = 1024 if ($size < 512);
441496b2	153	$size = $Too_Big if ($size > $Too_Big);
f716a1dd	154	}
f716a1dd	155
71be2cbc	156	$! = 0;
	157	for (;;) {
	158	my ($r, $w, $t);
23ba2776	159	defined($r = sysread($from_h, $buf, $size))
71be2cbc	160	or goto fail_inner;
	161	last unless $r;
	162	for ($w = 0; $w < $r; $w += $t) {
23ba2776	163	$t = syswrite($to_h, $buf, $r - $w, $w)
71be2cbc	164	or goto fail_inner;
f716a1dd	165	}
f716a1dd	166	}
71be2cbc	167
23ba2776	168	close($to_h) \|\| goto fail_open2 if $closeto;
23ba2776	169	close($from_h) \|\| goto fail_open1 if $closefrom;
71be2cbc	170
48a5c399	171	# Use this idiom to avoid uninitialized value warning.
f716a1dd	172	return 1;
1a04d035	173
f716a1dd	174	# All of these contortions try to preserve error messages...
	175	fail_inner:
	176	if ($closeto) {
	177	$status = $!;
	178	$! = 0;
23ba2776	179	close $to_h;
f716a1dd	180	$! = $status unless $!;
	181	}
	182	fail_open2:
	183	if ($closefrom) {
	184	$status = $!;
	185	$! = 0;
23ba2776	186	close $from_h;
f716a1dd	187	$! = $status unless $!;
	188	}
	189	fail_open1:
f716a1dd	190	return 0;
f716a1dd	191	}
9b957b78	192
441496b2	193	sub move {
754f2cd0	194	croak("Usage: move(FROM, TO) ") unless @_ == 2;
754f2cd0	195
71be2cbc	196	my($from,$to) = @_;
754f2cd0	197
fa76202e	198	my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
441496b2	199
71be2cbc	200	if (-d $to && ! -d $from) {
	201	$to = _catname($from, $to);
	202	}
	203
	204	($tosz1,$tomt1) = (stat($to))[7,9];
	205	$fromsz = -s $from;
e6434134	206	if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
	207	# will not rename with overwrite
	208	unlink $to;
	209	}
71be2cbc	210	return 1 if rename $from, $to;
71be2cbc	211
71be2cbc	212	# Did rename return an error even though it succeeded, because $to
	213	# is on a remote NFS file system, and NFS lost the server's ack?
	214	return 1 if defined($fromsz) && !-e $from && # $from disappeared
	215	(($tosz2,$tomt2) = (stat($to))[7,9]) && # $to's there
	216	($tosz1 != $tosz2 or $tomt1 != $tomt2) && # and changed
	217	$tosz2 == $fromsz; # it's all there
1a04d035	218
71be2cbc	219	($tosz1,$tomt1) = (stat($to))[7,9]; # just in case rename did something
762548ba	220
	221	{
	222	local $@;
	223	eval {
754f2cd0	224	local $SIG{__DIE__};
762548ba	225	copy($from,$to) or die;
	226	my($atime, $mtime) = (stat($from))[8,9];
	227	utime($atime, $mtime, $to);
	228	unlink($from) or die;
	229	};
	230	return 1 unless $@;
	231	}
fa76202e	232	($sts,$ossts) = ($! + 0, $^E + 0);
1a04d035	233
71be2cbc	234	($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
	235	unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
	236	($!,$^E) = ($sts,$ossts);
	237	return 0;
441496b2	238	}
9b957b78	239
71be2cbc	240	*cp = \©
	241	*mv = \&move;
	242
fa648be5	243
	244	if ($^O eq 'MacOS') {
	245	*_protect = sub { MacPerl::MakeFSSpec($_[0]) };
	246	} else {
	247	*_protect = sub { "./$_[0]" };
	248	}
	249
9b957b78	250	# &syscopy is an XSUB under OS/2
1d84e8df	251	unless (defined &syscopy) {
	252	if ($^O eq 'VMS') {
	253	*syscopy = \&rmscopy;
	254	} elsif ($^O eq 'mpeix') {
	255	*syscopy = sub {
3f5ee302	256	return 0 unless @_ == 2;
1d84e8df	257	# Use the MPE cp program in order to
	258	# preserve MPE file attributes.
	259	return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	260	};
7509b657	261	} elsif ($^O eq 'MSWin32') {
	262	*syscopy = sub {
	263	return 0 unless @_ == 2;
	264	return Win32::CopyFile(@_, 1);
	265	};
bcdb689b	266	} elsif ($macfiles) {
fa648be5	267	*syscopy = sub {
	268	my($from, $to) = @_;
	269	my($dir, $toname);
	270
	271	return 0 unless -e $from;
	272
	273	if ($to =~ /(.*:)([^:]+):?$/) {
	274	($dir, $toname) = ($1, $2);
	275	} else {
	276	($dir, $toname) = (":", $to);
	277	}
	278
	279	unlink($to);
	280	Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	281	};
1d84e8df	282	} else {
1a04d035	283	$Syscopy_is_copy = 1;
1d84e8df	284	*syscopy = \©
	285	}
	286	}
f716a1dd	287
	288	1;
	289
	290	__END__
a5f75d66	291
f716a1dd	292	=head1 NAME
	293
	294	File::Copy - Copy files or filehandles
	295
a5f75d66	296	=head1 SYNOPSIS
f716a1dd	297
5ce10329	298	use File::Copy;
f716a1dd	299
5ce10329	300	copy("file1","file2") or die "Copy failed: $!";
5ce10329	301	copy("Copy.pm",\*STDOUT);
441496b2	302	move("/dev1/fileA","/dev2/fileB");
f716a1dd	303
78e38bb6	304	use File::Copy "cp";
f716a1dd	305
23f3aea0	306	$n = FileHandle->new("/a/file","r");
c6dfe06b	307	cp($n,"x");
f716a1dd	308
	309	=head1 DESCRIPTION
	310
441496b2	311	The File::Copy module provides two basic functions, C<copy> and
	312	C<move>, which are useful for getting the contents of a file from
	313	one place to another.
	314
	315	=over 4
	316
0cdecedb	317	=item copy
0cdecedb	318	X<copy> X<cp>
441496b2	319
441496b2	320	The C<copy> function takes two
f716a1dd	321	parameters: a file to copy from and a file to copy to. Either
	322	argument may be a string, a FileHandle reference or a FileHandle
	323	glob. Obviously, if the first argument is a filehandle of some
	324	sort, it will be read from, and if it is a file I<name> it will
	325	be opened for reading. Likewise, the second argument will be
96a91e01	326	written to (and created if need be). Trying to copy a file on top
96a91e01	327	of itself is a fatal error.
71be2cbc	328
71be2cbc	329	B<Note that passing in
9b957b78	330	files as handles instead of names may lead to loss of information
9b957b78	331	on some operating systems; it is recommended that you use file
e6434134	332	names whenever possible.> Files are opened in binary mode where
8dcee03e	333	applicable. To get a consistent behaviour when copying from a
e6434134	334	filehandle to a file, use C<binmode> on the filehandle.
f716a1dd	335
	336	An optional third parameter can be used to specify the buffer
	337	size used for copying. This is the number of bytes from the
	338	first file, that wil be held in memory at any given time, before
	339	being written to the second file. The default buffer size depends
	340	upon the file, but will generally be the whole file (up to 2Mb), or
	341	1k for filehandles that do not reference files (eg. sockets).
	342
	343	You may use the syntax C<use File::Copy "cp"> to get at the
	344	"cp" alias for this function. The syntax is I<exactly> the same.
	345
0cdecedb	346	=item move
0cdecedb	347	X<move> X<mv> X<rename>
441496b2	348
441496b2	349	The C<move> function also takes two parameters: the current name
71be2cbc	350	and the intended name of the file to be moved. If the destination
	351	already exists and is a directory, and the source is not a
	352	directory, then the source file will be renamed into the directory
	353	specified by the destination.
	354
	355	If possible, move() will simply rename the file. Otherwise, it copies
	356	the file to the new location and deletes the original. If an error occurs
	357	during this copy-and-delete process, you may be left with a (possibly partial)
441496b2	358	copy of the file under the destination name.
	359
	360	You may use the "mv" alias for this function in the same way that
	361	you may use the "cp" alias for C<copy>.
	362
0cdecedb	363	=item syscopy
0cdecedb	364	X<syscopy>
441496b2	365
9b957b78	366	File::Copy also provides the C<syscopy> routine, which copies the
	367	file specified in the first parameter to the file specified in the
	368	second parameter, preserving OS-specific attributes and file
	369	structure. For Unix systems, this is equivalent to the simple
f1442e8b	370	C<copy> routine, which doesn't preserve OS-specific attributes. For
	371	VMS systems, this calls the C<rmscopy> routine (see below). For OS/2
	372	systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
	373	this calls C<Win32::CopyFile>.
9b957b78	374
bcdb689b	375	On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
	376	if available.
	377
0cdecedb	378	B<Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)>
9b957b78	379
71be2cbc	380	If both arguments to C<copy> are not file handles,
71be2cbc	381	then C<copy> will perform a "system copy" of
9b957b78	382	the input file to a new output file, in order to preserve file
9b957b78	383	attributes, indexed file structure, I<etc.> The buffer size
71be2cbc	384	parameter is ignored. If either argument to C<copy> is a
71be2cbc	385	handle to an opened file, then data is copied using Perl
9b957b78	386	operators, and no effort is made to preserve file attributes
	387	or record structure.
	388
55497cff	389	The system copy routine may also be called directly under VMS and OS/2
55497cff	390	as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
71be2cbc	391	is the routine that does the actual work for syscopy).
9b957b78	392
9b957b78	393	=item rmscopy($from,$to[,$date_flag])
0cdecedb	394	X<rmscopy>
9b957b78	395
71be2cbc	396	The first and second arguments may be strings, typeglobs, typeglob
	397	references, or objects inheriting from IO::Handle;
	398	they are used in all cases to obtain the
9b957b78	399	I<filespec> of the input and output files, respectively. The
	400	name and type of the input file are used as defaults for the
	401	output file, if necessary.
	402
	403	A new version of the output file is always created, which
	404	inherits the structure and RMS attributes of the input file,
	405	except for owner and protections (and possibly timestamps;
	406	see below). All data from the input file is copied to the
	407	output file; if either of the first two parameters to C<rmscopy>
	408	is a file handle, its position is unchanged. (Note that this
	409	means a file handle pointing to the output file will be
	410	associated with an old version of that file after C<rmscopy>
	411	returns, not the newly created version.)
	412
	413	The third parameter is an integer flag, which tells C<rmscopy>
1fef88e7	414	how to handle timestamps. If it is E<lt> 0, none of the input file's
1fef88e7	415	timestamps are propagated to the output file. If it is E<gt> 0, then
9b957b78	416	it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
	417	timestamps other than the revision date are propagated; if bit 1
	418	is set, the revision date is propagated. If the third parameter
	419	to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
	420	if the name or type of the output file was explicitly specified,
	421	then no timestamps are propagated, but if they were taken implicitly
	422	from the input filespec, then all timestamps other than the
	423	revision date are propagated. If this parameter is not supplied,
	424	it defaults to 0.
	425
	426	Like C<copy>, C<rmscopy> returns 1 on success. If an error occurs,
	427	it sets C<$!>, deletes the output file, and returns 0.
	428
55497cff	429	=back
55497cff	430
f716a1dd	431	=head1 RETURN
f716a1dd	432
441496b2	433	All functions return 1 on success, 0 on failure.
441496b2	434	$! will be set if an error was encountered.
f716a1dd	435
6c254d95	436	=head1 NOTES
	437
	438	=over 4
	439
	440	=item *
	441
	442	On Mac OS (Classic), the path separator is ':', not '/', and the
	443	current directory is denoted as ':', not '.'. You should be careful
	444	about specifying relative pathnames. While a full path always begins
	445	with a volume name, a relative pathname should always begin with a
	446	':'. If specifying a volume name only, a trailing ':' is required.
	447
	448	E.g.
	449
	450	copy("file1", "tmp"); # creates the file 'tmp' in the current directory
	451	copy("file1", ":tmp:"); # creates :tmp:file1
	452	copy("file1", ":tmp"); # same as above
0cdecedb	453	copy("file1", "tmp"); # same as above, if 'tmp' is a directory (but don't do
6c254d95	454	# that, since it may cause confusion, see example #1)
	455	copy("file1", "tmp:file1"); # error, since 'tmp:' is not a volume
	456	copy("file1", ":tmp:file1"); # ok, partial path
	457	copy("file1", "DataHD:"); # creates DataHD:file1
0cdecedb	458
0cdecedb	459	move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
6c254d95	460	# volume to another
	461
	462	=back
	463
f716a1dd	464	=head1 AUTHOR
f716a1dd	465
441496b2	466	File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
bd3fa61c	467	and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
f716a1dd	468
f716a1dd	469	=cut
441496b2	470