[p5sagit/Class-Accessor-Grouped.git] / lib / Class / Accessor / Grouped.pm

package Class::Accessor::Grouped;
use strict;
use warnings;
use Carp ();
use Class::Inspector ();
use Scalar::Util ();
use MRO::Compat;
use Sub::Name ();

our $VERSION = '0.09003';
$VERSION = eval $VERSION;

# Class::XSAccessor is segfaulting on win32, so be careful
# Win32 users can set $hasXS to try to use it anyway

our $hasXS;

sub _hasXS {

  if (not defined $hasXS) {
    $hasXS = 0;

    if ($^O ne 'MSWin32') {
      eval {
        require Class::XSAccessor;
        $hasXS = 1;
      };
    }
  }

  return $hasXS;
}

=head1 NAME

Class::Accessor::Grouped - Lets you build groups of accessors

=head1 SYNOPSIS

=head1 DESCRIPTION

This class lets you build groups of accessors that will call different
getters and setters.

=head1 METHODS

=head2 mk_group_accessors

=over 4

=item Arguments: $group, @fieldspec

Returns: none

=back

Creates a set of accessors in a given group.

$group is the name of the accessor group for the generated accessors; they
will call get_$group($field) on get and set_$group($field, $value) on set.

If you want to mimic Class::Accessor's mk_accessors $group has to be 'simple'
to tell Class::Accessor::Grouped to use its own get_simple and set_simple
methods.

@fieldspec is a list of field/accessor names; if a fieldspec is a scalar
this is used as both field and accessor name, if a listref it is expected to
be of the form [ $accessor, $field ].

=cut

sub mk_group_accessors {
  my ($self, $group, @fields) = @_;

  $self->_mk_group_accessors('make_group_accessor', $group, @fields);
  return;
}


{
    no strict 'refs';
    no warnings 'redefine';

    sub _mk_group_accessors {
        my($self, $maker, $group, @fields) = @_;
        my $class = Scalar::Util::blessed $self || $self;

        # So we don't have to do lots of lookups inside the loop.
        $maker = $self->can($maker) unless ref $maker;
        
        my $hasXS = _hasXS();

        foreach my $field (@fields) {
            if( $field eq 'DESTROY' ) {
                Carp::carp("Having a data accessor named DESTROY  in ".
                             "'$class' is unwise.");
            }

            my $name = $field;

            ($name, $field) = @$field if ref $field;
            
            my $alias = "_${name}_accessor";
            my $full_name = join('::', $class, $name);
            my $full_alias = join('::', $class, $alias);
            
            if ( $hasXS && $group eq 'simple' ) {
                require Class::XSAccessor;
                Class::XSAccessor::newxs_accessor("${class}::${name}", $field, 0);
                Class::XSAccessor::newxs_accessor("${class}::${alias}", $field, 0);
                
                # XXX: is the alias accessor really necessary?
            }
            else {
                my $accessor = $self->$maker($group, $field);
                my $alias_accessor = $self->$maker($group, $field);
                
                *$full_name = Sub::Name::subname($full_name, $accessor);
                  #unless defined &{$class."\:\:$field"}
                
                *$full_alias = Sub::Name::subname($full_alias, $alias_accessor);
                  #unless defined &{$class."\:\:$alias"}
            }
        }
    }
}

=head2 mk_group_ro_accessors

=over 4

=item Arguments: $group, @fieldspec

Returns: none

=back

Creates a set of read only accessors in a given group. Identical to
L</mk_group_accessors> but accessors will throw an error if passed a value
rather than setting the value.

=cut

sub mk_group_ro_accessors {
    my($self, $group, @fields) = @_;

    $self->_mk_group_accessors('make_group_ro_accessor', $group, @fields);
}

=head2 mk_group_wo_accessors

=over 4

=item Arguments: $group, @fieldspec

Returns: none

=back

Creates a set of write only accessors in a given group. Identical to
L</mk_group_accessors> but accessors will throw an error if not passed a
value rather than getting the value.

