[p5sagit/p5-mst-13.2.git] / lib / Cwd.pm

package Cwd;
require 5.000;

=head1 NAME

getcwd - get pathname of current working directory

=head1 SYNOPSIS

    use Cwd;
    $dir = cwd;

    use Cwd;
    $dir = getcwd;

    use Cwd;
    $dir = fastgetcwd;

    use Cwd 'chdir';
    chdir "/tmp";
    print $ENV{'PWD'};

    use Cwd 'abs_path';
    print abs_path($ENV{'PWD'});

    use Cwd 'fast_abs_path';
    print fast_abs_path($ENV{'PWD'});

=head1 DESCRIPTION

The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
in Perl.

The abs_path() function takes a single argument and returns the
absolute pathname for that argument. It uses the same algorithm as
getcwd(). (actually getcwd() is abs_path("."))

The fastcwd() function looks the same as getcwd(), but runs faster.
It's also more dangerous because it might conceivably chdir() you out
of a directory that it can't chdir() you back into.  If fastcwd
encounters a problem it will return undef but will probably leave you
in a different directory.  For a measure of extra security, if
everything appears to have worked, the fastcwd() function will check
that it leaves you in the same directory that it started in. If it has
changed it will C<die> with the message "Unstable directory path,
current directory changed unexpectedly". That should never happen.

The fast_abs_path() function looks the same as abs_path(), but runs faster.
And like fastcwd() is more dangerous.

The cwd() function looks the same as getcwd and fastgetcwd but is
implemented using the most natural and safe form for the current
architecture. For most systems it is identical to `pwd` (but without
the trailing line terminator).

It is recommended that cwd (or another *cwd() function) is used in
I<all> code to ensure portability.

If you ask to override your chdir() built-in function, then your PWD
environment variable will be kept up to date.  (See
L<perlsub/Overriding Builtin Functions>.) Note that it will only be
kept up to date if all packages which use chdir import it from Cwd.

=cut

## use strict;

use Carp;

$VERSION = '2.01';

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
@EXPORT_OK = qw(chdir abs_path fast_abs_path);


# The 'natural and safe form' for UNIX (pwd may be setuid root)

sub _backtick_pwd {
    my $cwd;
    chop($cwd = `pwd`);
    $cwd;
}

# Since some ports may predefine cwd internally (e.g., NT)
# we take care not to override an existing definition for cwd().

*cwd = \&_backtick_pwd unless defined &cwd;


# By Brandon S. Allbery
#
# Usage: $cwd = getcwd();

sub getcwd
{
    abs_path('.');
}

# By John Bazik
#
# Usage: $cwd = &fastcwd;
#
# This is a faster version of getcwd.  It's also more dangerous because
# you might chdir out of a directory that you can't chdir back into.
    
# List of metachars taken from do_exec() in doio.c
my $quoted_shell_meta = quotemeta('$&*(){}[]";\\|?<>~`'."'\n");

sub fastcwd {
    my($odev, $oino, $cdev, $cino, $tdev, $tino);
    my(@path, $path);
    local(*DIR);

    my($orig_cdev, $orig_cino) = stat('.');
    ($cdev, $cino) = ($orig_cdev, $orig_cino);
    for (;;) {
	my $direntry;
	($odev, $oino) = ($cdev, $cino);
	CORE::chdir('..') || return undef;
	($cdev, $cino) = stat('.');
	last if $odev == $cdev && $oino == $cino;
	opendir(DIR, '.') || return undef;
	for (;;) {
	    $direntry = readdir(DIR);
	    last unless defined $direntry;
	    next if $direntry eq '.';
	    next if $direntry eq '..';

	    ($tdev, $tino) = lstat($direntry);
	    last unless $tdev != $odev || $tino != $oino;
	}
	closedir(DIR);
	return undef unless defined $direntry; # should never happen
	unshift(@path, $direntry);
    }
    $path = '/' . join('/', @path);
    if ($^O eq 'apollo') { $path = "/".$path; }
    # At this point $path may be tainted (if tainting) and chdir would fail.
    # To be more useful we untaint it then check that we landed where we started.
    $path = $1 if $path =~ /^(.*)$/;	# untaint
    CORE::chdir($path) || return undef;
    ($cdev, $cino) = stat('.');
    die "Unstable directory path, current directory changed unexpectedly"
	if $cdev != $orig_cdev || $cino != $orig_cino;
    $path;
}


