[catagits/Catalyst-Authentication-Store-LDAP.git] / lib / Catalyst / Authentication / Store / LDAP / Backend.pm


=pod

=head1 NAME

Catalyst::Authentication::Store::LDAP::Backend
  - LDAP authentication storage backend.

=head1 SYNOPSIS

    # you probably just want Store::LDAP under most cases,
    # but if you insist you can instantiate your own store:

    use Catalyst::Authentication::Store::LDAP::Backend;

    use Catalyst qw/
        Authentication
        Authentication::Credential::Password
    /;

    my %config = (
            'ldap_server' => 'ldap1.yourcompany.com',
            'ldap_server_options' => {
                'timeout' => 30,
            },
            'binddn' => 'anonymous',
            'bindpw' => 'dontcarehow',
            'start_tls' => 1,
            'start_tls_options' => {
                'verify' => 'none',
            },
            'user_basedn' => 'ou=people,dc=yourcompany,dc=com',
            'user_filter' => '(&(objectClass=posixAccount)(uid=%s))',
            'user_scope' => 'one',  # or 'sub' for Active Directory
            'user_field' => 'uid',
            'user_search_options' => {
                'deref' => 'always',
                'attrs' => [qw( distinguishedname name mail )],
            },
            'user_results_filter' => sub { return shift->pop_entry },
            'entry_class' => 'MyApp::LDAP::Entry',
            'user_class' => 'MyUser',
            'use_roles' => 1,
            'role_basedn' => 'ou=groups,dc=yourcompany,dc=com',
            'role_filter' => '(&(objectClass=posixGroup)(member=%s))',
            'role_scope' => 'one',
            'role_field' => 'cn',
            'role_value' => 'dn',
            'role_search_options' => {
                'deref' => 'always',
            },
            'role_search_as_user' => 0,
            'persist_in_session'  => 'all',
    );

    our $users = Catalyst::Authentication::Store::LDAP::Backend->new(\%config);

=head1 DESCRIPTION

You probably want L<Catalyst::Authentication::Store::LDAP>.

Otherwise, this lets you create a store manually.

See the L<Catalyst::Authentication::Store::LDAP> documentation for
an explanation of the configuration options.

=head1 METHODS

=cut

package Catalyst::Authentication::Store::LDAP::Backend;
use base qw( Class::Accessor::Fast );

use strict;
use warnings;

our $VERSION = '1.015';

use Catalyst::Authentication::Store::LDAP::User;
use Net::LDAP;
use Catalyst::Utils ();

BEGIN {
    __PACKAGE__->mk_accessors(
        qw( ldap_server ldap_server_options binddn
            bindpw entry_class user_search_options
            user_filter user_basedn user_scope
            user_attrs user_field use_roles role_basedn
            role_filter role_scope role_field role_value
            role_search_options start_tls start_tls_options
            user_results_filter user_class role_search_as_user
            persist_in_session
            )
    );
}

=head2 new($config)

Creates a new L<Catalyst::Authentication::Store::LDAP::Backend> object.
$config should be a hashref, which should contain the configuration options
listed in L<Catalyst::Authentication::Store::LDAP>'s documentation.

Also sets a few sensible defaults.

=cut

sub new {
    my ( $class, $config ) = @_;

    unless ( defined($config) && ref($config) eq "HASH" ) {
        Catalyst::Exception->throw(
            "Catalyst::Authentication::Store::LDAP::Backend needs to be configured with a hashref."
        );
    }
    my %config_hash = %{$config};
    $config_hash{'binddn'}      ||= 'anonymous';
    $config_hash{'user_filter'} ||= '(uid=%s)';
    $config_hash{'user_scope'}  ||= 'sub';
    $config_hash{'user_field'}  ||= 'uid';
    $config_hash{'role_filter'} ||= '(memberUid=%s)';
    $config_hash{'role_scope'}  ||= 'sub';
    $config_hash{'role_field'}  ||= 'cn';
    $config_hash{'use_roles'}   ||= '1';
    $config_hash{'start_tls'}   ||= '0';
    $config_hash{'entry_class'} ||= 'Catalyst::Model::LDAP::Entry';
    $config_hash{'user_class'}
        ||= 'Catalyst::Authentication::Store::LDAP::User';
    $config_hash{'role_search_as_user'} ||= 0;

    Catalyst::Utils::ensure_class_loaded( $config_hash{'user_class'} );
    my $self = \%config_hash;
    bless( $self, $class );
    return $self;
}

