[catagits/Catalyst-Authentication-Store-LDAP.git] / lib / Catalyst / Authentication / Store / LDAP / Backend.pm


=pod

=head1 NAME

Catalyst::Authentication::Store::LDAP::Backend 
  - LDAP authentication storage backend.

=head1 SYNOPSIS

    # you probably just want Store::LDAP under most cases,
    # but if you insist you can instantiate your own store:

    use Catalyst::Authentication::Store::LDAP::Backend;

    use Catalyst qw/
        Authentication
        Authentication::Credential::Password
    /;

    my %config = (
            'ldap_server' => 'ldap1.yourcompany.com',
            'ldap_server_options' => {
                'timeout' => 30,
            },
            'binddn' => 'anonymous',
            'bindpw' => 'dontcarehow',
            'start_tls' => 1,
            'start_tls_options' => {
                'verify' => 'none',
            },
            'user_basedn' => 'ou=people,dc=yourcompany,dc=com',
            'user_filter' => '(&(objectClass=posixAccount)(uid=%s))',
            'user_scope' => 'one',
            'user_field' => 'uid',
            'user_search_options' => {
                'deref' => 'always',
            },
            'user_results_filter' => sub { return shift->pop_entry },
            'entry_class' => 'MyApp::LDAP::Entry',
            'user_class' => 'MyUser',
            'use_roles' => 1,
            'role_basedn' => 'ou=groups,dc=yourcompany,dc=com',
            'role_filter' => '(&(objectClass=posixGroup)(member=%s))',
            'role_scope' => 'one',
            'role_field' => 'cn',
            'role_value' => 'dn',
            'role_search_options' => {
                'deref' => 'always',
            },
            'role_search_as_user' => 0,
    );
    
    our $users = Catalyst::Authentication::Store::LDAP::Backend->new(\%config);

=head1 DESCRIPTION

You probably want L<Catalyst::Authentication::Store::LDAP>.

Otherwise, this lets you create a store manually.

See the L<Catalyst::Authentication::Store::LDAP> documentation for
an explanation of the configuration options.

=head1 METHODS

=cut

package Catalyst::Authentication::Store::LDAP::Backend;
use base qw( Class::Accessor::Fast );

use strict;
use warnings;

our $VERSION = '0.1005';

use Catalyst::Authentication::Store::LDAP::User;
use Net::LDAP;
use Catalyst::Utils ();

BEGIN {
    __PACKAGE__->mk_accessors(
        qw( ldap_server ldap_server_options binddn
            bindpw entry_class user_search_options
            user_filter user_basedn user_scope
            user_attrs user_field use_roles role_basedn
            role_filter role_scope role_field role_value
            role_search_options start_tls start_tls_options
            user_results_filter user_class role_search_as_user
            )
    );
}

=head2 new($config)

Creates a new L<Catalyst::Authentication::Store::LDAP::Backend> object.
$config should be a hashref, which should contain the configuration options
listed in L<Catalyst::Authentication::Store::LDAP>'s documentation.

Also sets a few sensible defaults.

=cut

sub new {
    my ( $class, $config ) = @_;

    unless ( defined($config) && ref($config) eq "HASH" ) {
        Catalyst::Exception->throw(
            "Catalyst::Authentication::Store::LDAP::Backend needs to be configured with a hashref."
        );
    }
    my %config_hash = %{$config};
    $config_hash{'binddn'}      ||= 'anonymous';
    $config_hash{'user_filter'} ||= '(uid=%s)';
    $config_hash{'user_scope'}  ||= 'sub';
    $config_hash{'user_field'}  ||= 'uid';
    $config_hash{'role_filter'} ||= '(memberUid=%s)';
    $config_hash{'role_scope'}  ||= 'sub';
    $config_hash{'role_field'}  ||= 'cn';
    $config_hash{'use_roles'}   ||= '1';
    $config_hash{'start_tls'}   ||= '0';
    $config_hash{'entry_class'} ||= 'Catalyst::Model::LDAP::Entry';
    $config_hash{'user_class'}  ||= 'Catalyst::Authentication::Store::LDAP::User';
    $config_hash{'role_search_as_user'} ||= 0;

    Catalyst::Utils::ensure_class_loaded($config_hash{'user_class'});
    my $self = \%config_hash;
    bless( $self, $class );
    return $self;
}