# Keeps track of current working directory in PWD environment var
# Usage:
#	use Cwd 'chdir';
#	chdir $newdir;

my $chdir_init = 0;

sub chdir_init {
    if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos') {
	my($dd,$di) = stat('.');
	my($pd,$pi) = stat($ENV{'PWD'});
	if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
	    $ENV{'PWD'} = cwd();
	}
    }
    else {
	$ENV{'PWD'} = cwd();
    }
    # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
    if ($ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|) {
	my($pd,$pi) = stat($2);
	my($dd,$di) = stat($1);
	if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
	    $ENV{'PWD'}="$2$3";
	}
    }
    $chdir_init = 1;
}

sub chdir {
    my $newdir = shift || '';	# allow for no arg (chdir to HOME dir)
    $newdir =~ s|///*|/|g;
    chdir_init() unless $chdir_init;
    return 0 unless CORE::chdir $newdir;
    if ($^O eq 'VMS') { return $ENV{'PWD'} = $ENV{'DEFAULT'} }

    if ($newdir =~ m#^/#) {
	$ENV{'PWD'} = $newdir;
    } else {
	my @curdir = split(m#/#,$ENV{'PWD'});
	@curdir = ('') unless @curdir;
	my $component;
	foreach $component (split(m#/#, $newdir)) {
	    next if $component eq '.';
	    pop(@curdir),next if $component eq '..';
	    push(@curdir,$component);
	}
	$ENV{'PWD'} = join('/',@curdir) || '/';
    }
    1;
}

# Taken from Cwd.pm It is really getcwd with an optional
# parameter instead of '.'
#

sub abs_path
{
    my $start = @_ ? shift : '.';
    my($dotdots, $cwd, @pst, @cst, $dir, @tst);

    unless (@cst = stat( $start ))
    {
	carp "stat($start): $!";
	return '';
    }
    $cwd = '';
    $dotdots = $start;
    do
    {
	$dotdots .= '/..';
	@pst = @cst;
	unless (opendir(PARENT, $dotdots))
	{
	    carp "opendir($dotdots): $!";
	    return '';
	}
	unless (@cst = stat($dotdots))
	{
	    carp "stat($dotdots): $!";
	    closedir(PARENT);
	    return '';
	}
	if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
	{
	    $dir = undef;
	}
	else
	{
	    do
	    {
		unless (defined ($dir = readdir(PARENT)))
	        {
		    carp "readdir($dotdots): $!";
		    closedir(PARENT);
		    return '';
		}
		$tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
	    }
	    while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
		   $tst[1] != $pst[1]);
	}
	$cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
	closedir(PARENT);
    } while (defined $dir);
    chop($cwd) unless $cwd eq '/'; # drop the trailing /
    $cwd;
}

sub fast_abs_path {
    my $cwd = getcwd();
    my $path = shift || '.';
    CORE::chdir($path) || croak "Cannot chdir to $path:$!";
    my $realpath = getcwd();
    CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
    $realpath;
}


# --- PORTING SECTION ---

# VMS: $ENV{'DEFAULT'} points to default directory at all times
# 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
# Note: Use of Cwd::chdir() causes the logical name PWD to be defined
#   in the process logical name table as the default device and directory
#   seen by Perl. This may not be the same as the default device
#   and directory seen by DCL after Perl exits, since the effects
#   the CRTL chdir() function persist only until Perl exits.

sub _vms_cwd {
    return $ENV{'DEFAULT'};
}

sub _vms_abs_path {
    return $ENV{'DEFAULT'} unless @_;
    my $path = VMS::Filespec::pathify($_[0]);
    croak("Invalid path name $_[0]") unless defined $path;
    return VMS::Filespec::rmsexpand($path);
}

sub _os2_cwd {
    $ENV{'PWD'} = `cmd /c cd`;
    chop $ENV{'PWD'};
    $ENV{'PWD'} =~ s:\\:/:g ;
    return $ENV{'PWD'};
}

sub _win32_cwd {
    $ENV{'PWD'} = Win32::GetCwd();
    $ENV{'PWD'} =~ s:\\:/:g ;
    return $ENV{'PWD'};
}

*_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd && 
                            defined &Win32::GetCwd);

