[p5sagit/p5-mst-13.2.git] / lib / Cwd.pm

package Cwd;
use 5.006;

=head1 NAME

Cwd - get pathname of current working directory

=head1 SYNOPSIS

    use Cwd;
    my $dir = getcwd;

    use Cwd 'abs_path';
    my $abs_path = abs_path($file);

=head1 DESCRIPTION

This module provides functions for determining the pathname of the
current working directory.  It is recommended that getcwd (or another
*cwd() function) be used in I<all> code to ensure portability.

By default, it exports the functions cwd(), getcwd(), fastcwd(), and
fastgetcwd() into the caller's namespace.  


=head2 getcwd and friends

Each of these functions are called without arguments and return the
absolute path of the current working directory.

=over 4

=item getcwd

    my $cwd = getcwd();

Returns the current working directory.

Re-implements the getcwd(3) (or getwd(3)) functions in Perl.

Taint-safe.

=item cwd

    my $cwd = cwd();

The cwd() is the most natural form for the current architecture. For
most systems it is identical to `pwd` (but without the trailing line
terminator).

Taint-safe.

=item fastcwd

    my $cwd = fastcwd();

A more dangerous version of getcwd(), but potentially faster.

It might conceivably chdir() you out of a directory that it can't
chdir() you back into.  If fastcwd encounters a problem it will return
undef but will probably leave you in a different directory.  For a
measure of extra security, if everything appears to have worked, the
fastcwd() function will check that it leaves you in the same directory
that it started in. If it has changed it will C<die> with the message
"Unstable directory path, current directory changed
unexpectedly". That should never happen.

=item fastgetcwd

  my $cwd = fastgetcwd();

The fastgetcwd() function is provided as a synonym for cwd().

=back


=head2 abs_path and friends

These functions are exported only on request.  They each take a single
argument and return the absolute pathname for it.

=over 4

=item abs_path

  my $abs_path = abs_path($file);

Uses the same algorithm as getcwd().  Symbolic links and relative-path
components ("." and "..") are resolved to return the canonical
pathname, just like realpath(3).

Taint-safe.

=item realpath

  my $abs_path = realpath($file);

A synonym for abs_path().

Taint-safe.

=item fast_abs_path

  my $abs_path = fast_abs_path($file);

A more dangerous, but potentially faster version of abs_path.

This function is B<Not> taint-safe : you can't use it in programs
that work under taint mode.

=back

=head2 $ENV{PWD}

If you ask to override your chdir() built-in function, 

  use Cwd qw(chdir);

then your PWD environment variable will be kept up to date.  Note that
it will only be kept up to date if all packages which use chdir import
it from Cwd.


=head1 NOTES

=over 4

=item *

Since the path seperators are different on some operating systems ('/'
on Unix, ':' on MacPerl, etc...) we recommend you use the File::Spec
modules wherever portability is a concern.

=item *

Actually, on Mac OS, the C<getcwd()>, C<fastgetcwd()> and C<fastcwd()>
functions  are all aliases for the C<cwd()> function, which, on Mac OS,
calls `pwd`. Likewise, the C<abs_path()> function is an alias for
C<fast_abs_path()>.

=back

=head1 SEE ALSO

L<File::chdir>

=cut

use strict;

use Carp;

our $VERSION = '2.06';

use base qw/ Exporter /;
our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);

# sys_cwd may keep the builtin command

# All the functionality of this module may provided by builtins,
# there is no sense to process the rest of the file.
# The best choice may be to have this in BEGIN, but how to return from BEGIN?

if ($^O eq 'os2' && defined &sys_cwd && defined &sys_abspath) {
    local $^W = 0;
    *cwd		= \&sys_cwd;
    *getcwd		= \&cwd;
    *fastgetcwd		= \&cwd;
    *fastcwd		= \&cwd;
    *abs_path		= \&sys_abspath;
    *fast_abs_path	= \&abs_path;
    *realpath		= \&abs_path;
    *fast_realpath	= \&abs_path;
    return 1;
}

eval {
    require XSLoader;
    undef *Cwd::fastcwd; # avoid redefinition warning
    XSLoader::load('Cwd');
};


# Find the pwd command in the expected locations.  We assume these
# are safe.  This prevents _backtick_pwd() consulting $ENV{PATH}
# so everything works under taint mode.
my $pwd_cmd;
foreach my $try (qw(/bin/pwd /usr/bin/pwd)) {
    if( -x $try ) {
        $pwd_cmd = $try;
        last;
    }
}
$pwd_cmd ||= 'pwd';

# The 'natural and safe form' for UNIX (pwd may be setuid root)
sub _backtick_pwd {
    local @ENV{qw(PATH IFS CDPATH ENV BASH_ENV)};
    my $cwd = `$pwd_cmd`;
    # Belt-and-suspenders in case someone said "undef $/".
    local $/ = "\n";
    # `pwd` may fail e.g. if the disk is full
    chomp($cwd) if defined $cwd;
    $cwd;
}