=cut

sub mk_group_wo_accessors {
    my($self, $group, @fields) = @_;

    $self->_mk_group_accessors('make_group_wo_accessor', $group, @fields);
}

=head2 make_group_accessor

=over 4

=item Arguments: $group, $field

Returns: $sub (\CODE)

=back

Returns a single accessor in a given group; called by mk_group_accessors
for each entry in @fieldspec.

=cut

sub make_group_accessor {
    my ($class, $group, $field) = @_;

    my $set = "set_$group";
    my $get = "get_$group";

    # eval for faster fastiness
    return eval "sub {
        if(\@_ > 1) {
            return shift->$set('$field', \@_);
        }
        else {
            return shift->$get('$field');
        }
    };"
}

=head2 make_group_ro_accessor

=over 4

=item Arguments: $group, $field

Returns: $sub (\CODE)

=back

Returns a single read-only accessor in a given group; called by
mk_group_ro_accessors for each entry in @fieldspec.

=cut

sub make_group_ro_accessor {
    my($class, $group, $field) = @_;

    my $get = "get_$group";

    return eval "sub {
        if(\@_ > 1) {
            my \$caller = caller;
            Carp::croak(\"'\$caller' cannot alter the value of '$field' on \".
                        \"objects of class '$class'\");
        }
        else {
            return shift->$get('$field');
        }
    };"
}

=head2 make_group_wo_accessor

=over 4

=item Arguments: $group, $field

Returns: $sub (\CODE)

=back

Returns a single write-only accessor in a given group; called by
mk_group_wo_accessors for each entry in @fieldspec.

=cut

sub make_group_wo_accessor {
    my($class, $group, $field) = @_;

    my $set = "set_$group";

    return eval "sub {
        unless (\@_ > 1) {
            my \$caller = caller;
            Carp::croak(\"'\$caller' cannot access the value of '$field' on \".
                        \"objects of class '$class'\");
        }
        else {
            return shift->$set('$field', \@_);
        }
    };"
}

=head2 get_simple

=over 4

=item Arguments: $field

Returns: $value

=back

Simple getter for hash-based objects which returns the value for the field
name passed as an argument.

=cut

sub get_simple {
  return $_[0]->{$_[1]};
}

=head2 set_simple

=over 4

=item Arguments: $field, $new_value

Returns: $new_value

=back

Simple setter for hash-based objects which sets and then returns the value
for the field name passed as an argument.

=cut

sub set_simple {
  return $_[0]->{$_[1]} = $_[2];
}


=head2 get_inherited

=over 4

=item Arguments: $field

Returns: $value

=back

Simple getter for Classes and hash-based objects which returns the value for
the field name passed as an argument. This behaves much like
L<Class::Data::Accessor> where the field can be set in a base class,
inherited and changed in subclasses, and inherited and changed for object
instances.

=cut

sub get_inherited {
    my $class;

    if (Scalar::Util::blessed $_[0]) {
        my $reftype = Scalar::Util::reftype $_[0];
        $class = ref $_[0];

        if ($reftype eq 'HASH' && exists $_[0]->{$_[1]}) {
            return $_[0]->{$_[1]};
        } elsif ($reftype ne 'HASH') {
            Carp::croak('Cannot get inherited value on an object instance that is not hash-based');
        };
    } else {
        $class = $_[0];
    };

    no strict 'refs';
    no warnings qw/uninitialized/;
    return ${$class.'::__cag_'.$_[1]} if defined(${$class.'::__cag_'.$_[1]});

    # we need to be smarter about recalculation, as @ISA (thus supers) can very well change in-flight
    my $pkg_gen = mro::get_pkg_gen ($class);
    if ( ${$class.'::__cag_pkg_gen'} != $pkg_gen ) {
        @{$class.'::__cag_supers'} = $_[0]->get_super_paths;
        ${$class.'::__cag_pkg_gen'} = $pkg_gen;
    };

    foreach (@{$class.'::__cag_supers'}) {
        return ${$_.'::__cag_'.$_[1]} if defined(${$_.'::__cag_'.$_[1]});
    };

    return undef;
}

