[p5sagit/p5-mst-13.2.git] / lib / File / Copy.pm

# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
# source code has been placed in the public domain by the author.
# Please be kind and preserve the documentation.
#
# Additions copyright 1996 by Charles Bailey.  Permission is granted
# to distribute the revised code under the same terms as Perl itself.

package File::Copy;

use 5.006;
use strict;
use warnings;
use File::Spec;
use Config;
our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
sub copy;
sub syscopy;
sub cp;
sub mv;

# Note that this module implements only *part* of the API defined by
# the File/Copy.pm module of the File-Tools-2.0 package.  However, that
# package has not yet been updated to work with Perl 5.004, and so it
# would be a Bad Thing for the CPAN module to grab it and replace this
# module.  Therefore, we set this module's version higher than 2.0.
$VERSION = '2.11';

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(copy move);
@EXPORT_OK = qw(cp mv);

$Too_Big = 1024 * 1024 * 2;

sub croak {
    require Carp;
    goto &Carp::croak;
}

sub carp {
    require Carp;
    goto &Carp::carp;
}

my $macfiles;
if ($^O eq 'MacOS') {
	$macfiles = eval { require Mac::MoreFiles };
	warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
		if $@ && $^W;
}

sub _catname {
    my($from, $to) = @_;
    if (not defined &basename) {
	require File::Basename;
	import  File::Basename 'basename';
    }

    if ($^O eq 'MacOS') {
	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	$to = ':' . $to if $to !~ /:/;
    }

    return File::Spec->catfile($to, basename($from));
}

# _eq($from, $to) tells whether $from and $to are identical
# works for strings and references
sub _eq {
    return $_[0] == $_[1] if ref $_[0] && ref $_[1];
    return $_[0] eq $_[1] if !ref $_[0] && !ref $_[1];
    return "";
}

sub copy {
    croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
      unless(@_ == 2 || @_ == 3);

    my $from = shift;
    my $to = shift;

    my $from_a_handle = (ref($from)
			 ? (ref($from) eq 'GLOB'
			    || UNIVERSAL::isa($from, 'GLOB')
                            || UNIVERSAL::isa($from, 'IO::Handle'))
			 : (ref(\$from) eq 'GLOB'));
    my $to_a_handle =   (ref($to)
			 ? (ref($to) eq 'GLOB'
			    || UNIVERSAL::isa($to, 'GLOB')
                            || UNIVERSAL::isa($to, 'IO::Handle'))
			 : (ref(\$to) eq 'GLOB'));

    if (_eq($from, $to)) { # works for references, too
	carp("'$from' and '$to' are identical (not copied)");
        # The "copy" was a success as the source and destination contain
        # the same data.
        return 1;
    }

    if ((($Config{d_symlink} && $Config{d_readlink}) || $Config{d_link}) &&
	!($^O eq 'MSWin32' || $^O eq 'os2' || $^O eq 'vms')) {
	my @fs = stat($from);
	if (@fs) {
	    my @ts = stat($to);
	    if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
		carp("'$from' and '$to' are identical (not copied)");
                return 0;
	    }
	}
    }

    if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    if (defined &syscopy && !$Syscopy_is_copy
	&& !$to_a_handle
	&& !($from_a_handle && $^O eq 'os2' )	# OS/2 cannot handle handles
	&& !($from_a_handle && $^O eq 'mpeix')	# and neither can MPE/iX.
	&& !($from_a_handle && $^O eq 'MSWin32')
	&& !($from_a_handle && $^O eq 'MacOS')
	&& !($from_a_handle && $^O eq 'NetWare')
       )
    {
	return syscopy($from, $to);
    }

    my $closefrom = 0;
    my $closeto = 0;
    my ($size, $status, $r, $buf);
    local($\) = '';

    my $from_h;
    if ($from_a_handle) {
       $from_h = $from;
    } else {
	$from = _protect($from) if $from =~ /^\s/s;
       $from_h = \do { local *FH };
       open($from_h, "< $from\0") or goto fail_open1;
       binmode $from_h or die "($!,$^E)";
	$closefrom = 1;
    }

    my $to_h;
    if ($to_a_handle) {
       $to_h = $to;
    } else {
	$to = _protect($to) if $to =~ /^\s/s;
       $to_h = \do { local *FH };
       open($to_h,"> $to\0") or goto fail_open2;
       binmode $to_h or die "($!,$^E)";
	$closeto = 1;
    }

    if (@_) {
	$size = shift(@_) + 0;
	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
    } else {
	$size = tied(*$from_h) ? 0 : -s $from_h || 0;
	$size = 1024 if ($size < 512);
	$size = $Too_Big if ($size > $Too_Big);
    }

    $! = 0;
    for (;;) {
	my ($r, $w, $t);
       defined($r = sysread($from_h, $buf, $size))
	    or goto fail_inner;
	last unless $r;
	for ($w = 0; $w < $r; $w += $t) {
           $t = syswrite($to_h, $buf, $r - $w, $w)
		or goto fail_inner;
	}
    }

    close($to_h) || goto fail_open2 if $closeto;
    close($from_h) || goto fail_open1 if $closefrom;

    # Use this idiom to avoid uninitialized value warning.
    return 1;

    # All of these contortions try to preserve error messages...
  fail_inner:
    if ($closeto) {
	$status = $!;
	$! = 0;
       close $to_h;
	$! = $status unless $!;
    }
  fail_open2:
    if ($closefrom) {
	$status = $!;
	$! = 0;
       close $from_h;
	$! = $status unless $!;
    }
  fail_open1:
    return 0;
}