# Since some ports may predefine cwd internally (e.g., NT)
# we take care not to override an existing definition for cwd().

unless(defined &cwd) {
    # The pwd command is not available in some chroot(2)'ed environments
    if( $^O eq 'MacOS' || (defined $ENV{PATH} && 
                           grep { -x "$_/pwd" } split(':', $ENV{PATH})) ) 
    {
	*cwd = \&_backtick_pwd;
    }
    else {
	*cwd = \&getcwd;
    }
}

# set a reasonable (and very safe) default for fastgetcwd, in case it
# isn't redefined later (20001212 rspier)
*fastgetcwd = \&cwd;

# By Brandon S. Allbery
#
# Usage: $cwd = getcwd();

sub getcwd
{
    abs_path('.');
}


# By John Bazik
#
# Usage: $cwd = &fastcwd;
#
# This is a faster version of getcwd.  It's also more dangerous because
# you might chdir out of a directory that you can't chdir back into.
    
sub fastcwd {
    my($odev, $oino, $cdev, $cino, $tdev, $tino);
    my(@path, $path);
    local(*DIR);

    my($orig_cdev, $orig_cino) = stat('.');
    ($cdev, $cino) = ($orig_cdev, $orig_cino);
    for (;;) {
	my $direntry;
	($odev, $oino) = ($cdev, $cino);
	CORE::chdir('..') || return undef;
	($cdev, $cino) = stat('.');
	last if $odev == $cdev && $oino == $cino;
	opendir(DIR, '.') || return undef;
	for (;;) {
	    $direntry = readdir(DIR);
	    last unless defined $direntry;
	    next if $direntry eq '.';
	    next if $direntry eq '..';

	    ($tdev, $tino) = lstat($direntry);
	    last unless $tdev != $odev || $tino != $oino;
	}
	closedir(DIR);
	return undef unless defined $direntry; # should never happen
	unshift(@path, $direntry);
    }
    $path = '/' . join('/', @path);
    if ($^O eq 'apollo') { $path = "/".$path; }
    # At this point $path may be tainted (if tainting) and chdir would fail.
    # Untaint it then check that we landed where we started.
    $path =~ /^(.*)\z/s		# untaint
	&& CORE::chdir($1) or return undef;
    ($cdev, $cino) = stat('.');
    die "Unstable directory path, current directory changed unexpectedly"
	if $cdev != $orig_cdev || $cino != $orig_cino;
    $path;
}


# Keeps track of current working directory in PWD environment var
# Usage:
#	use Cwd 'chdir';
#	chdir $newdir;

my $chdir_init = 0;

sub chdir_init {
    if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
	my($dd,$di) = stat('.');
	my($pd,$pi) = stat($ENV{'PWD'});
	if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
	    $ENV{'PWD'} = cwd();
	}
    }
    else {
	my $wd = cwd();
	$wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
	$ENV{'PWD'} = $wd;
    }
    # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
    if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
	my($pd,$pi) = stat($2);
	my($dd,$di) = stat($1);
	if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
	    $ENV{'PWD'}="$2$3";
	}
    }
    $chdir_init = 1;
}