=head2 set_inherited

=over 4

=item Arguments: $field, $new_value

Returns: $new_value

=back

Simple setter for Classes and hash-based objects which sets and then returns
the value for the field name passed as an argument. When called on a hash-based
object it will set the appropriate hash key value. When called on a class, it
will set a class level variable.

B<Note:>: This method will die if you try to set an object variable on a non
hash-based object.

=cut

sub set_inherited {
    if (Scalar::Util::blessed $_[0]) {
        if (Scalar::Util::reftype $_[0] eq 'HASH') {
            return $_[0]->{$_[1]} = $_[2];
        } else {
            Carp::croak('Cannot set inherited value on an object instance that is not hash-based');
        };
    } else {
        no strict 'refs';

        return ${$_[0].'::__cag_'.$_[1]} = $_[2];
    };
}

=head2 get_component_class

=over 4

=item Arguments: $field

Returns: $value

=back

Gets the value of the specified component class.

    __PACKAGE__->mk_group_accessors('component_class' => 'result_class');

    $self->result_class->method();

    ## same as
    $self->get_component_class('result_class')->method();

=cut

sub get_component_class {
    return $_[0]->get_inherited($_[1]);
};

=head2 set_component_class

=over 4

=item Arguments: $field, $class

Returns: $new_value

=back

Inherited accessor that automatically loads the specified class before setting
it. This method will die if the specified class could not be loaded.

    __PACKAGE__->mk_group_accessors('component_class' => 'result_class');
    __PACKAGE__->result_class('MyClass');

    $self->result_class->method();

=cut

sub set_component_class {
    if ($_[2]) {
        local $^W = 0;
        if (Class::Inspector->installed($_[2]) && !Class::Inspector->loaded($_[2])) {
            eval "use $_[2]";

            Carp::croak("Could not load $_[1] '$_[2]': ", $@) if $@;
        };
    };

    return $_[0]->set_inherited($_[1], $_[2]);
};

=head2 get_super_paths

Returns a list of 'parent' or 'super' class names that the current class inherited from.

=cut

sub get_super_paths {
    my $class = Scalar::Util::blessed $_[0] || $_[0];

    return @{mro::get_linear_isa($class)};
};

1;

=head1 PERFORMANCE

You can speed up accessors of type 'simple' by installing L<Class::XSAccessor>.
Note however that the use of this module is disabled by default on Win32
systems, as it causes yet unresolved segfaults. If you are a Win32 user, and
want to try this module with L<Class::XSAccessor>, set
C<$Class::Accessor::Grouped::hasXS> to a true value B<before> registering
your accessors (e.g. in a C<BEGIN> block)

=head1 AUTHORS

Matt S. Trout <mst@shadowcatsystems.co.uk>
Christopher H. Laco <claco@chrislaco.com>

With contributions from:

Guillermo Roditi <groditi@cpan.org>

=head1 COPYRIGHT & LICENSE

Copyright (c) 2006-2010 Matt S. Trout <mst@shadowcatsystems.co.uk>

This program is free software; you can redistribute it and/or modify
it under the same terms as perl itself.

=cut
Commit	Line	Data
963a69a5	1	package Class::Accessor::Grouped;
	2	use strict;
	3	use warnings;
a0bce8bc	4	use Carp ();
331e820d	5	use Class::Inspector ();
a0bce8bc	6	use Scalar::Util ();
8787799c	7	use MRO::Compat;
1ee74bdd	8	use Sub::Name ();
331e820d	9
af169484	10	our $VERSION = '0.09003';
15cf8e32	11	$VERSION = eval $VERSION;
963a69a5	12
a2537c55	13	# Class::XSAccessor is segfaulting on win32, so be careful
a2537c55	14	# Win32 users can set $hasXS to try to use it anyway
af169484	15
a2537c55	16	our $hasXS;
af169484	17
a2537c55	18	sub _hasXS {
	19
	20	if (not defined $hasXS) {
	21	$hasXS = 0;
	22
	23	if ($^O ne 'MSWin32') {
	24	eval {
	25	require Class::XSAccessor;
	26	$hasXS = 1;
	27	};
	28	}
	29	}
	30
	31	return $hasXS;
	32	}
	33