sub move {
    croak("Usage: move(FROM, TO) ") unless @_ == 2;

    my($from,$to) = @_;

    my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);

    if (-d $to && ! -d $from) {
	$to = _catname($from, $to);
    }

    ($tosz1,$tomt1) = (stat($to))[7,9];
    $fromsz = -s $from;
    if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
      # will not rename with overwrite
      unlink $to;
    }
    return 1 if rename $from, $to;

    # Did rename return an error even though it succeeded, because $to
    # is on a remote NFS file system, and NFS lost the server's ack?
    return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
                (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
                  ((!defined $tosz1) ||			   #  not before or
		   ($tosz1 != $tosz2 or $tomt1 != $tomt2)) &&  #   was changed
                $tosz2 == $fromsz;                         # it's all there

    ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something

    {
        local $@;
        eval {
            local $SIG{__DIE__};
            copy($from,$to) or die;
            my($atime, $mtime) = (stat($from))[8,9];
            utime($atime, $mtime, $to);
            unlink($from)   or die;
        };
        return 1 unless $@;
    }
    ($sts,$ossts) = ($! + 0, $^E + 0);

    ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
    unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
    ($!,$^E) = ($sts,$ossts);
    return 0;
}

*cp = \&copy;
*mv = \&move;


if ($^O eq 'MacOS') {
    *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
} else {
    *_protect = sub { "./$_[0]" };
}

# &syscopy is an XSUB under OS/2
unless (defined &syscopy) {
    if ($^O eq 'VMS') {
	*syscopy = \&rmscopy;
    } elsif ($^O eq 'mpeix') {
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    # Use the MPE cp program in order to
	    # preserve MPE file attributes.
	    return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	};
    } elsif ($^O eq 'MSWin32' && defined &DynaLoader::boot_DynaLoader) {
	# Win32::CopyFile() fill only work if we can load Win32.xs
	*syscopy = sub {
	    return 0 unless @_ == 2;
	    return Win32::CopyFile(@_, 1);
	};
    } elsif ($macfiles) {
	*syscopy = sub {
	    my($from, $to) = @_;
	    my($dir, $toname);

	    return 0 unless -e $from;

	    if ($to =~ /(.*:)([^:]+):?$/) {
		($dir, $toname) = ($1, $2);
	    } else {
		($dir, $toname) = (":", $to);
	    }

	    unlink($to);
	    Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	};
    } else {
	$Syscopy_is_copy = 1;
	*syscopy = \&copy;
    }
}

1;

__END__

=head1 NAME

File::Copy - Copy files or filehandles

=head1 SYNOPSIS

	use File::Copy;

	copy("file1","file2") or die "Copy failed: $!";
	copy("Copy.pm",\*STDOUT);
	move("/dev1/fileA","/dev2/fileB");

	use File::Copy "cp";

	$n = FileHandle->new("/a/file","r");
	cp($n,"x");

=head1 DESCRIPTION

The File::Copy module provides two basic functions, C<copy> and
C<move>, which are useful for getting the contents of a file from
one place to another.