=head2 find_user( I<authinfo>, $c )

Creates a L<Catalyst::Authentication::Store::LDAP::User> object
for the given User ID.  This is the preferred mechanism for getting a
given User out of the Store.

I<authinfo> should be a hashref with a key of either C<id> or
C<username>. The value will be compared against the LDAP C<user_field> field.

=cut

sub find_user {
    my ( $self, $authinfo, $c ) = @_;
    return $self->get_user( $authinfo->{id} || $authinfo->{username}, $c );
}

=head2 get_user( I<id>, $c)

Creates a L<Catalyst::Authentication::Store::LDAP::User> object
for the given User ID, or calls C<new> on the class specified in
C<user_class>.  This instance of the store object, the results of
C<lookup_user> and $c are passed as arguments (in that order) to C<new>.
This is the preferred mechanism for getting a given User out of the Store.

=cut

sub get_user {
    my ( $self, $id, $c ) = @_;
    my $user = $self->user_class->new( $self, $self->lookup_user($id), $c );
    return $user;
}

=head2 ldap_connect

Returns a L<Net::LDAP> object, connected to your LDAP server. (According
to how you configured the Backend, of course)

=cut

sub ldap_connect {
    my ($self) = shift;
    my $ldap;
    if ( defined( $self->ldap_server_options() ) ) {
        $ldap
            = Net::LDAP->new( $self->ldap_server,
            %{ $self->ldap_server_options } )
            or Catalyst::Exception->throw($@);
    }
    else {
        $ldap = Net::LDAP->new( $self->ldap_server )
            or Catalyst::Exception->throw($@);
    }
    if ( defined( $self->start_tls ) && $self->start_tls =~ /(1|true)/i ) {
        my $mesg;
        if ( defined( $self->start_tls_options ) ) {
            $mesg = $ldap->start_tls( %{ $self->start_tls_options } );
        }
        else {
            $mesg = $ldap->start_tls;
        }
        if ( $mesg->is_error ) {
            Catalyst::Exception->throw( "TLS Error: " . $mesg->error );
        }
    }
    return $ldap;
}

=head2 ldap_bind($ldap, $binddn, $bindpw)

Bind's to the directory.  If $ldap is undef, it will connect to the
LDAP server first.  $binddn should be the DN of the object you wish
to bind as, and $bindpw the password.

If $binddn is "anonymous", an anonymous bind will be performed.

=cut

sub ldap_bind {
    my ( $self, $ldap, $binddn, $bindpw ) = @_;
    $ldap ||= $self->ldap_connect;
    if ( !defined($ldap) ) {
        Catalyst::Exception->throw("LDAP Server undefined!");
    }

    # if username is present, make sure password is present too.
    # see https://rt.cpan.org/Ticket/Display.html?id=81908
    if ( !defined $binddn ) {
        $binddn = $self->binddn;
        $bindpw = $self->bindpw;
    }

    if ( $binddn eq "anonymous" ) {
        $self->_ldap_bind_anon($ldap);
    }
    else {
        if ($bindpw) {
            my $mesg = $ldap->bind( $binddn, 'password' => $bindpw );
            if ( $mesg->is_error ) {
                Catalyst::Exception->throw(
                    "Error on Initial Bind: " . $mesg->error );
            }
        }
        else {
            $self->_ldap_bind_anon( $ldap, $binddn );
        }
    }
    return $ldap;
}

sub _ldap_bind_anon {
    my ( $self, $ldap, $dn ) = @_;
    my $mesg = $ldap->bind($dn);
    if ( $mesg->is_error ) {
        Catalyst::Exception->throw( "Error on Bind: " . $mesg->error );
    }
}

=head2 ldap_auth( $binddn, $bindpw )

Connect to the LDAP server and do an authenticated bind against the
directory. Throws an exception if connecting to the LDAP server fails.
Returns 1 if binding succeeds, 0 if it fails.

=cut

sub ldap_auth {
    my ( $self, $binddn, $bindpw ) = @_;
    my $ldap = $self->ldap_connect;
    if ( !defined $ldap ) {
        Catalyst::Exception->throw("LDAP server undefined!");
    }
    my $mesg = $ldap->bind( $binddn, password => $bindpw );
    return $mesg->is_error ? 0 : 1;
}

=head2 lookup_user($id)