sub chdir {
    my $newdir = @_ ? shift : '';	# allow for no arg (chdir to HOME dir)
    $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
    chdir_init() unless $chdir_init;
    my $newpwd;
    if ($^O eq 'MSWin32') {
	# get the full path name *before* the chdir()
	$newpwd = Win32::GetFullPathName($newdir);
    }

    return 0 unless CORE::chdir $newdir;

    if ($^O eq 'VMS') {
	return $ENV{'PWD'} = $ENV{'DEFAULT'}
    }
    elsif ($^O eq 'MacOS') {
	return $ENV{'PWD'} = cwd();
    }
    elsif ($^O eq 'MSWin32') {
	$ENV{'PWD'} = $newpwd;
	return 1;
    }

    if ($newdir =~ m#^/#s) {
	$ENV{'PWD'} = $newdir;
    } else {
	my @curdir = split(m#/#,$ENV{'PWD'});
	@curdir = ('') unless @curdir;
	my $component;
	foreach $component (split(m#/#, $newdir)) {
	    next if $component eq '.';
	    pop(@curdir),next if $component eq '..';
	    push(@curdir,$component);
	}
	$ENV{'PWD'} = join('/',@curdir) || '/';
    }
    1;
}


# In case the XS version doesn't load.
*abs_path = \&_perl_abs_path unless defined &abs_path;
sub _perl_abs_path
{
    my $start = @_ ? shift : '.';
    my($dotdots, $cwd, @pst, @cst, $dir, @tst);

    unless (@cst = stat( $start ))
    {
	carp "stat($start): $!";
	return '';
    }
    $cwd = '';
    $dotdots = $start;
    do
    {
	$dotdots .= '/..';
	@pst = @cst;
	unless (opendir(PARENT, $dotdots))
	{
	    carp "opendir($dotdots): $!";
	    return '';
	}
	unless (@cst = stat($dotdots))
	{
	    carp "stat($dotdots): $!";
	    closedir(PARENT);
	    return '';
	}
	if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
	{
	    $dir = undef;
	}
	else
	{
	    do
	    {
		unless (defined ($dir = readdir(PARENT)))
	        {
		    carp "readdir($dotdots): $!";
		    closedir(PARENT);
		    return '';
		}
		$tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
	    }
	    while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
		   $tst[1] != $pst[1]);
	}
	$cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
	closedir(PARENT);
    } while (defined $dir);
    chop($cwd) unless $cwd eq '/'; # drop the trailing /
    $cwd;
}


# added function alias for those of us more
# used to the libc function.  --tchrist 27-Jan-00
*realpath = \&abs_path;

sub fast_abs_path {
    my $cwd = getcwd();
    require File::Spec;
    my $path = @_ ? shift : File::Spec->curdir;
    CORE::chdir($path) || croak "Cannot chdir to $path: $!";
    my $realpath = getcwd();
    -d $cwd && CORE::chdir($cwd) ||
	croak "Cannot chdir back to $cwd: $!";
    $realpath;
}

# added function alias to follow principle of least surprise
# based on previous aliasing.  --tchrist 27-Jan-00
*fast_realpath = \&fast_abs_path;


# --- PORTING SECTION ---

# VMS: $ENV{'DEFAULT'} points to default directory at all times
# 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
# Note: Use of Cwd::chdir() causes the logical name PWD to be defined
#   in the process logical name table as the default device and directory
#   seen by Perl. This may not be the same as the default device
#   and directory seen by DCL after Perl exits, since the effects
#   the CRTL chdir() function persist only until Perl exits.

sub _vms_cwd {
    return $ENV{'DEFAULT'};
}

sub _vms_abs_path {
    return $ENV{'DEFAULT'} unless @_;
    my $path = VMS::Filespec::pathify($_[0]);
    croak("Invalid path name $_[0]") unless defined $path;
    return VMS::Filespec::rmsexpand($path);
}

sub _os2_cwd {
    $ENV{'PWD'} = `cmd /c cd`;
    chop $ENV{'PWD'};
    $ENV{'PWD'} =~ s:\\:/:g ;
    return $ENV{'PWD'};
}

sub _win32_cwd {
    $ENV{'PWD'} = Win32::GetCwd();
    $ENV{'PWD'} =~ s:\\:/:g ;
    return $ENV{'PWD'};
}

*_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd && 
                            defined &Win32::GetCwd);

*_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;

sub _dos_cwd {
    if (!defined &Dos::GetCwd) {
        $ENV{'PWD'} = `command /c cd`;
        chop $ENV{'PWD'};
        $ENV{'PWD'} =~ s:\\:/:g ;
    } else {
        $ENV{'PWD'} = Dos::GetCwd();
    }
    return $ENV{'PWD'};
}

sub _qnx_cwd {
	local $ENV{PATH} = '';
	local $ENV{CDPATH} = '';
	local $ENV{ENV} = '';
    $ENV{'PWD'} = `/usr/bin/fullpath -t`;
    chop $ENV{'PWD'};
    return $ENV{'PWD'};
}

sub _qnx_abs_path {
	local $ENV{PATH} = '';
	local $ENV{CDPATH} = '';
	local $ENV{ENV} = '';
    my $path = @_ ? shift : '.';
    my $realpath=`/usr/bin/fullpath -t $path`;
    chop $realpath;
    return $realpath;
}

sub _epoc_cwd {
    $ENV{'PWD'} = EPOC::getcwd();
    return $ENV{'PWD'};
}