=over 4

=item copy
X<copy> X<cp>

The C<copy> function takes two
parameters: a file to copy from and a file to copy to. Either
argument may be a string, a FileHandle reference or a FileHandle
glob. Obviously, if the first argument is a filehandle of some
sort, it will be read from, and if it is a file I<name> it will
be opened for reading. Likewise, the second argument will be
written to (and created if need be).  Trying to copy a file on top
of itself is a fatal error.

B<Note that passing in
files as handles instead of names may lead to loss of information
on some operating systems; it is recommended that you use file
names whenever possible.>  Files are opened in binary mode where
applicable.  To get a consistent behaviour when copying from a
filehandle to a file, use C<binmode> on the filehandle.

An optional third parameter can be used to specify the buffer
size used for copying. This is the number of bytes from the
first file, that will be held in memory at any given time, before
being written to the second file. The default buffer size depends
upon the file, but will generally be the whole file (up to 2MB), or
1k for filehandles that do not reference files (eg. sockets).

You may use the syntax C<use File::Copy "cp"> to get at the
"cp" alias for this function. The syntax is I<exactly> the same.

=item move
X<move> X<mv> X<rename>

The C<move> function also takes two parameters: the current name
and the intended name of the file to be moved.  If the destination
already exists and is a directory, and the source is not a
directory, then the source file will be renamed into the directory
specified by the destination.

If possible, move() will simply rename the file.  Otherwise, it copies
the file to the new location and deletes the original.  If an error occurs
during this copy-and-delete process, you may be left with a (possibly partial)
copy of the file under the destination name.

You may use the "mv" alias for this function in the same way that
you may use the "cp" alias for C<copy>.

=item syscopy
X<syscopy>

File::Copy also provides the C<syscopy> routine, which copies the
file specified in the first parameter to the file specified in the
second parameter, preserving OS-specific attributes and file
structure.  For Unix systems, this is equivalent to the simple
C<copy> routine, which doesn't preserve OS-specific attributes.  For
VMS systems, this calls the C<rmscopy> routine (see below).  For OS/2
systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
this calls C<Win32::CopyFile>.

On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
if available.

B<Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)>:

If both arguments to C<copy> are not file handles,
then C<copy> will perform a "system copy" of
the input file to a new output file, in order to preserve file
attributes, indexed file structure, I<etc.>  The buffer size
parameter is ignored.  If either argument to C<copy> is a
handle to an opened file, then data is copied using Perl
operators, and no effort is made to preserve file attributes
or record structure.

The system copy routine may also be called directly under VMS and OS/2
as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
is the routine that does the actual work for syscopy).

=item rmscopy($from,$to[,$date_flag])
X<rmscopy>

The first and second arguments may be strings, typeglobs, typeglob
references, or objects inheriting from IO::Handle;
they are used in all cases to obtain the
I<filespec> of the input and output files, respectively.  The
name and type of the input file are used as defaults for the
output file, if necessary.

A new version of the output file is always created, which
inherits the structure and RMS attributes of the input file,
except for owner and protections (and possibly timestamps;
see below).  All data from the input file is copied to the
output file; if either of the first two parameters to C<rmscopy>
is a file handle, its position is unchanged.  (Note that this
means a file handle pointing to the output file will be
associated with an old version of that file after C<rmscopy>
returns, not the newly created version.)

The third parameter is an integer flag, which tells C<rmscopy>
how to handle timestamps.  If it is E<lt> 0, none of the input file's
timestamps are propagated to the output file.  If it is E<gt> 0, then
it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
timestamps other than the revision date are propagated; if bit 1
is set, the revision date is propagated.  If the third parameter
to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
if the name or type of the output file was explicitly specified,
then no timestamps are propagated, but if they were taken implicitly
from the input filespec, then all timestamps other than the
revision date are propagated.  If this parameter is not supplied,
it defaults to 0.

Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
it sets C<$!>, deletes the output file, and returns 0.

=back

=head1 RETURN

All functions return 1 on success, 0 on failure.
$! will be set if an error was encountered.

=head1 NOTES

=over 4

=item *

On Mac OS (Classic), the path separator is ':', not '/', and the 
current directory is denoted as ':', not '.'. You should be careful 
about specifying relative pathnames. While a full path always begins 
with a volume name, a relative pathname should always begin with a 
':'.  If specifying a volume name only, a trailing ':' is required.

