[catagits/Catalyst-Authentication-Store-LDAP.git] / lib / Catalyst / Authentication / Store / LDAP / Backend.pm


=pod

=head1 NAME

Catalyst::Authentication::Store::LDAP::Backend 
  - LDAP authentication storage backend.

=head1 SYNOPSIS

    # you probably just want Store::LDAP under most cases,
    # but if you insist you can instantiate your own store:

    use Catalyst::Authentication::Store::LDAP::Backend;

    use Catalyst qw/
        Authentication
        Authentication::Credential::Password
    /;

    my %config = (
            'ldap_server' => 'ldap1.yourcompany.com',
            'ldap_server_options' => {
                'timeout' => 30,
            },
            'binddn' => 'anonymous',
            'bindpw' => 'dontcarehow',
            'start_tls' => 1,
            'start_tls_options' => {
                'verify' => 'none',
            },
            'user_basedn' => 'ou=people,dc=yourcompany,dc=com',
            'user_filter' => '(&(objectClass=posixAccount)(uid=%s))',
            'user_scope' => 'one',  # or 'sub' for Active Directory
            'user_field' => 'uid',
            'user_search_options' => {
                'deref' => 'always',
            },
            'user_results_filter' => sub { return shift->pop_entry },
            'entry_class' => 'MyApp::LDAP::Entry',
            'user_class' => 'MyUser',
            'use_roles' => 1,
            'role_basedn' => 'ou=groups,dc=yourcompany,dc=com',
            'role_filter' => '(&(objectClass=posixGroup)(member=%s))',
            'role_scope' => 'one',
            'role_field' => 'cn',
            'role_value' => 'dn',
            'role_search_options' => {
                'deref' => 'always',
            },
            'role_search_as_user' => 0,
    );
    
    our $users = Catalyst::Authentication::Store::LDAP::Backend->new(\%config);

=head1 DESCRIPTION

You probably want L<Catalyst::Authentication::Store::LDAP>.

Otherwise, this lets you create a store manually.

See the L<Catalyst::Authentication::Store::LDAP> documentation for
an explanation of the configuration options.

=head1 METHODS

=cut

package Catalyst::Authentication::Store::LDAP::Backend;
use base qw( Class::Accessor::Fast );

use strict;
use warnings;

our $VERSION = '1.015';

use Catalyst::Authentication::Store::LDAP::User;
use Net::LDAP;
use Catalyst::Utils ();

BEGIN {
    __PACKAGE__->mk_accessors(
        qw( ldap_server ldap_server_options binddn
            bindpw entry_class user_search_options
            user_filter user_basedn user_scope
            user_attrs user_field use_roles role_basedn
            role_filter role_scope role_field role_value
            role_search_options start_tls start_tls_options
            user_results_filter user_class role_search_as_user
            )
    );
}

=head2 new($config)

Creates a new L<Catalyst::Authentication::Store::LDAP::Backend> object.
$config should be a hashref, which should contain the configuration options
listed in L<Catalyst::Authentication::Store::LDAP>'s documentation.

Also sets a few sensible defaults.

=cut

sub new {
    my ( $class, $config ) = @_;

    unless ( defined($config) && ref($config) eq "HASH" ) {
        Catalyst::Exception->throw(
            "Catalyst::Authentication::Store::LDAP::Backend needs to be configured with a hashref."
        );
    }
    my %config_hash = %{$config};
    $config_hash{'binddn'}      ||= 'anonymous';
    $config_hash{'user_filter'} ||= '(uid=%s)';
    $config_hash{'user_scope'}  ||= 'sub';
    $config_hash{'user_field'}  ||= 'uid';
    $config_hash{'role_filter'} ||= '(memberUid=%s)';
    $config_hash{'role_scope'}  ||= 'sub';
    $config_hash{'role_field'}  ||= 'cn';
    $config_hash{'use_roles'}   ||= '1';
    $config_hash{'start_tls'}   ||= '0';
    $config_hash{'entry_class'} ||= 'Catalyst::Model::LDAP::Entry';
    $config_hash{'user_class'}
        ||= 'Catalyst::Authentication::Store::LDAP::User';
    $config_hash{'role_search_as_user'} ||= 0;

    Catalyst::Utils::ensure_class_loaded( $config_hash{'user_class'} );
    my $self = \%config_hash;
    bless( $self, $class );
    return $self;
}

