[p5sagit/p5-mst-13.2.git] / lib / CGI / Carp.pm

package CGI::Carp;

=head1 NAME

B<CGI::Carp> - CGI routines for writing to the HTTPD (or other) error log

=head1 SYNOPSIS

    use CGI::Carp;

    croak "We're outta here!";
    confess "It was my fault: $!";
    carp "It was your fault!";   
    warn "I'm confused";
    die  "I'm dying.\n";

    use CGI::Carp qw(cluck);
    cluck "I wouldn't do that if I were you";

    use CGI::Carp qw(fatalsToBrowser);
    die "Fatal error messages are now sent to browser";

=head1 DESCRIPTION

CGI scripts have a nasty habit of leaving warning messages in the error
logs that are neither time stamped nor fully identified.  Tracking down
the script that caused the error is a pain.  This fixes that.  Replace
the usual

    use Carp;

with

    use CGI::Carp

And the standard warn(), die (), croak(), confess() and carp() calls
will automagically be replaced with functions that write out nicely
time-stamped messages to the HTTP server error log.

For example:

   [Fri Nov 17 21:40:43 1995] test.pl: I'm confused at test.pl line 3.
   [Fri Nov 17 21:40:43 1995] test.pl: Got an error message: Permission denied.
   [Fri Nov 17 21:40:43 1995] test.pl: I'm dying.

=head1 REDIRECTING ERROR MESSAGES

By default, error messages are sent to STDERR.  Most HTTPD servers
direct STDERR to the server's error log.  Some applications may wish
to keep private error logs, distinct from the server's error log, or
they may wish to direct error messages to STDOUT so that the browser
will receive them.

The C<carpout()> function is provided for this purpose.  Since
carpout() is not exported by default, you must import it explicitly by
saying

   use CGI::Carp qw(carpout);

The carpout() function requires one argument, which should be a
reference to an open filehandle for writing errors.  It should be
called in a C<BEGIN> block at the top of the CGI application so that
compiler errors will be caught.  Example:

   BEGIN {
     use CGI::Carp qw(carpout);
     open(LOG, ">>/usr/local/cgi-logs/mycgi-log") or
       die("Unable to open mycgi-log: $!\n");
     carpout(LOG);
   }

carpout() does not handle file locking on the log for you at this point.

The real STDERR is not closed -- it is moved to CGI::Carp::SAVEERR.  Some
servers, when dealing with CGI scripts, close their connection to the
browser when the script closes STDOUT and STDERR.  CGI::Carp::SAVEERR is there to
prevent this from happening prematurely.

You can pass filehandles to carpout() in a variety of ways.  The "correct"
way according to Tom Christiansen is to pass a reference to a filehandle 
GLOB:

    carpout(\*LOG);