E.g.

  copy("file1", "tmp");        # creates the file 'tmp' in the current directory
  copy("file1", ":tmp:");      # creates :tmp:file1
  copy("file1", ":tmp");       # same as above
  copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
                               # that, since it may cause confusion, see example #1)
  copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
  copy("file1", ":tmp:file1"); # ok, partial path
  copy("file1", "DataHD:");    # creates DataHD:file1

  move("MacintoshHD:fileA", "DataHD:fileB"); # moves (doesn't copy) files from one
                                             # volume to another

=back

=head1 AUTHOR

File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.

=cut
Commit	Line	Data
f716a1dd	1	# File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
	2	# source code has been placed in the public domain by the author.
	3	# Please be kind and preserve the documentation.
	4	#
71be2cbc	5	# Additions copyright 1996 by Charles Bailey. Permission is granted
71be2cbc	6	# to distribute the revised code under the same terms as Perl itself.
f716a1dd	7
	8	package File::Copy;
	9
3b825e41	10	use 5.006;
71be2cbc	11	use strict;
b395063c	12	use warnings;
6c254d95	13	use File::Spec;
96a91e01	14	use Config;
17f410f9	15	our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
	16	sub copy;
	17	sub syscopy;
	18	sub cp;
	19	sub mv;
71be2cbc	20
	21	# Note that this module implements only part of the API defined by
	22	# the File/Copy.pm module of the File-Tools-2.0 package. However, that
	23	# package has not yet been updated to work with Perl 5.004, and so it
	24	# would be a Bad Thing for the CPAN module to grab it and replace this
	25	# module. Therefore, we set this module's version higher than 2.0.
c9fbd0c8	26	$VERSION = '2.11';
f716a1dd	27
71be2cbc	28	require Exporter;
	29	@ISA = qw(Exporter);
	30	@EXPORT = qw(copy move);
	31	@EXPORT_OK = qw(cp mv);
f716a1dd	32
441496b2	33	$Too_Big = 1024 * 1024 * 2;
f716a1dd	34
8878f897	35	sub croak {
	36	require Carp;
	37	goto &Carp::croak;
	38	}
	39
754f2cd0	40	sub carp {
	41	require Carp;
	42	goto &Carp::carp;
	43	}
	44
bcdb689b	45	my $macfiles;
	46	if ($^O eq 'MacOS') {
	47	$macfiles = eval { require Mac::MoreFiles };
	48	warn 'Mac::MoreFiles could not be loaded; using non-native syscopy'
3a2263fe	49	if $@ && $^W;
bcdb689b	50	}
bcdb689b	51
6c254d95	52	sub _catname {
71be2cbc	53	my($from, $to) = @_;
	54	if (not defined &basename) {
	55	require File::Basename;
	56	import File::Basename 'basename';
	57	}
6c254d95	58
	59	if ($^O eq 'MacOS') {
	60	# a partial dir name that's valid only in the cwd (e.g. 'tmp')
	61	$to = ':' . $to if $to !~ /:/;
	62	}
	63
	64	return File::Spec->catfile($to, basename($from));
f716a1dd	65	}
f716a1dd	66
236a0738	67	# _eq($from, $to) tells whether $from and $to are identical
	68	# works for strings and references
	69	sub _eq {
	70	return $_[0] == $_[1] if ref $_[0] && ref $_[1];
	71	return $_[0] eq $_[1] if !ref $_[0] && !ref $_[1];
	72	return "";
	73	}
	74