=head2 find_user( I<authinfo>, $c )

Creates a L<Catalyst::Authentication::Store::LDAP::User> object
for the given User ID.  This is the preferred mechanism for getting a 
given User out of the Store.

I<authinfo> should be a hashref with a key of either C<id> or
C<username>. The value will be compared against the LDAP C<user_field> field.

=cut

sub find_user {
    my ( $self, $authinfo, $c ) = @_;
    return $self->get_user( $authinfo->{id} || $authinfo->{username}, $c );
}

=head2 get_user( I<id>, $c)

Creates a L<Catalyst::Authentication::Store::LDAP::User> object
for the given User ID, or calls C<new> on the class specified in
C<user_class>.  This instance of the store object, the results of
C<lookup_user> and $c are passed as arguments (in that order) to C<new>.
This is the preferred mechanism for getting a given User out of the Store.

=cut

sub get_user {
    my ( $self, $id, $c ) = @_;
    my $user = $self->user_class->new( $self, $self->lookup_user($id), $c );
    return $user;
}

=head2 ldap_connect

Returns a L<Net::LDAP> object, connected to your LDAP server. (According
to how you configured the Backend, of course)

=cut

sub ldap_connect {
    my ($self) = shift;
    my $ldap;
    if ( defined( $self->ldap_server_options() ) ) {
        $ldap
            = Net::LDAP->new( $self->ldap_server,
            %{ $self->ldap_server_options } )
            or Catalyst::Exception->throw($@);
    }
    else {
        $ldap = Net::LDAP->new( $self->ldap_server )
            or Catalyst::Exception->throw($@);
    }
    if ( defined( $self->start_tls ) && $self->start_tls =~ /(1|true)/i ) {
        my $mesg;
        if ( defined( $self->start_tls_options ) ) {
            $mesg = $ldap->start_tls( %{ $self->start_tls_options } );
        }
        else {
            $mesg = $ldap->start_tls;
        }
        if ( $mesg->is_error ) {
            Catalyst::Exception->throw( "TLS Error: " . $mesg->error );
        }
    }
    return $ldap;
}

=head2 ldap_bind($ldap, $binddn, $bindpw)

Bind's to the directory.  If $ldap is undef, it will connect to the
LDAP server first.  $binddn should be the DN of the object you wish
to bind as, and $bindpw the password.

If $binddn is "anonymous", an anonymous bind will be performed.

=cut

sub ldap_bind {
    my ( $self, $ldap, $binddn, $bindpw ) = @_;
    $ldap ||= $self->ldap_connect;
    if ( !defined($ldap) ) {
        Catalyst::Exception->throw("LDAP Server undefined!");
    }

    # if username is present, make sure password is present too.
    # see https://rt.cpan.org/Ticket/Display.html?id=81908
    if ( !defined $binddn ) {
        $binddn = $self->binddn;
        $bindpw = $self->bindpw;
    }

    if ( $binddn eq "anonymous" ) {
        $self->_ldap_bind_anon($ldap);
    }
    else {
        if ($bindpw) {
            my $mesg = $ldap->bind( $binddn, 'password' => $bindpw );
            if ( $mesg->is_error ) {
                Catalyst::Exception->throw(
                    "Error on Initial Bind: " . $mesg->error );
            }
        }
        else {
            $self->_ldap_bind_anon( $ldap, $binddn );
        }
    }
    return $ldap;
}

sub _ldap_bind_anon {
    my ( $self, $ldap, $dn ) = @_;
    my $mesg = $ldap->bind($dn);
    if ( $mesg->is_error ) {
        Catalyst::Exception->throw( "Error on Bind: " . $mesg->error );
    }
}

=head2 ldap_auth( $binddn, $bindpw )

Connect to the LDAP server and do an authenticated bind against the
directory. Throws an exception if connecting to the LDAP server fails.
Returns 1 if binding succeeds, 0 if it fails.

=cut

sub ldap_auth {
    my ( $self, $binddn, $bindpw ) = @_;
    my $ldap = $self->ldap_connect;
    if ( !defined $ldap ) {
        Catalyst::Exception->throw("LDAP server undefined!");
    }
    my $mesg = $ldap->bind( $binddn, password => $bindpw );
    return $mesg->is_error ? 0 : 1;
}

=head2 lookup_user($id)