=head2 find_user( I<authinfo> )

Creates a L<Catalyst::Authentication::Store::LDAP::User> object
for the given User ID.  This is the preferred mechanism for getting a 
given User out of the Store.

I<authinfo> should be a hashref with a key of either C<id> or
C<username>. The value will be compared against the LDAP C<user_field> field.

=cut

sub find_user {
    my ( $self, $authinfo, $c ) = @_;
    return $self->get_user( $authinfo->{id} || $authinfo->{username} );
}

=head2 get_user($id)

Creates a L<Catalyst::Authentication::Store::LDAP::User> object
for the given User ID.  This is the preferred mechanism for getting a 
given User out of the Store.

=cut

sub get_user {
    my ( $self, $id ) = @_;
    my $user = $self->user_class->new( $self,
        $self->lookup_user($id) );
    return $user;
}

=head2 ldap_connect

Returns a L<Net::LDAP> object, connected to your LDAP server. (According
to how you configured the Backend, of course)

=cut

sub ldap_connect {
    my ($self) = shift;
    my $ldap;
    if ( defined( $self->ldap_server_options() ) ) {
        $ldap
            = Net::LDAP->new( $self->ldap_server,
            %{ $self->ldap_server_options } )
            or Catalyst::Exception->throw($@);
    }
    else {
        $ldap = Net::LDAP->new( $self->ldap_server )
            or Catalyst::Exception->throw($@);
    }
    if ( defined( $self->start_tls ) && $self->start_tls =~ /(1|true)/i ) {
        my $mesg;
        if ( defined( $self->start_tls_options ) ) {
            $mesg = $ldap->start_tls( %{ $self->start_tls_options } );
        }
        else {
            $mesg = $ldap->start_tls;
        }
        if ( $mesg->is_error ) {
            Catalyst::Exception->throw( "TLS Error: " . $mesg->error );
        }
    }
    return $ldap;
}

=head2 ldap_bind($ldap, $binddn, $bindpw)

Bind's to the directory.  If $ldap is undef, it will connect to the
LDAP server first.  $binddn should be the DN of the object you wish
to bind as, and $bindpw the password.

If $binddn is "anonymous", an anonymous bind will be performed.

=cut

sub ldap_bind {
    my ( $self, $ldap, $binddn, $bindpw, $forauth ) = @_;
    $forauth ||= 0;
    $ldap    ||= $self->ldap_connect;
    if ( !defined($ldap) ) {
        Catalyst::Exception->throw("LDAP Server undefined!");
    }
    $binddn ||= $self->binddn;
    $bindpw ||= $self->bindpw;
    if ( $binddn eq "anonymous" ) {
        $self->_ldap_bind_anon($ldap);
    }
    else {
        if ($bindpw) {
            my $mesg = $ldap->bind( $binddn, 'password' => $bindpw );
            if ( $mesg->is_error ) {

                # If we're not checking this bind for authentication purposes
                # Go ahead an blow up if we fail.
                if ( $forauth ne 'forauth' ) {
                    Catalyst::Exception->throw(
                        "Error on Initial Bind: " . $mesg->error );
                }
                else {
                    return undef;
                }
            }
        }
        else {
            $self->_ldap_bind_anon($ldap, $binddn);
        }
    }
    return $ldap;
}

sub _ldap_bind_anon {
    my ($self, $ldap, $dn) = @_;
    my $mesg = $ldap->bind($dn);
    if ( $mesg->is_error ) {
        Catalyst::Exception->throw( "Error on Bind: " . $mesg->error );
    }
}

=head2 lookup_user($id)

