[p5sagit/Class-Accessor-Grouped.git] / lib / Class / Accessor / Grouped.pm

package Class::Accessor::Grouped;
use strict;
use warnings;
use Carp ();
use Class::Inspector ();
use Scalar::Util ();
use MRO::Compat;
use Sub::Name ();

our $VERSION = '0.09002';
$VERSION = eval $VERSION;

# Class::XSAccessor is segfaulting on win32, so be careful
# Win32 users can set $hasXS to try to use it anyway
our $hasXS;
sub _hasXS {

  if (not defined $hasXS) {
    $hasXS = 0;

    if ($^O ne 'MSWin32') {
      eval {
        require Class::XSAccessor;
        $hasXS = 1;
      };
    }
  }

  return $hasXS;
}

=head1 NAME

Class::Accessor::Grouped - Lets you build groups of accessors

=head1 SYNOPSIS

=head1 DESCRIPTION

This class lets you build groups of accessors that will call different
getters and setters.

=head1 METHODS

=head2 mk_group_accessors

=over 4

=item Arguments: $group, @fieldspec

Returns: none

=back

Creates a set of accessors in a given group.

$group is the name of the accessor group for the generated accessors; they
will call get_$group($field) on get and set_$group($field, $value) on set.

If you want to mimic Class::Accessor's mk_accessors $group has to be 'simple'
to tell Class::Accessor::Grouped to use its own get_simple and set_simple
methods.

@fieldspec is a list of field/accessor names; if a fieldspec is a scalar
this is used as both field and accessor name, if a listref it is expected to
be of the form [ $accessor, $field ].

=cut

sub mk_group_accessors {
  my ($self, $group, @fields) = @_;

  $self->_mk_group_accessors('make_group_accessor', $group, @fields);
  return;
}


{
    no strict 'refs';
    no warnings 'redefine';

    sub _mk_group_accessors {
        my($self, $maker, $group, @fields) = @_;
        my $class = Scalar::Util::blessed $self || $self;

        # So we don't have to do lots of lookups inside the loop.
        $maker = $self->can($maker) unless ref $maker;
        
        my $hasXS = _hasXS();

        foreach my $field (@fields) {
            if( $field eq 'DESTROY' ) {
                Carp::carp("Having a data accessor named DESTROY  in ".
                             "'$class' is unwise.");
            }

            my $name = $field;

            ($name, $field) = @$field if ref $field;
            
            my $alias = "_${name}_accessor";
            my $full_name = join('::', $class, $name);
            my $full_alias = join('::', $class, $alias);
            
            if ( $hasXS && $group eq 'simple' ) {
                Class::XSAccessor::newxs_accessor("${class}::${name}", $field, 0);
                Class::XSAccessor::newxs_accessor("${class}::${alias}", $field, 0);
                
                # XXX: is the alias accessor really necessary?
            }
            else {
                my $accessor = $self->$maker($group, $field);
                my $alias_accessor = $self->$maker($group, $field);
                
                *$full_name = Sub::Name::subname($full_name, $accessor);
                  #unless defined &{$class."\:\:$field"}
                
                *$full_alias = Sub::Name::subname($full_alias, $alias_accessor);
                  #unless defined &{$class."\:\:$alias"}
            }
        }
    }
}

=head2 mk_group_ro_accessors

=over 4

=item Arguments: $group, @fieldspec

Returns: none

=back

Creates a set of read only accessors in a given group. Identical to
L</mk_group_accessors> but accessors will throw an error if passed a value
rather than setting the value.

=cut

sub mk_group_ro_accessors {
    my($self, $group, @fields) = @_;

    $self->_mk_group_accessors('make_group_ro_accessor', $group, @fields);
}

=head2 mk_group_wo_accessors

=over 4

=item Arguments: $group, @fieldspec

Returns: none

=back

Creates a set of write only accessors in a given group. Identical to
L</mk_group_accessors> but accessors will throw an error if not passed a
value rather than getting the value.