Given a User ID, this method will:

  A) Bind to the directory using the configured binddn and bindpw
  B) Perform a search for the User Object in the directory, using
     user_basedn, user_filter, and user_scope.
  C) Assuming we found the object, we will walk it's attributes
     using L<Net::LDAP::Entry>'s get_value method.  We store the
     results in a hashref. If we do not find the object, then
     undef is returned.
  D) Return a hashref that looks like:

     $results = {
        'ldap_entry' => $entry, # The Net::LDAP::Entry object
        'attributes' => $attributes,
     }

This method is usually only called by find_user().

=cut

sub lookup_user {
    my ( $self, $id ) = @_;

    # Trim trailing space or we confuse ourselves
    $id =~ s/\s+$//;
    my $ldap = $self->ldap_bind;
    my @searchopts;
    if ( defined( $self->user_basedn ) ) {
        push( @searchopts, 'base' => $self->user_basedn );
    }
    else {
        Catalyst::Exception->throw(
            "You must set user_basedn before looking up users!");
    }
    my $filter = $self->_replace_filter( $self->user_filter, $id );
    push( @searchopts, 'filter' => $filter );
    push( @searchopts, 'scope'  => $self->user_scope );
    if ( defined( $self->user_search_options ) ) {
        push( @searchopts, %{ $self->user_search_options } );
    }
    my $usersearch = $ldap->search(@searchopts);

    return undef if ( $usersearch->is_error );

    my $userentry;
    my $user_field     = $self->user_field;
    my $results_filter = $self->user_results_filter;
    my $entry;
    if ( defined($results_filter) ) {
        $entry = &$results_filter($usersearch);
    }
    else {
        $entry = $usersearch->pop_entry;
    }
    if ( $usersearch->pop_entry ) {
        Catalyst::Exception->throw(
                  "More than one entry matches user search.\n"
                . "Consider defining a user_results_filter sub." );
    }

    # a little extra sanity check with the 'eq' since LDAP already
    # says it matches.
    # NOTE that Net::LDAP returns exactly what you asked for, but
    # because LDAP is often case insensitive, FoO can match foo
    # and so we normalize with lc().
    if ( defined($entry) ) {
        unless ( lc( $entry->get_value($user_field) ) eq lc($id) ) {
            Catalyst::Exception->throw(
                "LDAP claims '$user_field' equals '$id' but results entry does not match."
            );
        }
        $userentry = $entry;
    }

    $ldap->unbind;
    $ldap->disconnect;
    unless ($userentry) {
        return undef;
    }
    my $attrhash;
    foreach my $attr ( $userentry->attributes ) {
        my @attrvalues = $userentry->get_value($attr);
        if ( scalar(@attrvalues) == 1 ) {
            $attrhash->{ lc($attr) } = $attrvalues[0];
        }
        else {
            $attrhash->{ lc($attr) } = \@attrvalues;
        }
    }

    eval { Catalyst::Utils::ensure_class_loaded( $self->entry_class ) };
    if ( !$@ ) {
        bless( $userentry, $self->entry_class );
        $userentry->{_use_unicode}++;
    }
    my $rv = {
        'ldap_entry' => $userentry,
        'attributes' => $attrhash,
    };
    return $rv;
}

=head2 lookup_roles($userobj, [$ldap])

This method looks up the roles for a given user.  It takes a 
L<Catalyst::Authentication::Store::LDAP::User> object
as it's first argument, and can optionally take a I<Net::LDAP> object which
is used rather than the default binding if supplied.

It returns an array containing the role_field attribute from all the
objects that match it's criteria.

=cut

sub lookup_roles {
    my ( $self, $userobj, $ldap ) = @_;
    if ( $self->use_roles == 0 || $self->use_roles =~ /^false$/i ) {
        return undef;
    }
    $ldap ||= $self->role_search_as_user
        ? $userobj->ldap_connection : $self->ldap_bind;
    my @searchopts;
    if ( defined( $self->role_basedn ) ) {
        push( @searchopts, 'base' => $self->role_basedn );
    }
    else {
        Catalyst::Exception->throw(
            "You must set up role_basedn before looking up roles!");
    }
    my $filter_value = $userobj->has_attribute( $self->role_value );
    if ( !defined($filter_value) ) {
        Catalyst::Exception->throw( "User object "
                . $userobj->username
                . " has no "
                . $self->role_value
                . " attribute, so I can't look up it's roles!" );
    }
    my $filter = $self->_replace_filter( $self->role_filter, $filter_value );
    push( @searchopts, 'filter' => $filter );
    push( @searchopts, 'scope'  => $self->role_scope );
    push( @searchopts, 'attrs'  => [ $self->role_field ] );
    if ( defined( $self->role_search_options ) ) {
        push( @searchopts, %{ $self->role_search_options } );
    }
    my $rolesearch = $ldap->search(@searchopts);
    my @roles;
RESULT: foreach my $entry ( $rolesearch->entries ) {
        push( @roles, $entry->get_value( $self->role_field ) );
    }
    return @roles;
}