{
    no warnings;	# assignments trigger 'subroutine redefined' warning

    if ($^O eq 'VMS') {
        *cwd		= \&_vms_cwd;
        *getcwd		= \&_vms_cwd;
        *fastcwd	= \&_vms_cwd;
        *fastgetcwd	= \&_vms_cwd;
        *abs_path	= \&_vms_abs_path;
        *fast_abs_path	= \&_vms_abs_path;
    }
    elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
        # We assume that &_NT_cwd is defined as an XSUB or in the core.
        *cwd		= \&_NT_cwd;
        *getcwd		= \&_NT_cwd;
        *fastcwd	= \&_NT_cwd;
        *fastgetcwd	= \&_NT_cwd;
        *abs_path	= \&fast_abs_path;
        *realpath   = \&fast_abs_path;
    }
    elsif ($^O eq 'os2') {
        # sys_cwd may keep the builtin command
        *cwd		= defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
        *getcwd		= \&cwd;
        *fastgetcwd	= \&cwd;
        *fastcwd	= \&cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'dos') {
        *cwd		= \&_dos_cwd;
        *getcwd		= \&_dos_cwd;
        *fastgetcwd	= \&_dos_cwd;
        *fastcwd	= \&_dos_cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O =~ m/^(?:qnx|nto)$/ ) {
        *cwd		= \&_qnx_cwd;
        *getcwd		= \&_qnx_cwd;
        *fastgetcwd	= \&_qnx_cwd;
        *fastcwd	= \&_qnx_cwd;
        *abs_path	= \&_qnx_abs_path;
        *fast_abs_path	= \&_qnx_abs_path;
    }
    elsif ($^O eq 'cygwin') {
        *getcwd	= \&cwd;
        *fastgetcwd	= \&cwd;
        *fastcwd	= \&cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'epoc') {
        *cwd            = \&_epoc_cwd;
        *getcwd	        = \&_epoc_cwd;
        *fastgetcwd	= \&_epoc_cwd;
        *fastcwd	= \&_epoc_cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'MacOS') {
    	*getcwd     = \&cwd;
    	*fastgetcwd = \&cwd;
    	*fastcwd    = \&cwd;
    	*abs_path   = \&fast_abs_path;
    }
}


1;
Commit	Line	Data
a0d0e21e	1	package Cwd;
3b825e41	2	use 5.006;
a0d0e21e	3
f06db76b	4	=head1 NAME
f06db76b	5
902bacac	6	Cwd - get pathname of current working directory
f06db76b	7
	8	=head1 SYNOPSIS
	9
4633a7c4	10	use Cwd;
04929354	11	my $dir = getcwd;
4633a7c4	12
04929354	13	use Cwd 'abs_path';
04929354	14	my $abs_path = abs_path($file);
f06db76b	15
04929354	16	=head1 DESCRIPTION
902bacac	17
04929354	18	This module provides functions for determining the pathname of the
	19	current working directory. It is recommended that getcwd (or another
	20	*cwd() function) be used in I<all> code to ensure portability.
f06db76b	21
04929354	22	By default, it exports the functions cwd(), getcwd(), fastcwd(), and
04929354	23	fastgetcwd() into the caller's namespace.
f06db76b	24
20408e3c	25
04929354	26	=head2 getcwd and friends
20408e3c	27
04929354	28	Each of these functions are called without arguments and return the
04929354	29	absolute path of the current working directory.
f06db76b	30
04929354	31	=over 4
	32
	33	=item getcwd
	34
	35	my $cwd = getcwd();
	36
	37	Returns the current working directory.
	38
	39	Re-implements the getcwd(3) (or getwd(3)) functions in Perl.
	40
bde417e1	41	Taint-safe.
bde417e1	42
04929354	43	=item cwd
	44
	45	my $cwd = cwd();
	46
	47	The cwd() is the most natural form for the current architecture. For
	48	most systems it is identical to `pwd` (but without the trailing line
	49	terminator).
	50
248785eb	51	Taint-safe.
04929354	52
	53	=item fastcwd
	54
	55	my $cwd = fastcwd();
	56
	57	A more dangerous version of getcwd(), but potentially faster.
	58
	59	It might conceivably chdir() you out of a directory that it can't
	60	chdir() you back into. If fastcwd encounters a problem it will return
	61	undef but will probably leave you in a different directory. For a
	62	measure of extra security, if everything appears to have worked, the
	63	fastcwd() function will check that it leaves you in the same directory
	64	that it started in. If it has changed it will C<die> with the message
	65	"Unstable directory path, current directory changed
	66	unexpectedly". That should never happen.
	67
	68	=item fastgetcwd
	69
	70	my $cwd = fastgetcwd();
f06db76b	71
902bacac	72	The fastgetcwd() function is provided as a synonym for cwd().
fb73857a	73
04929354	74	=back
04929354	75
902bacac	76
04929354	77	=head2 abs_path and friends
	78
	79	These functions are exported only on request. They each take a single
	80	argument and return the absolute pathname for it.
	81
	82	=over 4
	83
	84	=item abs_path
	85
	86	my $abs_path = abs_path($file);
	87
	88	Uses the same algorithm as getcwd(). Symbolic links and relative-path
	89	components ("." and "..") are resolved to return the canonical
	90	pathname, just like realpath(3).
	91
bde417e1	92	Taint-safe.
bde417e1	93
04929354	94	=item realpath
	95
	96	my $abs_path = realpath($file);
	97
	98	A synonym for abs_path().
	99
bde417e1	100	Taint-safe.
bde417e1	101
04929354	102	=item fast_abs_path
04929354	103
510179aa	104	my $abs_path = fast_abs_path($file);
04929354	105
	106	A more dangerous, but potentially faster version of abs_path.
	107
