Custom HTML elements for blog authors

[scpubgit/App-SCS.git] / lib / App / SCS / Plugin / Core / PagePlugin / PageData.pm

package App::SCS::Plugin::Core::PagePlugin::PageData;

use Moo;

with 'App::SCS::Role::PagePlugin';

has static_dir => (is => 'ro', required => 1);

sub filter_content_zoom {
  my ($self, $zoom) = @_;

  my $page = $self->page;
  my $static_dir = $self->static_dir;

  $zoom->select('.page.title')->replace_content($page->title)
       ->select('.page.subtitle')->${\sub {
           $page->subtitle
             ? $_[0]->replace_content($page->subtitle)
             : $_[0]->replace('')
         }}
       ->select('.page.published_at')->${\sub {
           $page->published_at
           ? $_[0]->replace_content($page->published_at)
           : $_[0]->replace('')
         }}
       ->select('meta[name=description]')
         ->set_attribute(content => $page->description)
       ->select('meta[name=keywords]')
         ->set_attribute(content => $page->keywords)
       ->select('meta[name=created]')
         ->set_attribute(content => $page->created)
       ->select('link[data-cur-page-css]')->${\sub {
           my $path = '';
           my $replace = '';
           my @parts = split /\//, $page->path;

           foreach my $part (@parts) {
               next unless $part;

               $path .= "/" . $part;

               if (-f $static_dir . "/page-css/$path.css") {
                   $replace .= "<link href='/static/page-css/$path.css' rel='stylesheet' type='text/css' />";
               }
           }

           $_[0]->replace(HTML::Zoom->from_html($replace));
         }}
       ->select('script[data-cur-page-js]')->${\sub {
           my $path = '';
           my $replace = '';
           my @parts = split /\//, $page->path;

           foreach my $part (@parts) {
               next unless $part;

               $path .= "/" . $part;

               if (-f $static_dir . "/page-js/$path.js") {
                   $replace .= "<script src='/static/page-js/$path.js' type='text/javascript'></script>";
               }
           }

           $_[0]->replace(HTML::Zoom->from_html($replace));
         }}
       ->select('div[data-custom-blog-elements]')->${\sub {
           #blog/author(/post)

           return $_[0]->replace('') if $page->path !~ qr#^/blog/([^/]+)/+#;

           my $author = $1;
           my $author_templ = $static_dir . "/author-html/$author.html";

           if (-f $author_templ) {
               $_[0]->replace(HTML::Zoom->from_file($author_templ));
           } else {
               $_[0]->replace('');
           }
         }}
}

1;