initial import of App::SCS code

[scpubgit/App-SCS.git] / lib / App / SCS / Page.pm

package App::SCS::Page;

use IO::All;
use Time::Local qw(timelocal);
use Data::Pond qw(pond_read_datum pond_write_datum);
use List::Util qw(reduce);
use Moo;

with 'App::SCS::Role::PageChildren';

has $_ => (is => 'ro') for qw(
  title subtitle description keywords plugins html created path
);

has plugin_config => (is => 'lazy');

sub _build_plugin_config {
  my ($self) = @_;
  $self->plugins
    ? pond_read_datum('[ '.$self->plugins.' ]')
    : []
}

sub has_plugin_config { exists $_[0]->plugin_config->{$_[1]} }

sub with_plugin_config {
  my ($self, $with_name, $with_config) = @_;
  my @orig = @{$self->plugin_config};
  my @new;
  while (my ($name, $config) = splice @orig, 0, 2) {
    push @new, (
      $name eq $with_name
        ? ($name, { %$config, %$with_config })
        : ($name, $config)
    );
  }
  return $self->with(plugins => pond_write_datum(\@new));
}

has _page_plugins => (is => 'lazy');

sub _build__page_plugins {
  my ($self) = @_;
  my $plugin_config = $self->plugin_config;
  my ($plugin_map, $defaults) = @{$self->_page_set}{qw(plugin_map defaults)};

  my @spec = (@$defaults, @$plugin_config);
  my @plugins;
  while (my ($name, $config) = splice @spec, 0, 2) {
    my $info = $plugin_map->{$name};
    push @plugins,
      use_module($info->{class})->new(
        %{$info->{config}||{}}, %$config, page => $self
      );
  }
  return \@plugins;
}

sub published_at {
  $_[0]->created
    ? scalar localtime timelocal
        map +(@{$_}[0..3], $_->[4]-1, $_->[5]-1900),
          [ reverse split '\D+', $_[0]->created ]
    : ''
}

has "_$_" => (is => 'ro', init_arg => $_) for qw(page_set);

sub _page_set_class { ref($_[0]->_page_set) }
sub _top_dir { $_[0]->_page_set->top_dir }
sub _my_path { io->dir($_[0]->_top_dir)->catdir($_[0]->path) }

sub to_app {
  my ($self) = @_;
  return sub { $self->to_psgi_response(@_) };
}

sub to_psgi_response {
  my ($self, $env) = @_;

  if (my $cb = $env->{'App::SCS::Command::Generate.extra_pages'}) {
    $cb->($_->extra_pages) for @{$self->page_plugins};
  }

  $self->_psgi_response;
}

has _psgi_response => (is => 'lazy');

sub _build__psgi_response {
  my ($self) = @_;

  my @plugins = @{$self->page_plugins};

  my $html_zoom = reduce {
    $b->filter_html_zoom($a)
  } HTML::Zoom->from_html($self->html), @plugins;

  my $content_zoom = reduce {
    $b->filter_content_zoom($a)
  } $html_zoom, @plugins;

  my $psgi_res = [
    200, [ 'Content-type' => 'text/html' ], $content_zoom->to_fh
  ];

  return reduce {
    $b->filter_psgi_response($a)
  } $psgi_res, @plugins;
}

no Moo;

sub with {
  my $self = shift;
  return ref($self)->new(%$self, @_);
}

1;