248785eb	108	This function is B<Not> taint-safe : you can't use it in programs
248785eb	109	that work under taint mode.
bde417e1	110
04929354	111	=back
	112
	113	=head2 $ENV{PWD}
	114
	115	If you ask to override your chdir() built-in function,
	116
	117	use Cwd qw(chdir);
	118
	119	then your PWD environment variable will be kept up to date. Note that
	120	it will only be kept up to date if all packages which use chdir import
	121	it from Cwd.
4633a7c4	122
4633a7c4	123
4d6b4052	124	=head1 NOTES
	125
	126	=over 4
	127
	128	=item *
	129
04929354	130	Since the path seperators are different on some operating systems ('/'
	131	on Unix, ':' on MacPerl, etc...) we recommend you use the File::Spec
	132	modules wherever portability is a concern.
	133
04929354	134	=item *
4d6b4052	135
	136	Actually, on Mac OS, the C<getcwd()>, C<fastgetcwd()> and C<fastcwd()>
	137	functions are all aliases for the C<cwd()> function, which, on Mac OS,
	138	calls `pwd`. Likewise, the C<abs_path()> function is an alias for
	139	C<fast_abs_path()>.
	140
	141	=back
	142
04929354	143	=head1 SEE ALSO
	144
	145	L<File::chdir>
	146
f06db76b	147	=cut
f06db76b	148
b060a406	149	use strict;
96e4d5b1	150
	151	use Carp;
	152
04929354	153	our $VERSION = '2.06';
96e4d5b1	154
b060a406	155	use base qw/ Exporter /;
	156	our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
	157	our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
a0d0e21e	158
f5f423e4	159	# sys_cwd may keep the builtin command
	160
	161	# All the functionality of this module may provided by builtins,
	162	# there is no sense to process the rest of the file.
	163	# The best choice may be to have this in BEGIN, but how to return from BEGIN?
	164
	165	if ($^O eq 'os2' && defined &sys_cwd && defined &sys_abspath) {
	166	local $^W = 0;
	167	*cwd = \&sys_cwd;
	168	*getcwd = \&cwd;
	169	*fastgetcwd = \&cwd;
	170	*fastcwd = \&cwd;
	171	*abs_path = \&sys_abspath;
	172	*fast_abs_path = \&abs_path;
	173	*realpath = \&abs_path;
	174	*fast_realpath = \&abs_path;
	175	return 1;
	176	}
	177
f22d8e4b	178	eval {
f22d8e4b	179	require XSLoader;
716e3b8c	180	undef *Cwd::fastcwd; # avoid redefinition warning
f22d8e4b	181	XSLoader::load('Cwd');
f22d8e4b	182	};
4633a7c4	183
96e4d5b1	184
3547aa9a	185	# Find the pwd command in the expected locations. We assume these
	186	# are safe. This prevents _backtick_pwd() consulting $ENV{PATH}
	187	# so everything works under taint mode.
	188	my $pwd_cmd;
	189	foreach my $try (qw(/bin/pwd /usr/bin/pwd)) {
	190	if( -x $try ) {
	191	$pwd_cmd = $try;
	192	last;
	193	}
	194	}
	195	$pwd_cmd \|\|= 'pwd';
	196
	197	# The 'natural and safe form' for UNIX (pwd may be setuid root)
8b88ae92	198	sub _backtick_pwd {
db281859	199	local @ENV{qw(PATH IFS CDPATH ENV BASH_ENV)};
3547aa9a	200	my $cwd = `$pwd_cmd`;
ac3b20cb	201	# Belt-and-suspenders in case someone said "undef $/".
5cf6da5f	202	local $/ = "\n";
ac3b20cb	203	# `pwd` may fail e.g. if the disk is full
7e03f963	204	chomp($cwd) if defined $cwd;
4633a7c4	205	$cwd;
8b88ae92	206	}
4633a7c4	207
	208	# Since some ports may predefine cwd internally (e.g., NT)
	209	# we take care not to override an existing definition for cwd().
	210
ea54c8bd	211	unless(defined &cwd) {
ea54c8bd	212	# The pwd command is not available in some chroot(2)'ed environments
73b801a6	213	if( $^O eq 'MacOS' \|\| (defined $ENV{PATH} &&
	214	grep { -x "$_/pwd" } split(':', $ENV{PATH})) )
	215	{
ea54c8bd	216	*cwd = \&_backtick_pwd;
	217	}
	218	else {
	219	*cwd = \&getcwd;
	220	}
	221	}
a0d0e21e	222
1f4f94f5	223	# set a reasonable (and very safe) default for fastgetcwd, in case it
	224	# isn't redefined later (20001212 rspier)
	225	*fastgetcwd = \&cwd;