=cut

sub mk_group_wo_accessors {
    my($self, $group, @fields) = @_;

    $self->_mk_group_accessors('make_group_wo_accessor', $group, @fields);
}

=head2 make_group_accessor

=over 4

=item Arguments: $group, $field

Returns: $sub (\CODE)

=back

Returns a single accessor in a given group; called by mk_group_accessors
for each entry in @fieldspec.

=cut

sub make_group_accessor {
    my ($class, $group, $field) = @_;

    my $set = "set_$group";
    my $get = "get_$group";

    # eval for faster fastiness
    return eval "sub {
        if(\@_ > 1) {
            return shift->$set('$field', \@_);
        }
        else {
            return shift->$get('$field');
        }
    };"
}

=head2 make_group_ro_accessor

=over 4

=item Arguments: $group, $field

Returns: $sub (\CODE)

=back

Returns a single read-only accessor in a given group; called by
mk_group_ro_accessors for each entry in @fieldspec.

=cut

sub make_group_ro_accessor {
    my($class, $group, $field) = @_;

    my $get = "get_$group";

    return eval "sub {
        if(\@_ > 1) {
            my \$caller = caller;
            Carp::croak(\"'\$caller' cannot alter the value of '$field' on \".
                        \"objects of class '$class'\");
        }
        else {
            return shift->$get('$field');
        }
    };"
}

=head2 make_group_wo_accessor

=over 4

=item Arguments: $group, $field

Returns: $sub (\CODE)

=back

Returns a single write-only accessor in a given group; called by
mk_group_wo_accessors for each entry in @fieldspec.

=cut

sub make_group_wo_accessor {
    my($class, $group, $field) = @_;

    my $set = "set_$group";

    return eval "sub {
        unless (\@_ > 1) {
            my \$caller = caller;
            Carp::croak(\"'\$caller' cannot access the value of '$field' on \".
                        \"objects of class '$class'\");
        }
        else {
            return shift->$set('$field', \@_);
        }
    };"
}

=head2 get_simple

=over 4

=item Arguments: $field

Returns: $value

=back

Simple getter for hash-based objects which returns the value for the field
name passed as an argument.

=cut

sub get_simple {
  return $_[0]->{$_[1]};
}

=head2 set_simple

=over 4

=item Arguments: $field, $new_value

Returns: $new_value

=back

Simple setter for hash-based objects which sets and then returns the value
for the field name passed as an argument.

=cut

sub set_simple {
  return $_[0]->{$_[1]} = $_[2];
}


=head2 get_inherited

=over 4

=item Arguments: $field

Returns: $value

=back

Simple getter for Classes and hash-based objects which returns the value for
the field name passed as an argument. This behaves much like
L<Class::Data::Accessor> where the field can be set in a base class,
inherited and changed in subclasses, and inherited and changed for object
instances.

=cut

sub get_inherited {
    my $class;

    if (Scalar::Util::blessed $_[0]) {
        my $reftype = Scalar::Util::reftype $_[0];
        $class = ref $_[0];

        if ($reftype eq 'HASH' && exists $_[0]->{$_[1]}) {
            return $_[0]->{$_[1]};
        } elsif ($reftype ne 'HASH') {
            Carp::croak('Cannot get inherited value on an object instance that is not hash-based');
        };
    } else {
        $class = $_[0];
    };

    no strict 'refs';
    no warnings qw/uninitialized/;
    return ${$class.'::__cag_'.$_[1]} if defined(${$class.'::__cag_'.$_[1]});

    # we need to be smarter about recalculation, as @ISA (thus supers) can very well change in-flight
    my $pkg_gen = mro::get_pkg_gen ($class);
    if ( ${$class.'::__cag_pkg_gen'} != $pkg_gen ) {
        @{$class.'::__cag_supers'} = $_[0]->get_super_paths;
        ${$class.'::__cag_pkg_gen'} = $pkg_gen;
    };

    foreach (@{$class.'::__cag_supers'}) {
        return ${$_.'::__cag_'.$_[1]} if defined(${$_.'::__cag_'.$_[1]});
    };

    return undef;
}