Given a User ID, this method will:

  A) Bind to the directory using the configured binddn and bindpw
  B) Perform a search for the User Object in the directory, using
     user_basedn, user_filter, and user_scope.
  C) Assuming we found the object, we will walk it's attributes
     using L<Net::LDAP::Entry>'s get_value method.  We store the
     results in a hashref. If we do not find the object, then
     undef is returned.
  D) Return a hashref that looks like:

     $results = {
        'ldap_entry' => $entry, # The Net::LDAP::Entry object
        'attributes' => $attributes,
     }

This method is usually only called by find_user().

=cut

sub lookup_user {
    my ( $self, $id ) = @_;

    # Trim trailing space or we confuse ourselves
    $id =~ s/\s+$//;
    my $ldap = $self->ldap_bind;
    my @searchopts;
    if ( defined( $self->user_basedn ) ) {
        push( @searchopts, 'base' => $self->user_basedn );
    }
    else {
        Catalyst::Exception->throw(
            "You must set user_basedn before looking up users!");
    }
    my $filter = $self->_replace_filter( $self->user_filter, $id );
    push( @searchopts, 'filter' => $filter );
    push( @searchopts, 'scope'  => $self->user_scope );
    if ( defined( $self->user_search_options ) ) {
        push( @searchopts, %{ $self->user_search_options } );
    }
    my $usersearch = $ldap->search(@searchopts);

    return undef if ( $usersearch->is_error );

    my $userentry;
    my $user_field     = $self->user_field;
    my $results_filter = $self->user_results_filter;
    my $entry;
    if ( defined($results_filter) ) {
        $entry = &$results_filter($usersearch);
    }
    else {
        $entry = $usersearch->pop_entry;
    }
    if ( $usersearch->pop_entry ) {
        Catalyst::Exception->throw(
                  "More than one entry matches user search.\n"
                . "Consider defining a user_results_filter sub." );
    }

    # a little extra sanity check with the 'eq' since LDAP already
    # says it matches.
    # NOTE that Net::LDAP returns exactly what you asked for, but
    # because LDAP is often case insensitive, FoO can match foo
    # and so we normalize with lc().
    if ( defined($entry) ) {
        unless ( lc( $entry->get_value($user_field) ) eq lc($id) ) {
            Catalyst::Exception->throw(
                "LDAP claims '$user_field' equals '$id' but results entry does not match."
            );
        }
        $userentry = $entry;
    }

    $ldap->unbind;
    $ldap->disconnect;
    unless ($userentry) {
        return undef;
    }
    my $attrhash;
    foreach my $attr ( $userentry->attributes ) {
        my @attrvalues = $userentry->get_value($attr);
        if ( scalar(@attrvalues) == 1 ) {
            $attrhash->{ lc($attr) } = $attrvalues[0];
        }
        else {
            $attrhash->{ lc($attr) } = \@attrvalues;
        }
    }

    eval { Catalyst::Utils::ensure_class_loaded( $self->entry_class ) };
    if ( !$@ ) {
        bless( $userentry, $self->entry_class );
        $userentry->{_use_unicode}++;
    }
    my $rv = {
        'ldap_entry' => $userentry,
        'attributes' => $attrhash,
    };
    return $rv;
}

=head2 lookup_roles($userobj, [$ldap])

This method looks up the roles for a given user.  It takes a
L<Catalyst::Authentication::Store::LDAP::User> object
as it's first argument, and can optionally take a I<Net::LDAP> object which
is used rather than the default binding if supplied.

It returns an array containing the role_field attribute from all the
objects that match it's criteria.

=cut

sub lookup_roles {
    my ( $self, $userobj, $ldap ) = @_;
    if ( $self->use_roles == 0 || $self->use_roles =~ /^false$/i ) {
        return undef;
    }
    $ldap ||= $self->role_search_as_user
        ? $userobj->ldap_connection : $self->ldap_bind;
    my @searchopts;
    if ( defined( $self->role_basedn ) ) {
        push( @searchopts, 'base' => $self->role_basedn );
    }
    else {
        Catalyst::Exception->throw(
            "You must set up role_basedn before looking up roles!");
    }
    my $filter_value = $userobj->has_attribute( $self->role_value );
    if ( !defined($filter_value) ) {
        Catalyst::Exception->throw( "User object "
                . $userobj->username
                . " has no "
                . $self->role_value
                . " attribute, so I can't look up it's roles!" );
    }
    my $filter = $self->_replace_filter( $self->role_filter, $filter_value );
    push( @searchopts, 'filter' => $filter );
    push( @searchopts, 'scope'  => $self->role_scope );
    push( @searchopts, 'attrs'  => [ $self->role_field ] );
    if ( defined( $self->role_search_options ) ) {
        push( @searchopts, %{ $self->role_search_options } );
    }
    my $rolesearch = $ldap->search(@searchopts);
    my @roles;
RESULT: foreach my $entry ( $rolesearch->entries ) {
        push( @roles, $entry->get_value( $self->role_field ) );
    }
    return @roles;
}

