[p5sagit/p5-mst-13.2.git] / lib / AutoLoader.pm

package AutoLoader;

use 5.005_64;
our(@EXPORT, @EXPORT_OK, $VERSION);

my $is_dosish;
my $is_epoc;
my $is_vms;
my $is_macos;

BEGIN {
    require Exporter;
    @EXPORT = @EXPORT = ();
    @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
    $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32' || $^O eq 'NetWare';
    $is_epoc = $^O eq 'epoc';
    $is_vms = $^O eq 'VMS';
    $is_macos = $^O eq 'MacOS';
    $VERSION = '5.58';
}

AUTOLOAD {
    my $sub = $AUTOLOAD;
    my $filename;
    # Braces used to preserve $1 et al.
    {
	# Try to find the autoloaded file from the package-qualified
	# name of the sub. e.g., if the sub needed is
	# Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
	# something like '/usr/lib/perl5/Getopt/Long.pm', and the
	# autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
	#
	# However, if @INC is a relative path, this might not work.  If,
	# for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
	# 'lib/Getopt/Long.pm', and we want to require
	# 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
	# In this case, we simple prepend the 'auto/' and let the
	# C<require> take care of the searching for us.

	my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
	$pkg =~ s#::#/#g;
	if (defined($filename = $INC{"$pkg.pm"})) {
	    if ($is_macos) {
		$pkg =~ tr#/#:#;
		$filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
	    } else {
		$filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
	    }

	    # if the file exists, then make sure that it is a
	    # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
	    # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
	    # (and failing) to find the 'lib/auto/foo/bar.al' because it
	    # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').

	    if (-r $filename) {
		unless ($filename =~ m|^/|s) {
		    if ($is_dosish) {
			unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
			     if ($^O ne 'NetWare') {
					$filename = "./$filename";
				} else {
					$filename = "$filename";
				}
			}
		    }
		    elsif ($is_epoc) {
			unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
			     $filename = "./$filename";
			}
		    }elsif ($is_vms) {
			# XXX todo by VMSmiths
			$filename = "./$filename";
		    }
		    elsif (!$is_macos) {
			$filename = "./$filename";
		    }
		}
	    }
	    else {
		$filename = undef;
	    }
	}
	unless (defined $filename) {
	    # let C<require> do the searching
	    $filename = "auto/$sub.al";
	    $filename =~ s#::#/#g;
	}
    }
    my $save = $@;
    eval { local $SIG{__DIE__}; require $filename };
    if ($@) {
	if (substr($sub,-9) eq '::DESTROY') {
	    *$sub = sub {};
	} else {
	    # The load might just have failed because the filename was too
	    # long for some old SVR3 systems which treat long names as errors.
	    # If we can succesfully truncate a long name then it's worth a go.
	    # There is a slight risk that we could pick up the wrong file here
	    # but autosplit should have warned about that when splitting.
	    if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
		eval { local $SIG{__DIE__}; require $filename };
	    }
	    if ($@){
		$@ =~ s/ at .*\n//;
		my $error = $@;
		require Carp;
		Carp::croak($error);
	    }
	}
    }
    $@ = $save;
    goto &$sub;
}

sub import {
    my $pkg = shift;
    my $callpkg = caller;

    #
    # Export symbols, but not by accident of inheritance.
    #

    if ($pkg eq 'AutoLoader') {
      local $Exporter::ExportLevel = 1;
      Exporter::import $pkg, @_;
    }

    #
    # Try to find the autosplit index file.  Eg., if the call package
    # is POSIX, then $INC{POSIX.pm} is something like
    # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
    # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
    #
    # However, if @INC is a relative path, this might not work.  If,
    # for example, @INC = ('lib'), then
    # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
    # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
    #

    (my $calldir = $callpkg) =~ s#::#/#g;
    my $path = $INC{$calldir . '.pm'};
    if (defined($path)) {
	# Try absolute path name.
	$path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
	eval { require $path; };
	# If that failed, try relative path with normal @INC searching.
	if ($@) {
	    $path ="auto/$calldir/autosplit.ix";
	    eval { require $path; };
	}
	if ($@) {
	    my $error = $@;
	    require Carp;
	    Carp::carp($error);
	}
    } 
}

sub unimport {
  my $callpkg = caller;
  eval "package $callpkg; sub AUTOLOAD;";
}

1;

__END__

=head1 NAME

AutoLoader - load subroutines only on demand