=head2 set_inherited

=over 4

=item Arguments: $field, $new_value

Returns: $new_value

=back

Simple setter for Classes and hash-based objects which sets and then returns
the value for the field name passed as an argument. When called on a hash-based
object it will set the appropriate hash key value. When called on a class, it
will set a class level variable.

B<Note:>: This method will die if you try to set an object variable on a non
hash-based object.

=cut

sub set_inherited {
    if (Scalar::Util::blessed $_[0]) {
        if (Scalar::Util::reftype $_[0] eq 'HASH') {
            return $_[0]->{$_[1]} = $_[2];
        } else {
            Carp::croak('Cannot set inherited value on an object instance that is not hash-based');
        };
    } else {
        no strict 'refs';

        return ${$_[0].'::__cag_'.$_[1]} = $_[2];
    };
}

=head2 get_component_class

=over 4

=item Arguments: $field

Returns: $value

=back

Gets the value of the specified component class.

    __PACKAGE__->mk_group_accessors('component_class' => 'result_class');

    $self->result_class->method();

    ## same as
    $self->get_component_class('result_class')->method();

=cut

sub get_component_class {
    return $_[0]->get_inherited($_[1]);
};

=head2 set_component_class

=over 4

=item Arguments: $field, $class

Returns: $new_value

=back

Inherited accessor that automatically loads the specified class before setting
it. This method will die if the specified class could not be loaded.

    __PACKAGE__->mk_group_accessors('component_class' => 'result_class');
    __PACKAGE__->result_class('MyClass');

    $self->result_class->method();

=cut

sub set_component_class {
    if ($_[2]) {
        local $^W = 0;
        if (Class::Inspector->installed($_[2]) && !Class::Inspector->loaded($_[2])) {
            eval "use $_[2]";

            Carp::croak("Could not load $_[1] '$_[2]': ", $@) if $@;
        };
    };

    return $_[0]->set_inherited($_[1], $_[2]);
};

=head2 get_super_paths

Returns a list of 'parent' or 'super' class names that the current class inherited from.

=cut

sub get_super_paths {
    my $class = Scalar::Util::blessed $_[0] || $_[0];

    return @{mro::get_linear_isa($class)};
};

1;

=head1 Performance

You can speed up accessors of type 'simple' by installing L<Class::XSAccessor>.
Note however that the use of this module is disabled by default on Win32
systems, as it causes yet untracked segfaults. If you are a Win32 user, and
want to try this module with L<Class::XSAccessor>, set
C<$Class::Accessor::Grouped::hasXS> to a true value B<before> registering
your accessors (e.g. in a C<BEGIN> block)

=head1 AUTHORS

Matt S. Trout <mst@shadowcatsystems.co.uk>
Christopher H. Laco <claco@chrislaco.com>

With contributions from:

Guillermo Roditi <groditi@cpan.org>

=head1 COPYRIGHT & LICENSE

Copyright (c) 2006-2009 Matt S. Trout <mst@shadowcatsystems.co.uk>

This program is free software; you can redistribute it and/or modify
it under the same terms as perl itself.

=cut
Commit	Line	Data
963a69a5	1	package Class::Accessor::Grouped;
	2	use strict;
	3	use warnings;
a0bce8bc	4	use Carp ();
331e820d	5	use Class::Inspector ();
a0bce8bc	6	use Scalar::Util ();
8787799c	7	use MRO::Compat;
1ee74bdd	8	use Sub::Name ();
331e820d	9
b9a69571	10	our $VERSION = '0.09002';
15cf8e32	11	$VERSION = eval $VERSION;
963a69a5	12
a2537c55	13	# Class::XSAccessor is segfaulting on win32, so be careful
	14	# Win32 users can set $hasXS to try to use it anyway
	15	our $hasXS;
	16	sub _hasXS {
	17
	18	if (not defined $hasXS) {
	19	$hasXS = 0;
	20
	21	if ($^O ne 'MSWin32') {
	22	eval {
	23	require Class::XSAccessor;
	24	$hasXS = 1;
	25	};
	26	}
	27	}
	28
	29	return $hasXS;
	30	}
	31