sub _replace_filter {
    my $self    = shift;
    my $filter  = shift;
    my $replace = shift;
    $replace =~ s/([*()\\\x{0}])/sprintf '\\%02x', ord($1)/ge;
    $filter =~ s/\%s/$replace/g;
    return $filter;
}

=head2 user_supports

Returns the value of 
Catalyst::Authentication::Store::LDAP::User->supports(@_).

=cut

sub user_supports {
    my $self = shift;

    # this can work as a class method
    Catalyst::Authentication::Store::LDAP::User->supports(@_);
}

=head2 from_session( I<id>, I<$c> )

Returns get_user() for I<id>.

=cut

sub from_session {
    my ( $self, $c, $id ) = @_;
    $self->get_user( $id, $c );
}

1;

__END__

=head1 AUTHORS

Adam Jacob <holoway@cpan.org>

Some parts stolen shamelessly and entirely from
L<Catalyst::Plugin::Authentication::Store::Htpasswd>.

Currently maintained by Peter Karman <karman@cpan.org>.

=head1 THANKS

To nothingmuch, ghenry, castaway and the rest of #catalyst for the help. :)

=head1 SEE ALSO

L<Catalyst::Authentication::Store::LDAP>, L<Catalyst::Authentication::Store::LDAP::User>, L<Catalyst::Plugin::Authentication>, L<Net::LDAP>

=head1 COPYRIGHT & LICENSE

Copyright (c) 2005 the aforementioned authors. All rights
reserved. This program is free software; you can redistribute
it and/or modify it under the same terms as Perl itself.

=cut
Commit	Line	Data
f66d606b	1
	2	=pod
	3
	4	=head1 NAME
	5
	6	Catalyst::Authentication::Store::LDAP::Backend
	7	- LDAP authentication storage backend.
	8
	9	=head1 SYNOPSIS
	10
	11	# you probably just want Store::LDAP under most cases,
	12	# but if you insist you can instantiate your own store:
	13
	14	use Catalyst::Authentication::Store::LDAP::Backend;
	15
	16	use Catalyst qw/
	17	Authentication
	18	Authentication::Credential::Password
	19	/;
	20
	21	my %config = (
	22	'ldap_server' => 'ldap1.yourcompany.com',
	23	'ldap_server_options' => {
	24	'timeout' => 30,
	25	},
	26	'binddn' => 'anonymous',
	27	'bindpw' => 'dontcarehow',
	28	'start_tls' => 1,
	29	'start_tls_options' => {
	30	'verify' => 'none',
	31	},
	32	'user_basedn' => 'ou=people,dc=yourcompany,dc=com',
	33	'user_filter' => '(&(objectClass=posixAccount)(uid=%s))',
57d476f1	34	'user_scope' => 'one', # or 'sub' for Active Directory
f66d606b	35	'user_field' => 'uid',
	36	'user_search_options' => {
	37	'deref' => 'always',
	38	},
1647b33a	39	'user_results_filter' => sub { return shift->pop_entry },
f66d606b	40	'entry_class' => 'MyApp::LDAP::Entry',
405489b5	41	'user_class' => 'MyUser',
f66d606b	42	'use_roles' => 1,
	43	'role_basedn' => 'ou=groups,dc=yourcompany,dc=com',
	44	'role_filter' => '(&(objectClass=posixGroup)(member=%s))',
	45	'role_scope' => 'one',
	46	'role_field' => 'cn',
	47	'role_value' => 'dn',
	48	'role_search_options' => {
	49	'deref' => 'always',
	50	},
405489b5	51	'role_search_as_user' => 0,
f66d606b	52	);
	53
	54	our $users = Catalyst::Authentication::Store::LDAP::Backend->new(\%config);
	55