f716a1dd	75	sub copy {
71be2cbc	76	croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
f716a1dd	77	unless(@_ == 2 \|\| @_ == 3);
	78
	79	my $from = shift;
	80	my $to = shift;
71be2cbc	81
	82	my $from_a_handle = (ref($from)
	83	? (ref($from) eq 'GLOB'
d704f39a	84	\|\| UNIVERSAL::isa($from, 'GLOB')
d704f39a	85	\|\| UNIVERSAL::isa($from, 'IO::Handle'))
71be2cbc	86	: (ref(\$from) eq 'GLOB'));
	87	my $to_a_handle = (ref($to)
	88	? (ref($to) eq 'GLOB'
d704f39a	89	\|\| UNIVERSAL::isa($to, 'GLOB')
d704f39a	90	\|\| UNIVERSAL::isa($to, 'IO::Handle'))
71be2cbc	91	: (ref(\$to) eq 'GLOB'));
71be2cbc	92
236a0738	93	if (_eq($from, $to)) { # works for references, too
754f2cd0	94	carp("'$from' and '$to' are identical (not copied)");
	95	# The "copy" was a success as the source and destination contain
	96	# the same data.
	97	return 1;
96a91e01	98	}
96a91e01	99
ac7b122d	100	if ((($Config{d_symlink} && $Config{d_readlink}) \|\| $Config{d_link}) &&
b8ccb221	101	!($^O eq 'MSWin32' \|\| $^O eq 'os2' \|\| $^O eq 'vms')) {
ac7b122d	102	my @fs = stat($from);
ac7b122d	103	if (@fs) {
96a91e01	104	my @ts = stat($to);
ac7b122d	105	if (@ts && $fs[0] == $ts[0] && $fs[1] == $ts[1]) {
754f2cd0	106	carp("'$from' and '$to' are identical (not copied)");
754f2cd0	107	return 0;
96a91e01	108	}
	109	}
	110	}
	111
71be2cbc	112	if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
	113	$to = _catname($from, $to);
	114	}
	115
1a04d035	116	if (defined &syscopy && !$Syscopy_is_copy
e6434134	117	&& !$to_a_handle
1d84e8df	118	&& !($from_a_handle && $^O eq 'os2' ) # OS/2 cannot handle handles
1d84e8df	119	&& !($from_a_handle && $^O eq 'mpeix') # and neither can MPE/iX.
7509b657	120	&& !($from_a_handle && $^O eq 'MSWin32')
fa648be5	121	&& !($from_a_handle && $^O eq 'MacOS')
2986a63f	122	&& !($from_a_handle && $^O eq 'NetWare')
1a04d035	123	)
71be2cbc	124	{
	125	return syscopy($from, $to);
	126	}
	127
	128	my $closefrom = 0;
	129	my $closeto = 0;
f716a1dd	130	my ($size, $status, $r, $buf);
48a5c399	131	local($\) = '';
f716a1dd	132
23ba2776	133	my $from_h;
71be2cbc	134	if ($from_a_handle) {
23ba2776	135	$from_h = $from;
f716a1dd	136	} else {
fa648be5	137	$from = _protect($from) if $from =~ /^\s/s;
23ba2776	138	$from_h = \do { local *FH };
	139	open($from_h, "< $from\0") or goto fail_open1;
	140	binmode $from_h or die "($!,$^E)";
f716a1dd	141	$closefrom = 1;
1a04d035	142	}
1a04d035	143
23ba2776	144	my $to_h;
71be2cbc	145	if ($to_a_handle) {
23ba2776	146	$to_h = $to;
1a04d035	147	} else {
fa648be5	148	$to = _protect($to) if $to =~ /^\s/s;
23ba2776	149	$to_h = \do { local *FH };
	150	open($to_h,"> $to\0") or goto fail_open2;
	151	binmode $to_h or die "($!,$^E)";
71be2cbc	152	$closeto = 1;
1a04d035	153	}
f716a1dd	154
	155	if (@_) {
	156	$size = shift(@_) + 0;
	157	croak("Bad buffer size for copy: $size\n") unless ($size > 0);
	158	} else {
025a6ea3	159	$size = tied(*$from_h) ? 0 : -s $from_h \|\| 0;
f716a1dd	160	$size = 1024 if ($size < 512);
441496b2	161	$size = $Too_Big if ($size > $Too_Big);
f716a1dd	162	}
f716a1dd	163
71be2cbc	164	$! = 0;
	165	for (;;) {
	166	my ($r, $w, $t);
23ba2776	167	defined($r = sysread($from_h, $buf, $size))
71be2cbc	168	or goto fail_inner;
	169	last unless $r;
	170	for ($w = 0; $w < $r; $w += $t) {
23ba2776	171	$t = syswrite($to_h, $buf, $r - $w, $w)
71be2cbc	172	or goto fail_inner;
f716a1dd	173	}
f716a1dd	174	}
71be2cbc	175
23ba2776	176	close($to_h) \|\| goto fail_open2 if $closeto;
23ba2776	177	close($from_h) \|\| goto fail_open1 if $closefrom;
71be2cbc	178
48a5c399	179	# Use this idiom to avoid uninitialized value warning.
f716a1dd	180	return 1;
1a04d035	181
f716a1dd	182	# All of these contortions try to preserve error messages...
	183	fail_inner:
	184	if ($closeto) {
	185	$status = $!;
	186	$! = 0;
23ba2776	187	close $to_h;
f716a1dd	188	$! = $status unless $!;
	189	}
	190	fail_open2:
	191	if ($closefrom) {
	192	$status = $!;
	193	$! = 0;
23ba2776	194	close $from_h;
f716a1dd	195	$! = $status unless $!;
	196	}
	197	fail_open1:
f716a1dd	198	return 0;
f716a1dd	199	}
9b957b78	200
441496b2	201	sub move {
754f2cd0	202	croak("Usage: move(FROM, TO) ") unless @_ == 2;
754f2cd0	203
71be2cbc	204	my($from,$to) = @_;
754f2cd0	205
fa76202e	206	my($fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
441496b2	207
71be2cbc	208	if (-d $to && ! -d $from) {
	209	$to = _catname($from, $to);
	210	}
	211
	212	($tosz1,$tomt1) = (stat($to))[7,9];
	213	$fromsz = -s $from;
e6434134	214	if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
	215	# will not rename with overwrite
	216	unlink $to;
	217	}
71be2cbc	218	return 1 if rename $from, $to;
71be2cbc	219
71be2cbc	220	# Did rename return an error even though it succeeded, because $to
	221	# is on a remote NFS file system, and NFS lost the server's ack?
	222	return 1 if defined($fromsz) && !-e $from && # $from disappeared
	223	(($tosz2,$tomt2) = (stat($to))[7,9]) && # $to's there
c9fbd0c8	224	((!defined $tosz1) \|\| # not before or
c9fbd0c8	225	($tosz1 != $tosz2 or $tomt1 != $tomt2)) && # was changed
71be2cbc	226	$tosz2 == $fromsz; # it's all there
1a04d035	227
71be2cbc	228	($tosz1,$tomt1) = (stat($to))[7,9]; # just in case rename did something
762548ba	229
	230	{
	231	local $@;
	232	eval {
754f2cd0	233	local $SIG{__DIE__};
762548ba	234	copy($from,$to) or die;
	235	my($atime, $mtime) = (stat($from))[8,9];
	236	utime($atime, $mtime, $to);
	237	unlink($from) or die;
	238	};
	239	return 1 unless $@;
	240	}
fa76202e	241	($sts,$ossts) = ($! + 0, $^E + 0);
1a04d035	242
71be2cbc	243	($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
	244	unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
	245	($!,$^E) = ($sts,$ossts);
	246	return 0;
441496b2	247	}
9b957b78	248
71be2cbc	249	*cp = \©
	250	*mv = \&move;
	251
fa648be5	252
	253	if ($^O eq 'MacOS') {
	254	*_protect = sub { MacPerl::MakeFSSpec($_[0]) };
	255	} else {
	256	*_protect = sub { "./$_[0]" };
	257	}
	258
9b957b78	259	# &syscopy is an XSUB under OS/2
1d84e8df	260	unless (defined &syscopy) {
	261	if ($^O eq 'VMS') {
	262	*syscopy = \&rmscopy;
	263	} elsif ($^O eq 'mpeix') {
	264	*syscopy = sub {
3f5ee302	265	return 0 unless @_ == 2;
1d84e8df	266	# Use the MPE cp program in order to
	267	# preserve MPE file attributes.
	268	return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
	269	};
cf2f24a4	270	} elsif ($^O eq 'MSWin32' && defined &DynaLoader::boot_DynaLoader) {
cf2f24a4	271	# Win32::CopyFile() fill only work if we can load Win32.xs
7509b657	272	*syscopy = sub {
	273	return 0 unless @_ == 2;
	274	return Win32::CopyFile(@_, 1);
	275	};
bcdb689b	276	} elsif ($macfiles) {
fa648be5	277	*syscopy = sub {
	278	my($from, $to) = @_;
	279	my($dir, $toname);
	280
	281	return 0 unless -e $from;
	282
	283	if ($to =~ /(.*:)([^:]+):?$/) {
	284	($dir, $toname) = ($1, $2);
	285	} else {
	286	($dir, $toname) = (":", $to);
	287	}
	288
	289	unlink($to);
	290	Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
	291	};
1d84e8df	292	} else {
1a04d035	293	$Syscopy_is_copy = 1;
1d84e8df	294	*syscopy = \©
	295	}
	296	}
f716a1dd	297
	298	1;
	299
	300	__END__
a5f75d66	301
f716a1dd	302	=head1 NAME
	303
	304	File::Copy - Copy files or filehandles
	305
a5f75d66	306	=head1 SYNOPSIS
f716a1dd	307
5ce10329	308	use File::Copy;
f716a1dd	309
5ce10329	310	copy("file1","file2") or die "Copy failed: $!";
5ce10329	311	copy("Copy.pm",\*STDOUT);
441496b2	312	move("/dev1/fileA","/dev2/fileB");
f716a1dd	313
78e38bb6	314	use File::Copy "cp";
f716a1dd	315
23f3aea0	316	$n = FileHandle->new("/a/file","r");
c6dfe06b	317	cp($n,"x");
f716a1dd	318
	319	=head1 DESCRIPTION
	320
441496b2	321	The File::Copy module provides two basic functions, C<copy> and
	322	C<move>, which are useful for getting the contents of a file from
	323	one place to another.
	324
	325	=over 4
	326
0cdecedb	327	=item copy
0cdecedb	328	X<copy> X<cp>
441496b2	329
441496b2	330	The C<copy> function takes two
f716a1dd	331	parameters: a file to copy from and a file to copy to. Either
	332	argument may be a string, a FileHandle reference or a FileHandle
	333	glob. Obviously, if the first argument is a filehandle of some
	334	sort, it will be read from, and if it is a file I<name> it will
	335	be opened for reading. Likewise, the second argument will be
96a91e01	336	written to (and created if need be). Trying to copy a file on top
96a91e01	337	of itself is a fatal error.
71be2cbc	338
71be2cbc	339	B<Note that passing in
9b957b78	340	files as handles instead of names may lead to loss of information
9b957b78	341	on some operating systems; it is recommended that you use file
e6434134	342	names whenever possible.> Files are opened in binary mode where
8dcee03e	343	applicable. To get a consistent behaviour when copying from a
e6434134	344	filehandle to a file, use C<binmode> on the filehandle.
f716a1dd	345
	346	An optional third parameter can be used to specify the buffer
	347	size used for copying. This is the number of bytes from the
3a964d77	348	first file, that will be held in memory at any given time, before
f716a1dd	349	being written to the second file. The default buffer size depends
338de517	350	upon the file, but will generally be the whole file (up to 2MB), or
f716a1dd	351	1k for filehandles that do not reference files (eg. sockets).
	352
	353	You may use the syntax C<use File::Copy "cp"> to get at the
	354	"cp" alias for this function. The syntax is I<exactly> the same.
	355
0cdecedb	356	=item move
0cdecedb	357	X<move> X<mv> X<rename>
441496b2	358
441496b2	359	The C<move> function also takes two parameters: the current name
71be2cbc	360	and the intended name of the file to be moved. If the destination
	361	already exists and is a directory, and the source is not a
	362	directory, then the source file will be renamed into the directory
	363	specified by the destination.
	364
	365	If possible, move() will simply rename the file. Otherwise, it copies
	366	the file to the new location and deletes the original. If an error occurs
	367	during this copy-and-delete process, you may be left with a (possibly partial)
441496b2	368	copy of the file under the destination name.
	369
	370	You may use the "mv" alias for this function in the same way that
	371	you may use the "cp" alias for C<copy>.
	372
0cdecedb	373	=item syscopy
0cdecedb	374	X<syscopy>
441496b2	375
9b957b78	376	File::Copy also provides the C<syscopy> routine, which copies the
	377	file specified in the first parameter to the file specified in the
	378	second parameter, preserving OS-specific attributes and file
	379	structure. For Unix systems, this is equivalent to the simple
f1442e8b	380	C<copy> routine, which doesn't preserve OS-specific attributes. For
	381	VMS systems, this calls the C<rmscopy> routine (see below). For OS/2
	382	systems, this calls the C<syscopy> XSUB directly. For Win32 systems,
	383	this calls C<Win32::CopyFile>.
9b957b78	384
bcdb689b	385	On Mac OS (Classic), C<syscopy> calls C<Mac::MoreFiles::FSpFileCopy>,
	386	if available.
	387
338de517	388	B<Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)>:
9b957b78	389
71be2cbc	390	If both arguments to C<copy> are not file handles,
71be2cbc	391	then C<copy> will perform a "system copy" of
9b957b78	392	the input file to a new output file, in order to preserve file
9b957b78	393	attributes, indexed file structure, I<etc.> The buffer size
71be2cbc	394	parameter is ignored. If either argument to C<copy> is a
71be2cbc	395	handle to an opened file, then data is copied using Perl
9b957b78	396	operators, and no effort is made to preserve file attributes
	397	or record structure.
	398