748a9306	226
a0d0e21e	227	# By Brandon S. Allbery
	228	#
	229	# Usage: $cwd = getcwd();
	230
	231	sub getcwd
	232	{
07569ed3	233	abs_path('.');
a0d0e21e	234	}
a0d0e21e	235
a0c9c202	236
	237	# By John Bazik
	238	#
	239	# Usage: $cwd = &fastcwd;
	240	#
	241	# This is a faster version of getcwd. It's also more dangerous because
	242	# you might chdir out of a directory that you can't chdir back into.
	243
	244	sub fastcwd {
	245	my($odev, $oino, $cdev, $cino, $tdev, $tino);
	246	my(@path, $path);
	247	local(*DIR);
	248
	249	my($orig_cdev, $orig_cino) = stat('.');
	250	($cdev, $cino) = ($orig_cdev, $orig_cino);
	251	for (;;) {
	252	my $direntry;
	253	($odev, $oino) = ($cdev, $cino);
	254	CORE::chdir('..') \|\| return undef;
	255	($cdev, $cino) = stat('.');
	256	last if $odev == $cdev && $oino == $cino;
	257	opendir(DIR, '.') \|\| return undef;
	258	for (;;) {
	259	$direntry = readdir(DIR);
	260	last unless defined $direntry;
	261	next if $direntry eq '.';
	262	next if $direntry eq '..';
	263
	264	($tdev, $tino) = lstat($direntry);
	265	last unless $tdev != $odev \|\| $tino != $oino;
	266	}
	267	closedir(DIR);
	268	return undef unless defined $direntry; # should never happen
	269	unshift(@path, $direntry);
	270	}
	271	$path = '/' . join('/', @path);
	272	if ($^O eq 'apollo') { $path = "/".$path; }
	273	# At this point $path may be tainted (if tainting) and chdir would fail.
248785eb	274	# Untaint it then check that we landed where we started.
	275	$path =~ /^(.*)\z/s # untaint
	276	&& CORE::chdir($1) or return undef;
a0c9c202	277	($cdev, $cino) = stat('.');
	278	die "Unstable directory path, current directory changed unexpectedly"
	279	if $cdev != $orig_cdev \|\| $cino != $orig_cino;
	280	$path;
	281	}
	282
	283
4633a7c4	284	# Keeps track of current working directory in PWD environment var
a0d0e21e	285	# Usage:
	286	# use Cwd 'chdir';
	287	# chdir $newdir;
	288