=head1 SYNOPSIS

    package Foo;
    use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine

    package Bar;
    use AutoLoader;              # don't import AUTOLOAD, define our own
    sub AUTOLOAD {
        ...
        $AutoLoader::AUTOLOAD = "...";
        goto &AutoLoader::AUTOLOAD;
    }

=head1 DESCRIPTION

The B<AutoLoader> module works with the B<AutoSplit> module and the
C<__END__> token to defer the loading of some subroutines until they are
used rather than loading them all at once.

To use B<AutoLoader>, the author of a module has to place the
definitions of subroutines to be autoloaded after an C<__END__> token.
(See L<perldata>.)  The B<AutoSplit> module can then be run manually to
extract the definitions into individual files F<auto/funcname.al>.

B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
subroutine in is called in a client module of B<AutoLoader>,
B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
file with a name related to the location of the file from which the
client module was read.  As an example, if F<POSIX.pm> is located in
F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
the C<.al> file has the same name as the subroutine, sans package.  If
such a file exists, AUTOLOAD will read and evaluate it,
thus (presumably) defining the needed subroutine.  AUTOLOAD will then
C<goto> the newly defined subroutine.

Once this process completes for a given function, it is defined, so
future calls to the subroutine will bypass the AUTOLOAD mechanism.

=head2 Subroutine Stubs

In order for object method lookup and/or prototype checking to operate
correctly even when methods have not yet been defined it is necessary to
"forward declare" each subroutine (as in C<sub NAME;>).  See
L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
stubs", which are place holders with no code.

The AutoSplit and B<AutoLoader> modules automate the creation of forward
declarations.  The AutoSplit module creates an 'index' file containing
forward declarations of all the AutoSplit subroutines.  When the
AutoLoader module is 'use'd it loads these declarations into its callers
package.

Because of this mechanism it is important that B<AutoLoader> is always
C<use>d and not C<require>d.

=head2 Using B<AutoLoader>'s AUTOLOAD Subroutine

In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
explicitly import it:

    use AutoLoader 'AUTOLOAD';

=head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine

Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
They typically need to check for some special cases (such as constants)
and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.

Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
Instead, they should define their own AUTOLOAD subroutines along these
lines:

    use AutoLoader;
    use Carp;

    sub AUTOLOAD {
        my $sub = $AUTOLOAD;
        (my $constname = $sub) =~ s/.*:://;
        my $val = constant($constname, @_ ? $_[0] : 0);
        if ($! != 0) {
            if ($! =~ /Invalid/ || $!{EINVAL}) {
                $AutoLoader::AUTOLOAD = $sub;
                goto &AutoLoader::AUTOLOAD;
            }
            else {
                croak "Your vendor has not defined constant $constname";
            }
        }
        *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
        goto &$sub;
    }

If any module's own AUTOLOAD subroutine has no need to fallback to the
AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
subroutines), then that module should not use B<AutoLoader> at all.

=head2 Package Lexicals

Package lexicals declared with C<my> in the main block of a package
using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
the fact that the given scope ends at the C<__END__> marker.  A module
using such variables as package globals will not work properly under the
B<AutoLoader>.

The C<vars> pragma (see L<perlmod/"vars">) may be used in such
situations as an alternative to explicitly qualifying all globals with
the package namespace.  Variables pre-declared with this pragma will be
visible to any autoloaded routines (but will not be invisible outside
the package, unfortunately).

=head2 Not Using AutoLoader

You can stop using AutoLoader by simply

	no AutoLoader;

=head2 B<AutoLoader> vs. B<SelfLoader>

The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
loading of subroutines.

B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
While this avoids the use of a hierarchy of disk files and the
associated open/close for each routine loaded, B<SelfLoader> suffers a
startup speed disadvantage in the one-time parsing of the lines after
C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
handle multiple packages in a file.

B<AutoLoader> only reads code as it is requested, and in many cases
should be faster, but requires a mechanism like B<AutoSplit> be used to
create the individual files.  L<ExtUtils::MakeMaker> will invoke
B<AutoSplit> automatically if B<AutoLoader> is used in a module source
file.

=head1 CAVEATS

AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
old modules which use B<AutoLoader> should be changed to the new calling
style.  Typically this just means changing a require to a use, adding
the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
from C<@ISA>.

On systems with restrictions on file name length, the file corresponding
to a subroutine may have a shorter name that the routine itself.  This
can lead to conflicting file names.  The I<AutoSplit> package warns of
these potential conflicts when used to split a module.

AutoLoader may fail to find the autosplit files (or even find the wrong
ones) in cases where C<@INC> contains relative paths, B<and> the program
does C<chdir>.

=head1 SEE ALSO

