Pod::Html should not convert "foo" in `foo''

[p5sagit/p5-mst-13.2.git] / ext / Digest / SHA / bin / shasum

#!perl -w

	# shasum: filter for computing SHA digests (analogous to md5sum)
	#
	# Copyright (C) 2003-2006 Mark Shelor, All Rights Reserved
	#
	# Version: 5.37
	# Mon May  8 04:30:09 MST 2006

=head1 NAME

shasum - Print or Check SHA Checksums

=head1 SYNOPSIS

 Usage: shasum [OPTION] [FILE]...
    or: shasum [OPTION] --check [FILE]
 Print or check SHA checksums.
 With no FILE, or when FILE is -, read standard input.

  -a, --algorithm    1 (default), 224, 256, 384, 512
  -b, --binary       read files in binary mode (default on DOS/Windows)
  -c, --check        check SHA sums against given list
  -p, --portable     read files in portable mode
                         produces same digest on Windows/Unix/MacOS
  -t, --text         read files in text mode (default)

 The following two options are useful only when verifying checksums:

  -s, --status       don't output anything, status code shows success
  -w, --warn         warn about improperly formatted SHA checksum lines

  -h, --help         display this help and exit
  -v, --version      output version information and exit

 The sums are computed as described in FIPS PUB 180-2.  When checking,
 the input should be a former output of this program.  The default mode
 is to print a line with checksum, a character indicating type (`*'
 for binary, `?' for portable, ` ' for text), and name for each FILE.

=head1 AUTHOR

Copyright (c) 2003-2006 Mark Shelor <mshelor@cpan.org>.

=head1 SEE ALSO

shasum is implemented using the Perl module L<Digest::SHA> or
L<Digest::SHA::PurePerl>.

=cut

use strict;
use Getopt::Long;

my $VERSION = "5.37";


	# Try to use Digest::SHA, since it's faster.  If not installed,
	# use Digest::SHA::PurePerl instead.

my $MOD_PREFER = "Digest::SHA";
my $MOD_SECOND = "Digest::SHA::PurePerl";

my $module = $MOD_PREFER;
eval "require $module";
if ($@) {
	$module = $MOD_SECOND;
	eval "require $module";
	die "Unable to find $MOD_PREFER or $MOD_SECOND\n" if $@;
}


	# Usage statement adapted from Ulrich Drepper's md5sum.
	# Include an "-a" option for algorithm selection,
	# and a "-p" option for portable digest computation.

sub usage {
	my($err, $msg) = @_;

	$msg = "" unless defined $msg;
	if ($err) {
		print STDERR "$msg", "Type shasum -h for help\n";
		exit($err);
	}
	print STDOUT <<'END_OF_USAGE';
Usage: shasum [OPTION] [FILE]...
   or: shasum [OPTION] --check [FILE]
Print or check SHA checksums.
With no FILE, or when FILE is -, read standard input.

  -a, --algorithm    1 (default), 224, 256, 384, 512
  -b, --binary       read files in binary mode (default on DOS/Windows)
  -c, --check        check SHA sums against given list
  -p, --portable     read files in portable mode
                         produces same digest on Windows/Unix/MacOS
  -t, --text         read files in text mode (default)

The following two options are useful only when verifying checksums:
  -s, --status       don't output anything, status code shows success
  -w, --warn         warn about improperly formatted SHA checksum lines

  -h, --help         display this help and exit
  -v, --version      output version information and exit

The sums are computed as described in FIPS PUB 180-2.  When checking, the
input should be a former output of this program.  The default mode is to
print a line with checksum, a character indicating type (`*' for binary,
`?' for portable, ` ' for text), and name for each FILE.

Report bugs to <mshelor@cpan.org>.
END_OF_USAGE
	exit($err);
}


	# Collect options from command line

my ($alg, $binary, $check, $text, $status, $warn, $help, $version);
my ($portable);