Given a User ID, this method will:

  A) Bind to the directory using the configured binddn and bindpw
  B) Perform a search for the User Object in the directory, using
     user_basedn, user_filter, and user_scope.
  C) Assuming we found the object, we will walk it's attributes
     using L<Net::LDAP::Entry>'s get_value method.  We store the
     results in a hashref. If we do not find the object, then
     undef is returned.
  D) Return a hashref that looks like:

     $results = {
        'ldap_entry' => $entry, # The Net::LDAP::Entry object
        'attributes' => $attributes,
     }

This method is usually only called by find_user().

=cut

sub lookup_user {
    my ( $self, $id ) = @_;

    # No sneaking in wildcards!
    if ( $id =~ /\*/ ) {
        Catalyst::Exception->throw("ID $id contains wildcards!");
    }
    my $ldap = $self->ldap_bind;
    my @searchopts;
    if ( defined( $self->user_basedn ) ) {
        push( @searchopts, 'base' => $self->user_basedn );
    }
    else {
        Catalyst::Exception->throw(
            "You must set user_basedn before looking up users!");
    }
    my $filter = $self->_replace_filter( $self->user_filter, $id );
    push( @searchopts, 'filter' => $filter );
    push( @searchopts, 'scope'  => $self->user_scope );
    if ( defined( $self->user_search_options ) ) {
        push( @searchopts, %{ $self->user_search_options } );
    }
    my $usersearch = $ldap->search(@searchopts);

    return if ( $usersearch->is_error );

    my $userentry;
    my $user_field     = $self->user_field;
    my $results_filter = $self->user_results_filter;
    my $entry;
    if ( defined($results_filter) ) {
        $entry = &$results_filter($usersearch);
    }
    else {
        $entry = $usersearch->pop_entry;
    }
    if ( $usersearch->pop_entry ) {
        Catalyst::Exception->throw(
                  "More than one entry matches user search.\n"
                . "Consider defining a user_results_filter sub." );
    }

    # a little extra sanity check with the 'eq' since LDAP already
    # says it matches.
    # NOTE that Net::LDAP returns exactly what you asked for, but
    # because LDAP is often case insensitive, FoO can match foo
    # and so we normalize with lc().
    if ( defined($entry) ) {
        unless ( lc( $entry->get_value($user_field) ) eq lc($id) ) {
            Catalyst::Exception->throw(
                "LDAP claims '$user_field' equals '$id' but results entry does not match."
            );
        }
        $userentry = $entry;
    }

    $ldap->unbind;
    $ldap->disconnect;
    unless ($userentry) {
        return undef;
    }
    my $attrhash;
    foreach my $attr ( $userentry->attributes ) {
        my @attrvalues = $userentry->get_value($attr);
        if ( scalar(@attrvalues) == 1 ) {
            $attrhash->{ lc($attr) } = $attrvalues[0];
        }
        else {
            $attrhash->{ lc($attr) } = \@attrvalues;
        }
    }
    
    eval { Catalyst::Utils::ensure_class_loaded($self->entry_class) };
    if ( !$@ ) {
        bless( $userentry, $self->entry_class );
        $userentry->{_use_unicode}++;
    }
    my $rv = {
        'ldap_entry' => $userentry,
        'attributes' => $attrhash,
    };
    return $rv;
}

=head2 lookup_roles($userobj, [$ldap])

This method looks up the roles for a given user.  It takes a 
L<Catalyst::Authentication::Store::LDAP::User> object
as it's first argument, and can optionally take a I<Net::LDAP> object which
is used rather than the default binding if supplied.

It returns an array containing the role_field attribute from all the
objects that match it's criteria.

=cut