L<SelfLoader> - an autoloader that doesn't use external files.

=cut
Commit	Line	Data
8990e307	1	package AutoLoader;
21c92a1d	2
17f410f9	3	use 5.005_64;
17f410f9	4	our(@EXPORT, @EXPORT_OK, $VERSION);
f06db76b	5
adaafad2	6	my $is_dosish;
ed79a026	7	my $is_epoc;
adaafad2	8	my $is_vms;
084592ab	9	my $is_macos;
adaafad2	10
1be0b951	11	BEGIN {
1be0b951	12	require Exporter;
e3d0cac0	13	@EXPORT = @EXPORT = ();
e3d0cac0	14	@EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
2986a63f	15	$is_dosish = $^O eq 'dos' \|\| $^O eq 'os2' \|\| $^O eq 'MSWin32' \|\| $^O eq 'NetWare';
ed79a026	16	$is_epoc = $^O eq 'epoc';
adaafad2	17	$is_vms = $^O eq 'VMS';
084592ab	18	$is_macos = $^O eq 'MacOS';
084592ab	19	$VERSION = '5.58';
1be0b951	20	}
f06db76b	21
8990e307	22	AUTOLOAD {
7d4fbd98	23	my $sub = $AUTOLOAD;
7d4fbd98	24	my $filename;
5a556d17	25	# Braces used to preserve $1 et al.
5a556d17	26	{
adaafad2	27	# Try to find the autoloaded file from the package-qualified
	28	# name of the sub. e.g., if the sub needed is
	29	# Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
	30	# something like '/usr/lib/perl5/Getopt/Long.pm', and the
	31	# autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
	32	#
	33	# However, if @INC is a relative path, this might not work. If,
	34	# for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
	35	# 'lib/Getopt/Long.pm', and we want to require
	36	# 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
	37	# In this case, we simple prepend the 'auto/' and let the
	38	# C<require> take care of the searching for us.
	39
7d4fbd98	40	my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
adaafad2	41	$pkg =~ s#::#/#g;
7d4fbd98	42	if (defined($filename = $INC{"$pkg.pm"})) {
084592ab	43	if ($is_macos) {
	44	$pkg =~ tr#/#:#;
	45	$filename =~ s#^(.*)$pkg\.pm\z#$1auto:$pkg:$func.al#s;
	46	} else {
	47	$filename =~ s#^(.*)$pkg\.pm\z#$1auto/$pkg/$func.al#s;
	48	}
adaafad2	49
	50	# if the file exists, then make sure that it is a
	51	# a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
	52	# or './lib/auto/foo/bar.al'. This avoids C<require> searching
	53	# (and failing) to find the 'lib/auto/foo/bar.al' because it
	54	# looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
	55
7d4fbd98	56	if (-r $filename) {
14a089c5	57	unless ($filename =~ m\|^/\|s) {
adaafad2	58	if ($is_dosish) {
14a089c5	59	unless ($filename =~ m{^([a-z]:)?[\\/]}is) {
2986a63f	60	if ($^O ne 'NetWare') {
	61	$filename = "./$filename";
	62	} else {
	63	$filename = "$filename";
	64	}
adaafad2	65	}
adaafad2	66	}
ed79a026	67	elsif ($is_epoc) {
	68	unless ($filename =~ m{^([a-z?]:)?[\\/]}is) {
	69	$filename = "./$filename";
	70	}
	71	}elsif ($is_vms) {
7d4fbd98	72	# XXX todo by VMSmiths
7d4fbd98	73	$filename = "./$filename";
adaafad2	74	}
084592ab	75	elsif (!$is_macos) {
7d4fbd98	76	$filename = "./$filename";
adaafad2	77	}
	78	}
	79	}
	80	else {
7d4fbd98	81	$filename = undef;
adaafad2	82	}
adaafad2	83	}
7d4fbd98	84	unless (defined $filename) {
adaafad2	85	# let C<require> do the searching
7d4fbd98	86	$filename = "auto/$sub.al";
7d4fbd98	87	$filename =~ s#::#/#g;
adaafad2	88	}
5a556d17	89	}
e14baed2	90	my $save = $@;
7d4fbd98	91	eval { local $SIG{__DIE__}; require $filename };
8990e307	92	if ($@) {
7d4fbd98	93	if (substr($sub,-9) eq '::DESTROY') {
7d4fbd98	94	*$sub = sub {};
e14baed2	95	} else {
	96	# The load might just have failed because the filename was too
	97	# long for some old SVR3 systems which treat long names as errors.
	98	# If we can succesfully truncate a long name then it's worth a go.
	99	# There is a slight risk that we could pick up the wrong file here
	100	# but autosplit should have warned about that when splitting.
7d4fbd98	101	if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
7d4fbd98	102	eval { local $SIG{__DIE__}; require $filename };
e14baed2	103	}
	104	if ($@){
	105	$@ =~ s/ at .*\n//;
fb73857a	106	my $error = $@;
	107	require Carp;
	108	Carp::croak($error);
e14baed2	109	}
a0d0e21e	110	}
8990e307	111	}
e14baed2	112	$@ = $save;
7d4fbd98	113	goto &$sub;
8990e307	114	}
1be0b951	115
c2960299	116	sub import {
1be0b951	117	my $pkg = shift;
	118	my $callpkg = caller;
	119
	120	#
	121	# Export symbols, but not by accident of inheritance.
	122	#
	123
e3d0cac0	124	if ($pkg eq 'AutoLoader') {
	125	local $Exporter::ExportLevel = 1;
	126	Exporter::import $pkg, @_;
	127	}
1be0b951	128
1be0b951	129	#
c2960299	130	# Try to find the autosplit index file. Eg., if the call package
	131	# is POSIX, then $INC{POSIX.pm} is something like
	132	# '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
	133	# '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
	134	#
	135	# However, if @INC is a relative path, this might not work. If,
	136	# for example, @INC = ('lib'), then
	137	# $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
	138	# 'auto/POSIX/autosplit.ix' (without the leading 'lib').
	139	#
1be0b951	140
1c1c7f20	141	(my $calldir = $callpkg) =~ s#::#/#g;
1be0b951	142	my $path = $INC{$calldir . '.pm'};
1be0b951	143	if (defined($path)) {
c2960299	144	# Try absolute path name.
1be0b951	145	$path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
c2960299	146	eval { require $path; };
	147	# If that failed, try relative path with normal @INC searching.
	148	if ($@) {
1be0b951	149	$path ="auto/$calldir/autosplit.ix";
c2960299	150	eval { require $path; };
c2960299	151	}
fb73857a	152	if ($@) {
	153	my $error = $@;
	154	require Carp;
	155	Carp::carp($error);
	156	}
f06db76b	157	}
f06db76b	158	}
8990e307	159
cb0cff20	160	sub unimport {
	161	my $callpkg = caller;
	162	eval "package $callpkg; sub AUTOLOAD;";
	163	}
	164