f66d606b	56	=head1 DESCRIPTION
f66d606b	57
afb8e81c	58	You probably want L<Catalyst::Authentication::Store::LDAP>.
f66d606b	59
afb8e81c	60	Otherwise, this lets you create a store manually.
f66d606b	61
	62	See the L<Catalyst::Authentication::Store::LDAP> documentation for
	63	an explanation of the configuration options.
	64
	65	=head1 METHODS
	66
	67	=cut
	68
	69	package Catalyst::Authentication::Store::LDAP::Backend;
	70	use base qw( Class::Accessor::Fast );
	71
	72	use strict;
	73	use warnings;
	74
dfead577	75	our $VERSION = '1.015';
f66d606b	76
	77	use Catalyst::Authentication::Store::LDAP::User;
	78	use Net::LDAP;
405489b5	79	use Catalyst::Utils ();
f66d606b	80
	81	BEGIN {
	82	__PACKAGE__->mk_accessors(
	83	qw( ldap_server ldap_server_options binddn
	84	bindpw entry_class user_search_options
	85	user_filter user_basedn user_scope
	86	user_attrs user_field use_roles role_basedn
	87	role_filter role_scope role_field role_value
	88	role_search_options start_tls start_tls_options
405489b5	89	user_results_filter user_class role_search_as_user
f66d606b	90	)
	91	);
	92	}
	93
	94	=head2 new($config)
	95
	96	Creates a new L<Catalyst::Authentication::Store::LDAP::Backend> object.
	97	$config should be a hashref, which should contain the configuration options
	98	listed in L<Catalyst::Authentication::Store::LDAP>'s documentation.
	99
	100	Also sets a few sensible defaults.
	101
	102	=cut
	103
	104	sub new {
	105	my ( $class, $config ) = @_;
	106
	107	unless ( defined($config) && ref($config) eq "HASH" ) {
	108	Catalyst::Exception->throw(
	109	"Catalyst::Authentication::Store::LDAP::Backend needs to be configured with a hashref."
	110	);
	111	}
	112	my %config_hash = %{$config};
	113	$config_hash{'binddn'} \|\|= 'anonymous';
	114	$config_hash{'user_filter'} \|\|= '(uid=%s)';
	115	$config_hash{'user_scope'} \|\|= 'sub';
	116	$config_hash{'user_field'} \|\|= 'uid';
	117	$config_hash{'role_filter'} \|\|= '(memberUid=%s)';
	118	$config_hash{'role_scope'} \|\|= 'sub';
	119	$config_hash{'role_field'} \|\|= 'cn';
	120	$config_hash{'use_roles'} \|\|= '1';
	121	$config_hash{'start_tls'} \|\|= '0';
	122	$config_hash{'entry_class'} \|\|= 'Catalyst::Model::LDAP::Entry';
d05c83dd	123	$config_hash{'user_class'}
d05c83dd	124	\|\|= 'Catalyst::Authentication::Store::LDAP::User';
405489b5	125	$config_hash{'role_search_as_user'} \|\|= 0;
f66d606b	126
d05c83dd	127	Catalyst::Utils::ensure_class_loaded( $config_hash{'user_class'} );
f66d606b	128	my $self = \%config_hash;
	129	bless( $self, $class );
	130	return $self;
	131	}
	132
52a972a4	133	=head2 find_user( I<authinfo>, $c )
f66d606b	134
	135	Creates a L<Catalyst::Authentication::Store::LDAP::User> object
	136	for the given User ID. This is the preferred mechanism for getting a
	137	given User out of the Store.
	138
	139	I<authinfo> should be a hashref with a key of either C<id> or
	140	C<username>. The value will be compared against the LDAP C<user_field> field.
	141
	142	=cut
	143
	144	sub find_user {
	145	my ( $self, $authinfo, $c ) = @_;
52a972a4	146	return $self->get_user( $authinfo->{id} \|\| $authinfo->{username}, $c );
f66d606b	147	}
f66d606b	148
5faab354	149	=head2 get_user( I<id>, $c)
f66d606b	150
f66d606b	151	Creates a L<Catalyst::Authentication::Store::LDAP::User> object
52a972a4	152	for the given User ID, or calls C<new> on the class specified in
	153	C<user_class>. This instance of the store object, the results of
	154	C<lookup_user> and $c are passed as arguments (in that order) to C<new>.
	155	This is the preferred mechanism for getting a given User out of the Store.