sub lookup_roles {
    my ( $self, $userobj, $ldap ) = @_;
    if ( $self->use_roles == 0 || $self->use_roles =~ /^false$/i ) {
        return undef;
    }
    $ldap ||= $self->ldap_bind;
    my @searchopts;
    if ( defined( $self->role_basedn ) ) {
        push( @searchopts, 'base' => $self->role_basedn );
    }
    else {
        Catalyst::Exception->throw(
            "You must set up role_basedn before looking up roles!");
    }
    my $filter_value = $userobj->has_attribute( $self->role_value );
    if ( !defined($filter_value) ) {
        Catalyst::Exception->throw( "User object "
                . $userobj->username
                . " has no "
                . $self->role_value
                . " attribute, so I can't look up it's roles!" );
    }
    my $filter = $self->_replace_filter( $self->role_filter, $filter_value );
    push( @searchopts, 'filter' => $filter );
    push( @searchopts, 'scope'  => $self->role_scope );
    push( @searchopts, 'attrs'  => [ $self->role_field ] );
    if ( defined( $self->role_search_options ) ) {
        push( @searchopts, %{ $self->role_search_options } );
    }
    my $rolesearch = $ldap->search(@searchopts);
    my @roles;
RESULT: foreach my $entry ( $rolesearch->entries ) {
        push( @roles, $entry->get_value( $self->role_field ) );
    }
    return @roles;
}

sub _replace_filter {
    my $self    = shift;
    my $filter  = shift;
    my $replace = shift;
    $filter =~ s/\%s/$replace/g;
    return $filter;
}

=head2 user_supports

Returns the value of 
Catalyst::Authentication::Store::LDAP::User->supports(@_).

=cut

sub user_supports {
    my $self = shift;

    # this can work as a class method
    Catalyst::Authentication::Store::LDAP::User->supports(@_);
}

=head2 from_session( I<id> )

Returns get_user() for I<id>.

=cut

sub from_session {
    my ( $self, $c, $id ) = @_;
    $self->get_user($id);
}

1;

__END__

=head1 AUTHORS

Adam Jacob <holoway@cpan.org>

Some parts stolen shamelessly and entirely from
L<Catalyst::Plugin::Authentication::Store::Htpasswd>.

Currently maintained by Peter Karman <karman@cpan.org>.

=head1 THANKS

To nothingmuch, ghenry, castaway and the rest of #catalyst for the help. :)

=head1 SEE ALSO

L<Catalyst::Authentication::Store::LDAP>, L<Catalyst::Authentication::Store::LDAP::User>, L<Catalyst::Plugin::Authentication>, L<Net::LDAP>

=head1 COPYRIGHT & LICENSE

Copyright (c) 2005 the aforementioned authors. All rights
reserved. This program is free software; you can redistribute
it and/or modify it under the same terms as Perl itself.

=cut
Commit	Line	Data
f66d606b	1
	2	=pod
	3
	4	=head1 NAME
	5
	6	Catalyst::Authentication::Store::LDAP::Backend
	7	- LDAP authentication storage backend.
	8
	9	=head1 SYNOPSIS
	10
	11	# you probably just want Store::LDAP under most cases,
	12	# but if you insist you can instantiate your own store:
	13
	14	use Catalyst::Authentication::Store::LDAP::Backend;
	15
	16	use Catalyst qw/
	17	Authentication
	18	Authentication::Credential::Password
	19	/;
	20
	21	my %config = (
	22	'ldap_server' => 'ldap1.yourcompany.com',
	23	'ldap_server_options' => {
	24	'timeout' => 30,
	25	},
	26	'binddn' => 'anonymous',
	27	'bindpw' => 'dontcarehow',
	28	'start_tls' => 1,
	29	'start_tls_options' => {
	30	'verify' => 'none',
	31	},
	32	'user_basedn' => 'ou=people,dc=yourcompany,dc=com',
	33	'user_filter' => '(&(objectClass=posixAccount)(uid=%s))',
	34	'user_scope' => 'one',
	35	'user_field' => 'uid',
	36	'user_search_options' => {
	37	'deref' => 'always',
	38	},
1647b33a	39	'user_results_filter' => sub { return shift->pop_entry },
f66d606b	40	'entry_class' => 'MyApp::LDAP::Entry',
405489b5	41	'user_class' => 'MyUser',
f66d606b	42	'use_roles' => 1,
	43	'role_basedn' => 'ou=groups,dc=yourcompany,dc=com',
	44	'role_filter' => '(&(objectClass=posixGroup)(member=%s))',
	45	'role_scope' => 'one',
	46	'role_field' => 'cn',
	47	'role_value' => 'dn',
	48	'role_search_options' => {
	49	'deref' => 'always',
	50	},
405489b5	51	'role_search_as_user' => 0,
f66d606b	52	);
	53
	54	our $users = Catalyst::Authentication::Store::LDAP::Backend->new(\%config);
	55