8990e307	165	1;
1be0b951	166
	167	__END__
	168
	169	=head1 NAME
	170
	171	AutoLoader - load subroutines only on demand
	172
	173	=head1 SYNOPSIS
	174
	175	package Foo;
	176	use AutoLoader 'AUTOLOAD'; # import the default AUTOLOAD subroutine
	177
	178	package Bar;
	179	use AutoLoader; # don't import AUTOLOAD, define our own
	180	sub AUTOLOAD {
	181	...
	182	$AutoLoader::AUTOLOAD = "...";
	183	goto &AutoLoader::AUTOLOAD;
	184	}
	185
	186	=head1 DESCRIPTION
	187
	188	The B<AutoLoader> module works with the B<AutoSplit> module and the
	189	C<__END__> token to defer the loading of some subroutines until they are
	190	used rather than loading them all at once.
	191
	192	To use B<AutoLoader>, the author of a module has to place the
	193	definitions of subroutines to be autoloaded after an C<__END__> token.
	194	(See L<perldata>.) The B<AutoSplit> module can then be run manually to
	195	extract the definitions into individual files F<auto/funcname.al>.
	196
	197	B<AutoLoader> implements an AUTOLOAD subroutine. When an undefined
	198	subroutine in is called in a client module of B<AutoLoader>,
	199	B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
	200	file with a name related to the location of the file from which the
	201	client module was read. As an example, if F<POSIX.pm> is located in
	202	F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
	203	subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
	204	the C<.al> file has the same name as the subroutine, sans package. If
	205	such a file exists, AUTOLOAD will read and evaluate it,
	206	thus (presumably) defining the needed subroutine. AUTOLOAD will then
	207	C<goto> the newly defined subroutine.
	208