f66d606b	156
	157	=cut
	158
	159	sub get_user {
52a972a4	160	my ( $self, $id, $c ) = @_;
d05c83dd	161	my $user = $self->user_class->new( $self, $self->lookup_user($id), $c );
f66d606b	162	return $user;
	163	}
	164
	165	=head2 ldap_connect
	166
	167	Returns a L<Net::LDAP> object, connected to your LDAP server. (According
	168	to how you configured the Backend, of course)
	169
	170	=cut
	171
	172	sub ldap_connect {
	173	my ($self) = shift;
	174	my $ldap;
	175	if ( defined( $self->ldap_server_options() ) ) {
	176	$ldap
	177	= Net::LDAP->new( $self->ldap_server,
	178	%{ $self->ldap_server_options } )
	179	or Catalyst::Exception->throw($@);
	180	}
	181	else {
	182	$ldap = Net::LDAP->new( $self->ldap_server )
	183	or Catalyst::Exception->throw($@);
	184	}
	185	if ( defined( $self->start_tls ) && $self->start_tls =~ /(1\|true)/i ) {
	186	my $mesg;
	187	if ( defined( $self->start_tls_options ) ) {
	188	$mesg = $ldap->start_tls( %{ $self->start_tls_options } );
	189	}
	190	else {
	191	$mesg = $ldap->start_tls;
	192	}
	193	if ( $mesg->is_error ) {
	194	Catalyst::Exception->throw( "TLS Error: " . $mesg->error );
	195	}
	196	}
	197	return $ldap;
	198	}
	199
	200	=head2 ldap_bind($ldap, $binddn, $bindpw)
	201
	202	Bind's to the directory. If $ldap is undef, it will connect to the
	203	LDAP server first. $binddn should be the DN of the object you wish
	204	to bind as, and $bindpw the password.
	205
	206	If $binddn is "anonymous", an anonymous bind will be performed.
	207
	208	=cut
	209
	210	sub ldap_bind {
238a096f	211	my ( $self, $ldap, $binddn, $bindpw ) = @_;
d05c83dd	212	$ldap \|\|= $self->ldap_connect;
f66d606b	213	if ( !defined($ldap) ) {
	214	Catalyst::Exception->throw("LDAP Server undefined!");
	215	}
50f88c5d	216
	217	# if username is present, make sure password is present too.
	218	# see https://rt.cpan.org/Ticket/Display.html?id=81908
	219	if ( !defined $binddn ) {
	220	$binddn = $self->binddn;
	221	$bindpw = $self->bindpw;
	222	}
	223
f66d606b	224	if ( $binddn eq "anonymous" ) {
405489b5	225	$self->_ldap_bind_anon($ldap);
f66d606b	226	}
f66d606b	227	else {
238a096f	228	if ($bindpw) {
f66d606b	229	my $mesg = $ldap->bind( $binddn, 'password' => $bindpw );
f66d606b	230	if ( $mesg->is_error ) {
238a096f	231	Catalyst::Exception->throw(
238a096f	232	"Error on Initial Bind: " . $mesg->error );
f66d606b	233	}
	234	}
	235	else {
d05c83dd	236	$self->_ldap_bind_anon( $ldap, $binddn );
f66d606b	237	}
	238	}
	239	return $ldap;
	240	}
	241
405489b5	242	sub _ldap_bind_anon {
d05c83dd	243	my ( $self, $ldap, $dn ) = @_;
405489b5	244	my $mesg = $ldap->bind($dn);
	245	if ( $mesg->is_error ) {
	246	Catalyst::Exception->throw( "Error on Bind: " . $mesg->error );
	247	}
	248	}
	249
238a096f	250	=head2 ldap_auth( $binddn, $bindpw )
	251
	252	Connect to the LDAP server and do an authenticated bind against the
	253	directory. Throws an exception if connecting to the LDAP server fails.
	254	Returns 1 if binding succeeds, 0 if it fails.
	255
	256	=cut
	257
	258	sub ldap_auth {
	259	my ( $self, $binddn, $bindpw ) = @_;
	260	my $ldap = $self->ldap_connect;
	261	if ( !defined $ldap ) {
	262	Catalyst::Exception->throw("LDAP server undefined!");
	263	}
	264	my $mesg = $ldap->bind( $binddn, password => $bindpw );
	265	return $mesg->is_error ? 0 : 1;
	266	}
	267