f66d606b	56	=head1 DESCRIPTION
f66d606b	57
afb8e81c	58	You probably want L<Catalyst::Authentication::Store::LDAP>.
f66d606b	59
afb8e81c	60	Otherwise, this lets you create a store manually.
f66d606b	61
	62	See the L<Catalyst::Authentication::Store::LDAP> documentation for
	63	an explanation of the configuration options.
	64
	65	=head1 METHODS
	66
	67	=cut
	68
	69	package Catalyst::Authentication::Store::LDAP::Backend;
	70	use base qw( Class::Accessor::Fast );
	71
	72	use strict;
	73	use warnings;
	74
d94851da	75	our $VERSION = '0.1005';
f66d606b	76
	77	use Catalyst::Authentication::Store::LDAP::User;
	78	use Net::LDAP;
405489b5	79	use Catalyst::Utils ();
f66d606b	80
	81	BEGIN {
	82	__PACKAGE__->mk_accessors(
	83	qw( ldap_server ldap_server_options binddn
	84	bindpw entry_class user_search_options
	85	user_filter user_basedn user_scope
	86	user_attrs user_field use_roles role_basedn
	87	role_filter role_scope role_field role_value
	88	role_search_options start_tls start_tls_options
405489b5	89	user_results_filter user_class role_search_as_user
f66d606b	90	)
	91	);
	92	}
	93
	94	=head2 new($config)
	95
	96	Creates a new L<Catalyst::Authentication::Store::LDAP::Backend> object.
	97	$config should be a hashref, which should contain the configuration options
	98	listed in L<Catalyst::Authentication::Store::LDAP>'s documentation.
	99
	100	Also sets a few sensible defaults.
	101
	102	=cut
	103
	104	sub new {
	105	my ( $class, $config ) = @_;
	106
	107	unless ( defined($config) && ref($config) eq "HASH" ) {
	108	Catalyst::Exception->throw(
	109	"Catalyst::Authentication::Store::LDAP::Backend needs to be configured with a hashref."
	110	);
	111	}
	112	my %config_hash = %{$config};
	113	$config_hash{'binddn'} \|\|= 'anonymous';
	114	$config_hash{'user_filter'} \|\|= '(uid=%s)';
	115	$config_hash{'user_scope'} \|\|= 'sub';
	116	$config_hash{'user_field'} \|\|= 'uid';
	117	$config_hash{'role_filter'} \|\|= '(memberUid=%s)';
	118	$config_hash{'role_scope'} \|\|= 'sub';
	119	$config_hash{'role_field'} \|\|= 'cn';
	120	$config_hash{'use_roles'} \|\|= '1';
	121	$config_hash{'start_tls'} \|\|= '0';
	122	$config_hash{'entry_class'} \|\|= 'Catalyst::Model::LDAP::Entry';
405489b5	123	$config_hash{'user_class'} \|\|= 'Catalyst::Authentication::Store::LDAP::User';
405489b5	124	$config_hash{'role_search_as_user'} \|\|= 0;
f66d606b	125
405489b5	126	Catalyst::Utils::ensure_class_loaded($config_hash{'user_class'});
f66d606b	127	my $self = \%config_hash;
	128	bless( $self, $class );
	129	return $self;
	130	}
	131
	132	=head2 find_user( I<authinfo> )
	133
	134	Creates a L<Catalyst::Authentication::Store::LDAP::User> object
	135	for the given User ID. This is the preferred mechanism for getting a
	136	given User out of the Store.
	137
	138	I<authinfo> should be a hashref with a key of either C<id> or
	139	C<username>. The value will be compared against the LDAP C<user_field> field.
	140
	141	=cut
	142
	143	sub find_user {
	144	my ( $self, $authinfo, $c ) = @_;
	145	return $self->get_user( $authinfo->{id} \|\| $authinfo->{username} );
	146	}
	147
	148	=head2 get_user($id)
	149
	150	Creates a L<Catalyst::Authentication::Store::LDAP::User> object
	151	for the given User ID. This is the preferred mechanism for getting a
	152	given User out of the Store.
	153
	154	=cut
	155
	156	sub get_user {
	157	my ( $self, $id ) = @_;
405489b5	158	my $user = $self->user_class->new( $self,
f66d606b	159	$self->lookup_user($id) );
	160	return $user;
	161	}
	162
	163	=head2 ldap_connect
	164
	165	Returns a L<Net::LDAP> object, connected to your LDAP server. (According
	166	to how you configured the Backend, of course)
	167
	168	=cut
	169
	170	sub ldap_connect {
	171	my ($self) = shift;
	172	my $ldap;
	173	if ( defined( $self->ldap_server_options() ) ) {
	174	$ldap
	175	= Net::LDAP->new( $self->ldap_server,
	176	%{ $self->ldap_server_options } )
	177	or Catalyst::Exception->throw($@);
	178	}
	179	else {
	180	$ldap = Net::LDAP->new( $self->ldap_server )
	181	or Catalyst::Exception->throw($@);
	182	}
	183	if ( defined( $self->start_tls ) && $self->start_tls =~ /(1\|true)/i ) {
	184	my $mesg;
	185	if ( defined( $self->start_tls_options ) ) {
	186	$mesg = $ldap->start_tls( %{ $self->start_tls_options } );
	187	}
	188	else {
	189	$mesg = $ldap->start_tls;
	190	}
	191	if ( $mesg->is_error ) {
	192	Catalyst::Exception->throw( "TLS Error: " . $mesg->error );
	193	}
	194	}
	195	return $ldap;
	196	}
	197
	198	=head2 ldap_bind($ldap, $binddn, $bindpw)
	199
	200	Bind's to the directory. If $ldap is undef, it will connect to the
	201	LDAP server first. $binddn should be the DN of the object you wish
	202	to bind as, and $bindpw the password.
	203
	204	If $binddn is "anonymous", an anonymous bind will be performed.
	205
	206	=cut
	207
	208	sub ldap_bind {
	209	my ( $self, $ldap, $binddn, $bindpw, $forauth ) = @_;
	210	$forauth \|\|= 0;
	211	$ldap \|\|= $self->ldap_connect;
	212	if ( !defined($ldap) ) {
	213	Catalyst::Exception->throw("LDAP Server undefined!");
	214	}
	215	$binddn \|\|= $self->binddn;
	216	$bindpw \|\|= $self->bindpw;
	217	if ( $binddn eq "anonymous" ) {
405489b5	218	$self->_ldap_bind_anon($ldap);
f66d606b	219	}
	220	else {
	221	if ($bindpw) {
	222	my $mesg = $ldap->bind( $binddn, 'password' => $bindpw );
	223	if ( $mesg->is_error ) {
	224
	225	# If we're not checking this bind for authentication purposes
	226	# Go ahead an blow up if we fail.
	227	if ( $forauth ne 'forauth' ) {
	228	Catalyst::Exception->throw(
	229	"Error on Initial Bind: " . $mesg->error );
	230	}
	231	else {
	232	return undef;
	233	}
	234	}
	235	}
	236	else {
405489b5	237	$self->_ldap_bind_anon($ldap, $binddn);
f66d606b	238	}
	239	}
	240	return $ldap;
	241	}
	242
