move the actual doing stuff code for FS lib into a Guts.pm

[scpubgit/DKit.git] / lib / DX / Lib / FS / Action / RewriteFile.pm

package DX::Lib::FS::Action::RewriteFile;

use DX::Lib::FS::Fact::FileContent;
use DX::Lib::FS::Guts;
use Moo;

with 'DX::Role::Action';

has from => (is => 'ro', required => 1, handles => [ 'path' ]);

has add_lines => (is => 'ro', default => sub { [] });

has remove_lines => (is => 'ro', default => sub { {} });

has final_content => (is => 'lazy', init_arg => undef, builder => sub {
  my ($self) = @_;
  my %remove = %{$self->remove_lines};
  join("\n",
    (grep !$remove{$_}, $self->from->lines->all),
    @{$self->add_lines},
    ''
  );
});

sub but_add {
  $_[0]->but(add_lines => [ @{$_[0]->add_lines}, $_[1] ]);
}

sub but_remove {
  $_[0]->but(remove_lines => [ %{$_[0]->remove_lines}, $_[1] => 1 ]);
}

sub expected_effect {
  my ($self) = @_;
  +(file_content => DX::Lib::FS::Fact::FileContent->new(
    path => $self->path,
    data => $self->final_content
  ));
}

sub _do_run {
  my ($self) = @_;
  DX::Lib::FS::Guts->rewrite_file($self->path, $self->final_content);
  return +(file_content => $self->path);
}

1;