f66d606b	268	=head2 lookup_user($id)
	269
	270	Given a User ID, this method will:
	271
	272	A) Bind to the directory using the configured binddn and bindpw
	273	B) Perform a search for the User Object in the directory, using
	274	user_basedn, user_filter, and user_scope.
d94851da	275	C) Assuming we found the object, we will walk it's attributes
f66d606b	276	using L<Net::LDAP::Entry>'s get_value method. We store the
d94851da	277	results in a hashref. If we do not find the object, then
	278	undef is returned.
	279	D) Return a hashref that looks like:
	280
f66d606b	281	$results = {
	282	'ldap_entry' => $entry, # The Net::LDAP::Entry object
	283	'attributes' => $attributes,
	284	}
	285
1647b33a	286	This method is usually only called by find_user().
f66d606b	287
	288	=cut
	289
	290	sub lookup_user {
	291	my ( $self, $id ) = @_;
	292
02f3c071	293	# Trim trailing space or we confuse ourselves
02f3c071	294	$id =~ s/\s+$//;
f66d606b	295	my $ldap = $self->ldap_bind;
	296	my @searchopts;
	297	if ( defined( $self->user_basedn ) ) {
	298	push( @searchopts, 'base' => $self->user_basedn );
	299	}
	300	else {
	301	Catalyst::Exception->throw(
	302	"You must set user_basedn before looking up users!");
	303	}
	304	my $filter = $self->_replace_filter( $self->user_filter, $id );
	305	push( @searchopts, 'filter' => $filter );
	306	push( @searchopts, 'scope' => $self->user_scope );
	307	if ( defined( $self->user_search_options ) ) {
	308	push( @searchopts, %{ $self->user_search_options } );
	309	}
	310	my $usersearch = $ldap->search(@searchopts);
d94851da	311
a2f66fa8	312	return undef if ( $usersearch->is_error );
d94851da	313
f66d606b	314	my $userentry;
1647b33a	315	my $user_field = $self->user_field;
	316	my $results_filter = $self->user_results_filter;
	317	my $entry;
	318	if ( defined($results_filter) ) {
	319	$entry = &$results_filter($usersearch);
	320	}
	321	else {
	322	$entry = $usersearch->pop_entry;
	323	}
	324	if ( $usersearch->pop_entry ) {
	325	Catalyst::Exception->throw(
	326	"More than one entry matches user search.\n"
	327	. "Consider defining a user_results_filter sub." );
	328	}
	329
	330	# a little extra sanity check with the 'eq' since LDAP already
	331	# says it matches.
5772b468	332	# NOTE that Net::LDAP returns exactly what you asked for, but
	333	# because LDAP is often case insensitive, FoO can match foo
	334	# and so we normalize with lc().
1647b33a	335	if ( defined($entry) ) {
5772b468	336	unless ( lc( $entry->get_value($user_field) ) eq lc($id) ) {
1647b33a	337	Catalyst::Exception->throw(
	338	"LDAP claims '$user_field' equals '$id' but results entry does not match."
	339	);
f66d606b	340	}
1647b33a	341	$userentry = $entry;
f66d606b	342	}
1647b33a	343
f66d606b	344	$ldap->unbind;
	345	$ldap->disconnect;
	346	unless ($userentry) {
	347	return undef;
	348	}
	349	my $attrhash;
	350	foreach my $attr ( $userentry->attributes ) {
	351	my @attrvalues = $userentry->get_value($attr);
	352	if ( scalar(@attrvalues) == 1 ) {
	353	$attrhash->{ lc($attr) } = $attrvalues[0];
	354	}
	355	else {
	356	$attrhash->{ lc($attr) } = \@attrvalues;
	357	}
	358	}
d05c83dd	359
d05c83dd	360	eval { Catalyst::Utils::ensure_class_loaded( $self->entry_class ) };
f66d606b	361	if ( !$@ ) {
	362	bless( $userentry, $self->entry_class );
	363	$userentry->{_use_unicode}++;
	364	}
	365	my $rv = {
	366	'ldap_entry' => $userentry,
	367	'attributes' => $attrhash,
	368	};
	369	return $rv;
	370	}
	371