405489b5	243	sub _ldap_bind_anon {
	244	my ($self, $ldap, $dn) = @_;
	245	my $mesg = $ldap->bind($dn);
	246	if ( $mesg->is_error ) {
	247	Catalyst::Exception->throw( "Error on Bind: " . $mesg->error );
	248	}
	249	}
	250
f66d606b	251	=head2 lookup_user($id)
	252
	253	Given a User ID, this method will:
	254
	255	A) Bind to the directory using the configured binddn and bindpw
	256	B) Perform a search for the User Object in the directory, using
	257	user_basedn, user_filter, and user_scope.
d94851da	258	C) Assuming we found the object, we will walk it's attributes
f66d606b	259	using L<Net::LDAP::Entry>'s get_value method. We store the
d94851da	260	results in a hashref. If we do not find the object, then
	261	undef is returned.
	262	D) Return a hashref that looks like:
	263
f66d606b	264	$results = {
	265	'ldap_entry' => $entry, # The Net::LDAP::Entry object
	266	'attributes' => $attributes,
	267	}
	268
1647b33a	269	This method is usually only called by find_user().
f66d606b	270
	271	=cut
	272
	273	sub lookup_user {
	274	my ( $self, $id ) = @_;
	275
	276	# No sneaking in wildcards!
	277	if ( $id =~ /\*/ ) {
	278	Catalyst::Exception->throw("ID $id contains wildcards!");
	279	}
	280	my $ldap = $self->ldap_bind;
	281	my @searchopts;
	282	if ( defined( $self->user_basedn ) ) {
	283	push( @searchopts, 'base' => $self->user_basedn );
	284	}
	285	else {
	286	Catalyst::Exception->throw(
	287	"You must set user_basedn before looking up users!");
	288	}
	289	my $filter = $self->_replace_filter( $self->user_filter, $id );
	290	push( @searchopts, 'filter' => $filter );
	291	push( @searchopts, 'scope' => $self->user_scope );
	292	if ( defined( $self->user_search_options ) ) {
	293	push( @searchopts, %{ $self->user_search_options } );
	294	}
	295	my $usersearch = $ldap->search(@searchopts);
d94851da	296
	297	return if ( $usersearch->is_error );
	298
f66d606b	299	my $userentry;
1647b33a	300	my $user_field = $self->user_field;
	301	my $results_filter = $self->user_results_filter;
	302	my $entry;
	303	if ( defined($results_filter) ) {
	304	$entry = &$results_filter($usersearch);
	305	}
	306	else {
	307	$entry = $usersearch->pop_entry;
	308	}
	309	if ( $usersearch->pop_entry ) {
	310	Catalyst::Exception->throw(
	311	"More than one entry matches user search.\n"
	312	. "Consider defining a user_results_filter sub." );
	313	}
	314
	315	# a little extra sanity check with the 'eq' since LDAP already
	316	# says it matches.
5772b468	317	# NOTE that Net::LDAP returns exactly what you asked for, but
	318	# because LDAP is often case insensitive, FoO can match foo
	319	# and so we normalize with lc().
1647b33a	320	if ( defined($entry) ) {
5772b468	321	unless ( lc( $entry->get_value($user_field) ) eq lc($id) ) {
1647b33a	322	Catalyst::Exception->throw(
	323	"LDAP claims '$user_field' equals '$id' but results entry does not match."
	324	);
f66d606b	325	}
1647b33a	326	$userentry = $entry;
f66d606b	327	}
1647b33a	328
f66d606b	329	$ldap->unbind;
	330	$ldap->disconnect;
	331	unless ($userentry) {
	332	return undef;
	333	}
	334	my $attrhash;
	335	foreach my $attr ( $userentry->attributes ) {
	336	my @attrvalues = $userentry->get_value($attr);
	337	if ( scalar(@attrvalues) == 1 ) {
	338	$attrhash->{ lc($attr) } = $attrvalues[0];
	339	}
	340	else {
	341	$attrhash->{ lc($attr) } = \@attrvalues;
	342	}
	343	}
405489b5	344
405489b5	345	eval { Catalyst::Utils::ensure_class_loaded($self->entry_class) };
f66d606b	346	if ( !$@ ) {
	347	bless( $userentry, $self->entry_class );
	348	$userentry->{_use_unicode}++;
	349	}
	350	my $rv = {
	351	'ldap_entry' => $userentry,
	352	'attributes' => $attrhash,
	353	};
	354	return $rv;
	355	}
	356
