[dbsrgits/DBIx-Class-Schema-Loader.git] / lib / DBIx / Class / Schema / Loader / DBI.pm

package DBIx::Class::Schema::Loader::DBI;

use strict;
use warnings;
use base qw/DBIx::Class::Schema::Loader::Base/;
use Class::C3;
use Carp::Clan qw/^DBIx::Class/;

our $VERSION = '0.04999_10';

=head1 NAME

DBIx::Class::Schema::Loader::DBI - DBIx::Class::Schema::Loader DBI Implementation.

=head1 SYNOPSIS

See L<DBIx::Class::Schema::Loader::Base>

=head1 DESCRIPTION

This is the base class for L<DBIx::Class::Schema::Loader::Base> classes for
DBI-based storage backends, and implements the common functionality between them.

See L<DBIx::Class::Schema::Loader::Base> for the available options.

=head1 METHODS

=head2 new

Overlays L<DBIx::Class::Schema::Loader::Base/new> to do some DBI-specific
things.

=cut

sub new {
    my $self = shift->next::method(@_);

    # rebless to vendor-specific class if it exists and loads
    my $dbh = $self->schema->storage->dbh;
    my $driver = $dbh->{Driver}->{Name};

    my $subclass = 'DBIx::Class::Schema::Loader::DBI::' . $driver;
    if ($self->load_optional_class($subclass)) {
        bless $self, $subclass unless $self->isa($subclass);
        $self->_rebless;
    }

    # Set up the default quoting character and name seperators
    $self->{_quoter} = $self->_build_quoter;
    $self->{_namesep} = $self->_build_namesep;
    # For our usage as regex matches, concatenating multiple quoter
    # values works fine (e.g. s/\Q<>\E// if quoter was [ '<', '>' ])
    if( ref $self->{_quoter} eq 'ARRAY') {
        $self->{_quoter} = join(q{}, @{$self->{_quoter}});
    }

    $self->_setup;

    $self;
}

