[p5sagit/p5-mst-13.2.git] / lib / Cwd.pm

package Cwd;
require 5.000;

=head1 NAME

Cwd - get pathname of current working directory

=head1 SYNOPSIS

    use Cwd;
    $dir = cwd;

    use Cwd;
    $dir = getcwd;

    use Cwd;
    $dir = fastcwd;

    use Cwd;
    $dir = fastgetcwd;

    use Cwd 'chdir';
    chdir "/tmp";
    print $ENV{'PWD'};

    use Cwd 'abs_path';	    # aka realpath()
    print abs_path($ENV{'PWD'});

    use Cwd 'fast_abs_path';
    print fast_abs_path($ENV{'PWD'});

=head1 DESCRIPTION

This module provides functions for determining the pathname of the
current working directory.  By default, it exports the functions
cwd(), getcwd(), fastcwd(), and fastgetcwd() into the caller's
namespace.  Each of these functions are called without arguments and
return the absolute path of the current working directory.  It is
recommended that cwd (or another *cwd() function) be used in I<all>
code to ensure portability.

The cwd() is the most natural and safe form for the current
architecture. For most systems it is identical to `pwd` (but without
the trailing line terminator).

The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
in Perl.

The fastcwd() function looks the same as getcwd(), but runs faster.
It's also more dangerous because it might conceivably chdir() you out
of a directory that it can't chdir() you back into.  If fastcwd
encounters a problem it will return undef but will probably leave you
in a different directory.  For a measure of extra security, if
everything appears to have worked, the fastcwd() function will check
that it leaves you in the same directory that it started in. If it has
changed it will C<die> with the message "Unstable directory path,
current directory changed unexpectedly". That should never happen.

The fastgetcwd() function is provided as a synonym for cwd().

The abs_path() function takes a single argument and returns the
absolute pathname for that argument.  It uses the same algorithm as
getcwd().  (Actually, getcwd() is abs_path("."))  Symbolic links and
relative-path components ("." and "..") are resolved to return the
canonical pathname, just like realpath(3).  This function is also
callable as realpath().

The fast_abs_path() function looks the same as abs_path() but runs
faster and, like fastcwd(), is more dangerous.

If you ask to override your chdir() built-in function, then your PWD
environment variable will be kept up to date.  (See
L<perlsub/Overriding Builtin Functions>.) Note that it will only be
kept up to date if all packages which use chdir import it from Cwd.

=cut

use strict;

use Carp;

our $VERSION = '2.04';

use base qw/ Exporter /;
our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);

eval {
    require XSLoader;
    XSLoader::load('Cwd');
};

# The 'natural and safe form' for UNIX (pwd may be setuid root)

sub _backtick_pwd {
    my $cwd = `pwd`;
    # `pwd` may fail e.g. if the disk is full
    chomp($cwd) if defined $cwd;
    $cwd;
}

# Since some ports may predefine cwd internally (e.g., NT)
# we take care not to override an existing definition for cwd().

unless(defined &cwd) {
    # The pwd command is not available in some chroot(2)'ed environments
    if($^O eq 'MacOS' || grep { -x "$_/pwd" } split(':', $ENV{PATH})) {
	*cwd = \&_backtick_pwd;
    }
    else {
	*cwd = \&getcwd;
    }
}

# set a reasonable (and very safe) default for fastgetcwd, in case it
# isn't redefined later (20001212 rspier)
*fastgetcwd = \&cwd;

# By Brandon S. Allbery
#
# Usage: $cwd = getcwd();

sub getcwd
{
    abs_path('.');
}

# Keeps track of current working directory in PWD environment var
# Usage:
#	use Cwd 'chdir';
#	chdir $newdir;

my $chdir_init = 0;

sub chdir_init {
    if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
	my($dd,$di) = stat('.');
	my($pd,$pi) = stat($ENV{'PWD'});
	if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
	    $ENV{'PWD'} = cwd();
	}
    }
    else {
	my $wd = cwd();
	$wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
	$ENV{'PWD'} = $wd;
    }
    # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
    if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
	my($pd,$pi) = stat($2);
	my($dd,$di) = stat($1);
	if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
	    $ENV{'PWD'}="$2$3";
	}
    }
    $chdir_init = 1;
}