Getopt::Long::Configure ("bundling");
GetOptions(
	'b|binary' => \$binary, 'c|check' => \$check,
	't|text' => \$text, 'a|algorithm=i' => \$alg,
	's|status' => \$status, 'w|warn' => \$warn,
	'h|help' => \$help, 'v|version' => \$version,
	'p|portable' => \$portable
) or usage(1, "");


	# Deal with help requests and incorrect uses

usage(0)
	if $help;
usage(1, "ambiguous file mode\n")
	if scalar(grep { defined $_ } ($binary, $portable, $text)) > 1;
usage(1, "warn option used only when verifying checksums\n")
	if $warn && !$check;
usage(1, "status option used only when verifying checksums\n")
	if $status && !$check;


	# Default to SHA-1 unless overriden by command line option

$alg = 1 unless $alg;
grep { $_ == $alg } (1, 224, 256, 384, 512)
	or usage(1, "unrecognized algorithm\n");


	# Display version information if requested

if ($version) {
	print "$VERSION\n";
	exit(0);
}


	# Try to figure out if the OS is DOS-like.  If it is,
	# default to binary mode when reading files, unless
	# explicitly overriden by command line "text" or
	# "portable" options.

my $isDOSish = ($^O =~ /^(MSWin\d\d|os2|dos|mint|cygwin)$/);
if ($isDOSish) { $binary = 1 unless $text || $portable }

my $mode = $binary ? '*' : ($portable ? '?' : ' ');


	# Read from STDIN (-) if no files listed on command line

@ARGV = ("-") unless @ARGV;


	# sumfile($file): computes SHA digest of $file

sub sumfile {
	my $file = shift;

	local *F;
	return unless open(F, "<$file");
	binmode(F) if $binary || $portable;

	my $digest = $module->new($alg);
	if ($portable && -T $file) {
		local $/ = \4096;
		while (defined (my $rec = <F>)) {
			while (substr($rec, -1) eq "\015") {
				defined (my $extra = <F>) or last;
				$rec .= $extra;
			}
			$rec =~ s/\015+\012/\012/g;
			$rec =~ s/\015/\012/g;
			$digest->add($rec);
		}
	}
	else { $digest->addfile(*F) }
	close(F);

	$digest->hexdigest;
}


	# %len2alg: maps hex digest length to SHA algorithm

my %len2alg = (40 => 1, 56 => 224, 64 => 256, 96 => 384, 128 => 512);


	# Verify checksums if requested

if ($check) {
	my $checkfile = shift(@ARGV);
	my $err = 0;
	my ($fh, $sum, $fname, $rsp);

	die "shasum: $checkfile: No such file or directory\n"
		unless open($fh, "<$checkfile");
	while (<$fh>) {
		s/\s+$//;
		($sum, $mode, $fname) = /^(\S+) (.)(.*)$/;
		unless (-e $fname) {
			warn "shasum: $fname: No such file or directory\n";
			next;
		}
		($binary, $portable, $text) =
			map { $_ eq $mode } ('*', '?', ' ');
		unless ($alg = $len2alg{length($sum)}) {
			warn("shasum: $checkfile: $.: improperly " .
				"formatted SHA checksum line\n") if $warn;
			next;
		}
		$rsp = "$fname: ";
		unless (my $digest = sumfile($fname)) {
			$rsp .= "FAILED open or read\n";
			$err = 1;
		}
		else {
			if (lc($sum) eq $digest) { $rsp .= "OK\n" }
			else { $rsp .= "FAILED\n"; $err = 1 }
		}
		print $rsp unless $status;
	}
	close($fh);
	exit($err);
}


	# Compute and display SHA checksums of requested files

for my $arg (@ARGV) {
	if (-d $arg) {
		print STDERR "shasum: $arg: Is a directory\n";
		next;
	}
	next unless my $digest = sumfile($arg);
	print "$digest $mode", "$arg\n";
}