sub _build_quoter {
    my $self = shift;
    my $dbh = $self->schema->storage->dbh;
    return $dbh->get_info(29)
           || $self->schema->storage->sql_maker->quote_char
           || q{"};
}

sub _build_namesep {
    my $self = shift;
    my $dbh = $self->schema->storage->dbh;
    return $dbh->get_info(41)
           || $self->schema->storage->sql_maker->name_sep
           || q{.};
}

# Override this in vendor modules to do things at the end of ->new()
sub _setup { }

# Override this in vendor module to load a subclass if necessary
sub _rebless { }

# Returns an array of table names
sub _tables_list { 
    my $self = shift;

    my ($table, $type) = @_ ? @_ : ('%', '%');

    my $dbh = $self->schema->storage->dbh;
    my @tables = $dbh->tables(undef, $self->db_schema, $table, $type);

    my $qt = qr/\Q$self->{_quoter}\E/;

    if ($self->{_quoter} && $tables[0] =~ /$qt/) {
        s/.* $qt (?= .* $qt)//xg for @tables;
    } else {
        s/^.*\Q$self->{_namesep}\E// for @tables;
    }
    s/$qt//g for @tables;

    return @tables;
}

=head2 load

We override L<DBIx::Class::Schema::Loader::Base/load> here to hook in our localized settings for C<$dbh> error handling.

=cut

sub load {
    my $self = shift;

    local $self->schema->storage->dbh->{RaiseError} = 1;
    local $self->schema->storage->dbh->{PrintError} = 0;
    $self->next::method(@_);
}

# Returns an arrayref of column names
sub _table_columns {
    my ($self, $table) = @_;

    my $dbh = $self->schema->storage->dbh;

    if($self->{db_schema}) {
        $table = $self->{db_schema} . $self->{_namesep} .
            $self->_quote_table_name($table);
    } else {
        $table = $self->_quote_table_name($table);
    }

    my $sth = $dbh->prepare($self->schema->storage->sql_maker->select(\$table, undef, \'1 = 0'));
    $sth->execute;
    my $retval = \@{$sth->{NAME_lc}};
    $sth->finish;

    $retval;
}

# Returns arrayref of pk col names
sub _table_pk_info { 
    my ($self, $table) = @_;

    my $dbh = $self->schema->storage->dbh;

    my @primary = map { lc } $dbh->primary_key('', $self->db_schema, $table);
    s/\Q$self->{_quoter}\E//g for @primary;

    return \@primary;
}

# Override this for vendor-specific uniq info
sub _table_uniq_info {
    my ($self, $table) = @_;

    my $dbh = $self->schema->storage->dbh;
    if(!$dbh->can('statistics_info')) {
        warn "No UNIQUE constraint information can be gathered for this vendor";
        return [];
    }

    my %indices;
    my $sth = $dbh->statistics_info(undef, $self->db_schema, $table, 1, 1);
    while(my $row = $sth->fetchrow_hashref) {
        # skip table-level stats, conditional indexes, and any index missing
        #  critical fields
        next if $row->{TYPE} eq 'table'
            || defined $row->{FILTER_CONDITION}
            || !$row->{INDEX_NAME}
            || !defined $row->{ORDINAL_POSITION}
            || !$row->{COLUMN_NAME};

        $indices{$row->{INDEX_NAME}}->{$row->{ORDINAL_POSITION}} = $row->{COLUMN_NAME};
    }
    $sth->finish;

    my @retval;
    foreach my $index_name (keys %indices) {
        my $index = $indices{$index_name};
        push(@retval, [ $index_name => [
            map { $index->{$_} }
                sort keys %$index
        ]]);
    }

    return \@retval;
}

# Find relationships
sub _table_fk_info {
    my ($self, $table) = @_;

    my $dbh = $self->schema->storage->dbh;
    my $sth = $dbh->foreign_key_info( '', $self->db_schema, '',
                                      '', $self->db_schema, $table );
    return [] if !$sth;

    my %rels;

    my $i = 1; # for unnamed rels, which hopefully have only 1 column ...
    while(my $raw_rel = $sth->fetchrow_arrayref) {
        my $uk_tbl  = $raw_rel->[2];
        my $uk_col  = lc $raw_rel->[3];
        my $fk_col  = lc $raw_rel->[7];
        my $relid   = ($raw_rel->[11] || ( "__dcsld__" . $i++ ));
        $uk_tbl =~ s/\Q$self->{_quoter}\E//g;
        $uk_col =~ s/\Q$self->{_quoter}\E//g;
        $fk_col =~ s/\Q$self->{_quoter}\E//g;
        $relid  =~ s/\Q$self->{_quoter}\E//g;
        $rels{$relid}->{tbl} = $uk_tbl;
        $rels{$relid}->{cols}->{$uk_col} = $fk_col;
    }
    $sth->finish;

    my @rels;
    foreach my $relid (keys %rels) {
        push(@rels, {
            remote_columns => [ keys   %{$rels{$relid}->{cols}} ],
            local_columns  => [ values %{$rels{$relid}->{cols}} ],
            remote_table   => $rels{$relid}->{tbl},
        });
    }

    return \@rels;
}

# ported in from DBIx::Class::Storage::DBI:
sub _columns_info_for {
    my ($self, $table) = @_;

    my $dbh = $self->schema->storage->dbh;

    if ($dbh->can('column_info')) {
        my %result;
        eval {
            my $sth = $dbh->column_info( undef, $self->db_schema, $table, '%' );
            while ( my $info = $sth->fetchrow_hashref() ){
                my %column_info;
                $column_info{data_type}   = $info->{TYPE_NAME};
                $column_info{size}      = $info->{COLUMN_SIZE};
                $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
                $column_info{default_value} = $info->{COLUMN_DEF};
                my $col_name = $info->{COLUMN_NAME};
                $col_name =~ s/^\"(.*)\"$/$1/;

                my $extra_info = $self->_extra_column_info($info) || {};

                $result{$col_name} = { %column_info, %$extra_info };
            }
            $sth->finish;
        };
      return \%result if !$@ && scalar keys %result;
    }

    if($self->db_schema) {
        $table = $self->db_schema . $self->{_namesep} . $table;
    }
    my %result;
    my $sth = $dbh->prepare($self->schema->storage->sql_maker->select($table, undef, \'1 = 0'));
    $sth->execute;
    my @columns = @{$sth->{NAME_lc}};
    for my $i ( 0 .. $#columns ){
        my %column_info;
        $column_info{data_type} = $sth->{TYPE}->[$i];
        $column_info{size} = $sth->{PRECISION}->[$i];
        $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;

        if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
            $column_info{data_type} = $1;
            $column_info{size}    = $2;
        }

        my $extra_info = $self->_extra_column_info($table, $columns[$i], $sth, $i) || {};

        $result{$columns[$i]} = { %column_info, %$extra_info };
    }
    $sth->finish;

    foreach my $col (keys %result) {
        my $colinfo = $result{$col};
        my $type_num = $colinfo->{data_type};
        my $type_name;
        if(defined $type_num && $dbh->can('type_info')) {
            my $type_info = $dbh->type_info($type_num);
            $type_name = $type_info->{TYPE_NAME} if $type_info;
            $colinfo->{data_type} = $type_name if $type_name;
        }
    }

    return \%result;
}