sub _replace_filter {
    my $self    = shift;
    my $filter  = shift;
    my $replace = shift;
    $replace =~ s/([*()\\\x{0}])/sprintf '\\%02x', ord($1)/ge;
    $filter =~ s/\%s/$replace/g;
    return $filter;
}

=head2 user_supports

Returns the value of
Catalyst::Authentication::Store::LDAP::User->supports(@_).

=cut

sub user_supports {
    my $self = shift;

    # this can work as a class method
    Catalyst::Authentication::Store::LDAP::User->supports(@_);
}

=head2 from_session( I<id>, I<$c> )

Returns get_user() for I<id>.

=cut

sub from_session {
    my ( $self, $c, $frozenuser ) = @_;

    if ( $self->persist_in_session eq 'all' ) {
        return $self->user_class->new( $self, $frozenuser->{user}, $c, $frozenuser->{_roles} );
    }

    return $self->get_user( $frozenuser, $c );
}

1;

__END__

=head1 AUTHORS

Adam Jacob <holoway@cpan.org>

Some parts stolen shamelessly and entirely from
L<Catalyst::Plugin::Authentication::Store::Htpasswd>.

Currently maintained by Peter Karman <karman@cpan.org>.

=head1 THANKS

To nothingmuch, ghenry, castaway and the rest of #catalyst for the help. :)

=head1 SEE ALSO

L<Catalyst::Authentication::Store::LDAP>, L<Catalyst::Authentication::Store::LDAP::User>, L<Catalyst::Plugin::Authentication>, L<Net::LDAP>

=head1 COPYRIGHT & LICENSE

Copyright (c) 2005 the aforementioned authors. All rights
reserved. This program is free software; you can redistribute
it and/or modify it under the same terms as Perl itself.

=cut
Commit	Line	Data
f66d606b	1
	2	=pod
	3
	4	=head1 NAME
	5
9638f14b	6	Catalyst::Authentication::Store::LDAP::Backend
f66d606b	7	- LDAP authentication storage backend.
	8
	9	=head1 SYNOPSIS
	10
	11	# you probably just want Store::LDAP under most cases,
	12	# but if you insist you can instantiate your own store:
	13
	14	use Catalyst::Authentication::Store::LDAP::Backend;
	15
	16	use Catalyst qw/
	17	Authentication
	18	Authentication::Credential::Password
	19	/;
	20
	21	my %config = (
	22	'ldap_server' => 'ldap1.yourcompany.com',
	23	'ldap_server_options' => {
	24	'timeout' => 30,
	25	},
	26	'binddn' => 'anonymous',
	27	'bindpw' => 'dontcarehow',
	28	'start_tls' => 1,
	29	'start_tls_options' => {
	30	'verify' => 'none',
	31	},
	32	'user_basedn' => 'ou=people,dc=yourcompany,dc=com',
	33	'user_filter' => '(&(objectClass=posixAccount)(uid=%s))',
57d476f1	34	'user_scope' => 'one', # or 'sub' for Active Directory
f66d606b	35	'user_field' => 'uid',
	36	'user_search_options' => {
	37	'deref' => 'always',
a03db022	38	'attrs' => [qw( distinguishedname name mail )],
f66d606b	39	},
1647b33a	40	'user_results_filter' => sub { return shift->pop_entry },
f66d606b	41	'entry_class' => 'MyApp::LDAP::Entry',
405489b5	42	'user_class' => 'MyUser',
f66d606b	43	'use_roles' => 1,
	44	'role_basedn' => 'ou=groups,dc=yourcompany,dc=com',
	45	'role_filter' => '(&(objectClass=posixGroup)(member=%s))',
	46	'role_scope' => 'one',
	47	'role_field' => 'cn',
	48	'role_value' => 'dn',
	49	'role_search_options' => {
	50	'deref' => 'always',
	51	},
405489b5	52	'role_search_as_user' => 0,
439924cb	53	'persist_in_session' => 'all',
f66d606b	54	);
9638f14b	55
f66d606b	56	our $users = Catalyst::Authentication::Store::LDAP::Backend->new(\%config);
f66d606b	57
f66d606b	58	=head1 DESCRIPTION
f66d606b	59
afb8e81c	60	You probably want L<Catalyst::Authentication::Store::LDAP>.
f66d606b	61
afb8e81c	62	Otherwise, this lets you create a store manually.
f66d606b	63
	64	See the L<Catalyst::Authentication::Store::LDAP> documentation for
	65	an explanation of the configuration options.
	66
	67	=head1 METHODS
	68
	69	=cut
	70
	71	package Catalyst::Authentication::Store::LDAP::Backend;
	72	use base qw( Class::Accessor::Fast );
	73
	74	use strict;
	75	use warnings;
	76