55497cff	399	The system copy routine may also be called directly under VMS and OS/2
55497cff	400	as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
71be2cbc	401	is the routine that does the actual work for syscopy).
9b957b78	402
9b957b78	403	=item rmscopy($from,$to[,$date_flag])
0cdecedb	404	X<rmscopy>
9b957b78	405
71be2cbc	406	The first and second arguments may be strings, typeglobs, typeglob
	407	references, or objects inheriting from IO::Handle;
	408	they are used in all cases to obtain the
9b957b78	409	I<filespec> of the input and output files, respectively. The
	410	name and type of the input file are used as defaults for the
	411	output file, if necessary.
	412
	413	A new version of the output file is always created, which
	414	inherits the structure and RMS attributes of the input file,
	415	except for owner and protections (and possibly timestamps;
	416	see below). All data from the input file is copied to the
	417	output file; if either of the first two parameters to C<rmscopy>
	418	is a file handle, its position is unchanged. (Note that this
	419	means a file handle pointing to the output file will be
	420	associated with an old version of that file after C<rmscopy>
	421	returns, not the newly created version.)
	422
	423	The third parameter is an integer flag, which tells C<rmscopy>
1fef88e7	424	how to handle timestamps. If it is E<lt> 0, none of the input file's
1fef88e7	425	timestamps are propagated to the output file. If it is E<gt> 0, then
9b957b78	426	it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
	427	timestamps other than the revision date are propagated; if bit 1
	428	is set, the revision date is propagated. If the third parameter
	429	to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
	430	if the name or type of the output file was explicitly specified,
	431	then no timestamps are propagated, but if they were taken implicitly
	432	from the input filespec, then all timestamps other than the
	433	revision date are propagated. If this parameter is not supplied,
	434	it defaults to 0.
	435
	436	Like C<copy>, C<rmscopy> returns 1 on success. If an error occurs,
	437	it sets C<$!>, deletes the output file, and returns 0.
	438