*_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;

sub _dos_cwd {
    if (!defined &Dos::GetCwd) {
        $ENV{'PWD'} = `command /c cd`;
        chop $ENV{'PWD'};
        $ENV{'PWD'} =~ s:\\:/:g ;
    } else {
        $ENV{'PWD'} = Dos::GetCwd();
    }
    return $ENV{'PWD'};
}

sub _qnx_cwd {
    $ENV{'PWD'} = `/usr/bin/fullpath -t`;
    chop $ENV{'PWD'};
    return $ENV{'PWD'};
}

sub _qnx_abs_path {
    my $path = shift || '.';
    my $realpath=`/usr/bin/fullpath -t $path`;
    chop $realpath;
    return $realpath;
}

{
    local $^W = 0;	# assignments trigger 'subroutine redefined' warning

    if ($^O eq 'VMS') {
        *cwd		= \&_vms_cwd;
        *getcwd		= \&_vms_cwd;
        *fastcwd	= \&_vms_cwd;
        *fastgetcwd	= \&_vms_cwd;
        *abs_path	= \&_vms_abs_path;
        *fast_abs_path	= \&_vms_abs_path;
    }
    elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
        # We assume that &_NT_cwd is defined as an XSUB or in the core.
        *cwd		= \&_NT_cwd;
        *getcwd		= \&_NT_cwd;
        *fastcwd	= \&_NT_cwd;
        *fastgetcwd	= \&_NT_cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'os2') {
        # sys_cwd may keep the builtin command
        *cwd		= defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
        *getcwd		= \&cwd;
        *fastgetcwd	= \&cwd;
        *fastcwd	= \&cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'dos') {
        *cwd		= \&_dos_cwd;
        *getcwd		= \&_dos_cwd;
        *fastgetcwd	= \&_dos_cwd;
        *fastcwd	= \&_dos_cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'qnx') {
        *cwd		= \&_qnx_cwd;
        *getcwd		= \&_qnx_cwd;
        *fastgetcwd	= \&_qnx_cwd;
        *fastcwd	= \&_qnx_cwd;
        *abs_path	= \&_qnx_abs_path;
        *fast_abs_path	= \&_qnx_abs_path;
    }
    elsif ($^O eq 'cygwin') {
        *getcwd	= \&cwd;
        *fastgetcwd	= \&cwd;
        *fastcwd	= \&cwd;
        *abs_path	= \&fast_abs_path;
    }
}

# package main; eval join('',<DATA>) || die $@;	# quick test

1;

__END__
BEGIN { import Cwd qw(:DEFAULT chdir); }
print join("\n", cwd, getcwd, fastcwd, "");
chdir('..');
print join("\n", cwd, getcwd, fastcwd, "");
print "$ENV{PWD}\n";
Commit	Line	Data
a0d0e21e	1	package Cwd;
a0d0e21e	2	require 5.000;
a0d0e21e	3
f06db76b	4	=head1 NAME
	5
	6	getcwd - get pathname of current working directory
	7
	8	=head1 SYNOPSIS
	9
4633a7c4	10	use Cwd;
	11	$dir = cwd;
	12
	13	use Cwd;
	14	$dir = getcwd;
f06db76b	15
f06db76b	16	use Cwd;
4633a7c4	17	$dir = fastgetcwd;
f06db76b	18
	19	use Cwd 'chdir';
	20	chdir "/tmp";
	21	print $ENV{'PWD'};
	22