dfead577	77	our $VERSION = '1.015';
f66d606b	78
	79	use Catalyst::Authentication::Store::LDAP::User;
	80	use Net::LDAP;
405489b5	81	use Catalyst::Utils ();
f66d606b	82
	83	BEGIN {
	84	__PACKAGE__->mk_accessors(
	85	qw( ldap_server ldap_server_options binddn
	86	bindpw entry_class user_search_options
	87	user_filter user_basedn user_scope
	88	user_attrs user_field use_roles role_basedn
	89	role_filter role_scope role_field role_value
	90	role_search_options start_tls start_tls_options
405489b5	91	user_results_filter user_class role_search_as_user
439924cb	92	persist_in_session
f66d606b	93	)
	94	);
	95	}
	96
	97	=head2 new($config)
	98
	99	Creates a new L<Catalyst::Authentication::Store::LDAP::Backend> object.
	100	$config should be a hashref, which should contain the configuration options
	101	listed in L<Catalyst::Authentication::Store::LDAP>'s documentation.
	102
	103	Also sets a few sensible defaults.
	104
	105	=cut
	106
	107	sub new {
	108	my ( $class, $config ) = @_;
	109
	110	unless ( defined($config) && ref($config) eq "HASH" ) {
	111	Catalyst::Exception->throw(
	112	"Catalyst::Authentication::Store::LDAP::Backend needs to be configured with a hashref."
	113	);
	114	}
	115	my %config_hash = %{$config};
	116	$config_hash{'binddn'} \|\|= 'anonymous';
	117	$config_hash{'user_filter'} \|\|= '(uid=%s)';
	118	$config_hash{'user_scope'} \|\|= 'sub';
	119	$config_hash{'user_field'} \|\|= 'uid';
	120	$config_hash{'role_filter'} \|\|= '(memberUid=%s)';
	121	$config_hash{'role_scope'} \|\|= 'sub';
	122	$config_hash{'role_field'} \|\|= 'cn';
	123	$config_hash{'use_roles'} \|\|= '1';
	124	$config_hash{'start_tls'} \|\|= '0';
	125	$config_hash{'entry_class'} \|\|= 'Catalyst::Model::LDAP::Entry';
d05c83dd	126	$config_hash{'user_class'}
d05c83dd	127	\|\|= 'Catalyst::Authentication::Store::LDAP::User';
405489b5	128	$config_hash{'role_search_as_user'} \|\|= 0;
f66d606b	129
d05c83dd	130	Catalyst::Utils::ensure_class_loaded( $config_hash{'user_class'} );
f66d606b	131	my $self = \%config_hash;
	132	bless( $self, $class );
	133	return $self;
	134	}
	135
52a972a4	136	=head2 find_user( I<authinfo>, $c )
f66d606b	137
f66d606b	138	Creates a L<Catalyst::Authentication::Store::LDAP::User> object
9638f14b	139	for the given User ID. This is the preferred mechanism for getting a
f66d606b	140	given User out of the Store.
	141
	142	I<authinfo> should be a hashref with a key of either C<id> or
	143	C<username>. The value will be compared against the LDAP C<user_field> field.
	144
	145	=cut
	146
	147	sub find_user {
	148	my ( $self, $authinfo, $c ) = @_;
52a972a4	149	return $self->get_user( $authinfo->{id} \|\| $authinfo->{username}, $c );
f66d606b	150	}
f66d606b	151
5faab354	152	=head2 get_user( I<id>, $c)
f66d606b	153
f66d606b	154	Creates a L<Catalyst::Authentication::Store::LDAP::User> object
52a972a4	155	for the given User ID, or calls C<new> on the class specified in
	156	C<user_class>. This instance of the store object, the results of
	157	C<lookup_user> and $c are passed as arguments (in that order) to C<new>.
	158	This is the preferred mechanism for getting a given User out of the Store.