405489b5	372	=head2 lookup_roles($userobj, [$ldap])
f66d606b	373
	374	This method looks up the roles for a given user. It takes a
	375	L<Catalyst::Authentication::Store::LDAP::User> object
405489b5	376	as it's first argument, and can optionally take a I<Net::LDAP> object which
405489b5	377	is used rather than the default binding if supplied.
f66d606b	378
	379	It returns an array containing the role_field attribute from all the
	380	objects that match it's criteria.
	381
	382	=cut
	383
	384	sub lookup_roles {
405489b5	385	my ( $self, $userobj, $ldap ) = @_;
f66d606b	386	if ( $self->use_roles == 0 \|\| $self->use_roles =~ /^false$/i ) {
	387	return undef;
	388	}
5a9aba6e	389	$ldap \|\|= $self->role_search_as_user
5a9aba6e	390	? $userobj->ldap_connection : $self->ldap_bind;
f66d606b	391	my @searchopts;
	392	if ( defined( $self->role_basedn ) ) {
	393	push( @searchopts, 'base' => $self->role_basedn );
	394	}
	395	else {
	396	Catalyst::Exception->throw(
	397	"You must set up role_basedn before looking up roles!");
	398	}
	399	my $filter_value = $userobj->has_attribute( $self->role_value );
	400	if ( !defined($filter_value) ) {
	401	Catalyst::Exception->throw( "User object "
	402	. $userobj->username
	403	. " has no "
	404	. $self->role_value
	405	. " attribute, so I can't look up it's roles!" );
	406	}
	407	my $filter = $self->_replace_filter( $self->role_filter, $filter_value );
	408	push( @searchopts, 'filter' => $filter );
	409	push( @searchopts, 'scope' => $self->role_scope );
	410	push( @searchopts, 'attrs' => [ $self->role_field ] );
	411	if ( defined( $self->role_search_options ) ) {
	412	push( @searchopts, %{ $self->role_search_options } );
	413	}
	414	my $rolesearch = $ldap->search(@searchopts);
	415	my @roles;
ab62b426	416	RESULT: foreach my $entry ( $rolesearch->entries ) {
ab62b426	417	push( @roles, $entry->get_value( $self->role_field ) );
f66d606b	418	}
	419	return @roles;
	420	}
	421
	422	sub _replace_filter {
	423	my $self = shift;
	424	my $filter = shift;
	425	my $replace = shift;
18d41a8f	426	$replace =~ s/([*()\\\x{0}])/sprintf '\\%02x', ord($1)/ge;
f66d606b	427	$filter =~ s/\%s/$replace/g;
	428	return $filter;
	429	}
	430
	431	=head2 user_supports
	432
	433	Returns the value of
	434	Catalyst::Authentication::Store::LDAP::User->supports(@_).
	435
	436	=cut
	437
	438	sub user_supports {
	439	my $self = shift;
	440
	441	# this can work as a class method
	442	Catalyst::Authentication::Store::LDAP::User->supports(@_);
	443	}
	444
5faab354	445	=head2 from_session( I<id>, I<$c> )
f66d606b	446
	447	Returns get_user() for I<id>.
	448
	449	=cut
	450
	451	sub from_session {
	452	my ( $self, $c, $id ) = @_;
d05c83dd	453	$self->get_user( $id, $c );
f66d606b	454	}
	455
	456	1;
	457
	458	__END__
	459
	460	=head1 AUTHORS
	461
	462	Adam Jacob <holoway@cpan.org>
	463
	464	Some parts stolen shamelessly and entirely from
	465	L<Catalyst::Plugin::Authentication::Store::Htpasswd>.
	466
	467	Currently maintained by Peter Karman <karman@cpan.org>.
	468
	469	=head1 THANKS
	470
	471	To nothingmuch, ghenry, castaway and the rest of #catalyst for the help. :)
	472
	473	=head1 SEE ALSO
	474
	475	L<Catalyst::Authentication::Store::LDAP>, L<Catalyst::Authentication::Store::LDAP::User>, L<Catalyst::Plugin::Authentication>, L<Net::LDAP>
	476
	477	=head1 COPYRIGHT & LICENSE
	478
	479	Copyright (c) 2005 the aforementioned authors. All rights
	480	reserved. This program is free software; you can redistribute
	481	it and/or modify it under the same terms as Perl itself.
	482
	483	=cut
	484