963a69a5	34	=head1 NAME
963a69a5	35
1ad8d8c6	36	Class::Accessor::Grouped - Lets you build groups of accessors
963a69a5	37
	38	=head1 SYNOPSIS
	39
	40	=head1 DESCRIPTION
	41
	42	This class lets you build groups of accessors that will call different
	43	getters and setters.
	44
	45	=head1 METHODS
	46
	47	=head2 mk_group_accessors
	48
	49	=over 4
	50
	51	=item Arguments: $group, @fieldspec
	52
	53	Returns: none
	54
	55	=back
	56
	57	Creates a set of accessors in a given group.
	58
	59	$group is the name of the accessor group for the generated accessors; they
	60	will call get_$group($field) on get and set_$group($field, $value) on set.
	61
22fa6720	62	If you want to mimic Class::Accessor's mk_accessors $group has to be 'simple'
	63	to tell Class::Accessor::Grouped to use its own get_simple and set_simple
	64	methods.
	65
963a69a5	66	@fieldspec is a list of field/accessor names; if a fieldspec is a scalar
	67	this is used as both field and accessor name, if a listref it is expected to
	68	be of the form [ $accessor, $field ].
	69
	70	=cut
	71
	72	sub mk_group_accessors {
	73	my ($self, $group, @fields) = @_;
	74
	75	$self->_mk_group_accessors('make_group_accessor', $group, @fields);
	76	return;
	77	}
	78
	79
	80	{
	81	no strict 'refs';
	82	no warnings 'redefine';
	83
	84	sub _mk_group_accessors {
	85	my($self, $maker, $group, @fields) = @_;
a0bce8bc	86	my $class = Scalar::Util::blessed $self \|\| $self;
963a69a5	87
	88	# So we don't have to do lots of lookups inside the loop.
	89	$maker = $self->can($maker) unless ref $maker;
9540f4e4	90
9540f4e4	91	my $hasXS = _hasXS();
963a69a5	92
	93	foreach my $field (@fields) {
	94	if( $field eq 'DESTROY' ) {
a0bce8bc	95	Carp::carp("Having a data accessor named DESTROY in ".
963a69a5	96	"'$class' is unwise.");
	97	}
	98
	99	my $name = $field;
	100
	101	($name, $field) = @$field if ref $field;
9540f4e4	102
963a69a5	103	my $alias = "_${name}_accessor";
1ee74bdd	104	my $full_name = join('::', $class, $name);
1ee74bdd	105	my $full_alias = join('::', $class, $alias);
9540f4e4	106
9540f4e4	107	if ( $hasXS && $group eq 'simple' ) {
46f1ef81	108	require Class::XSAccessor;
9540f4e4	109	Class::XSAccessor::newxs_accessor("${class}::${name}", $field, 0);
	110	Class::XSAccessor::newxs_accessor("${class}::${alias}", $field, 0);
	111
	112	# XXX: is the alias accessor really necessary?
	113	}
	114	else {
	115	my $accessor = $self->$maker($group, $field);
	116	my $alias_accessor = $self->$maker($group, $field);
	117
	118	*$full_name = Sub::Name::subname($full_name, $accessor);
	119	#unless defined &{$class."\:\:$field"}
	120
	121	*$full_alias = Sub::Name::subname($full_alias, $alias_accessor);
	122	#unless defined &{$class."\:\:$alias"}
	123	}
963a69a5	124	}
	125	}
	126	}
	127
	128	=head2 mk_group_ro_accessors
	129
	130	=over 4
	131
	132	=item Arguments: $group, @fieldspec
	133
	134	Returns: none
	135
	136	=back
	137
	138	Creates a set of read only accessors in a given group. Identical to