sub chdir {
    my $newdir = @_ ? shift : '';	# allow for no arg (chdir to HOME dir)
    $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
    chdir_init() unless $chdir_init;
    my $newpwd;
    if ($^O eq 'MSWin32') {
	# get the full path name *before* the chdir()
	$newpwd = Win32::GetFullPathName($newdir);
    }

    return 0 unless CORE::chdir $newdir;

    if ($^O eq 'VMS') {
	return $ENV{'PWD'} = $ENV{'DEFAULT'}
    }
    elsif ($^O eq 'MacOS') {
	return $ENV{'PWD'} = cwd();
    }
    elsif ($^O eq 'MSWin32') {
	$ENV{'PWD'} = $newpwd;
	return 1;
    }

    if ($newdir =~ m#^/#s) {
	$ENV{'PWD'} = $newdir;
    } else {
	my @curdir = split(m#/#,$ENV{'PWD'});
	@curdir = ('') unless @curdir;
	my $component;
	foreach $component (split(m#/#, $newdir)) {
	    next if $component eq '.';
	    pop(@curdir),next if $component eq '..';
	    push(@curdir,$component);
	}
	$ENV{'PWD'} = join('/',@curdir) || '/';
    }
    1;
}

# added function alias for those of us more
# used to the libc function.  --tchrist 27-Jan-00
*realpath = \&abs_path;

sub fast_abs_path {
    my $cwd = getcwd();
    my $path = @_ ? shift : '.';
    CORE::chdir($path) || croak "Cannot chdir to $path:$!";
    my $realpath = getcwd();
    CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
    $realpath;
}

# added function alias to follow principle of least surprise
# based on previous aliasing.  --tchrist 27-Jan-00
*fast_realpath = \&fast_abs_path;


# --- PORTING SECTION ---

# VMS: $ENV{'DEFAULT'} points to default directory at all times
# 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
# Note: Use of Cwd::chdir() causes the logical name PWD to be defined
#   in the process logical name table as the default device and directory
#   seen by Perl. This may not be the same as the default device
#   and directory seen by DCL after Perl exits, since the effects
#   the CRTL chdir() function persist only until Perl exits.

sub _vms_cwd {
    return $ENV{'DEFAULT'};
}

sub _vms_abs_path {
    return $ENV{'DEFAULT'} unless @_;
    my $path = VMS::Filespec::pathify($_[0]);
    croak("Invalid path name $_[0]") unless defined $path;
    return VMS::Filespec::rmsexpand($path);
}

sub _os2_cwd {
    $ENV{'PWD'} = `cmd /c cd`;
    chop $ENV{'PWD'};
    $ENV{'PWD'} =~ s:\\:/:g ;
    return $ENV{'PWD'};
}

sub _win32_cwd {
    $ENV{'PWD'} = Win32::GetCwd();
    $ENV{'PWD'} =~ s:\\:/:g ;
    return $ENV{'PWD'};
}

*_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd && 
                            defined &Win32::GetCwd);

*_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;

sub _dos_cwd {
    if (!defined &Dos::GetCwd) {
        $ENV{'PWD'} = `command /c cd`;
        chop $ENV{'PWD'};
        $ENV{'PWD'} =~ s:\\:/:g ;
    } else {
        $ENV{'PWD'} = Dos::GetCwd();
    }
    return $ENV{'PWD'};
}

sub _qnx_cwd {
    $ENV{'PWD'} = `/usr/bin/fullpath -t`;
    chop $ENV{'PWD'};
    return $ENV{'PWD'};
}

sub _qnx_abs_path {
    my $path = @_ ? shift : '.';
    my $realpath=`/usr/bin/fullpath -t $path`;
    chop $realpath;
    return $realpath;
}

sub _epoc_cwd {
    $ENV{'PWD'} = EPOC::getcwd();
    return $ENV{'PWD'};
}

{
    no warnings;	# assignments trigger 'subroutine redefined' warning

    if ($^O eq 'VMS') {
        *cwd		= \&_vms_cwd;
        *getcwd		= \&_vms_cwd;
        *fastcwd	= \&_vms_cwd;
        *fastgetcwd	= \&_vms_cwd;
        *abs_path	= \&_vms_abs_path;
        *fast_abs_path	= \&_vms_abs_path;
    }
    elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
        # We assume that &_NT_cwd is defined as an XSUB or in the core.
        *cwd		= \&_NT_cwd;
        *getcwd		= \&_NT_cwd;
        *fastcwd	= \&_NT_cwd;
        *fastgetcwd	= \&_NT_cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'os2') {
        # sys_cwd may keep the builtin command
        *cwd		= defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
        *getcwd		= \&cwd;
        *fastgetcwd	= \&cwd;
        *fastcwd	= \&cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'dos') {
        *cwd		= \&_dos_cwd;
        *getcwd		= \&_dos_cwd;
        *fastgetcwd	= \&_dos_cwd;
        *fastcwd	= \&_dos_cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'qnx') {
        *cwd		= \&_qnx_cwd;
        *getcwd		= \&_qnx_cwd;
        *fastgetcwd	= \&_qnx_cwd;
        *fastcwd	= \&_qnx_cwd;
        *abs_path	= \&_qnx_abs_path;
        *fast_abs_path	= \&_qnx_abs_path;
    }
    elsif ($^O eq 'cygwin') {
        *getcwd	= \&cwd;
        *fastgetcwd	= \&cwd;
        *fastcwd	= \&cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'epoc') {
        *cwd            = \&_epoc_cwd;
        *getcwd	        = \&_epoc_cwd;
        *fastgetcwd	= \&_epoc_cwd;
        *fastcwd	= \&_epoc_cwd;
        *abs_path	= \&fast_abs_path;
    }
    elsif ($^O eq 'MacOS') {
    	*getcwd     = \&cwd;
    	*fastgetcwd = \&cwd;
    	*fastcwd    = \&cwd;
    	*abs_path   = \&fast_abs_path;
    }
}