963a69a5	32	=head1 NAME
963a69a5	33
1ad8d8c6	34	Class::Accessor::Grouped - Lets you build groups of accessors
963a69a5	35
	36	=head1 SYNOPSIS
	37
	38	=head1 DESCRIPTION
	39
	40	This class lets you build groups of accessors that will call different
	41	getters and setters.
	42
	43	=head1 METHODS
	44
	45	=head2 mk_group_accessors
	46
	47	=over 4
	48
	49	=item Arguments: $group, @fieldspec
	50
	51	Returns: none
	52
	53	=back
	54
	55	Creates a set of accessors in a given group.
	56
	57	$group is the name of the accessor group for the generated accessors; they
	58	will call get_$group($field) on get and set_$group($field, $value) on set.
	59
22fa6720	60	If you want to mimic Class::Accessor's mk_accessors $group has to be 'simple'
	61	to tell Class::Accessor::Grouped to use its own get_simple and set_simple
	62	methods.
	63
963a69a5	64	@fieldspec is a list of field/accessor names; if a fieldspec is a scalar
	65	this is used as both field and accessor name, if a listref it is expected to
	66	be of the form [ $accessor, $field ].
	67
	68	=cut
	69
	70	sub mk_group_accessors {
	71	my ($self, $group, @fields) = @_;
	72
	73	$self->_mk_group_accessors('make_group_accessor', $group, @fields);
	74	return;
	75	}
	76
	77
	78	{
	79	no strict 'refs';
	80	no warnings 'redefine';
	81
	82	sub _mk_group_accessors {
	83	my($self, $maker, $group, @fields) = @_;
a0bce8bc	84	my $class = Scalar::Util::blessed $self \|\| $self;
963a69a5	85
	86	# So we don't have to do lots of lookups inside the loop.
	87	$maker = $self->can($maker) unless ref $maker;
9540f4e4	88
9540f4e4	89	my $hasXS = _hasXS();
963a69a5	90
	91	foreach my $field (@fields) {
	92	if( $field eq 'DESTROY' ) {
a0bce8bc	93	Carp::carp("Having a data accessor named DESTROY in ".
963a69a5	94	"'$class' is unwise.");
	95	}
	96
	97	my $name = $field;
	98
	99	($name, $field) = @$field if ref $field;
9540f4e4	100
963a69a5	101	my $alias = "_${name}_accessor";
1ee74bdd	102	my $full_name = join('::', $class, $name);
1ee74bdd	103	my $full_alias = join('::', $class, $alias);
9540f4e4	104
	105	if ( $hasXS && $group eq 'simple' ) {
	106	Class::XSAccessor::newxs_accessor("${class}::${name}", $field, 0);
	107	Class::XSAccessor::newxs_accessor("${class}::${alias}", $field, 0);
	108
	109	# XXX: is the alias accessor really necessary?
	110	}
	111	else {
	112	my $accessor = $self->$maker($group, $field);
	113	my $alias_accessor = $self->$maker($group, $field);
	114
	115	*$full_name = Sub::Name::subname($full_name, $accessor);
	116	#unless defined &{$class."\:\:$field"}
	117
	118	*$full_alias = Sub::Name::subname($full_alias, $alias_accessor);
	119	#unless defined &{$class."\:\:$alias"}
	120	}
963a69a5	121	}
	122	}
	123	}
	124
	125	=head2 mk_group_ro_accessors
	126
	127	=over 4
	128
	129	=item Arguments: $group, @fieldspec
	130
	131	Returns: none
	132
	133	=back
	134
	135	Creates a set of read only accessors in a given group. Identical to
