wheeeeeeeeee

[scpubgit/DKit.git] / lib / DX / Op / CallRule.pm

package DX::Op::CallRule;

use DX::Op::SetScope;
use DX::Op::FromCode;
use DX::Var;
use DX::ArrayStream;
use Moo;

with 'DX::Role::Op';

has rule_name => (is => 'ro', required => 1);
has rule_args => (is => 'ro', required => 1);
has full_name => (is => 'lazy', builder => sub {
  my ($self) = @_;
  join('/', $self->rule_name, scalar @{$self->rule_args});
});

sub run {
  my ($self, $state) = @_;
  my @args = map {
    if (!ref($_)) {
      $state->scope_var($_)
    } elsif (ref($_) eq 'ARRAY') {
      if ($_->[0] eq 'value') {
        +{ bound_value => $_->[1] };
      } else {
        die "Arrayref in argspec is not value";
      }
    } else {
      die "Argspec incomprehensible";
    }
  } @{$self->rule_args};
  my @rules = @{$state->rule_set->rules->{$self->full_name}||[]};
  die "No rules for ${\$self->full_name}" unless @rules;
  my $var = DX::Var->new(id => 'OR')
                   ->with_stream(DX::ArrayStream->from_array(@rules));
  my $invoke = DX::Op::FromCode->new(
    code => sub {
      my ($self, $state) = @_;
      my ($names, $body) = @{$var->bound_value};
      my %new; @new{@$names} = @args;
      $state->but(scope => {})->assign_vars(%new)->then($body);
    }
  );
  my $ret_op = DX::Op::SetScope->new(
    scope => $state->scope, next => $self->next
  );
  $state->push_return_then($ret_op, $invoke)->mark_choice($var);
}

1;