# package main; eval join('',<DATA>) || die $@;	# quick test

1;

__END__
BEGIN { import Cwd qw(:DEFAULT chdir); }
print join("\n", cwd, getcwd, fastcwd, "");
chdir('..');
print join("\n", cwd, getcwd, fastcwd, "");
print "$ENV{PWD}\n";
Commit	Line	Data
a0d0e21e	1	package Cwd;
a0d0e21e	2	require 5.000;
a0d0e21e	3
f06db76b	4	=head1 NAME
f06db76b	5
902bacac	6	Cwd - get pathname of current working directory
f06db76b	7
	8	=head1 SYNOPSIS
	9
4633a7c4	10	use Cwd;
	11	$dir = cwd;
	12
	13	use Cwd;
	14	$dir = getcwd;
f06db76b	15
f06db76b	16	use Cwd;
902bacac	17	$dir = fastcwd;
	18
	19	use Cwd;
4633a7c4	20	$dir = fastgetcwd;
f06db76b	21
	22	use Cwd 'chdir';
	23	chdir "/tmp";
	24	print $ENV{'PWD'};
	25
e4c51978	26	use Cwd 'abs_path'; # aka realpath()
20408e3c	27	print abs_path($ENV{'PWD'});
	28
	29	use Cwd 'fast_abs_path';
	30	print fast_abs_path($ENV{'PWD'});
	31
f06db76b	32	=head1 DESCRIPTION
f06db76b	33
902bacac	34	This module provides functions for determining the pathname of the
	35	current working directory. By default, it exports the functions
	36	cwd(), getcwd(), fastcwd(), and fastgetcwd() into the caller's
	37	namespace. Each of these functions are called without arguments and
	38	return the absolute path of the current working directory. It is
	39	recommended that cwd (or another *cwd() function) be used in I<all>
	40	code to ensure portability.
	41
	42	The cwd() is the most natural and safe form for the current
	43	architecture. For most systems it is identical to `pwd` (but without
	44	the trailing line terminator).
	45
f06db76b	46	The getcwd() function re-implements the getcwd(3) (or getwd(3)) functions
4633a7c4	47	in Perl.
f06db76b	48
cb1a09d0	49	The fastcwd() function looks the same as getcwd(), but runs faster.
fb73857a	50	It's also more dangerous because it might conceivably chdir() you out
	51	of a directory that it can't chdir() you back into. If fastcwd
	52	encounters a problem it will return undef but will probably leave you
	53	in a different directory. For a measure of extra security, if
	54	everything appears to have worked, the fastcwd() function will check
	55	that it leaves you in the same directory that it started in. If it has
	56	changed it will C<die> with the message "Unstable directory path,
	57	current directory changed unexpectedly". That should never happen.