a557f8ad	136	L</mk_group_accessors> but accessors will throw an error if passed a value
963a69a5	137	rather than setting the value.
	138
	139	=cut
	140
	141	sub mk_group_ro_accessors {
	142	my($self, $group, @fields) = @_;
	143
	144	$self->_mk_group_accessors('make_group_ro_accessor', $group, @fields);
	145	}
	146
	147	=head2 mk_group_wo_accessors
	148
	149	=over 4
	150
	151	=item Arguments: $group, @fieldspec
	152
	153	Returns: none
	154
	155	=back
	156
	157	Creates a set of write only accessors in a given group. Identical to
a557f8ad	158	L</mk_group_accessors> but accessors will throw an error if not passed a
963a69a5	159	value rather than getting the value.
	160
	161	=cut
	162
	163	sub mk_group_wo_accessors {
	164	my($self, $group, @fields) = @_;
	165
	166	$self->_mk_group_accessors('make_group_wo_accessor', $group, @fields);
	167	}
	168
	169	=head2 make_group_accessor
	170
	171	=over 4
	172
	173	=item Arguments: $group, $field
	174
	175	Returns: $sub (\CODE)
	176
	177	=back
	178
	179	Returns a single accessor in a given group; called by mk_group_accessors
	180	for each entry in @fieldspec.
	181
	182	=cut
	183
	184	sub make_group_accessor {
	185	my ($class, $group, $field) = @_;
	186
	187	my $set = "set_$group";
	188	my $get = "get_$group";
	189
a0bce8bc	190	# eval for faster fastiness
	191	return eval "sub {
	192	if(\@_ > 1) {
	193	return shift->$set('$field', \@_);
963a69a5	194	}
963a69a5	195	else {
a0bce8bc	196	return shift->$get('$field');
963a69a5	197	}
a0bce8bc	198	};"
963a69a5	199	}
	200
	201	=head2 make_group_ro_accessor
	202
	203	=over 4
	204
	205	=item Arguments: $group, $field
	206
	207	Returns: $sub (\CODE)
	208
	209	=back
	210
	211	Returns a single read-only accessor in a given group; called by
	212	mk_group_ro_accessors for each entry in @fieldspec.
	213
	214	=cut
	215
	216	sub make_group_ro_accessor {
	217	my($class, $group, $field) = @_;
	218
	219	my $get = "get_$group";
	220
a0bce8bc	221	return eval "sub {
	222	if(\@_ > 1) {
	223	my \$caller = caller;
	224	Carp::croak(\"'\$caller' cannot alter the value of '$field' on \".
	225	\"objects of class '$class'\");
963a69a5	226	}
963a69a5	227	else {
a0bce8bc	228	return shift->$get('$field');
963a69a5	229	}
a0bce8bc	230	};"
963a69a5	231	}
	232
	233	=head2 make_group_wo_accessor
	234
	235	=over 4
	236
	237	=item Arguments: $group, $field
	238
	239	Returns: $sub (\CODE)
	240
	241	=back
	242
	243	Returns a single write-only accessor in a given group; called by
	244	mk_group_wo_accessors for each entry in @fieldspec.
	245
	246	=cut
	247
	248	sub make_group_wo_accessor {
	249	my($class, $group, $field) = @_;
	250
	251	my $set = "set_$group";
	252
a0bce8bc	253	return eval "sub {
	254	unless (\@_ > 1) {
	255	my \$caller = caller;
	256	Carp::croak(\"'\$caller' cannot access the value of '$field' on \".
	257	\"objects of class '$class'\");
963a69a5	258	}
963a69a5	259	else {
a0bce8bc	260	return shift->$set('$field', \@_);
963a69a5	261	}
a0bce8bc	262	};"
963a69a5	263	}
	264
	265	=head2 get_simple
	266
	267	=over 4
	268
	269	=item Arguments: $field
	270
	271	Returns: $value
	272
	273	=back
	274
	275	Simple getter for hash-based objects which returns the value for the field
	276	name passed as an argument.
	277
	278	=cut
	279
	280	sub get_simple {
a0bce8bc	281	return $_[0]->{$_[1]};
963a69a5	282	}
	283
	284	=head2 set_simple
	285
	286	=over 4
	287
	288	=item Arguments: $field, $new_value
	289
	290	Returns: $new_value
	291
	292	=back
	293
	294	Simple setter for hash-based objects which sets and then returns the value
	295	for the field name passed as an argument.
	296
	297	=cut
	298
	299	sub set_simple {
a0bce8bc	300	return $_[0]->{$_[1]} = $_[2];
963a69a5	301	}
963a69a5	302
e6f2a0fd	303
	304	=head2 get_inherited
	305
	306	=over 4
	307
	308	=item Arguments: $field
	309
	310	Returns: $value
	311
	312	=back
	313