f66d606b	159
	160	=cut
	161
	162	sub get_user {
52a972a4	163	my ( $self, $id, $c ) = @_;
d05c83dd	164	my $user = $self->user_class->new( $self, $self->lookup_user($id), $c );
f66d606b	165	return $user;
	166	}
	167
	168	=head2 ldap_connect
	169
	170	Returns a L<Net::LDAP> object, connected to your LDAP server. (According
	171	to how you configured the Backend, of course)
	172
	173	=cut
	174
	175	sub ldap_connect {
	176	my ($self) = shift;
	177	my $ldap;
	178	if ( defined( $self->ldap_server_options() ) ) {
	179	$ldap
	180	= Net::LDAP->new( $self->ldap_server,
	181	%{ $self->ldap_server_options } )
	182	or Catalyst::Exception->throw($@);
	183	}
	184	else {
	185	$ldap = Net::LDAP->new( $self->ldap_server )
	186	or Catalyst::Exception->throw($@);
	187	}
	188	if ( defined( $self->start_tls ) && $self->start_tls =~ /(1\|true)/i ) {
	189	my $mesg;
	190	if ( defined( $self->start_tls_options ) ) {
	191	$mesg = $ldap->start_tls( %{ $self->start_tls_options } );
	192	}
	193	else {
	194	$mesg = $ldap->start_tls;
	195	}
	196	if ( $mesg->is_error ) {
	197	Catalyst::Exception->throw( "TLS Error: " . $mesg->error );
	198	}
	199	}
	200	return $ldap;
	201	}
	202
	203	=head2 ldap_bind($ldap, $binddn, $bindpw)
	204
	205	Bind's to the directory. If $ldap is undef, it will connect to the
	206	LDAP server first. $binddn should be the DN of the object you wish
	207	to bind as, and $bindpw the password.
	208
	209	If $binddn is "anonymous", an anonymous bind will be performed.
	210
	211	=cut
	212
	213	sub ldap_bind {
238a096f	214	my ( $self, $ldap, $binddn, $bindpw ) = @_;
d05c83dd	215	$ldap \|\|= $self->ldap_connect;
f66d606b	216	if ( !defined($ldap) ) {
	217	Catalyst::Exception->throw("LDAP Server undefined!");
	218	}
50f88c5d	219
	220	# if username is present, make sure password is present too.
	221	# see https://rt.cpan.org/Ticket/Display.html?id=81908
	222	if ( !defined $binddn ) {
	223	$binddn = $self->binddn;
	224	$bindpw = $self->bindpw;
	225	}
	226
f66d606b	227	if ( $binddn eq "anonymous" ) {
405489b5	228	$self->_ldap_bind_anon($ldap);
f66d606b	229	}
f66d606b	230	else {
238a096f	231	if ($bindpw) {
f66d606b	232	my $mesg = $ldap->bind( $binddn, 'password' => $bindpw );
f66d606b	233	if ( $mesg->is_error ) {
238a096f	234	Catalyst::Exception->throw(
238a096f	235	"Error on Initial Bind: " . $mesg->error );
f66d606b	236	}
	237	}
	238	else {
d05c83dd	239	$self->_ldap_bind_anon( $ldap, $binddn );
f66d606b	240	}
	241	}
	242	return $ldap;
	243	}
	244
405489b5	245	sub _ldap_bind_anon {
d05c83dd	246	my ( $self, $ldap, $dn ) = @_;
405489b5	247	my $mesg = $ldap->bind($dn);
	248	if ( $mesg->is_error ) {
	249	Catalyst::Exception->throw( "Error on Bind: " . $mesg->error );
	250	}
	251	}
	252
238a096f	253	=head2 ldap_auth( $binddn, $bindpw )
	254
	255	Connect to the LDAP server and do an authenticated bind against the
	256	directory. Throws an exception if connecting to the LDAP server fails.
	257	Returns 1 if binding succeeds, 0 if it fails.
	258
	259	=cut
	260
	261	sub ldap_auth {
	262	my ( $self, $binddn, $bindpw ) = @_;
	263	my $ldap = $self->ldap_connect;
	264	if ( !defined $ldap ) {
	265	Catalyst::Exception->throw("LDAP server undefined!");
	266	}
	267	my $mesg = $ldap->bind( $binddn, password => $bindpw );
	268	return $mesg->is_error ? 0 : 1;
	269	}
	270