f06db76b	58
902bacac	59	The fastgetcwd() function is provided as a synonym for cwd().
fb73857a	60
902bacac	61	The abs_path() function takes a single argument and returns the
	62	absolute pathname for that argument. It uses the same algorithm as
	63	getcwd(). (Actually, getcwd() is abs_path(".")) Symbolic links and
	64	relative-path components ("." and "..") are resolved to return the
	65	canonical pathname, just like realpath(3). This function is also
	66	callable as realpath().
	67
	68	The fast_abs_path() function looks the same as abs_path() but runs
	69	faster and, like fastcwd(), is more dangerous.
4633a7c4	70
	71	If you ask to override your chdir() built-in function, then your PWD
	72	environment variable will be kept up to date. (See
55497cff	73	L<perlsub/Overriding Builtin Functions>.) Note that it will only be
1fef88e7	74	kept up to date if all packages which use chdir import it from Cwd.
4633a7c4	75
f06db76b	76	=cut
f06db76b	77
b060a406	78	use strict;
96e4d5b1	79
	80	use Carp;
	81
1f4f94f5	82	our $VERSION = '2.04';
96e4d5b1	83
b060a406	84	use base qw/ Exporter /;
	85	our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
	86	our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
a0d0e21e	87
f22d8e4b	88	eval {
	89	require XSLoader;
	90	XSLoader::load('Cwd');
	91	};
4633a7c4	92
8b88ae92	93	# The 'natural and safe form' for UNIX (pwd may be setuid root)
96e4d5b1	94
8b88ae92	95	sub _backtick_pwd {
7e03f963	96	my $cwd = `pwd`;
	97	# `pwd` may fail e.g. if the disk is full
	98	chomp($cwd) if defined $cwd;
4633a7c4	99	$cwd;
8b88ae92	100	}
4633a7c4	101
	102	# Since some ports may predefine cwd internally (e.g., NT)
	103	# we take care not to override an existing definition for cwd().
	104
ea54c8bd	105	unless(defined &cwd) {
ea54c8bd	106	# The pwd command is not available in some chroot(2)'ed environments
4aecb5b5	107	if($^O eq 'MacOS' \|\| grep { -x "$_/pwd" } split(':', $ENV{PATH})) {
ea54c8bd	108	*cwd = \&_backtick_pwd;
	109	}
	110	else {
	111	*cwd = \&getcwd;
	112	}
	113	}
a0d0e21e	114
1f4f94f5	115	# set a reasonable (and very safe) default for fastgetcwd, in case it
	116	# isn't redefined later (20001212 rspier)
	117	*fastgetcwd = \&cwd;
748a9306	118
a0d0e21e	119	# By Brandon S. Allbery
	120	#
	121	# Usage: $cwd = getcwd();
	122
	123	sub getcwd
	124	{
07569ed3	125	abs_path('.');
a0d0e21e	126	}
a0d0e21e	127
4633a7c4	128	# Keeps track of current working directory in PWD environment var
a0d0e21e	129	# Usage:
	130	# use Cwd 'chdir';
	131	# chdir $newdir;
	132