20408e3c	23	use Cwd 'abs_path';
	24	print abs_path($ENV{'PWD'});
	25
	26	use Cwd 'fast_abs_path';
	27	print fast_abs_path($ENV{'PWD'});
	28
f06db76b	29	=head1 DESCRIPTION
	30
	31	The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
4633a7c4	32	in Perl.
f06db76b	33
20408e3c	34	The abs_path() function takes a single argument and returns the
f610777f	35	absolute pathname for that argument. It uses the same algorithm as
20408e3c	36	getcwd(). (actually getcwd() is abs_path("."))
20408e3c	37
cb1a09d0	38	The fastcwd() function looks the same as getcwd(), but runs faster.
fb73857a	39	It's also more dangerous because it might conceivably chdir() you out
	40	of a directory that it can't chdir() you back into. If fastcwd
	41	encounters a problem it will return undef but will probably leave you
	42	in a different directory. For a measure of extra security, if
	43	everything appears to have worked, the fastcwd() function will check
	44	that it leaves you in the same directory that it started in. If it has
	45	changed it will C<die> with the message "Unstable directory path,
	46	current directory changed unexpectedly". That should never happen.
f06db76b	47
20408e3c	48	The fast_abs_path() function looks the same as abs_path(), but runs faster.
	49	And like fastcwd() is more dangerous.
	50
4633a7c4	51	The cwd() function looks the same as getcwd and fastgetcwd but is
	52	implemented using the most natural and safe form for the current
	53	architecture. For most systems it is identical to `pwd` (but without
fb73857a	54	the trailing line terminator).
	55
	56	It is recommended that cwd (or another *cwd() function) is used in
	57	I<all> code to ensure portability.
4633a7c4	58
	59	If you ask to override your chdir() built-in function, then your PWD
	60	environment variable will be kept up to date. (See
55497cff	61	L<perlsub/Overriding Builtin Functions>.) Note that it will only be
1fef88e7	62	kept up to date if all packages which use chdir import it from Cwd.
4633a7c4	63
f06db76b	64	=cut
f06db76b	65
96e4d5b1	66	## use strict;
	67
	68	use Carp;
	69
07569ed3	70	$VERSION = '2.01';
96e4d5b1	71
96e4d5b1	72	require Exporter;
a0d0e21e	73	@ISA = qw(Exporter);
e7ae0116	74	@EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
96e4d5b1	75	@EXPORT_OK = qw(chdir abs_path fast_abs_path);
a0d0e21e	76
4633a7c4	77
8b88ae92	78	# The 'natural and safe form' for UNIX (pwd may be setuid root)
96e4d5b1	79
8b88ae92	80	sub _backtick_pwd {
4633a7c4	81	my $cwd;
	82	chop($cwd = `pwd`);
	83	$cwd;
8b88ae92	84	}
4633a7c4	85
	86	# Since some ports may predefine cwd internally (e.g., NT)
	87	# we take care not to override an existing definition for cwd().
	88
	89	*cwd = \&_backtick_pwd unless defined &cwd;
a0d0e21e	90
748a9306	91
a0d0e21e	92	# By Brandon S. Allbery
	93	#
	94	# Usage: $cwd = getcwd();
	95
	96	sub getcwd
	97	{
07569ed3	98	abs_path('.');
a0d0e21e	99	}
a0d0e21e	100
a0d0e21e	101	# By John Bazik
	102	#
	103	# Usage: $cwd = &fastcwd;
	104	#
	105	# This is a faster version of getcwd. It's also more dangerous because
	106	# you might chdir out of a directory that you can't chdir back into.
fb73857a	107
	108	# List of metachars taken from do_exec() in doio.c
	109	my $quoted_shell_meta = quotemeta('$&*(){}[]";\\\|?<>~`'."'\n");