a557f8ad	139	L</mk_group_accessors> but accessors will throw an error if passed a value
963a69a5	140	rather than setting the value.
	141
	142	=cut
	143
	144	sub mk_group_ro_accessors {
	145	my($self, $group, @fields) = @_;
	146
	147	$self->_mk_group_accessors('make_group_ro_accessor', $group, @fields);
	148	}
	149
	150	=head2 mk_group_wo_accessors
	151
	152	=over 4
	153
	154	=item Arguments: $group, @fieldspec
	155
	156	Returns: none
	157
	158	=back
	159
	160	Creates a set of write only accessors in a given group. Identical to
a557f8ad	161	L</mk_group_accessors> but accessors will throw an error if not passed a
963a69a5	162	value rather than getting the value.
	163
	164	=cut
	165
	166	sub mk_group_wo_accessors {
	167	my($self, $group, @fields) = @_;
	168
	169	$self->_mk_group_accessors('make_group_wo_accessor', $group, @fields);
	170	}
	171
	172	=head2 make_group_accessor
	173
	174	=over 4
	175
	176	=item Arguments: $group, $field
	177
	178	Returns: $sub (\CODE)
	179
	180	=back
	181
	182	Returns a single accessor in a given group; called by mk_group_accessors
	183	for each entry in @fieldspec.
	184
	185	=cut
	186
	187	sub make_group_accessor {
	188	my ($class, $group, $field) = @_;
	189
	190	my $set = "set_$group";
	191	my $get = "get_$group";
	192
a0bce8bc	193	# eval for faster fastiness
	194	return eval "sub {
	195	if(\@_ > 1) {
	196	return shift->$set('$field', \@_);
963a69a5	197	}
963a69a5	198	else {
a0bce8bc	199	return shift->$get('$field');
963a69a5	200	}
a0bce8bc	201	};"
963a69a5	202	}
	203
	204	=head2 make_group_ro_accessor
	205
	206	=over 4
	207
	208	=item Arguments: $group, $field
	209
	210	Returns: $sub (\CODE)
	211
	212	=back
	213
	214	Returns a single read-only accessor in a given group; called by
	215	mk_group_ro_accessors for each entry in @fieldspec.
	216
	217	=cut
	218
	219	sub make_group_ro_accessor {
	220	my($class, $group, $field) = @_;
	221
	222	my $get = "get_$group";
	223
a0bce8bc	224	return eval "sub {
	225	if(\@_ > 1) {
	226	my \$caller = caller;
	227	Carp::croak(\"'\$caller' cannot alter the value of '$field' on \".
	228	\"objects of class '$class'\");
963a69a5	229	}
963a69a5	230	else {
a0bce8bc	231	return shift->$get('$field');
963a69a5	232	}
a0bce8bc	233	};"
963a69a5	234	}
	235
	236	=head2 make_group_wo_accessor
	237
	238	=over 4
	239
	240	=item Arguments: $group, $field
	241
	242	Returns: $sub (\CODE)
	243
	244	=back
	245
	246	Returns a single write-only accessor in a given group; called by
	247	mk_group_wo_accessors for each entry in @fieldspec.
	248
	249	=cut
	250
	251	sub make_group_wo_accessor {
	252	my($class, $group, $field) = @_;
	253
	254	my $set = "set_$group";
	255
a0bce8bc	256	return eval "sub {
	257	unless (\@_ > 1) {
	258	my \$caller = caller;
	259	Carp::croak(\"'\$caller' cannot access the value of '$field' on \".
	260	\"objects of class '$class'\");
963a69a5	261	}
963a69a5	262	else {
a0bce8bc	263	return shift->$set('$field', \@_);
963a69a5	264	}
a0bce8bc	265	};"
963a69a5	266	}
	267
	268	=head2 get_simple
	269
	270	=over 4
	271
	272	=item Arguments: $field
	273
	274	Returns: $value
	275
	276	=back
	277
	278	Simple getter for hash-based objects which returns the value for the field
	279	name passed as an argument.
	280
	281	=cut
	282
	283	sub get_simple {
a0bce8bc	284	return $_[0]->{$_[1]};
963a69a5	285	}
	286
	287	=head2 set_simple
	288
	289	=over 4
	290
	291	=item Arguments: $field, $new_value
	292
	293	Returns: $new_value
	294
	295	=back
	296
	297	Simple setter for hash-based objects which sets and then returns the value
	298	for the field name passed as an argument.
	299
	300	=cut
	301
	302	sub set_simple {
a0bce8bc	303	return $_[0]->{$_[1]} = $_[2];
963a69a5	304	}
963a69a5	305
e6f2a0fd	306
	307	=head2 get_inherited
	308
	309	=over 4
	310
	311	=item Arguments: $field
	312
	313	Returns: $value
	314
	315	=back
	316