4633a7c4	289	my $chdir_init = 0;
a0d0e21e	290
4633a7c4	291	sub chdir_init {
3b8e3443	292	if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
a0d0e21e	293	my($dd,$di) = stat('.');
	294	my($pd,$pi) = stat($ENV{'PWD'});
	295	if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
4633a7c4	296	$ENV{'PWD'} = cwd();
a0d0e21e	297	}
	298	}
	299	else {
3b8e3443	300	my $wd = cwd();
	301	$wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
	302	$ENV{'PWD'} = $wd;
a0d0e21e	303	}
4633a7c4	304	# Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
3b8e3443	305	if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m\|(/[^/]+(/[^/]+/[^/]+))(.*)\|s) {
a0d0e21e	306	my($pd,$pi) = stat($2);
	307	my($dd,$di) = stat($1);
	308	if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
	309	$ENV{'PWD'}="$2$3";
	310	}
	311	}
	312	$chdir_init = 1;
	313	}
	314
	315	sub chdir {
22978713	316	my $newdir = @_ ? shift : ''; # allow for no arg (chdir to HOME dir)
3b8e3443	317	$newdir =~ s\|///*\|/\|g unless $^O eq 'MSWin32';
a0d0e21e	318	chdir_init() unless $chdir_init;
4ffa1610	319	my $newpwd;
	320	if ($^O eq 'MSWin32') {
	321	# get the full path name before the chdir()
	322	$newpwd = Win32::GetFullPathName($newdir);
	323	}
	324
4633a7c4	325	return 0 unless CORE::chdir $newdir;
4ffa1610	326
3b8e3443	327	if ($^O eq 'VMS') {
	328	return $ENV{'PWD'} = $ENV{'DEFAULT'}
	329	}
4aecb5b5	330	elsif ($^O eq 'MacOS') {
	331	return $ENV{'PWD'} = cwd();
	332	}
3b8e3443	333	elsif ($^O eq 'MSWin32') {
4ffa1610	334	$ENV{'PWD'} = $newpwd;
3b8e3443	335	return 1;
3b8e3443	336	}
748a9306	337
392d8ab8	338	if ($newdir =~ m#^/#s) {
a0d0e21e	339	$ENV{'PWD'} = $newdir;
4633a7c4	340	} else {
	341	my @curdir = split(m#/#,$ENV{'PWD'});
	342	@curdir = ('') unless @curdir;
	343	my $component;
a0d0e21e	344	foreach $component (split(m#/#, $newdir)) {
	345	next if $component eq '.';
	346	pop(@curdir),next if $component eq '..';
	347	push(@curdir,$component);
	348	}
	349	$ENV{'PWD'} = join('/',@curdir) \|\| '/';
	350	}
4633a7c4	351	1;
a0d0e21e	352	}
a0d0e21e	353
a0c9c202	354
	355	# In case the XS version doesn't load.
	356	*abs_path = \&_perl_abs_path unless defined &abs_path;
	357	sub _perl_abs_path
	358	{
	359	my $start = @_ ? shift : '.';
	360	my($dotdots, $cwd, @pst, @cst, $dir, @tst);
	361
	362	unless (@cst = stat( $start ))
	363	{
	364	carp "stat($start): $!";
	365	return '';
	366	}
	367	$cwd = '';
	368	$dotdots = $start;
	369	do
	370	{
	371	$dotdots .= '/..';
	372	@pst = @cst;
	373	unless (opendir(PARENT, $dotdots))
	374	{
	375	carp "opendir($dotdots): $!";
	376	return '';
	377	}
	378	unless (@cst = stat($dotdots))
	379	{
	380	carp "stat($dotdots): $!";
	381	closedir(PARENT);
	382	return '';
	383	}
	384	if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
	385	{
	386	$dir = undef;
	387	}
	388	else
	389	{
	390	do
	391	{
	392	unless (defined ($dir = readdir(PARENT)))
	393	{
	394	carp "readdir($dotdots): $!";
	395	closedir(PARENT);
	396	return '';
	397	}
	398	$tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
	399	}
	400	while ($dir eq '.' \|\| $dir eq '..' \|\| $tst[0] != $pst[0] \|\|
	401	$tst[1] != $pst[1]);
	402	}
	403	$cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
	404	closedir(PARENT);
	405	} while (defined $dir);
	406	chop($cwd) unless $cwd eq '/'; # drop the trailing /
	407	$cwd;
	408	}
	409
	410
e4c51978	411	# added function alias for those of us more
	412	# used to the libc function. --tchrist 27-Jan-00
	413	*realpath = \&abs_path;
	414
96e4d5b1	415	sub fast_abs_path {
96e4d5b1	416	my $cwd = getcwd();
4d6b4052	417	require File::Spec;
4d6b4052	418	my $path = @_ ? shift : File::Spec->curdir;
926cbafe	419	CORE::chdir($path) \|\| croak "Cannot chdir to $path: $!";
96e4d5b1	420	my $realpath = getcwd();
bde417e1	421	-d $cwd && CORE::chdir($cwd) \|\|
926cbafe	422	croak "Cannot chdir back to $cwd: $!";
96e4d5b1	423	$realpath;
8b88ae92	424	}
8b88ae92	425
e4c51978	426	# added function alias to follow principle of least surprise
	427	# based on previous aliasing. --tchrist 27-Jan-00
	428	*fast_realpath = \&fast_abs_path;
	429
4633a7c4	430
	431	# --- PORTING SECTION ---
	432
	433	# VMS: $ENV{'DEFAULT'} points to default directory at all times
bd3fa61c	434	# 06-Mar-1996 Charles Bailey bailey@newman.upenn.edu
c6538b72	435	# Note: Use of Cwd::chdir() causes the logical name PWD to be defined
8b88ae92	436	# in the process logical name table as the default device and directory
8b88ae92	437	# seen by Perl. This may not be the same as the default device
4633a7c4	438	# and directory seen by DCL after Perl exits, since the effects
4633a7c4	439	# the CRTL chdir() function persist only until Perl exits.
4633a7c4	440
4633a7c4	441	sub _vms_cwd {
96e4d5b1	442	return $ENV{'DEFAULT'};
	443	}
	444
	445	sub _vms_abs_path {
	446	return $ENV{'DEFAULT'} unless @_;
	447	my $path = VMS::Filespec::pathify($_[0]);
	448	croak("Invalid path name $_[0]") unless defined $path;
	449	return VMS::Filespec::rmsexpand($path);
4633a7c4	450	}
68dc0745	451
4633a7c4	452	sub _os2_cwd {
	453	$ENV{'PWD'} = `cmd /c cd`;
	454	chop $ENV{'PWD'};
aa6b7957	455	$ENV{'PWD'} =~ s:\\:/:g ;
4633a7c4	456	return $ENV{'PWD'};
	457	}
	458
96e4d5b1	459	sub _win32_cwd {
2d7a9237	460	$ENV{'PWD'} = Win32::GetCwd();
aa6b7957	461	$ENV{'PWD'} =~ s:\\:/:g ;
96e4d5b1	462	return $ENV{'PWD'};
	463	}
	464
	465	*_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
2d7a9237	466	defined &Win32::GetCwd);
96e4d5b1	467
96e4d5b1	468	*_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
68dc0745	469
39e571d4	470	sub _dos_cwd {
	471	if (!defined &Dos::GetCwd) {
	472	$ENV{'PWD'} = `command /c cd`;
	473	chop $ENV{'PWD'};
aa6b7957	474	$ENV{'PWD'} =~ s:\\:/:g ;
39e571d4	475	} else {
	476	$ENV{'PWD'} = Dos::GetCwd();
	477	}
55497cff	478	return $ENV{'PWD'};
	479	}
	480
7fbf1995	481	sub _qnx_cwd {
35b807ef	482	local $ENV{PATH} = '';
	483	local $ENV{CDPATH} = '';
	484	local $ENV{ENV} = '';
7fbf1995	485	$ENV{'PWD'} = `/usr/bin/fullpath -t`;
	486	chop $ENV{'PWD'};
	487	return $ENV{'PWD'};
	488	}
	489
	490	sub _qnx_abs_path {
35b807ef	491	local $ENV{PATH} = '';
	492	local $ENV{CDPATH} = '';
	493	local $ENV{ENV} = '';
fa921dc6	494	my $path = @_ ? shift : '.';
7fbf1995	495	my $realpath=`/usr/bin/fullpath -t $path`;
	496	chop $realpath;
	497	return $realpath;
	498	}
	499
ed79a026	500	sub _epoc_cwd {
	501	$ENV{'PWD'} = EPOC::getcwd();
	502	return $ENV{'PWD'};
	503	}
	504
ac1ad7f0	505	{
db376a24	506	no warnings; # assignments trigger 'subroutine redefined' warning
4633a7c4	507
ac1ad7f0	508	if ($^O eq 'VMS') {
96e4d5b1	509	*cwd = \&_vms_cwd;
	510	*getcwd = \&_vms_cwd;
	511	*fastcwd = \&_vms_cwd;
	512	*fastgetcwd = \&_vms_cwd;
	513	*abs_path = \&_vms_abs_path;
	514	*fast_abs_path = \&_vms_abs_path;
ac1ad7f0	515	}
	516	elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
	517	# We assume that &_NT_cwd is defined as an XSUB or in the core.
96e4d5b1	518	*cwd = \&_NT_cwd;
	519	*getcwd = \&_NT_cwd;
	520	*fastcwd = \&_NT_cwd;
	521	*fastgetcwd = \&_NT_cwd;
	522	*abs_path = \&fast_abs_path;
cade0c02	523	*realpath = \&fast_abs_path;
ac1ad7f0	524	}
	525	elsif ($^O eq 'os2') {
	526	# sys_cwd may keep the builtin command
96e4d5b1	527	*cwd = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
	528	*getcwd = \&cwd;
	529	*fastgetcwd = \&cwd;
	530	*fastcwd = \&cwd;
	531	*abs_path = \&fast_abs_path;
ac1ad7f0	532	}
39e571d4	533	elsif ($^O eq 'dos') {
	534	*cwd = \&_dos_cwd;
	535	*getcwd = \&_dos_cwd;
	536	*fastgetcwd = \&_dos_cwd;
	537	*fastcwd = \&_dos_cwd;
96e4d5b1	538	*abs_path = \&fast_abs_path;
ac1ad7f0	539	}
7438b6ad	540	elsif ($^O =~ m/^(?:qnx\|nto)$/ ) {
7fbf1995	541	*cwd = \&_qnx_cwd;
	542	*getcwd = \&_qnx_cwd;
	543	*fastgetcwd = \&_qnx_cwd;
	544	*fastcwd = \&_qnx_cwd;
	545	*abs_path = \&_qnx_abs_path;
	546	*fast_abs_path = \&_qnx_abs_path;
	547	}
4fabb596	548	elsif ($^O eq 'cygwin') {
1cab015a	549	*getcwd = \&cwd;
	550	*fastgetcwd = \&cwd;
	551	*fastcwd = \&cwd;
	552	*abs_path = \&fast_abs_path;
	553	}
ed79a026	554	elsif ($^O eq 'epoc') {
fa6a1c44	555	*cwd = \&_epoc_cwd;
fa6a1c44	556	*getcwd = \&_epoc_cwd;
ed79a026	557	*fastgetcwd = \&_epoc_cwd;
	558	*fastcwd = \&_epoc_cwd;
	559	*abs_path = \&fast_abs_path;
	560	}
4aecb5b5	561	elsif ($^O eq 'MacOS') {
	562	*getcwd = \&cwd;
	563	*fastgetcwd = \&cwd;
	564	*fastcwd = \&cwd;
	565	*abs_path = \&fast_abs_path;
	566	}
55497cff	567	}
4633a7c4	568
4633a7c4	569
a0d0e21e	570	1;