# Override this in vendor class to return any additional column
# attributes
sub _extra_column_info {}

=head1 SEE ALSO

L<DBIx::Class::Schema::Loader>

=head1 AUTHOR

See L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.

=head1 LICENSE

This library is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
Commit	Line	Data
996be9ee	1	package DBIx::Class::Schema::Loader::DBI;
	2
	3	use strict;
	4	use warnings;
abaf2c66	5	use base qw/DBIx::Class::Schema::Loader::Base/;
996be9ee	6	use Class::C3;
fa994d3c	7	use Carp::Clan qw/^DBIx::Class/;
996be9ee	8
b1ad1a84	9	our $VERSION = '0.04999_10';
32f784fc	10
996be9ee	11	=head1 NAME
	12
	13	DBIx::Class::Schema::Loader::DBI - DBIx::Class::Schema::Loader DBI Implementation.
	14
	15	=head1 SYNOPSIS
	16
	17	See L<DBIx::Class::Schema::Loader::Base>
	18
	19	=head1 DESCRIPTION
	20
	21	This is the base class for L<DBIx::Class::Schema::Loader::Base> classes for
	22	DBI-based storage backends, and implements the common functionality between them.
	23
	24	See L<DBIx::Class::Schema::Loader::Base> for the available options.
	25
	26	=head1 METHODS
	27
	28	=head2 new
	29
	30	Overlays L<DBIx::Class::Schema::Loader::Base/new> to do some DBI-specific
	31	things.
	32
	33	=cut
	34
	35	sub new {
	36	my $self = shift->next::method(@_);
	37
	38	# rebless to vendor-specific class if it exists and loads
	39	my $dbh = $self->schema->storage->dbh;
	40	my $driver = $dbh->{Driver}->{Name};
6ae3f335	41
996be9ee	42	my $subclass = 'DBIx::Class::Schema::Loader::DBI::' . $driver;
ee1c392c	43	if ($self->load_optional_class($subclass)) {
3953cbee	44	bless $self, $subclass unless $self->isa($subclass);
ee1c392c	45	$self->_rebless;
996be9ee	46	}
	47
	48	# Set up the default quoting character and name seperators
77d3753e	49	$self->{_quoter} = $self->_build_quoter;
77d3753e	50	$self->{_namesep} = $self->_build_namesep;
996be9ee	51	# For our usage as regex matches, concatenating multiple quoter
	52	# values works fine (e.g. s/\Q<>\E// if quoter was [ '<', '>' ])
	53	if( ref $self->{_quoter} eq 'ARRAY') {
	54	$self->{_quoter} = join(q{}, @{$self->{_quoter}});
	55	}
	56
	57	$self->_setup;
	58
	59	$self;
	60	}
	61