This looks weird to mere mortals however, so the following syntaxes are
accepted as well:

    carpout(LOG);
    carpout(main::LOG);
    carpout(main'LOG);
    carpout(\LOG);
    carpout(\'main::LOG');

    ... and so on

FileHandle and other objects work as well.

Use of carpout() is not great for performance, so it is recommended
for debugging purposes or for moderate-use applications.  A future
version of this module may delay redirecting STDERR until one of the
CGI::Carp methods is called to prevent the performance hit.

=head1 MAKING PERL ERRORS APPEAR IN THE BROWSER WINDOW

If you want to send fatal (die, confess) errors to the browser, ask to 
import the special "fatalsToBrowser" subroutine:

    use CGI::Carp qw(fatalsToBrowser);
    die "Bad error here";

Fatal errors will now be echoed to the browser as well as to the log.  CGI::Carp
arranges to send a minimal HTTP header to the browser so that even errors that
occur in the early compile phase will be seen.
Nonfatal errors will still be directed to the log file only (unless redirected
with carpout).

=head2 Changing the default message

By default, the software error message is followed by a note to
contact the Webmaster by e-mail with the time and date of the error.
If this message is not to your liking, you can change it using the
set_message() routine.  This is not imported by default; you should
import it on the use() line:

    use CGI::Carp qw(fatalsToBrowser set_message);
    set_message("It's not a bug, it's a feature!");

You may also pass in a code reference in order to create a custom
error message.  At run time, your code will be called with the text
of the error message that caused the script to die.  Example:

    use CGI::Carp qw(fatalsToBrowser set_message);
    BEGIN {
       sub handle_errors {
          my $msg = shift;
          print "<h1>Oh gosh</h1>";
          print "<p>Got an error: $msg</p>";
      }
      set_message(\&handle_errors);
    }

In order to correctly intercept compile-time errors, you should call
set_message() from within a BEGIN{} block.

=head1 MAKING WARNINGS APPEAR AS HTML COMMENTS

It is now also possible to make non-fatal errors appear as HTML
comments embedded in the output of your program.  To enable this
feature, export the new "warningsToBrowser" subroutine.  Since sending
warnings to the browser before the HTTP headers have been sent would
cause an error, any warnings are stored in an internal buffer until
you call the warningsToBrowser() subroutine with a true argument:

    use CGI::Carp qw(fatalsToBrowser warningsToBrowser);
    use CGI qw(:standard);
    print header();
    warningsToBrowser(1);

You may also give a false argument to warningsToBrowser() to prevent
warnings from being sent to the browser while you are printing some
content where HTML comments are not allowed:

    warningsToBrowser(0);    # disable warnings
    print "<script type=\"text/javascript\"><!--\n";
    print_some_javascript_code();
    print "//--></script>\n";
    warningsToBrowser(1);    # re-enable warnings

Note: In this respect warningsToBrowser() differs fundamentally from
fatalsToBrowser(), which you should never call yourself!

=head1 OVERRIDING THE NAME OF THE PROGRAM

CGI::Carp includes the name of the program that generated the error or
warning in the messages written to the log and the browser window.
Sometimes, Perl can get confused about what the actual name of the
executed program was.  In these cases, you can override the program
name that CGI::Carp will use for all messages.

The quick way to do that is to tell CGI::Carp the name of the program
in its use statement.  You can do that by adding
"name=cgi_carp_log_name" to your "use" statement.  For example:

    use CGI::Carp qw(name=cgi_carp_log_name);

.  If you want to change the program name partway through the program,
you can use the C<set_progname()> function instead.  It is not
exported by default, you must import it explicitly by saying

    use CGI::Carp qw(set_progname);

Once you've done that, you can change the logged name of the program
at any time by calling

    set_progname(new_program_name);

You can set the program back to the default by calling

    set_progname(undef);

Note that this override doesn't happen until after the program has
compiled, so any compile-time errors will still show up with the
non-overridden program name
  
=head1 CHANGE LOG

1.05 carpout() added and minor corrections by Marc Hedlund
     <hedlund@best.com> on 11/26/95.

1.06 fatalsToBrowser() no longer aborts for fatal errors within
     eval() statements.

1.08 set_message() added and carpout() expanded to allow for FileHandle
     objects.

1.09 set_message() now allows users to pass a code REFERENCE for 
     really custom error messages.  croak and carp are now
     exported by default.  Thanks to Gunther Birznieks for the
     patches.

1.10 Patch from Chris Dean (ctdean@cogit.com) to allow 
     module to run correctly under mod_perl.

1.11 Changed order of &gt; and &lt; escapes.

1.12 Changed die() on line 217 to CORE::die to avoid B<-w> warning.

1.13 Added cluck() to make the module orthogonal with Carp.
     More mod_perl related fixes.

1.20 Patch from Ilmari Karonen (perl@itz.pp.sci.fi):  Added
     warningsToBrowser().  Replaced <CODE> tags with <PRE> in
     fatalsToBrowser() output.

1.23 ineval() now checks both $^S and inspects the message for the "eval" pattern
     (hack alert!) in order to accomodate various combinations of Perl and
     mod_perl.

1.24 Patch from Scott Gifford (sgifford@suspectclass.com): Add support
     for overriding program name.

=head1 AUTHORS

Copyright 1995-2002, Lincoln D. Stein.  All rights reserved.  

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

Address bug reports and comments to: lstein@cshl.org

=head1 SEE ALSO

Carp, CGI::Base, CGI::BasePlus, CGI::Request, CGI::MiniSvr, CGI::Form,
CGI::Response
    if (defined($CGI::Carp::PROGNAME)) 
    {
      $file = $CGI::Carp::PROGNAME;
    }

=cut

require 5.000;
use Exporter;
#use Carp;
BEGIN { require Carp; }
use File::Spec;

@ISA = qw(Exporter);
@EXPORT = qw(confess croak carp);
@EXPORT_OK = qw(carpout fatalsToBrowser warningsToBrowser wrap set_message set_progname cluck ^name=);

$main::SIG{__WARN__}=\&CGI::Carp::warn;
*CORE::GLOBAL::die = \&CGI::Carp::die;
$CGI::Carp::VERSION = '1.24';
$CGI::Carp::CUSTOM_MSG = undef;

# fancy import routine detects and handles 'errorWrap' specially.
sub import {
    my $pkg = shift;
    my(%routines);
    my(@name);
  
    if (@name=grep(/^name=/,@_))
      {
        my($n) = (split(/=/,$name[0]))[1];
        set_progname($n);
        @_=grep(!/^name=/,@_);
      }

    grep($routines{$_}++,@_,@EXPORT);
    $WRAP++ if $routines{'fatalsToBrowser'} || $routines{'wrap'};
    $WARN++ if $routines{'warningsToBrowser'};
    my($oldlevel) = $Exporter::ExportLevel;
    $Exporter::ExportLevel = 1;
    Exporter::import($pkg,keys %routines);
    $Exporter::ExportLevel = $oldlevel;
}

# These are the originals
sub realwarn { CORE::warn(@_); }
sub realdie { CORE::die(@_); }

sub id {
    my $level = shift;
    my($pack,$file,$line,$sub) = caller($level);
    my($dev,$dirs,$id) = File::Spec->splitpath($file);
    return ($file,$line,$id);
}

sub stamp {
    my $time = scalar(localtime);
    my $frame = 0;
    my ($id,$pack,$file,$dev,$dirs);
    if (defined($CGI::Carp::PROGNAME)) {
        $id = $CGI::Carp::PROGNAME;
    } else {
        do {
  	  $id = $file;
	  ($pack,$file) = caller($frame++);
        } until !$file;
    }
    ($dev,$dirs,$id) = File::Spec->splitpath($id);
    return "[$time] $id: ";
}

sub set_progname {
    $CGI::Carp::PROGNAME = shift;
    return $CGI::Carp::PROGNAME;
}


sub warn {
    my $message = shift;
    my($file,$line,$id) = id(1);
    $message .= " at $file line $line.\n" unless $message=~/\n$/;
    _warn($message) if $WARN;
    my $stamp = stamp;
    $message=~s/^/$stamp/gm;
    realwarn $message;
}

sub _warn {
    my $msg = shift;
    if ($EMIT_WARNINGS) {
	# We need to mangle the message a bit to make it a valid HTML
	# comment.  This is done by substituting similar-looking ISO
	# 8859-1 characters for <, > and -.  This is a hack.
	$msg =~ tr/<>-/\253\273\255/;
	chomp $msg;
	print STDOUT "<!-- warning: $msg -->\n";
    } else {
	push @WARNINGS, $msg;
    }
}

sub ineval { 
  (exists $ENV{MOD_PERL} ? 0 : $^S) || _longmess() =~ /eval [\{\']/m 
}


# The mod_perl package Apache::Registry loads CGI programs by calling
# eval.  These evals don't count when looking at the stack backtrace.
sub _longmess {
    my $message = Carp::longmess();
    my $mod_perl = exists $ENV{MOD_PERL};
    $message =~ s,eval[^\n]+Apache/Registry\.pm.*,,s if $mod_perl;
    return $message;    
}

sub die {
  realdie @_ if ineval;
  my ($message) = @_;
  my $time = scalar(localtime);
  my($file,$line,$id) = id(1);
  $message .= " at $file line $line." unless $message=~/\n$/;
  &fatalsToBrowser($message) if $WRAP;
  my $stamp = stamp;
  $message=~s/^/$stamp/gm;
  realdie $message;
}

sub set_message {
    $CGI::Carp::CUSTOM_MSG = shift;
    return $CGI::Carp::CUSTOM_MSG;
}

sub confess { CGI::Carp::die Carp::longmess @_; }
sub croak   { CGI::Carp::die Carp::shortmess @_; }
sub carp    { CGI::Carp::warn Carp::shortmess @_; }
sub cluck   { CGI::Carp::warn Carp::longmess @_; }

# We have to be ready to accept a filehandle as a reference
# or a string.
sub carpout {
    my($in) = @_;
    my($no) = fileno(to_filehandle($in));
    realdie("Invalid filehandle $in\n") unless defined $no;
    
    open(SAVEERR, ">&STDERR");
    open(STDERR, ">&$no") or 
	( print SAVEERR "Unable to redirect STDERR: $!\n" and exit(1) );
}

sub warningsToBrowser {
    $EMIT_WARNINGS = @_ ? shift : 1;
    _warn(shift @WARNINGS) while $EMIT_WARNINGS and @WARNINGS;
}

# headers
sub fatalsToBrowser {
    my($msg) = @_;
    $msg=~s/&/&amp;/g;
    $msg=~s/>/&gt;/g;
    $msg=~s/</&lt;/g;
    $msg=~s/\"/&quot;/g;
    my($wm) = $ENV{SERVER_ADMIN} ? 
	qq[the webmaster (<a href="mailto:$ENV{SERVER_ADMIN}">$ENV{SERVER_ADMIN}</a>)] :
	"this site's webmaster";
    my ($outer_message) = <<END;
For help, please send mail to $wm, giving this error message 
and the time and date of the error.
END
    ;
    my $mod_perl = exists $ENV{MOD_PERL};
    print STDOUT "Content-type: text/html\n\n" 
	unless $mod_perl;

    warningsToBrowser(1);    # emit warnings before dying

    if ($CUSTOM_MSG) {
	if (ref($CUSTOM_MSG) eq 'CODE') {
	    &$CUSTOM_MSG($msg); # nicer to perl 5.003 users
	    return;
	} else {
	    $outer_message = $CUSTOM_MSG;
	}
    }
    
    my $mess = <<END;
<h1>Software error:</h1>
<pre>$msg</pre>
<p>
$outer_message
</p>
END
    ;

    if ($mod_perl && (my $r = Apache->request)) {
	# If bytes have already been sent, then
	# we print the message out directly.
	# Otherwise we make a custom error
	# handler to produce the doc for us.
	if ($r->bytes_sent) {
	    $r->print($mess);
	    $r->exit;
	} else {
	    $r->status(500);
	    $r->custom_response(500,$mess);
	}
    } else {
	print STDOUT $mess;
    }
}

# Cut and paste from CGI.pm so that we don't have the overhead of
# always loading the entire CGI module.
sub to_filehandle {
    my $thingy = shift;
    return undef unless $thingy;
    return $thingy if UNIVERSAL::isa($thingy,'GLOB');
    return $thingy if UNIVERSAL::isa($thingy,'FileHandle');
    if (!ref($thingy)) {
	my $caller = 1;
	while (my $package = caller($caller++)) {
	    my($tmp) = $thingy=~/[\':]/ ? $thingy : "$package\:\:$thingy"; 
	    return $tmp if defined(fileno($tmp));
	}
    }
    return undef;
}

1;
Commit	Line	Data
54310121	1	package CGI::Carp;
	2
	3	=head1 NAME
	4
	5	B<CGI::Carp> - CGI routines for writing to the HTTPD (or other) error log
	6
	7	=head1 SYNOPSIS
	8
	9	use CGI::Carp;
	10
	11	croak "We're outta here!";
	12	confess "It was my fault: $!";
	13	carp "It was your fault!";
	14	warn "I'm confused";
	15	die "I'm dying.\n";
	16
71f3e297	17	use CGI::Carp qw(cluck);
	18	cluck "I wouldn't do that if I were you";
	19
	20	use CGI::Carp qw(fatalsToBrowser);
	21	die "Fatal error messages are now sent to browser";
	22
54310121	23	=head1 DESCRIPTION
	24
	25	CGI scripts have a nasty habit of leaving warning messages in the error
	26	logs that are neither time stamped nor fully identified. Tracking down
	27	the script that caused the error is a pain. This fixes that. Replace
	28	the usual
	29
	30	use Carp;
	31
	32	with
	33
	34	use CGI::Carp
	35
	36	And the standard warn(), die (), croak(), confess() and carp() calls
	37	will automagically be replaced with functions that write out nicely
	38	time-stamped messages to the HTTP server error log.
	39
	40	For example:
	41
	42	[Fri Nov 17 21:40:43 1995] test.pl: I'm confused at test.pl line 3.
	43	[Fri Nov 17 21:40:43 1995] test.pl: Got an error message: Permission denied.
	44	[Fri Nov 17 21:40:43 1995] test.pl: I'm dying.
	45
	46	=head1 REDIRECTING ERROR MESSAGES
	47
	48	By default, error messages are sent to STDERR. Most HTTPD servers
	49	direct STDERR to the server's error log. Some applications may wish
	50	to keep private error logs, distinct from the server's error log, or
	51	they may wish to direct error messages to STDOUT so that the browser
	52	will receive them.
	53
	54	The C<carpout()> function is provided for this purpose. Since
	55	carpout() is not exported by default, you must import it explicitly by
	56	saying
	57
	58	use CGI::Carp qw(carpout);
	59
	60	The carpout() function requires one argument, which should be a
	61	reference to an open filehandle for writing errors. It should be
	62	called in a C<BEGIN> block at the top of the CGI application so that
	63	compiler errors will be caught. Example:
	64
	65	BEGIN {
	66	use CGI::Carp qw(carpout);
	67	open(LOG, ">>/usr/local/cgi-logs/mycgi-log") or
	68	die("Unable to open mycgi-log: $!\n");
	69	carpout(LOG);
	70	}
	71
	72	carpout() does not handle file locking on the log for you at this point.
	73
ba056755	74	The real STDERR is not closed -- it is moved to CGI::Carp::SAVEERR. Some
54310121	75	servers, when dealing with CGI scripts, close their connection to the
ba056755	76	browser when the script closes STDOUT and STDERR. CGI::Carp::SAVEERR is there to
54310121	77	prevent this from happening prematurely.
	78
	79	You can pass filehandles to carpout() in a variety of ways. The "correct"
	80	way according to Tom Christiansen is to pass a reference to a filehandle
	81	GLOB:
	82
	83	carpout(\*LOG);
	84
	85	This looks weird to mere mortals however, so the following syntaxes are
	86	accepted as well:
	87
	88	carpout(LOG);
	89	carpout(main::LOG);
	90	carpout(main'LOG);
	91	carpout(\LOG);
	92	carpout(\'main::LOG');
	93
	94	... and so on
	95
424ec8fa	96	FileHandle and other objects work as well.
424ec8fa	97
54310121	98	Use of carpout() is not great for performance, so it is recommended
	99	for debugging purposes or for moderate-use applications. A future
	100	version of this module may delay redirecting STDERR until one of the
	101	CGI::Carp methods is called to prevent the performance hit.
	102
	103	=head1 MAKING PERL ERRORS APPEAR IN THE BROWSER WINDOW
	104
	105	If you want to send fatal (die, confess) errors to the browser, ask to
	106	import the special "fatalsToBrowser" subroutine:
	107
	108	use CGI::Carp qw(fatalsToBrowser);
	109	die "Bad error here";
	110
	111	Fatal errors will now be echoed to the browser as well as to the log. CGI::Carp
	112	arranges to send a minimal HTTP header to the browser so that even errors that
	113	occur in the early compile phase will be seen.
	114	Nonfatal errors will still be directed to the log file only (unless redirected
	115	with carpout).
	116
424ec8fa	117	=head2 Changing the default message
	118
	119	By default, the software error message is followed by a note to
	120	contact the Webmaster by e-mail with the time and date of the error.
	121	If this message is not to your liking, you can change it using the
	122	set_message() routine. This is not imported by default; you should
	123	import it on the use() line:
	124
	125	use CGI::Carp qw(fatalsToBrowser set_message);
	126	set_message("It's not a bug, it's a feature!");
	127
	128	You may also pass in a code reference in order to create a custom
	129	error message. At run time, your code will be called with the text
	130	of the error message that caused the script to die. Example:
	131
	132	use CGI::Carp qw(fatalsToBrowser set_message);
	133	BEGIN {
	134	sub handle_errors {
	135	my $msg = shift;
	136	print "<h1>Oh gosh</h1>";
b2d0d414	137	print "<p>Got an error: $msg</p>";
424ec8fa	138	}
	139	set_message(\&handle_errors);
	140	}
	141
	142	In order to correctly intercept compile-time errors, you should call
	143	set_message() from within a BEGIN{} block.
	144
6b4ac661	145	=head1 MAKING WARNINGS APPEAR AS HTML COMMENTS
	146
	147	It is now also possible to make non-fatal errors appear as HTML
	148	comments embedded in the output of your program. To enable this
	149	feature, export the new "warningsToBrowser" subroutine. Since sending
	150	warnings to the browser before the HTTP headers have been sent would
	151	cause an error, any warnings are stored in an internal buffer until
	152	you call the warningsToBrowser() subroutine with a true argument:
	153
	154	use CGI::Carp qw(fatalsToBrowser warningsToBrowser);
	155	use CGI qw(:standard);
	156	print header();
	157	warningsToBrowser(1);
	158
	159	You may also give a false argument to warningsToBrowser() to prevent
	160	warnings from being sent to the browser while you are printing some
	161	content where HTML comments are not allowed:
	162
	163	warningsToBrowser(0); # disable warnings
b2d0d414	164	print "<script type=\"text/javascript\"><!--\n";
6b4ac661	165	print_some_javascript_code();
b2d0d414	166	print "//--></script>\n";
6b4ac661	167	warningsToBrowser(1); # re-enable warnings
	168
	169	Note: In this respect warningsToBrowser() differs fundamentally from
	170	fatalsToBrowser(), which you should never call yourself!
	171
188ba755	172	=head1 OVERRIDING THE NAME OF THE PROGRAM
	173
	174	CGI::Carp includes the name of the program that generated the error or
	175	warning in the messages written to the log and the browser window.
	176	Sometimes, Perl can get confused about what the actual name of the
	177	executed program was. In these cases, you can override the program
	178	name that CGI::Carp will use for all messages.
	179
	180	The quick way to do that is to tell CGI::Carp the name of the program
	181	in its use statement. You can do that by adding
	182	"name=cgi_carp_log_name" to your "use" statement. For example:
	183
	184	use CGI::Carp qw(name=cgi_carp_log_name);
	185
	186	. If you want to change the program name partway through the program,
	187	you can use the C<set_progname()> function instead. It is not
	188	exported by default, you must import it explicitly by saying
	189
	190	use CGI::Carp qw(set_progname);
	191
	192	Once you've done that, you can change the logged name of the program
	193	at any time by calling
	194
	195	set_progname(new_program_name);
	196
	197	You can set the program back to the default by calling
	198
	199	set_progname(undef);
	200
	201	Note that this override doesn't happen until after the program has
	202	compiled, so any compile-time errors will still show up with the
	203	non-overridden program name
	204
54310121	205	=head1 CHANGE LOG
	206
	207	1.05 carpout() added and minor corrections by Marc Hedlund
	208	<hedlund@best.com> on 11/26/95.
	209
	210	1.06 fatalsToBrowser() no longer aborts for fatal errors within
	211	eval() statements.
	212
424ec8fa	213	1.08 set_message() added and carpout() expanded to allow for FileHandle
	214	objects.
	215
	216	1.09 set_message() now allows users to pass a code REFERENCE for
	217	really custom error messages. croak and carp are now
	218	exported by default. Thanks to Gunther Birznieks for the
	219	patches.
	220
	221	1.10 Patch from Chris Dean (ctdean@cogit.com) to allow
	222	module to run correctly under mod_perl.
	223
71f3e297	224	1.11 Changed order of > and < escapes.
	225
	226	1.12 Changed die() on line 217 to CORE::die to avoid B<-w> warning.
	227
	228	1.13 Added cluck() to make the module orthogonal with Carp.
6b4ac661	229	More mod_perl related fixes.
	230
	231	1.20 Patch from Ilmari Karonen (perl@itz.pp.sci.fi): Added
	232	warningsToBrowser(). Replaced <CODE> tags with <PRE> in
	233	fatalsToBrowser() output.
71f3e297	234
b2d0d414	235	1.23 ineval() now checks both $^S and inspects the message for the "eval" pattern
	236	(hack alert!) in order to accomodate various combinations of Perl and
	237	mod_perl.
	238
188ba755	239	1.24 Patch from Scott Gifford (sgifford@suspectclass.com): Add support
	240	for overriding program name.
	241
54310121	242	=head1 AUTHORS
54310121	243
b2d0d414	244	Copyright 1995-2002, Lincoln D. Stein. All rights reserved.
71f3e297	245
	246	This library is free software; you can redistribute it and/or modify
	247	it under the same terms as Perl itself.
54310121	248
71f3e297	249	Address bug reports and comments to: lstein@cshl.org
54310121	250
	251	=head1 SEE ALSO
	252
	253	Carp, CGI::Base, CGI::BasePlus, CGI::Request, CGI::MiniSvr, CGI::Form,
	254	CGI::Response
188ba755	255	if (defined($CGI::Carp::PROGNAME))
	256	{
	257	$file = $CGI::Carp::PROGNAME;
	258	}
54310121	259
	260	=cut
	261
	262	require 5.000;
	263	use Exporter;
3acbd4f5	264	#use Carp;
3acbd4f5	265	BEGIN { require Carp; }
7f16a916	266	use File::Spec;
54310121	267
	268	@ISA = qw(Exporter);
	269	@EXPORT = qw(confess croak carp);
188ba755	270	@EXPORT_OK = qw(carpout fatalsToBrowser warningsToBrowser wrap set_message set_progname cluck ^name=);
3538e1d5	271
54310121	272	$main::SIG{__WARN__}=\&CGI::Carp::warn;
188ba755	273	*CORE::GLOBAL::die = \&CGI::Carp::die;
188ba755	274	$CGI::Carp::VERSION = '1.24';
424ec8fa	275	$CGI::Carp::CUSTOM_MSG = undef;
54310121	276
	277	# fancy import routine detects and handles 'errorWrap' specially.
	278	sub import {
	279	my $pkg = shift;
	280	my(%routines);
188ba755	281	my(@name);
	282
	283	if (@name=grep(/^name=/,@_))
	284	{
	285	my($n) = (split(/=/,$name[0]))[1];
	286	set_progname($n);
	287	@_=grep(!/^name=/,@_);
	288	}
	289
424ec8fa	290	grep($routines{$_}++,@_,@EXPORT);
424ec8fa	291	$WRAP++ if $routines{'fatalsToBrowser'} \|\| $routines{'wrap'};
6b4ac661	292	$WARN++ if $routines{'warningsToBrowser'};
54310121	293	my($oldlevel) = $Exporter::ExportLevel;
	294	$Exporter::ExportLevel = 1;
	295	Exporter::import($pkg,keys %routines);
	296	$Exporter::ExportLevel = $oldlevel;
	297	}
	298
	299	# These are the originals
9014bb8e	300	sub realwarn { CORE::warn(@_); }
9014bb8e	301	sub realdie { CORE::die(@_); }
54310121	302
	303	sub id {
	304	my $level = shift;
	305	my($pack,$file,$line,$sub) = caller($level);
7f16a916	306	my($dev,$dirs,$id) = File::Spec->splitpath($file);
54310121	307	return ($file,$line,$id);
	308	}
	309
	310	sub stamp {
	311	my $time = scalar(localtime);
	312	my $frame = 0;
ac734d8b	313	my ($id,$pack,$file,$dev,$dirs);
188ba755	314	if (defined($CGI::Carp::PROGNAME)) {
	315	$id = $CGI::Carp::PROGNAME;
	316	} else {
	317	do {
	318	$id = $file;
	319	($pack,$file) = caller($frame++);
	320	} until !$file;
	321	}
7f16a916	322	($dev,$dirs,$id) = File::Spec->splitpath($id);
54310121	323	return "[$time] $id: ";
	324	}
	325
188ba755	326	sub set_progname {
	327	$CGI::Carp::PROGNAME = shift;
	328	return $CGI::Carp::PROGNAME;
	329	}
	330
	331
54310121	332	sub warn {
	333	my $message = shift;
	334	my($file,$line,$id) = id(1);
	335	$message .= " at $file line $line.\n" unless $message=~/\n$/;
6b4ac661	336	_warn($message) if $WARN;
54310121	337	my $stamp = stamp;
	338	$message=~s/^/$stamp/gm;
	339	realwarn $message;
	340	}
	341
6b4ac661	342	sub _warn {
	343	my $msg = shift;
	344	if ($EMIT_WARNINGS) {
	345	# We need to mangle the message a bit to make it a valid HTML
	346	# comment. This is done by substituting similar-looking ISO
	347	# 8859-1 characters for <, > and -. This is a hack.
	348	$msg =~ tr/<>-/\253\273\255/;
	349	chomp $msg;
	350	print STDOUT "<!-- warning: $msg -->\n";
	351	} else {
	352	push @WARNINGS, $msg;
	353	}
	354	}
	355
188ba755	356	sub ineval {
	357	(exists $ENV{MOD_PERL} ? 0 : $^S) \|\| _longmess() =~ /eval [\{\']/m
	358	}
	359
6b4ac661	360
424ec8fa	361	# The mod_perl package Apache::Registry loads CGI programs by calling
	362	# eval. These evals don't count when looking at the stack backtrace.
	363	sub _longmess {
	364	my $message = Carp::longmess();
71f3e297	365	my $mod_perl = exists $ENV{MOD_PERL};
424ec8fa	366	$message =~ s,eval[^\n]+Apache/Registry\.pm.*,,s if $mod_perl;
6b4ac661	367	return $message;
424ec8fa	368	}
424ec8fa	369
54310121	370	sub die {
3538e1d5	371	realdie @_ if ineval;
6b4ac661	372	my ($message) = @_;
3538e1d5	373	my $time = scalar(localtime);
	374	my($file,$line,$id) = id(1);
	375	$message .= " at $file line $line." unless $message=~/\n$/;
	376	&fatalsToBrowser($message) if $WRAP;
	377	my $stamp = stamp;
	378	$message=~s/^/$stamp/gm;
	379	realdie $message;
54310121	380	}
54310121	381
424ec8fa	382	sub set_message {
	383	$CGI::Carp::CUSTOM_MSG = shift;
	384	return $CGI::Carp::CUSTOM_MSG;
	385	}
	386
2371fea9	387	sub confess { CGI::Carp::die Carp::longmess @_; }
	388	sub croak { CGI::Carp::die Carp::shortmess @_; }
	389	sub carp { CGI::Carp::warn Carp::shortmess @_; }
	390	sub cluck { CGI::Carp::warn Carp::longmess @_; }
54310121	391
	392	# We have to be ready to accept a filehandle as a reference
	393	# or a string.
	394	sub carpout {
	395	my($in) = @_;
424ec8fa	396	my($no) = fileno(to_filehandle($in));
71f3e297	397	realdie("Invalid filehandle $in\n") unless defined $no;
54310121	398
	399	open(SAVEERR, ">&STDERR");
	400	open(STDERR, ">&$no") or
	401	( print SAVEERR "Unable to redirect STDERR: $!\n" and exit(1) );
	402	}
	403
6b4ac661	404	sub warningsToBrowser {
	405	$EMIT_WARNINGS = @_ ? shift : 1;
	406	_warn(shift @WARNINGS) while $EMIT_WARNINGS and @WARNINGS;
	407	}
	408
54310121	409	# headers
	410	sub fatalsToBrowser {
	411	my($msg) = @_;
71f3e297	412	$msg=~s/&/&/g;
54310121	413	$msg=~s/>/>/g;
54310121	414	$msg=~s/</</g;
424ec8fa	415	$msg=~s/\"/"/g;
	416	my($wm) = $ENV{SERVER_ADMIN} ?
	417	qq[the webmaster (<a href="mailto:$ENV{SERVER_ADMIN}">$ENV{SERVER_ADMIN}</a>)] :
	418	"this site's webmaster";
	419	my ($outer_message) = <<END;
	420	For help, please send mail to $wm, giving this error message
	421	and the time and date of the error.
	422	END
	423	;
71f3e297	424	my $mod_perl = exists $ENV{MOD_PERL};
	425	print STDOUT "Content-type: text/html\n\n"
	426	unless $mod_perl;
424ec8fa	427
6b4ac661	428	warningsToBrowser(1); # emit warnings before dying
6b4ac661	429
424ec8fa	430	if ($CUSTOM_MSG) {
	431	if (ref($CUSTOM_MSG) eq 'CODE') {
	432	&$CUSTOM_MSG($msg); # nicer to perl 5.003 users
	433	return;
	434	} else {
	435	$outer_message = $CUSTOM_MSG;
	436	}
	437	}
	438
71f3e297	439	my $mess = <<END;
b2d0d414	440	<h1>Software error:</h1>
	441	<pre>$msg</pre>
	442	<p>
71f3e297	443	$outer_message
b2d0d414	444	</p>
54310121	445	END
424ec8fa	446	;
71f3e297	447
3d1a2ec4	448	if ($mod_perl && (my $r = Apache->request)) {
71f3e297	449	# If bytes have already been sent, then
	450	# we print the message out directly.
	451	# Otherwise we make a custom error
	452	# handler to produce the doc for us.
	453	if ($r->bytes_sent) {
	454	$r->print($mess);
	455	$r->exit;
	456	} else {
	457	$r->status(500);
	458	$r->custom_response(500,$mess);
	459	}
	460	} else {
	461	print STDOUT $mess;
	462	}
424ec8fa	463	}
	464
	465	# Cut and paste from CGI.pm so that we don't have the overhead of
	466	# always loading the entire CGI module.
	467	sub to_filehandle {
	468	my $thingy = shift;
	469	return undef unless $thingy;
	470	return $thingy if UNIVERSAL::isa($thingy,'GLOB');
	471	return $thingy if UNIVERSAL::isa($thingy,'FileHandle');
	472	if (!ref($thingy)) {
	473	my $caller = 1;
	474	while (my $package = caller($caller++)) {
	475	my($tmp) = $thingy=~/[\':]/ ? $thingy : "$package\:\:$thingy";
	476	return $tmp if defined(fileno($tmp));
	477	}
	478	}
	479	return undef;
54310121	480	}
	481
	482	1;