a0d0e21e	110
	111	sub fastcwd {
	112	my($odev, $oino, $cdev, $cino, $tdev, $tino);
	113	my(@path, $path);
	114	local(*DIR);
	115
fb73857a	116	my($orig_cdev, $orig_cino) = stat('.');
fb73857a	117	($cdev, $cino) = ($orig_cdev, $orig_cino);
a0d0e21e	118	for (;;) {
40000a8c	119	my $direntry;
a0d0e21e	120	($odev, $oino) = ($cdev, $cino);
e79e61e4	121	CORE::chdir('..') \|\| return undef;
a0d0e21e	122	($cdev, $cino) = stat('.');
a0d0e21e	123	last if $odev == $cdev && $oino == $cino;
fb73857a	124	opendir(DIR, '.') \|\| return undef;
a0d0e21e	125	for (;;) {
40000a8c	126	$direntry = readdir(DIR);
fb73857a	127	last unless defined $direntry;
40000a8c	128	next if $direntry eq '.';
40000a8c	129	next if $direntry eq '..';
a0d0e21e	130
40000a8c	131	($tdev, $tino) = lstat($direntry);
a0d0e21e	132	last unless $tdev != $odev \|\| $tino != $oino;
	133	}
	134	closedir(DIR);
fb73857a	135	return undef unless defined $direntry; # should never happen
40000a8c	136	unshift(@path, $direntry);
a0d0e21e	137	}
fb73857a	138	$path = '/' . join('/', @path);
21ac5ced	139	if ($^O eq 'apollo') { $path = "/".$path; }
fb73857a	140	# At this point $path may be tainted (if tainting) and chdir would fail.
	141	# To be more useful we untaint it then check that we landed where we started.
	142	$path = $1 if $path =~ /^(.*)$/; # untaint
e79e61e4	143	CORE::chdir($path) \|\| return undef;
fb73857a	144	($cdev, $cino) = stat('.');
	145	die "Unstable directory path, current directory changed unexpectedly"
	146	if $cdev != $orig_cdev \|\| $cino != $orig_cino;
a0d0e21e	147	$path;
	148	}
	149
	150
4633a7c4	151	# Keeps track of current working directory in PWD environment var
a0d0e21e	152	# Usage:
	153	# use Cwd 'chdir';
	154	# chdir $newdir;
	155