331e820d	314	Simple getter for Classes and hash-based objects which returns the value for
	315	the field name passed as an argument. This behaves much like
	316	L<Class::Data::Accessor> where the field can be set in a base class,
	317	inherited and changed in subclasses, and inherited and changed for object
	318	instances.
e6f2a0fd	319
	320	=cut
	321
	322	sub get_inherited {
a49c32d9	323	my $class;
e6f2a0fd	324
a0bce8bc	325	if (Scalar::Util::blessed $_[0]) {
	326	my $reftype = Scalar::Util::reftype $_[0];
	327	$class = ref $_[0];
a49c32d9	328
a0bce8bc	329	if ($reftype eq 'HASH' && exists $_[0]->{$_[1]}) {
a0bce8bc	330	return $_[0]->{$_[1]};
a49c32d9	331	} elsif ($reftype ne 'HASH') {
a0bce8bc	332	Carp::croak('Cannot get inherited value on an object instance that is not hash-based');
e6f2a0fd	333	};
a49c32d9	334	} else {
a0bce8bc	335	$class = $_[0];
e6f2a0fd	336	};
	337
	338	no strict 'refs';
fe63d727	339	no warnings qw/uninitialized/;
a0bce8bc	340	return ${$class.'::__cag_'.$_[1]} if defined(${$class.'::__cag_'.$_[1]});
e6f2a0fd	341
4f8ce9da	342	# we need to be smarter about recalculation, as @ISA (thus supers) can very well change in-flight
4f8ce9da	343	my $pkg_gen = mro::get_pkg_gen ($class);
fe63d727	344	if ( ${$class.'::__cag_pkg_gen'} != $pkg_gen ) {
a0bce8bc	345	@{$class.'::__cag_supers'} = $_[0]->get_super_paths;
4f8ce9da	346	${$class.'::__cag_pkg_gen'} = $pkg_gen;
a49c32d9	347	};
	348
	349	foreach (@{$class.'::__cag_supers'}) {
a0bce8bc	350	return ${$_.'::__cag_'.$_[1]} if defined(${$_.'::__cag_'.$_[1]});
e6f2a0fd	351	};
c46050d3	352
9c3d5179	353	return undef;
e6f2a0fd	354	}
	355
	356	=head2 set_inherited
	357
	358	=over 4
	359
	360	=item Arguments: $field, $new_value
	361
	362	Returns: $new_value
	363
	364	=back
	365
331e820d	366	Simple setter for Classes and hash-based objects which sets and then returns
	367	the value for the field name passed as an argument. When called on a hash-based
	368	object it will set the appropriate hash key value. When called on a class, it
	369	will set a class level variable.