405489b5	357	=head2 lookup_roles($userobj, [$ldap])
f66d606b	358
	359	This method looks up the roles for a given user. It takes a
	360	L<Catalyst::Authentication::Store::LDAP::User> object
405489b5	361	as it's first argument, and can optionally take a I<Net::LDAP> object which
405489b5	362	is used rather than the default binding if supplied.
f66d606b	363
	364	It returns an array containing the role_field attribute from all the
	365	objects that match it's criteria.
	366
	367	=cut
	368
	369	sub lookup_roles {
405489b5	370	my ( $self, $userobj, $ldap ) = @_;
f66d606b	371	if ( $self->use_roles == 0 \|\| $self->use_roles =~ /^false$/i ) {
	372	return undef;
	373	}
405489b5	374	$ldap \|\|= $self->ldap_bind;
f66d606b	375	my @searchopts;
	376	if ( defined( $self->role_basedn ) ) {
	377	push( @searchopts, 'base' => $self->role_basedn );
	378	}
	379	else {
	380	Catalyst::Exception->throw(
	381	"You must set up role_basedn before looking up roles!");
	382	}
	383	my $filter_value = $userobj->has_attribute( $self->role_value );
	384	if ( !defined($filter_value) ) {
	385	Catalyst::Exception->throw( "User object "
	386	. $userobj->username
	387	. " has no "
	388	. $self->role_value
	389	. " attribute, so I can't look up it's roles!" );
	390	}
	391	my $filter = $self->_replace_filter( $self->role_filter, $filter_value );
	392	push( @searchopts, 'filter' => $filter );
	393	push( @searchopts, 'scope' => $self->role_scope );
	394	push( @searchopts, 'attrs' => [ $self->role_field ] );
	395	if ( defined( $self->role_search_options ) ) {
	396	push( @searchopts, %{ $self->role_search_options } );
	397	}
	398	my $rolesearch = $ldap->search(@searchopts);
	399	my @roles;
ab62b426	400	RESULT: foreach my $entry ( $rolesearch->entries ) {
ab62b426	401	push( @roles, $entry->get_value( $self->role_field ) );
f66d606b	402	}
	403	return @roles;
	404	}
	405
	406	sub _replace_filter {
	407	my $self = shift;
	408	my $filter = shift;
	409	my $replace = shift;
	410	$filter =~ s/\%s/$replace/g;
	411	return $filter;
	412	}
	413
	414	=head2 user_supports
	415
	416	Returns the value of
	417	Catalyst::Authentication::Store::LDAP::User->supports(@_).
	418
	419	=cut
	420
	421	sub user_supports {
	422	my $self = shift;
	423
	424	# this can work as a class method
	425	Catalyst::Authentication::Store::LDAP::User->supports(@_);
	426	}
	427
	428	=head2 from_session( I<id> )
	429
	430	Returns get_user() for I<id>.
	431
	432	=cut
	433
	434	sub from_session {
	435	my ( $self, $c, $id ) = @_;
	436	$self->get_user($id);
	437	}
	438
	439	1;
	440
	441	__END__
	442
	443	=head1 AUTHORS
	444
	445	Adam Jacob <holoway@cpan.org>
	446
	447	Some parts stolen shamelessly and entirely from
	448	L<Catalyst::Plugin::Authentication::Store::Htpasswd>.
	449
	450	Currently maintained by Peter Karman <karman@cpan.org>.
	451
	452	=head1 THANKS
	453
	454	To nothingmuch, ghenry, castaway and the rest of #catalyst for the help. :)
	455
	456	=head1 SEE ALSO
	457
	458	L<Catalyst::Authentication::Store::LDAP>, L<Catalyst::Authentication::Store::LDAP::User>, L<Catalyst::Plugin::Authentication>, L<Net::LDAP>
	459
	460	=head1 COPYRIGHT & LICENSE
	461
	462	Copyright (c) 2005 the aforementioned authors. All rights
	463	reserved. This program is free software; you can redistribute
	464	it and/or modify it under the same terms as Perl itself.
	465
466	=cut
467