331e820d	317	Simple getter for Classes and hash-based objects which returns the value for
	318	the field name passed as an argument. This behaves much like
	319	L<Class::Data::Accessor> where the field can be set in a base class,
	320	inherited and changed in subclasses, and inherited and changed for object
	321	instances.
e6f2a0fd	322
	323	=cut
	324
	325	sub get_inherited {
a49c32d9	326	my $class;
e6f2a0fd	327
a0bce8bc	328	if (Scalar::Util::blessed $_[0]) {
	329	my $reftype = Scalar::Util::reftype $_[0];
	330	$class = ref $_[0];
a49c32d9	331
a0bce8bc	332	if ($reftype eq 'HASH' && exists $_[0]->{$_[1]}) {
a0bce8bc	333	return $_[0]->{$_[1]};
a49c32d9	334	} elsif ($reftype ne 'HASH') {
a0bce8bc	335	Carp::croak('Cannot get inherited value on an object instance that is not hash-based');
e6f2a0fd	336	};
a49c32d9	337	} else {
a0bce8bc	338	$class = $_[0];
e6f2a0fd	339	};
	340
	341	no strict 'refs';
fe63d727	342	no warnings qw/uninitialized/;
a0bce8bc	343	return ${$class.'::__cag_'.$_[1]} if defined(${$class.'::__cag_'.$_[1]});
e6f2a0fd	344
4f8ce9da	345	# we need to be smarter about recalculation, as @ISA (thus supers) can very well change in-flight
4f8ce9da	346	my $pkg_gen = mro::get_pkg_gen ($class);
fe63d727	347	if ( ${$class.'::__cag_pkg_gen'} != $pkg_gen ) {
a0bce8bc	348	@{$class.'::__cag_supers'} = $_[0]->get_super_paths;
4f8ce9da	349	${$class.'::__cag_pkg_gen'} = $pkg_gen;
a49c32d9	350	};
	351
	352	foreach (@{$class.'::__cag_supers'}) {
a0bce8bc	353	return ${$_.'::__cag_'.$_[1]} if defined(${$_.'::__cag_'.$_[1]});
e6f2a0fd	354	};
c46050d3	355
9c3d5179	356	return undef;
e6f2a0fd	357	}
	358
	359	=head2 set_inherited
	360
	361	=over 4
	362
	363	=item Arguments: $field, $new_value
	364
	365	Returns: $new_value
	366
	367	=back
	368
331e820d	369	Simple setter for Classes and hash-based objects which sets and then returns
	370	the value for the field name passed as an argument. When called on a hash-based
	371	object it will set the appropriate hash key value. When called on a class, it
	372	will set a class level variable.
e6f2a0fd	373
331e820d	374	B<Note:>: This method will die if you try to set an object variable on a non
331e820d	375	hash-based object.
e6f2a0fd	376
	377	=cut
	378
	379	sub set_inherited {
a0bce8bc	380	if (Scalar::Util::blessed $_[0]) {
	381	if (Scalar::Util::reftype $_[0] eq 'HASH') {
	382	return $_[0]->{$_[1]} = $_[2];
e6f2a0fd	383	} else {
a0bce8bc	384	Carp::croak('Cannot set inherited value on an object instance that is not hash-based');
e6f2a0fd	385	};
	386	} else {
	387	no strict 'refs';
	388
a0bce8bc	389	return ${$_[0].'::__cag_'.$_[1]} = $_[2];
e6f2a0fd	390	};
	391	}
	392