77d3753e	62	sub _build_quoter {
	63	my $self = shift;
	64	my $dbh = $self->schema->storage->dbh;
	65	return $dbh->get_info(29)
	66	\|\| $self->schema->storage->sql_maker->quote_char
	67	\|\| q{"};
	68	}
	69
	70	sub _build_namesep {
	71	my $self = shift;
	72	my $dbh = $self->schema->storage->dbh;
	73	return $dbh->get_info(41)
	74	\|\| $self->schema->storage->sql_maker->name_sep
	75	\|\| q{.};
	76	}
	77
996be9ee	78	# Override this in vendor modules to do things at the end of ->new()
	79	sub _setup { }
	80
6ae3f335	81	# Override this in vendor module to load a subclass if necessary
	82	sub _rebless { }
	83
996be9ee	84	# Returns an array of table names
	85	sub _tables_list {
	86	my $self = shift;
	87
e57fd726	88	my ($table, $type) = @_ ? @_ : ('%', '%');
e57fd726	89
996be9ee	90	my $dbh = $self->schema->storage->dbh;
e57fd726	91	my @tables = $dbh->tables(undef, $self->db_schema, $table, $type);
77d3753e	92
385c593b	93	my $qt = qr/\Q$self->{_quoter}\E/;
	94
	95	if ($self->{_quoter} && $tables[0] =~ /$qt/) {
	96	s/.* $qt (?= .* $qt)//xg for @tables;
	97	} else {
	98	s/^.*\Q$self->{_namesep}\E// for @tables;
	99	}
	100	s/$qt//g for @tables;
996be9ee	101
	102	return @tables;
	103	}
	104
12af3806	105	=head2 load
	106
	107	We override L<DBIx::Class::Schema::Loader::Base/load> here to hook in our localized settings for C<$dbh> error handling.
	108
	109	=cut
	110
	111	sub load {
	112	my $self = shift;
	113
	114	local $self->schema->storage->dbh->{RaiseError} = 1;
	115	local $self->schema->storage->dbh->{PrintError} = 0;
	116	$self->next::method(@_);
	117	}
	118
996be9ee	119	# Returns an arrayref of column names
	120	sub _table_columns {
	121	my ($self, $table) = @_;
	122
	123	my $dbh = $self->schema->storage->dbh;
	124
	125	if($self->{db_schema}) {
385c593b	126	$table = $self->{db_schema} . $self->{_namesep} .
	127	$self->_quote_table_name($table);
	128	} else {
	129	$table = $self->_quote_table_name($table);
996be9ee	130	}
996be9ee	131
385c593b	132	my $sth = $dbh->prepare($self->schema->storage->sql_maker->select(\$table, undef, \'1 = 0'));
996be9ee	133	$sth->execute;
3b7f80f9	134	my $retval = \@{$sth->{NAME_lc}};
	135	$sth->finish;
	136
	137	$retval;
996be9ee	138	}
	139
	140	# Returns arrayref of pk col names
	141	sub _table_pk_info {
fd589700	142	my ($self, $table) = @_;
996be9ee	143
	144	my $dbh = $self->schema->storage->dbh;
	145
	146	my @primary = map { lc } $dbh->primary_key('', $self->db_schema, $table);
	147	s/\Q$self->{_quoter}\E//g for @primary;
	148
	149	return \@primary;
	150	}
	151
fd589700	152	# Override this for vendor-specific uniq info
996be9ee	153	sub _table_uniq_info {
fd589700	154	my ($self, $table) = @_;
	155
	156	my $dbh = $self->schema->storage->dbh;
	157	if(!$dbh->can('statistics_info')) {
	158	warn "No UNIQUE constraint information can be gathered for this vendor";
	159	return [];
	160	}
	161
	162	my %indices;
	163	my $sth = $dbh->statistics_info(undef, $self->db_schema, $table, 1, 1);
	164	while(my $row = $sth->fetchrow_hashref) {
	165	# skip table-level stats, conditional indexes, and any index missing
	166	# critical fields
	167	next if $row->{TYPE} eq 'table'
	168	\|\| defined $row->{FILTER_CONDITION}
	169	\|\| !$row->{INDEX_NAME}
	170	\|\| !defined $row->{ORDINAL_POSITION}
	171	\|\| !$row->{COLUMN_NAME};
	172
	173	$indices{$row->{INDEX_NAME}}->{$row->{ORDINAL_POSITION}} = $row->{COLUMN_NAME};
	174	}
3b7f80f9	175	$sth->finish;
fd589700	176
	177	my @retval;
	178	foreach my $index_name (keys %indices) {
	179	my $index = $indices{$index_name};
	180	push(@retval, [ $index_name => [
	181	map { $index->{$_} }
	182	sort keys %$index
	183	]]);
	184	}
	185
	186	return \@retval;
996be9ee	187	}
	188
	189	# Find relationships
	190	sub _table_fk_info {
	191	my ($self, $table) = @_;
	192
	193	my $dbh = $self->schema->storage->dbh;
a168c1c4	194	my $sth = $dbh->foreign_key_info( '', $self->db_schema, '',
a168c1c4	195	'', $self->db_schema, $table );
996be9ee	196	return [] if !$sth;
	197
	198	my %rels;
	199
	200	my $i = 1; # for unnamed rels, which hopefully have only 1 column ...
	201	while(my $raw_rel = $sth->fetchrow_arrayref) {
	202	my $uk_tbl = $raw_rel->[2];
	203	my $uk_col = lc $raw_rel->[3];
	204	my $fk_col = lc $raw_rel->[7];
	205	my $relid = ($raw_rel->[11] \|\| ( "__dcsld__" . $i++ ));
	206	$uk_tbl =~ s/\Q$self->{_quoter}\E//g;
	207	$uk_col =~ s/\Q$self->{_quoter}\E//g;
	208	$fk_col =~ s/\Q$self->{_quoter}\E//g;
	209	$relid =~ s/\Q$self->{_quoter}\E//g;
	210	$rels{$relid}->{tbl} = $uk_tbl;
	211	$rels{$relid}->{cols}->{$uk_col} = $fk_col;
	212	}
3b7f80f9	213	$sth->finish;
996be9ee	214
	215	my @rels;
	216	foreach my $relid (keys %rels) {
	217	push(@rels, {
	218	remote_columns => [ keys %{$rels{$relid}->{cols}} ],
	219	local_columns => [ values %{$rels{$relid}->{cols}} ],
	220	remote_table => $rels{$relid}->{tbl},
	221	});
	222	}
	223
	224	return \@rels;
	225	}
	226
12af3806	227	# ported in from DBIx::Class::Storage::DBI:
	228	sub _columns_info_for {
	229	my ($self, $table) = @_;
	230
	231	my $dbh = $self->schema->storage->dbh;
	232
	233	if ($dbh->can('column_info')) {
	234	my %result;
	235	eval {
	236	my $sth = $dbh->column_info( undef, $self->db_schema, $table, '%' );
12af3806	237	while ( my $info = $sth->fetchrow_hashref() ){
	238	my %column_info;
	239	$column_info{data_type} = $info->{TYPE_NAME};
	240	$column_info{size} = $info->{COLUMN_SIZE};
	241	$column_info{is_nullable} = $info->{NULLABLE} ? 1 : 0;
	242	$column_info{default_value} = $info->{COLUMN_DEF};
	243	my $col_name = $info->{COLUMN_NAME};
	244	$col_name =~ s/^\"(.*)\"$/$1/;
	245
a8df0345	246	my $extra_info = $self->_extra_column_info($info) \|\| {};
78b7ccaa	247
a8df0345	248	$result{$col_name} = { %column_info, %$extra_info };
12af3806	249	}
3b7f80f9	250	$sth->finish;
12af3806	251	};
	252	return \%result if !$@ && scalar keys %result;
	253	}
	254
	255	if($self->db_schema) {
	256	$table = $self->db_schema . $self->{_namesep} . $table;
	257	}
	258	my %result;
6ce0bcc3	259	my $sth = $dbh->prepare($self->schema->storage->sql_maker->select($table, undef, \'1 = 0'));
12af3806	260	$sth->execute;
	261	my @columns = @{$sth->{NAME_lc}};
	262	for my $i ( 0 .. $#columns ){
	263	my %column_info;
6ce0bcc3	264	$column_info{data_type} = $sth->{TYPE}->[$i];
12af3806	265	$column_info{size} = $sth->{PRECISION}->[$i];
	266	$column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
	267
	268	if ($column_info{data_type} =~ m/^(.?)\((.?)\)$/) {
	269	$column_info{data_type} = $1;
	270	$column_info{size} = $2;
	271	}
	272
a8df0345	273	my $extra_info = $self->_extra_column_info($table, $columns[$i], $sth, $i) \|\| {};
78b7ccaa	274
a8df0345	275	$result{$columns[$i]} = { %column_info, %$extra_info };
12af3806	276	}
6ce0bcc3	277	$sth->finish;
	278
	279	foreach my $col (keys %result) {
	280	my $colinfo = $result{$col};
	281	my $type_num = $colinfo->{data_type};
	282	my $type_name;
	283	if(defined $type_num && $dbh->can('type_info')) {
	284	my $type_info = $dbh->type_info($type_num);
	285	$type_name = $type_info->{TYPE_NAME} if $type_info;
	286	$colinfo->{data_type} = $type_name if $type_name;
	287	}
	288	}
12af3806	289
	290	return \%result;
	291	}
	292
a8df0345	293	# Override this in vendor class to return any additional column
	294	# attributes
	295	sub _extra_column_info {}
c5baf131	296
996be9ee	297	=head1 SEE ALSO
	298
	299	L<DBIx::Class::Schema::Loader>
	300
be80bba7	301	=head1 AUTHOR
	302
	303	See L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
	304
	305	=head1 LICENSE
	306
	307	This library is free software; you can redistribute it and/or modify it under
	308	the same terms as Perl itself.
	309
996be9ee	310	=cut
	311
	312	1;