e6f2a0fd	370
331e820d	371	B<Note:>: This method will die if you try to set an object variable on a non
331e820d	372	hash-based object.
e6f2a0fd	373
	374	=cut
	375
	376	sub set_inherited {
a0bce8bc	377	if (Scalar::Util::blessed $_[0]) {
	378	if (Scalar::Util::reftype $_[0] eq 'HASH') {
	379	return $_[0]->{$_[1]} = $_[2];
e6f2a0fd	380	} else {
a0bce8bc	381	Carp::croak('Cannot set inherited value on an object instance that is not hash-based');
e6f2a0fd	382	};
	383	} else {
	384	no strict 'refs';
	385
a0bce8bc	386	return ${$_[0].'::__cag_'.$_[1]} = $_[2];
e6f2a0fd	387	};
	388	}
	389
331e820d	390	=head2 get_component_class
	391
	392	=over 4
	393
	394	=item Arguments: $field
	395
	396	Returns: $value
	397
	398	=back
	399
	400	Gets the value of the specified component class.
	401
	402	__PACKAGE__->mk_group_accessors('component_class' => 'result_class');
97d76fb4	403
331e820d	404	$self->result_class->method();
97d76fb4	405
331e820d	406	## same as
	407	$self->get_component_class('result_class')->method();
	408
	409	=cut
	410
	411	sub get_component_class {
a0bce8bc	412	return $_[0]->get_inherited($_[1]);
331e820d	413	};
	414
	415	=head2 set_component_class
	416
	417	=over 4
	418
	419	=item Arguments: $field, $class
	420
	421	Returns: $new_value
	422
	423	=back
	424
	425	Inherited accessor that automatically loads the specified class before setting
	426	it. This method will die if the specified class could not be loaded.
	427
	428	__PACKAGE__->mk_group_accessors('component_class' => 'result_class');
	429	__PACKAGE__->result_class('MyClass');
97d76fb4	430
331e820d	431	$self->result_class->method();
	432
	433	=cut
	434
	435	sub set_component_class {
a0bce8bc	436	if ($_[2]) {
bce7bdf8	437	local $^W = 0;
a0bce8bc	438	if (Class::Inspector->installed($_[2]) && !Class::Inspector->loaded($_[2])) {
a0bce8bc	439	eval "use $_[2]";
331e820d	440
a0bce8bc	441	Carp::croak("Could not load $_[1] '$_[2]': ", $@) if $@;
331e820d	442	};
	443	};
	444
a0bce8bc	445	return $_[0]->set_inherited($_[1], $_[2]);
331e820d	446	};
331e820d	447
a49c32d9	448	=head2 get_super_paths
	449
	450	Returns a list of 'parent' or 'super' class names that the current class inherited from.
	451
	452	=cut
	453
	454	sub get_super_paths {
a0bce8bc	455	my $class = Scalar::Util::blessed $_[0] \|\| $_[0];
a49c32d9	456
8787799c	457	return @{mro::get_linear_isa($class)};
a49c32d9	458	};
a49c32d9	459
a2537c55	460	1;
b9a69571	461
a2537c55	462	=head1 Performance
15cf8e32	463
a2537c55	464	You can speed up accessors of type 'simple' by installing L<Class::XSAccessor>.
	465	Note however that the use of this module is disabled by default on Win32
	466	systems, as it causes yet untracked segfaults. If you are a Win32 user, and
	467	want to try this module with L<Class::XSAccessor>, set
	468	C<$Class::Accessor::Grouped::hasXS> to a true value B<before> registering
	469	your accessors (e.g. in a C<BEGIN> block)
963a69a5	470
	471	=head1 AUTHORS
	472
	473	Matt S. Trout <mst@shadowcatsystems.co.uk>
97972dcb	474	Christopher H. Laco <claco@chrislaco.com>
963a69a5	475
dfb86526	476	With contributions from:
	477
	478	Guillermo Roditi <groditi@cpan.org>
	479
4fe25633	480	=head1 COPYRIGHT & LICENSE
963a69a5	481
4fe25633	482	Copyright (c) 2006-2009 Matt S. Trout <mst@shadowcatsystems.co.uk>
963a69a5	483
4fe25633	484	This program is free software; you can redistribute it and/or modify
4fe25633	485	it under the same terms as perl itself.
963a69a5	486
4fe25633	487	=cut