f66d606b	271	=head2 lookup_user($id)
	272
	273	Given a User ID, this method will:
	274
	275	A) Bind to the directory using the configured binddn and bindpw
	276	B) Perform a search for the User Object in the directory, using
	277	user_basedn, user_filter, and user_scope.
d94851da	278	C) Assuming we found the object, we will walk it's attributes
f66d606b	279	using L<Net::LDAP::Entry>'s get_value method. We store the
d94851da	280	results in a hashref. If we do not find the object, then
	281	undef is returned.
	282	D) Return a hashref that looks like:
	283
f66d606b	284	$results = {
	285	'ldap_entry' => $entry, # The Net::LDAP::Entry object
	286	'attributes' => $attributes,
	287	}
	288
1647b33a	289	This method is usually only called by find_user().
f66d606b	290
	291	=cut
	292
	293	sub lookup_user {
	294	my ( $self, $id ) = @_;
	295
02f3c071	296	# Trim trailing space or we confuse ourselves
02f3c071	297	$id =~ s/\s+$//;
f66d606b	298	my $ldap = $self->ldap_bind;
	299	my @searchopts;
	300	if ( defined( $self->user_basedn ) ) {
	301	push( @searchopts, 'base' => $self->user_basedn );
	302	}
	303	else {
	304	Catalyst::Exception->throw(
	305	"You must set user_basedn before looking up users!");
	306	}
	307	my $filter = $self->_replace_filter( $self->user_filter, $id );
	308	push( @searchopts, 'filter' => $filter );
	309	push( @searchopts, 'scope' => $self->user_scope );
	310	if ( defined( $self->user_search_options ) ) {
	311	push( @searchopts, %{ $self->user_search_options } );
	312	}
	313	my $usersearch = $ldap->search(@searchopts);
d94851da	314
a2f66fa8	315	return undef if ( $usersearch->is_error );
d94851da	316
f66d606b	317	my $userentry;
1647b33a	318	my $user_field = $self->user_field;
	319	my $results_filter = $self->user_results_filter;
	320	my $entry;
	321	if ( defined($results_filter) ) {
	322	$entry = &$results_filter($usersearch);
	323	}
	324	else {
	325	$entry = $usersearch->pop_entry;
	326	}
	327	if ( $usersearch->pop_entry ) {
	328	Catalyst::Exception->throw(
	329	"More than one entry matches user search.\n"
	330	. "Consider defining a user_results_filter sub." );
	331	}
	332
	333	# a little extra sanity check with the 'eq' since LDAP already
	334	# says it matches.
5772b468	335	# NOTE that Net::LDAP returns exactly what you asked for, but
	336	# because LDAP is often case insensitive, FoO can match foo
	337	# and so we normalize with lc().
1647b33a	338	if ( defined($entry) ) {
5772b468	339	unless ( lc( $entry->get_value($user_field) ) eq lc($id) ) {
1647b33a	340	Catalyst::Exception->throw(
	341	"LDAP claims '$user_field' equals '$id' but results entry does not match."
	342	);
f66d606b	343	}
1647b33a	344	$userentry = $entry;
f66d606b	345	}
1647b33a	346
f66d606b	347	$ldap->unbind;
	348	$ldap->disconnect;
	349	unless ($userentry) {
	350	return undef;
	351	}
	352	my $attrhash;
	353	foreach my $attr ( $userentry->attributes ) {
	354	my @attrvalues = $userentry->get_value($attr);
	355	if ( scalar(@attrvalues) == 1 ) {
	356	$attrhash->{ lc($attr) } = $attrvalues[0];
	357	}
	358	else {
	359	$attrhash->{ lc($attr) } = \@attrvalues;
	360	}
	361	}
d05c83dd	362
d05c83dd	363	eval { Catalyst::Utils::ensure_class_loaded( $self->entry_class ) };
f66d606b	364	if ( !$@ ) {
	365	bless( $userentry, $self->entry_class );
	366	$userentry->{_use_unicode}++;
	367	}
	368	my $rv = {
	369	'ldap_entry' => $userentry,
	370	'attributes' => $attrhash,
	371	};
	372	return $rv;
	373	}
	374
