initial partial sketch

[scpubgit/DX.git] / lib / DX / Scope.pm

package DX::Scope;

use DX::Class;

has predicates => (is => 'ro', required => 1);

has globals => (is => 'ro', required => 1);

has locals => (is => 'ro', required => 1);

has known_facts => (is => 'ro', required => 1);

sub lookup_predicate {
  my ($self, $predicate) = @_;
  return $self->predicates->{$predicate} || die "No such predicate: $predicate";
}

sub lookup {
  my ($self, $name) = @_;
  my $lookup_in = ($name =~ /^[_A-Z]/ ? $self->locals->[-1] : $self->globals);
  return $lookup_in->get_member_at($name) || die "No such name in scope: $name";
}

sub depth { $#{$_[0]->locals} }

sub prune_to {
  my ($self, $to) = @_;
  $self->but(locals => [ @{$self->locals}[0..$to] ]);
}

sub get_member_at {
  my ($self, $at) = @_;
  if ($at =~ /^[0-9]+$/) {
    return $self->locals->[$at];
  }
  return $self->globals->get_member_at($at);
}

sub with_member_at {
  my ($self, $at, $value) = @_;
  if ($at =~ /^[0-9]+$/) {
    my @locals = @{$self->locals};
    $locals[$at] = $at;
    return $self->but(
      locals => \@locals
    );
  }
  return $self->but(
    globals => $self->globals->with_member_at($at, $value)
  );
}

1;