f610777f	209	Once this process completes for a given function, it is defined, so
1be0b951	210	future calls to the subroutine will bypass the AUTOLOAD mechanism.
	211
	212	=head2 Subroutine Stubs
	213
	214	In order for object method lookup and/or prototype checking to operate
	215	correctly even when methods have not yet been defined it is necessary to
	216	"forward declare" each subroutine (as in C<sub NAME;>). See
	217	L<perlsub/"SYNOPSIS">. Such forward declaration creates "subroutine
	218	stubs", which are place holders with no code.
	219
	220	The AutoSplit and B<AutoLoader> modules automate the creation of forward
	221	declarations. The AutoSplit module creates an 'index' file containing
	222	forward declarations of all the AutoSplit subroutines. When the
	223	AutoLoader module is 'use'd it loads these declarations into its callers
	224	package.
	225
	226	Because of this mechanism it is important that B<AutoLoader> is always
	227	C<use>d and not C<require>d.
	228
	229	=head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
	230
	231	In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
	232	explicitly import it:
	233
	234	use AutoLoader 'AUTOLOAD';
	235
	236	=head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
	237
	238	Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
	239	They typically need to check for some special cases (such as constants)
	240	and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
	241
	242	Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
	243	Instead, they should define their own AUTOLOAD subroutines along these
	244	lines:
	245
	246	use AutoLoader;
fb73857a	247	use Carp;
1be0b951	248
1be0b951	249	sub AUTOLOAD {
7d4fbd98	250	my $sub = $AUTOLOAD;
7d4fbd98	251	(my $constname = $sub) =~ s/.*:://;
1be0b951	252	my $val = constant($constname, @_ ? $_[0] : 0);
1be0b951	253	if ($! != 0) {
265f5c4a	254	if ($! =~ /Invalid/ \|\| $!{EINVAL}) {
7d4fbd98	255	$AutoLoader::AUTOLOAD = $sub;
1be0b951	256	goto &AutoLoader::AUTOLOAD;
	257	}
	258	else {
	259	croak "Your vendor has not defined constant $constname";
	260	}
	261	}
7d4fbd98	262	*$sub = sub { $val }; # same as: eval "sub $sub { $val }";
7d4fbd98	263	goto &$sub;
1be0b951	264	}
	265
	266	If any module's own AUTOLOAD subroutine has no need to fallback to the
	267	AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
	268	subroutines), then that module should not use B<AutoLoader> at all.
	269
	270	=head2 Package Lexicals
	271
	272	Package lexicals declared with C<my> in the main block of a package
	273	using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
	274	the fact that the given scope ends at the C<__END__> marker. A module
	275	using such variables as package globals will not work properly under the
	276	B<AutoLoader>.
	277
	278	The C<vars> pragma (see L<perlmod/"vars">) may be used in such
	279	situations as an alternative to explicitly qualifying all globals with
	280	the package namespace. Variables pre-declared with this pragma will be
	281	visible to any autoloaded routines (but will not be invisible outside
	282	the package, unfortunately).
	283
cb0cff20	284	=head2 Not Using AutoLoader
	285
	286	You can stop using AutoLoader by simply
	287
	288	no AutoLoader;
	289
1be0b951	290	=head2 B<AutoLoader> vs. B<SelfLoader>
	291
	292	The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
	293	loading of subroutines.
	294
	295	B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
	296	While this avoids the use of a hierarchy of disk files and the
	297	associated open/close for each routine loaded, B<SelfLoader> suffers a
	298	startup speed disadvantage in the one-time parsing of the lines after
	299	C<__DATA__>, after which routines are cached. B<SelfLoader> can also
	300	handle multiple packages in a file.
	301
	302	B<AutoLoader> only reads code as it is requested, and in many cases
f610777f	303	should be faster, but requires a mechanism like B<AutoSplit> be used to
1be0b951	304	create the individual files. L<ExtUtils::MakeMaker> will invoke
	305	B<AutoSplit> automatically if B<AutoLoader> is used in a module source
	306	file.
	307
	308	=head1 CAVEATS
	309
	310	AutoLoaders prior to Perl 5.002 had a slightly different interface. Any
	311	old modules which use B<AutoLoader> should be changed to the new calling
	312	style. Typically this just means changing a require to a use, adding
	313	the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
	314	from C<@ISA>.
	315
	316	On systems with restrictions on file name length, the file corresponding
	317	to a subroutine may have a shorter name that the routine itself. This
	318	can lead to conflicting file names. The I<AutoSplit> package warns of
	319	these potential conflicts when used to split a module.
	320
adaafad2	321	AutoLoader may fail to find the autosplit files (or even find the wrong
	322	ones) in cases where C<@INC> contains relative paths, B<and> the program
	323	does C<chdir>.
	324
1be0b951	325	=head1 SEE ALSO
	326
	327	L<SelfLoader> - an autoloader that doesn't use external files.
	328
	329	=cut