55497cff	439	=back
55497cff	440
f716a1dd	441	=head1 RETURN
f716a1dd	442
441496b2	443	All functions return 1 on success, 0 on failure.
441496b2	444	$! will be set if an error was encountered.
f716a1dd	445
6c254d95	446	=head1 NOTES
	447
	448	=over 4
	449
	450	=item *
	451
	452	On Mac OS (Classic), the path separator is ':', not '/', and the
	453	current directory is denoted as ':', not '.'. You should be careful
	454	about specifying relative pathnames. While a full path always begins
	455	with a volume name, a relative pathname should always begin with a
	456	':'. If specifying a volume name only, a trailing ':' is required.
	457
	458	E.g.
	459
	460	copy("file1", "tmp"); # creates the file 'tmp' in the current directory
	461	copy("file1", ":tmp:"); # creates :tmp:file1
	462	copy("file1", ":tmp"); # same as above
0cdecedb	463	copy("file1", "tmp"); # same as above, if 'tmp' is a directory (but don't do
6c254d95	464	# that, since it may cause confusion, see example #1)
	465	copy("file1", "tmp:file1"); # error, since 'tmp:' is not a volume
	466	copy("file1", ":tmp:file1"); # ok, partial path
	467	copy("file1", "DataHD:"); # creates DataHD:file1
0cdecedb	468
907fbfa1	469	move("MacintoshHD:fileA", "DataHD:fileB"); # moves (doesn't copy) files from one
6c254d95	470	# volume to another
	471
	472	=back
	473
f716a1dd	474	=head1 AUTHOR
f716a1dd	475
441496b2	476	File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
bd3fa61c	477	and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
f716a1dd	478
f716a1dd	479	=cut
441496b2	480