4633a7c4	133	my $chdir_init = 0;
a0d0e21e	134
4633a7c4	135	sub chdir_init {
3b8e3443	136	if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
a0d0e21e	137	my($dd,$di) = stat('.');
	138	my($pd,$pi) = stat($ENV{'PWD'});
	139	if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
4633a7c4	140	$ENV{'PWD'} = cwd();
a0d0e21e	141	}
	142	}
	143	else {
3b8e3443	144	my $wd = cwd();
	145	$wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
	146	$ENV{'PWD'} = $wd;
a0d0e21e	147	}
4633a7c4	148	# Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
3b8e3443	149	if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m\|(/[^/]+(/[^/]+/[^/]+))(.*)\|s) {
a0d0e21e	150	my($pd,$pi) = stat($2);
	151	my($dd,$di) = stat($1);
	152	if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
	153	$ENV{'PWD'}="$2$3";
	154	}
	155	}
	156	$chdir_init = 1;
	157	}
	158
	159	sub chdir {
22978713	160	my $newdir = @_ ? shift : ''; # allow for no arg (chdir to HOME dir)
3b8e3443	161	$newdir =~ s\|///*\|/\|g unless $^O eq 'MSWin32';
a0d0e21e	162	chdir_init() unless $chdir_init;
4ffa1610	163	my $newpwd;
	164	if ($^O eq 'MSWin32') {
	165	# get the full path name before the chdir()
	166	$newpwd = Win32::GetFullPathName($newdir);
	167	}
	168
4633a7c4	169	return 0 unless CORE::chdir $newdir;
4ffa1610	170
3b8e3443	171	if ($^O eq 'VMS') {
	172	return $ENV{'PWD'} = $ENV{'DEFAULT'}
	173	}
4aecb5b5	174	elsif ($^O eq 'MacOS') {
	175	return $ENV{'PWD'} = cwd();
	176	}
3b8e3443	177	elsif ($^O eq 'MSWin32') {
4ffa1610	178	$ENV{'PWD'} = $newpwd;
3b8e3443	179	return 1;
3b8e3443	180	}
748a9306	181
392d8ab8	182	if ($newdir =~ m#^/#s) {
a0d0e21e	183	$ENV{'PWD'} = $newdir;
4633a7c4	184	} else {
	185	my @curdir = split(m#/#,$ENV{'PWD'});
	186	@curdir = ('') unless @curdir;
	187	my $component;
a0d0e21e	188	foreach $component (split(m#/#, $newdir)) {
	189	next if $component eq '.';
	190	pop(@curdir),next if $component eq '..';
	191	push(@curdir,$component);
	192	}
	193	$ENV{'PWD'} = join('/',@curdir) \|\| '/';
	194	}
4633a7c4	195	1;
a0d0e21e	196	}
a0d0e21e	197
e4c51978	198	# added function alias for those of us more
	199	# used to the libc function. --tchrist 27-Jan-00
	200	*realpath = \&abs_path;
	201
96e4d5b1	202	sub fast_abs_path {
96e4d5b1	203	my $cwd = getcwd();
3c65c14b	204	my $path = @_ ? shift : '.';
e79e61e4	205	CORE::chdir($path) \|\| croak "Cannot chdir to $path:$!";
96e4d5b1	206	my $realpath = getcwd();
e79e61e4	207	CORE::chdir($cwd) \|\| croak "Cannot chdir back to $cwd:$!";
96e4d5b1	208	$realpath;
8b88ae92	209	}
8b88ae92	210
e4c51978	211	# added function alias to follow principle of least surprise
	212	# based on previous aliasing. --tchrist 27-Jan-00
	213	*fast_realpath = \&fast_abs_path;
	214
4633a7c4	215
	216	# --- PORTING SECTION ---
	217
	218	# VMS: $ENV{'DEFAULT'} points to default directory at all times
bd3fa61c	219	# 06-Mar-1996 Charles Bailey bailey@newman.upenn.edu
c6538b72	220	# Note: Use of Cwd::chdir() causes the logical name PWD to be defined
8b88ae92	221	# in the process logical name table as the default device and directory
8b88ae92	222	# seen by Perl. This may not be the same as the default device
4633a7c4	223	# and directory seen by DCL after Perl exits, since the effects
4633a7c4	224	# the CRTL chdir() function persist only until Perl exits.
4633a7c4	225
4633a7c4	226	sub _vms_cwd {
96e4d5b1	227	return $ENV{'DEFAULT'};
	228	}
	229
	230	sub _vms_abs_path {
	231	return $ENV{'DEFAULT'} unless @_;
	232	my $path = VMS::Filespec::pathify($_[0]);
	233	croak("Invalid path name $_[0]") unless defined $path;
	234	return VMS::Filespec::rmsexpand($path);
4633a7c4	235	}
68dc0745	236
4633a7c4	237	sub _os2_cwd {
	238	$ENV{'PWD'} = `cmd /c cd`;
	239	chop $ENV{'PWD'};
	240	$ENV{'PWD'} =~ s:\\:/:g ;
	241	return $ENV{'PWD'};
	242	}
	243
96e4d5b1	244	sub _win32_cwd {
2d7a9237	245	$ENV{'PWD'} = Win32::GetCwd();
96e4d5b1	246	$ENV{'PWD'} =~ s:\\:/:g ;
	247	return $ENV{'PWD'};
	248	}
	249
	250	*_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
2d7a9237	251	defined &Win32::GetCwd);
96e4d5b1	252
96e4d5b1	253	*_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
68dc0745	254
39e571d4	255	sub _dos_cwd {
	256	if (!defined &Dos::GetCwd) {
	257	$ENV{'PWD'} = `command /c cd`;
	258	chop $ENV{'PWD'};
	259	$ENV{'PWD'} =~ s:\\:/:g ;
	260	} else {
	261	$ENV{'PWD'} = Dos::GetCwd();
	262	}
55497cff	263	return $ENV{'PWD'};
	264	}
	265
7fbf1995	266	sub _qnx_cwd {
	267	$ENV{'PWD'} = `/usr/bin/fullpath -t`;
	268	chop $ENV{'PWD'};
	269	return $ENV{'PWD'};
	270	}
	271
	272	sub _qnx_abs_path {
fa921dc6	273	my $path = @_ ? shift : '.';
7fbf1995	274	my $realpath=`/usr/bin/fullpath -t $path`;
	275	chop $realpath;
	276	return $realpath;
	277	}
	278
ed79a026	279	sub _epoc_cwd {
	280	$ENV{'PWD'} = EPOC::getcwd();
	281	return $ENV{'PWD'};
	282	}
	283
ac1ad7f0	284	{
db376a24	285	no warnings; # assignments trigger 'subroutine redefined' warning
4633a7c4	286
ac1ad7f0	287	if ($^O eq 'VMS') {
96e4d5b1	288	*cwd = \&_vms_cwd;
	289	*getcwd = \&_vms_cwd;
	290	*fastcwd = \&_vms_cwd;
	291	*fastgetcwd = \&_vms_cwd;
	292	*abs_path = \&_vms_abs_path;
	293	*fast_abs_path = \&_vms_abs_path;
ac1ad7f0	294	}
	295	elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
	296	# We assume that &_NT_cwd is defined as an XSUB or in the core.
96e4d5b1	297	*cwd = \&_NT_cwd;
	298	*getcwd = \&_NT_cwd;
	299	*fastcwd = \&_NT_cwd;
	300	*fastgetcwd = \&_NT_cwd;
	301	*abs_path = \&fast_abs_path;
ac1ad7f0	302	}
	303	elsif ($^O eq 'os2') {
	304	# sys_cwd may keep the builtin command
96e4d5b1	305	*cwd = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
	306	*getcwd = \&cwd;
	307	*fastgetcwd = \&cwd;
	308	*fastcwd = \&cwd;
	309	*abs_path = \&fast_abs_path;
ac1ad7f0	310	}
39e571d4	311	elsif ($^O eq 'dos') {
	312	*cwd = \&_dos_cwd;
	313	*getcwd = \&_dos_cwd;
	314	*fastgetcwd = \&_dos_cwd;
	315	*fastcwd = \&_dos_cwd;
96e4d5b1	316	*abs_path = \&fast_abs_path;
ac1ad7f0	317	}
7fbf1995	318	elsif ($^O eq 'qnx') {
	319	*cwd = \&_qnx_cwd;
	320	*getcwd = \&_qnx_cwd;
	321	*fastgetcwd = \&_qnx_cwd;
	322	*fastcwd = \&_qnx_cwd;
	323	*abs_path = \&_qnx_abs_path;
	324	*fast_abs_path = \&_qnx_abs_path;
	325	}
4fabb596	326	elsif ($^O eq 'cygwin') {
1cab015a	327	*getcwd = \&cwd;
	328	*fastgetcwd = \&cwd;
	329	*fastcwd = \&cwd;
	330	*abs_path = \&fast_abs_path;
	331	}
ed79a026	332	elsif ($^O eq 'epoc') {
fa6a1c44	333	*cwd = \&_epoc_cwd;
fa6a1c44	334	*getcwd = \&_epoc_cwd;
ed79a026	335	*fastgetcwd = \&_epoc_cwd;
	336	*fastcwd = \&_epoc_cwd;
	337	*abs_path = \&fast_abs_path;
	338	}
4aecb5b5	339	elsif ($^O eq 'MacOS') {
	340	*getcwd = \&cwd;
	341	*fastgetcwd = \&cwd;
	342	*fastcwd = \&cwd;
	343	*abs_path = \&fast_abs_path;
	344	}
55497cff	345	}
4633a7c4	346
	347	# package main; eval join('',<DATA>) \|\| die $@; # quick test
	348
a0d0e21e	349	1;
a0d0e21e	350
4633a7c4	351	__END__
	352	BEGIN { import Cwd qw(:DEFAULT chdir); }
	353	print join("\n", cwd, getcwd, fastcwd, "");
	354	chdir('..');
	355	print join("\n", cwd, getcwd, fastcwd, "");
	356	print "$ENV{PWD}\n";