4633a7c4	156	my $chdir_init = 0;
a0d0e21e	157
4633a7c4	158	sub chdir_init {
39e571d4	159	if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos') {
a0d0e21e	160	my($dd,$di) = stat('.');
	161	my($pd,$pi) = stat($ENV{'PWD'});
	162	if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
4633a7c4	163	$ENV{'PWD'} = cwd();
a0d0e21e	164	}
	165	}
	166	else {
4633a7c4	167	$ENV{'PWD'} = cwd();
a0d0e21e	168	}
4633a7c4	169	# Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
a0d0e21e	170	if ($ENV{'PWD'} =~ m\|(/[^/]+(/[^/]+/[^/]+))(.*)\|) {
	171	my($pd,$pi) = stat($2);
	172	my($dd,$di) = stat($1);
	173	if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
	174	$ENV{'PWD'}="$2$3";
	175	}
	176	}
	177	$chdir_init = 1;
	178	}
	179
	180	sub chdir {
4633a7c4	181	my $newdir = shift \|\| ''; # allow for no arg (chdir to HOME dir)
4633a7c4	182	$newdir =~ s\|///*\|/\|g;
a0d0e21e	183	chdir_init() unless $chdir_init;
4633a7c4	184	return 0 unless CORE::chdir $newdir;
c6538b72	185	if ($^O eq 'VMS') { return $ENV{'PWD'} = $ENV{'DEFAULT'} }
748a9306	186
a0d0e21e	187	if ($newdir =~ m#^/#) {
a0d0e21e	188	$ENV{'PWD'} = $newdir;
4633a7c4	189	} else {
	190	my @curdir = split(m#/#,$ENV{'PWD'});
	191	@curdir = ('') unless @curdir;
	192	my $component;
a0d0e21e	193	foreach $component (split(m#/#, $newdir)) {
	194	next if $component eq '.';
	195	pop(@curdir),next if $component eq '..';
	196	push(@curdir,$component);
	197	}
	198	$ENV{'PWD'} = join('/',@curdir) \|\| '/';
	199	}
4633a7c4	200	1;
a0d0e21e	201	}
a0d0e21e	202
8b88ae92	203	# Taken from Cwd.pm It is really getcwd with an optional
	204	# parameter instead of '.'
	205	#
	206
	207	sub abs_path
	208	{
07569ed3	209	my $start = @_ ? shift : '.';
8b88ae92	210	my($dotdots, $cwd, @pst, @cst, $dir, @tst);
	211
	212	unless (@cst = stat( $start ))
	213	{
	214	carp "stat($start): $!";
	215	return '';
	216	}
	217	$cwd = '';
	218	$dotdots = $start;
	219	do
	220	{
	221	$dotdots .= '/..';
	222	@pst = @cst;
	223	unless (opendir(PARENT, $dotdots))
	224	{
	225	carp "opendir($dotdots): $!";
	226	return '';
	227	}
	228	unless (@cst = stat($dotdots))
	229	{
	230	carp "stat($dotdots): $!";
	231	closedir(PARENT);
	232	return '';
	233	}
	234	if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
	235	{
07569ed3	236	$dir = undef;
8b88ae92	237	}
	238	else
	239	{
	240	do
	241	{
	242	unless (defined ($dir = readdir(PARENT)))
	243	{
	244	carp "readdir($dotdots): $!";
	245	closedir(PARENT);
	246	return '';
	247	}
	248	$tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
	249	}
	250	while ($dir eq '.' \|\| $dir eq '..' \|\| $tst[0] != $pst[0] \|\|
	251	$tst[1] != $pst[1]);
	252	}
07569ed3	253	$cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
8b88ae92	254	closedir(PARENT);
07569ed3	255	} while (defined $dir);
07569ed3	256	chop($cwd) unless $cwd eq '/'; # drop the trailing /
8b88ae92	257	$cwd;
	258	}
	259
96e4d5b1	260	sub fast_abs_path {
	261	my $cwd = getcwd();
	262	my $path = shift \|\| '.';
e79e61e4	263	CORE::chdir($path) \|\| croak "Cannot chdir to $path:$!";
96e4d5b1	264	my $realpath = getcwd();
e79e61e4	265	CORE::chdir($cwd) \|\| croak "Cannot chdir back to $cwd:$!";
96e4d5b1	266	$realpath;
8b88ae92	267	}
8b88ae92	268
4633a7c4	269
	270	# --- PORTING SECTION ---
	271
	272	# VMS: $ENV{'DEFAULT'} points to default directory at all times
bd3fa61c	273	# 06-Mar-1996 Charles Bailey bailey@newman.upenn.edu
c6538b72	274	# Note: Use of Cwd::chdir() causes the logical name PWD to be defined
8b88ae92	275	# in the process logical name table as the default device and directory
8b88ae92	276	# seen by Perl. This may not be the same as the default device
4633a7c4	277	# and directory seen by DCL after Perl exits, since the effects
4633a7c4	278	# the CRTL chdir() function persist only until Perl exits.
4633a7c4	279
4633a7c4	280	sub _vms_cwd {
96e4d5b1	281	return $ENV{'DEFAULT'};
	282	}
	283
	284	sub _vms_abs_path {
	285	return $ENV{'DEFAULT'} unless @_;
	286	my $path = VMS::Filespec::pathify($_[0]);
	287	croak("Invalid path name $_[0]") unless defined $path;
	288	return VMS::Filespec::rmsexpand($path);
4633a7c4	289	}
68dc0745	290
4633a7c4	291	sub _os2_cwd {
	292	$ENV{'PWD'} = `cmd /c cd`;
	293	chop $ENV{'PWD'};
	294	$ENV{'PWD'} =~ s:\\:/:g ;
	295	return $ENV{'PWD'};
	296	}
	297
96e4d5b1	298	sub _win32_cwd {
2d7a9237	299	$ENV{'PWD'} = Win32::GetCwd();
96e4d5b1	300	$ENV{'PWD'} =~ s:\\:/:g ;
	301	return $ENV{'PWD'};
	302	}
	303
	304	*_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
2d7a9237	305	defined &Win32::GetCwd);
96e4d5b1	306
96e4d5b1	307	*_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
68dc0745	308
39e571d4	309	sub _dos_cwd {
	310	if (!defined &Dos::GetCwd) {
	311	$ENV{'PWD'} = `command /c cd`;
	312	chop $ENV{'PWD'};
	313	$ENV{'PWD'} =~ s:\\:/:g ;
	314	} else {
	315	$ENV{'PWD'} = Dos::GetCwd();
	316	}
55497cff	317	return $ENV{'PWD'};
	318	}
	319
7fbf1995	320	sub _qnx_cwd {
	321	$ENV{'PWD'} = `/usr/bin/fullpath -t`;
	322	chop $ENV{'PWD'};
	323	return $ENV{'PWD'};
	324	}
	325
	326	sub _qnx_abs_path {
	327	my $path = shift \|\| '.';
	328	my $realpath=`/usr/bin/fullpath -t $path`;
	329	chop $realpath;
	330	return $realpath;
	331	}
	332
ac1ad7f0	333	{
ac1ad7f0	334	local $^W = 0; # assignments trigger 'subroutine redefined' warning
4633a7c4	335
ac1ad7f0	336	if ($^O eq 'VMS') {
96e4d5b1	337	*cwd = \&_vms_cwd;
	338	*getcwd = \&_vms_cwd;
	339	*fastcwd = \&_vms_cwd;
	340	*fastgetcwd = \&_vms_cwd;
	341	*abs_path = \&_vms_abs_path;
	342	*fast_abs_path = \&_vms_abs_path;
ac1ad7f0	343	}
	344	elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
	345	# We assume that &_NT_cwd is defined as an XSUB or in the core.
96e4d5b1	346	*cwd = \&_NT_cwd;
	347	*getcwd = \&_NT_cwd;
	348	*fastcwd = \&_NT_cwd;
	349	*fastgetcwd = \&_NT_cwd;
	350	*abs_path = \&fast_abs_path;
ac1ad7f0	351	}
	352	elsif ($^O eq 'os2') {
	353	# sys_cwd may keep the builtin command
96e4d5b1	354	*cwd = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
	355	*getcwd = \&cwd;
	356	*fastgetcwd = \&cwd;
	357	*fastcwd = \&cwd;
	358	*abs_path = \&fast_abs_path;
ac1ad7f0	359	}
39e571d4	360	elsif ($^O eq 'dos') {
	361	*cwd = \&_dos_cwd;
	362	*getcwd = \&_dos_cwd;
	363	*fastgetcwd = \&_dos_cwd;
	364	*fastcwd = \&_dos_cwd;
96e4d5b1	365	*abs_path = \&fast_abs_path;
ac1ad7f0	366	}
7fbf1995	367	elsif ($^O eq 'qnx') {
	368	*cwd = \&_qnx_cwd;
	369	*getcwd = \&_qnx_cwd;
	370	*fastgetcwd = \&_qnx_cwd;
	371	*fastcwd = \&_qnx_cwd;
	372	*abs_path = \&_qnx_abs_path;
	373	*fast_abs_path = \&_qnx_abs_path;
	374	}
146174a9	375	elsif ($^O eq 'cygwin') {
1cab015a	376	*getcwd = \&cwd;
	377	*fastgetcwd = \&cwd;
	378	*fastcwd = \&cwd;
	379	*abs_path = \&fast_abs_path;
	380	}
55497cff	381	}
4633a7c4	382
	383	# package main; eval join('',<DATA>) \|\| die $@; # quick test
	384
a0d0e21e	385	1;
a0d0e21e	386
4633a7c4	387	__END__
	388	BEGIN { import Cwd qw(:DEFAULT chdir); }
	389	print join("\n", cwd, getcwd, fastcwd, "");
	390	chdir('..');
	391	print join("\n", cwd, getcwd, fastcwd, "");
	392	print "$ENV{PWD}\n";