331e820d	393	=head2 get_component_class
	394
	395	=over 4
	396
	397	=item Arguments: $field
	398
	399	Returns: $value
	400
	401	=back
	402
	403	Gets the value of the specified component class.
	404
	405	__PACKAGE__->mk_group_accessors('component_class' => 'result_class');
97d76fb4	406
331e820d	407	$self->result_class->method();
97d76fb4	408
331e820d	409	## same as
	410	$self->get_component_class('result_class')->method();
	411
	412	=cut
	413
	414	sub get_component_class {
a0bce8bc	415	return $_[0]->get_inherited($_[1]);
331e820d	416	};
	417
	418	=head2 set_component_class
	419
	420	=over 4
	421
	422	=item Arguments: $field, $class
	423
	424	Returns: $new_value
	425
	426	=back
	427
	428	Inherited accessor that automatically loads the specified class before setting
	429	it. This method will die if the specified class could not be loaded.
	430
	431	__PACKAGE__->mk_group_accessors('component_class' => 'result_class');
	432	__PACKAGE__->result_class('MyClass');
97d76fb4	433
331e820d	434	$self->result_class->method();
	435
	436	=cut
	437
	438	sub set_component_class {
a0bce8bc	439	if ($_[2]) {
bce7bdf8	440	local $^W = 0;
a0bce8bc	441	if (Class::Inspector->installed($_[2]) && !Class::Inspector->loaded($_[2])) {
a0bce8bc	442	eval "use $_[2]";
331e820d	443
a0bce8bc	444	Carp::croak("Could not load $_[1] '$_[2]': ", $@) if $@;
331e820d	445	};
	446	};
	447
a0bce8bc	448	return $_[0]->set_inherited($_[1], $_[2]);
331e820d	449	};
331e820d	450
a49c32d9	451	=head2 get_super_paths
	452
	453	Returns a list of 'parent' or 'super' class names that the current class inherited from.
	454
	455	=cut
	456
	457	sub get_super_paths {
a0bce8bc	458	my $class = Scalar::Util::blessed $_[0] \|\| $_[0];
a49c32d9	459
8787799c	460	return @{mro::get_linear_isa($class)};
a49c32d9	461	};
a49c32d9	462
a2537c55	463	1;
b9a69571	464
9d7d52da	465	=head1 PERFORMANCE
15cf8e32	466
a2537c55	467	You can speed up accessors of type 'simple' by installing L<Class::XSAccessor>.
a2537c55	468	Note however that the use of this module is disabled by default on Win32
af169484	469	systems, as it causes yet unresolved segfaults. If you are a Win32 user, and
a2537c55	470	want to try this module with L<Class::XSAccessor>, set
	471	C<$Class::Accessor::Grouped::hasXS> to a true value B<before> registering
	472	your accessors (e.g. in a C<BEGIN> block)
963a69a5	473
	474	=head1 AUTHORS
	475
	476	Matt S. Trout <mst@shadowcatsystems.co.uk>
97972dcb	477	Christopher H. Laco <claco@chrislaco.com>
963a69a5	478
dfb86526	479	With contributions from:
	480
	481	Guillermo Roditi <groditi@cpan.org>
	482
4fe25633	483	=head1 COPYRIGHT & LICENSE
963a69a5	484
af169484	485	Copyright (c) 2006-2010 Matt S. Trout <mst@shadowcatsystems.co.uk>
963a69a5	486
4fe25633	487	This program is free software; you can redistribute it and/or modify
4fe25633	488	it under the same terms as perl itself.
963a69a5	489
4fe25633	490	=cut