405489b5	375	=head2 lookup_roles($userobj, [$ldap])
f66d606b	376
9638f14b	377	This method looks up the roles for a given user. It takes a
f66d606b	378	L<Catalyst::Authentication::Store::LDAP::User> object
405489b5	379	as it's first argument, and can optionally take a I<Net::LDAP> object which
405489b5	380	is used rather than the default binding if supplied.
f66d606b	381
	382	It returns an array containing the role_field attribute from all the
	383	objects that match it's criteria.
	384
	385	=cut
	386
	387	sub lookup_roles {
405489b5	388	my ( $self, $userobj, $ldap ) = @_;
f66d606b	389	if ( $self->use_roles == 0 \|\| $self->use_roles =~ /^false$/i ) {
	390	return undef;
	391	}
5a9aba6e	392	$ldap \|\|= $self->role_search_as_user
5a9aba6e	393	? $userobj->ldap_connection : $self->ldap_bind;
f66d606b	394	my @searchopts;
	395	if ( defined( $self->role_basedn ) ) {
	396	push( @searchopts, 'base' => $self->role_basedn );
	397	}
	398	else {
	399	Catalyst::Exception->throw(
	400	"You must set up role_basedn before looking up roles!");
	401	}
	402	my $filter_value = $userobj->has_attribute( $self->role_value );
	403	if ( !defined($filter_value) ) {
	404	Catalyst::Exception->throw( "User object "
	405	. $userobj->username
	406	. " has no "
	407	. $self->role_value
	408	. " attribute, so I can't look up it's roles!" );
	409	}
	410	my $filter = $self->_replace_filter( $self->role_filter, $filter_value );
	411	push( @searchopts, 'filter' => $filter );
	412	push( @searchopts, 'scope' => $self->role_scope );
	413	push( @searchopts, 'attrs' => [ $self->role_field ] );
	414	if ( defined( $self->role_search_options ) ) {
	415	push( @searchopts, %{ $self->role_search_options } );
	416	}
	417	my $rolesearch = $ldap->search(@searchopts);
	418	my @roles;
ab62b426	419	RESULT: foreach my $entry ( $rolesearch->entries ) {
ab62b426	420	push( @roles, $entry->get_value( $self->role_field ) );
f66d606b	421	}
	422	return @roles;
	423	}
	424
	425	sub _replace_filter {
	426	my $self = shift;
	427	my $filter = shift;
	428	my $replace = shift;
18d41a8f	429	$replace =~ s/([*()\\\x{0}])/sprintf '\\%02x', ord($1)/ge;
f66d606b	430	$filter =~ s/\%s/$replace/g;
	431	return $filter;
	432	}
	433
	434	=head2 user_supports
	435
9638f14b	436	Returns the value of
f66d606b	437	Catalyst::Authentication::Store::LDAP::User->supports(@_).
	438
	439	=cut
	440
	441	sub user_supports {
	442	my $self = shift;
	443
	444	# this can work as a class method
	445	Catalyst::Authentication::Store::LDAP::User->supports(@_);
	446	}
	447
5faab354	448	=head2 from_session( I<id>, I<$c> )
f66d606b	449
	450	Returns get_user() for I<id>.
	451
	452	=cut
	453
	454	sub from_session {
439924cb	455	my ( $self, $c, $frozenuser ) = @_;
	456
	457	if ( $self->persist_in_session eq 'all' ) {
	458	return $self->user_class->new( $self, $frozenuser->{user}, $c, $frozenuser->{_roles} );
	459	}
	460
	461	return $self->get_user( $frozenuser, $c );
f66d606b	462	}
	463
	464	1;
	465
	466	__END__
	467
	468	=head1 AUTHORS
	469
	470	Adam Jacob <holoway@cpan.org>
	471
	472	Some parts stolen shamelessly and entirely from
	473	L<Catalyst::Plugin::Authentication::Store::Htpasswd>.
	474
	475	Currently maintained by Peter Karman <karman@cpan.org>.
	476
	477	=head1 THANKS
	478
	479	To nothingmuch, ghenry, castaway and the rest of #catalyst for the help. :)
	480
	481	=head1 SEE ALSO
	482
	483	L<Catalyst::Authentication::Store::LDAP>, L<Catalyst::Authentication::Store::LDAP::User>, L<Catalyst::Plugin::Authentication>, L<Net::LDAP>
	484
	485	=head1 COPYRIGHT & LICENSE
	486
	487	Copyright (c) 2005 the aforementioned authors. All rights
	488	reserved. This program is free software; you can redistribute
	489	it and/or modify it under the same terms as Perl itself.
	490
	491	=cut
	492