[p5sagit/p5-mst-13.2.git] / ext / B / t / concise-xs.t

#!./perl

# 2 purpose file: 1-test 2-demonstrate (via args, -v -a options)

=head1 SYNOPSIS

To verify that B::Concise properly reports whether functions are XS,
perl, or optimized constant subs, we test against a few core packages
which have a stable API, and which have functions of all 3 types.

=head1 WHAT IS TESTED

5 core packages are tested; Digest::MD5, B, B::Deparse, Data::Dumper,
and POSIX.  These have a mix of the 3 expected implementation types;
perl, XS, and constant (optimized constant subs).

%$testpkgs specifies what packages are tested; each package is loaded,
and the stash is scanned for the function-names in that package.

Each value in %$testpkgs is a hash-of-lists (HoL) whose keys are
implementation-types and values are lists of function-names of that type.

To keep these HoLs smaller and more managable, they may carry an
additional 'dflt' => $impl_Type, which means that unnamed functions
are expected to be of that default implementation type.  Those unnamed
functions are known from the scan of the package stash.

=head1 HOW THEY'RE TESTED

Each function is 'rendered' by B::Concise, and result is matched
against regexs for each possible implementation-type.  For some
packages, some functions may be unimplemented on some platforms.

To slay this maintenance dragon, the regexs used in like() match
against renderings which indicate that there is no implementation.

If a function is implemented differently on different platforms, the
test for that function will fail on one of those platforms.  These
specific functions can be skipped by a 'skip' => [ @list ] to the HoL
mentioned previously.  See usage for skip in B's HoL, which avoids
testing a function which doesnt exist on non-threaded builds.

=head1 OPTIONS AND ARGUMENTS

C<-v> and C<-V> trigger 2 levels of verbosity.

C<-a> uses Module::CoreList to run all core packages through the test, which
gives some interesting results.

C<-c> causes the expected XS/non-XS results to be marked with
corrections, which are then reported at program END, in a form that's
readily cut-and-pastable into this file.


C<< -r <file> >> reads a file, as written by C<-c>, and adjusts the expected
results accordingly.  The file is 'required', so @INC settings apply.

If module-names are given as args, those packages are run through the
test harness; this is handy for collecting further items to test, and
may be useful otherwise (ie just to see).

=head1 EXAMPLES

=over 4

=item ./perl -Ilib -wS ext/B/t/concise-xs.t -c Storable

Tests Storable.pm for XS/non-XS routines, writes findings (along with
test results) to stdout.  You could edit results to produce a test
file, as in next example

=item ./perl -Ilib -wS ext/B/t/concise-xs.t -r ./storable

Loads file, and uses it to set expectations, and run tests

=item ./perl -Ilib -wS ext/B/t/concise-xs.t -avc > ../foo-avc 2> ../foo-avc2

Gets module list from Module::Corelist, and runs them all through the
test.  Since -c is used, this generates corrections, which are saved
in a file, which is edited down to produce ../all-xs

=item ./perl -Ilib -wS ext/B/t/concise-xs.t -cr ../all-xs > ../foo 2> ../foo2

This runs the tests specified in the file created in previous example.
-c is used again, and stdout verifies that all the expected results
given by -r ../all-xs are now seen.

Looking at ../foo2, you'll see 34 occurrences of the following error:

# err: Can't use an undefined value as a SCALAR reference at
# lib/B/Concise.pm line 634, <DATA> line 1.

=back

=cut

BEGIN {
    if ($ENV{PERL_CORE}) {
	chdir('t') if -d 't';
	@INC = ('.', '../lib');
    } else {
	unshift @INC, 't';
	push @INC, "../../t";
    }
    require Config;
    if (($Config::Config{'extensions'} !~ /\bB\b/) ){
        print "1..0 # Skip -- Perl configured without B module\n";
        exit 0;
    }
    unless ($Config::Config{useperlio}) {
        print "1..0 # Skip -- Perl configured without perlio\n";
        exit 0;
    }
}

use Getopt::Std;
use Carp;
use Test::More tests => ( # per-pkg tests (function ct + require_ok)
			  40 + 16	# Data::Dumper, Digest::MD5
			  + 517 + 276	# B::Deparse, B
			  + 595 + 190	# POSIX, IO::Socket
			  - 20);		# fudge

require_ok("B::Concise");

my %matchers = 
    ( constant	=> qr{ (?-x: is a constant sub, optimized to a \w+)
		      |(?-x: exists in stash, but has no START) }x,
      XS	=> qr/ is XS code/,
      perl	=> qr/ (next|db)state/,
      noSTART	=> qr/ exists in stash, but has no START/,
);

my $testpkgs = {
    # packages to test, with expected types for named funcs

    Digest::MD5 => { perl => [qw/ import /],
		     dflt => 'XS' },

    Data::Dumper => { XS => [qw/ bootstrap Dumpxs /],
		      dflt => 'perl' },
    B => { 
	dflt => 'constant',		# all but 47/297
	skip => [ 'regex_padav' ],	# threaded only
	perl => [qw(
		    walksymtable walkoptree_slow walkoptree_exec
		    timing_info savesym peekop parents objsym debug
		    compile_stats clearsym class
		    )],
	XS => [qw(
		  warnhook walkoptree_debug walkoptree threadsv_names
		  svref_2object sv_yes sv_undef sv_no save_BEGINs
		  regex_padav ppname perlstring opnumber minus_c
		  main_start main_root main_cv init_av inc_gv hash
		  formfeed end_av dowarn diehook defstash curstash
		  cstring comppadlist check_av cchar cast_I32 bootstrap
		  begin_av amagic_generation sub_generation address
		  ), $] > 5.009 ? ('unitcheck_av') : ()],
    },

    B::Deparse => { dflt => 'perl',	# 235 functions

	XS => [qw( svref_2object perlstring opnumber main_start
		   main_root main_cv )],

	constant => [qw/ ASSIGN CVf_LOCKED CVf_LVALUE
		     CVf_METHOD LIST_CONTEXT OP_CONST OP_LIST OP_RV2SV
		     OP_STRINGIFY OPf_KIDS OPf_MOD OPf_REF OPf_SPECIAL
		     OPf_STACKED OPf_WANT OPf_WANT_LIST OPf_WANT_SCALAR
		     OPf_WANT_VOID OPpCONST_ARYBASE OPpCONST_BARE
		     OPpENTERSUB_AMPER OPpEXISTS_SUB OPpITER_REVERSED
		     OPpLVAL_INTRO OPpOUR_INTRO OPpSLICE OPpSORT_DESCEND
		     OPpSORT_INPLACE OPpSORT_INTEGER OPpSORT_NUMERIC
		     OPpSORT_REVERSE OPpTARGET_MY OPpTRANS_COMPLEMENT
		     OPpTRANS_DELETE OPpTRANS_SQUASH PMf_CONTINUE
		     PMf_EVAL PMf_EXTENDED PMf_FOLD PMf_GLOBAL PMf_KEEP
		     PMf_MULTILINE PMf_ONCE PMf_SINGLELINE
		     POSTFIX SVf_FAKE SVf_IOK SVf_NOK SVf_POK SVf_ROK
		     SVpad_OUR SVs_RMG SVs_SMG SWAP_CHILDREN OPpPAD_STATE
		     /, $] > 5.009 ? ('RXf_SKIPWHITE') : ('PMf_SKIPWHITE')],
		 },

    POSIX => { dflt => 'constant',			# all but 252/589
	       skip => [qw/ _POSIX_JOB_CONTROL /],	# platform varying
	       perl => [qw/ import croak AUTOLOAD /],

	       XS => [qw/ write wctomb wcstombs uname tzset tzname
		      ttyname tmpnam times tcsetpgrp tcsendbreak
		      tcgetpgrp tcflush tcflow tcdrain tanh tan
		      sysconf strxfrm strtoul strtol strtod
		      strftime strcoll sinh sigsuspend sigprocmask
		      sigpending sigaction setuid setsid setpgid
		      setlocale setgid read pipe pause pathconf
		      open nice modf mktime mkfifo mbtowc mbstowcs
		      mblen lseek log10 localeconv ldexp lchown
		      isxdigit isupper isspace ispunct isprint
		      islower isgraph isdigit iscntrl isalpha
		      isalnum int_macro_int getcwd frexp fpathconf
		      fmod floor dup2 dup difftime cuserid ctime
		      ctermid cosh constant close clock ceil
		      bootstrap atan asin asctime acos access abort
		      _exit
		      /],
	       },

    IO::Socket => { dflt => 'constant',		# 157/190

		    perl => [qw/ timeout socktype sockopt sockname
			     socketpair socket sockdomain sockaddr_un
			     sockaddr_in shutdown setsockopt send
			     register_domain recv protocol peername
			     new listen import getsockopt croak
			     connected connect configure confess close
			     carp bind atmark accept
			     /, $] > 5.009 ? ('blocking') : () ],

		    XS => [qw/ unpack_sockaddr_un unpack_sockaddr_in
			   sockatmark sockaddr_family pack_sockaddr_un
			   pack_sockaddr_in inet_ntoa inet_aton
			   /],
		},
};

############

B::Concise::compile('-nobanner');	# set a silent default
getopts('vaVcr:', \my %opts) or
    die <<EODIE;

usage: PERL_CORE=1 ./perl ext/B/t/concise-xs.t [-av] [module-list]
    tests ability to discern XS funcs using Digest::MD5 package
    -v	: runs verbosely
    -V	: more verbosity
    -a	: runs all modules in CoreList
    -c  : writes test corrections as a Data::Dumper expression
    -r <file>	: reads file of tests, as written by -c
    <args>	: additional modules are loaded and tested
    	(will report failures, since no XS funcs are known apriori)

EODIE
    ;

if (%opts) {
    require Data::Dumper;
    Data::Dumper->import('Dumper');
    $Data::Dumper::Sortkeys = 1;
}
my @argpkgs = @ARGV;
my %report;

if ($opts{r}) {
    my $refpkgs = require "$opts{r}";
    $testpkgs->{$_} = $refpkgs->{$_} foreach keys %$refpkgs;
}

unless ($opts{a}) {
    unless (@argpkgs) {
	foreach $pkg (sort keys %$testpkgs) {
	    test_pkg($pkg, $testpkgs->{$pkg});
	}
    } else {
	foreach $pkg (@argpkgs) {
	    test_pkg($pkg, $testpkgs->{$pkg});
	}
    }
} else {
    corecheck();
}
############

sub test_pkg {
    my ($pkg, $fntypes) = @_;
    require_ok($pkg);

    # build %stash: keys are func-names, vals filled in below
    my (%stash) = map
	( ($_ => 0)
	  => ( grep exists &{"$pkg\::$_"}	# grab CODE symbols
	       => grep !/__ANON__/		# but not anon subs
	       => keys %{$pkg.'::'}		# from symbol table
	       ));

    for my $type (keys %matchers) {
	foreach my $fn (@{$fntypes->{$type}}) {
	    carp "$fn can only be one of $type, $stash{$fn}\n"
		if $stash{$fn};
	    $stash{$fn} = $type;
	}
    }
    # set default type for un-named functions
    my $dflt = $fntypes->{dflt} || 'perl';
    for my $k (keys %stash) {
	$stash{$k} = $dflt unless $stash{$k};
    }
    $stash{$_} = 'skip' foreach @{$fntypes->{skip}};

    if ($opts{v}) {
	diag("fntypes: " => Dumper($fntypes));
	diag("$pkg stash: " => Dumper(\%stash));
    }
    foreach my $fn (reverse sort keys %stash) {
	next if $stash{$fn} eq 'skip';
	my $res = checkXS("${pkg}::$fn", $stash{$fn});
	if ($res ne '1') {
	    push @{$report{$pkg}{$res}}, $fn;
	}
    }
}

sub checkXS {
    my ($func_name, $want) = @_;

    croak "unknown type $want: $func_name\n"
	unless defined $matchers{$want};

    my ($buf, $err) = render($func_name);
    my $res = like($buf, $matchers{$want}, "$want sub:\t $func_name");

    unless ($res) {
	# test failed. return type that would give success
	for my $m (keys %matchers) {
	    return $m if $buf =~ $matchers{$m};
	}
    }
    $res;
}

sub render {
    my ($func_name) = @_;

    B::Concise::reset_sequence();
    B::Concise::walk_output(\my $buf);

    my $walker = B::Concise::compile($func_name);
    eval { $walker->() };
    diag("err: $@ $buf") if $@;
    diag("verbose: $buf") if $opts{V};

    return ($buf, $@);
}

sub corecheck {
    eval { require Module::CoreList };
    if ($@) {
	warn "Module::CoreList not available on $]\n";
	return;
    }
    my $mods = $Module::CoreList::version{'5.009002'};
    $mods = [ sort keys %$mods ];
    print Dumper($mods);

    foreach my $pkgnm (@$mods) {
	test_pkg($pkgnm);
    }
}

END {
    if ($opts{c}) {
	$Data::Dumper::Indent = 1;
	print "Corrections: ", Dumper(\%report);

	foreach my $pkg (sort keys %report) {
	    for my $type (keys %matchers) {
		print "$pkg: $type: @{$report{$pkg}{$type}}\n"
		    if @{$report{$pkg}{$type}};
	    }
	}
    }
}

__END__
Commit	Line	Data
c0939cee	1	#!./perl
	2
	3	# 2 purpose file: 1-test 2-demonstrate (via args, -v -a options)
	4
5b493bdf	5	=head1 SYNOPSIS
c0939cee	6
d51cf0c9	7	To verify that B::Concise properly reports whether functions are XS,
	8	perl, or optimized constant subs, we test against a few core packages
	9	which have a stable API, and which have functions of all 3 types.
	10
	11	=head1 WHAT IS TESTED
	12
	13	5 core packages are tested; Digest::MD5, B, B::Deparse, Data::Dumper,
	14	and POSIX. These have a mix of the 3 expected implementation types;
	15	perl, XS, and constant (optimized constant subs).
	16
	17	%$testpkgs specifies what packages are tested; each package is loaded,
	18	and the stash is scanned for the function-names in that package.
	19
	20	Each value in %$testpkgs is a hash-of-lists (HoL) whose keys are
	21	implementation-types and values are lists of function-names of that type.
	22
	23	To keep these HoLs smaller and more managable, they may carry an
	24	additional 'dflt' => $impl_Type, which means that unnamed functions
	25	are expected to be of that default implementation type. Those unnamed
	26	functions are known from the scan of the package stash.
	27
	28	=head1 HOW THEY'RE TESTED
	29
	30	Each function is 'rendered' by B::Concise, and result is matched
	31	against regexs for each possible implementation-type. For some
	32	packages, some functions may be unimplemented on some platforms.
	33
	34	To slay this maintenance dragon, the regexs used in like() match
	35	against renderings which indicate that there is no implementation.
	36
	37	If a function is implemented differently on different platforms, the
	38	test for that function will fail on one of those platforms. These
	39	specific functions can be skipped by a 'skip' => [ @list ] to the HoL
	40	mentioned previously. See usage for skip in B's HoL, which avoids
	41	testing a function which doesnt exist on non-threaded builds.
c0939cee	42
5b493bdf	43	=head1 OPTIONS AND ARGUMENTS
	44
	45	C<-v> and C<-V> trigger 2 levels of verbosity.
	46
	47	C<-a> uses Module::CoreList to run all core packages through the test, which
	48	gives some interesting results.
	49
	50	C<-c> causes the expected XS/non-XS results to be marked with
d51cf0c9	51	corrections, which are then reported at program END, in a form that's
	52	readily cut-and-pastable into this file.
	53
5b493bdf	54
	55	C<< -r <file> >> reads a file, as written by C<-c>, and adjusts the expected
	56	results accordingly. The file is 'required', so @INC settings apply.
	57
c0939cee	58	If module-names are given as args, those packages are run through the
	59	test harness; this is handy for collecting further items to test, and
	60	may be useful otherwise (ie just to see).
	61
5b493bdf	62	=head1 EXAMPLES
5b493bdf	63
5b493bdf	64	=over 4
	65
	66	=item ./perl -Ilib -wS ext/B/t/concise-xs.t -c Storable
	67
	68	Tests Storable.pm for XS/non-XS routines, writes findings (along with
	69	test results) to stdout. You could edit results to produce a test
	70	file, as in next example
	71
	72	=item ./perl -Ilib -wS ext/B/t/concise-xs.t -r ./storable
c0939cee	73
5b493bdf	74	Loads file, and uses it to set expectations, and run tests
	75
	76	=item ./perl -Ilib -wS ext/B/t/concise-xs.t -avc > ../foo-avc 2> ../foo-avc2
	77
	78	Gets module list from Module::Corelist, and runs them all through the
	79	test. Since -c is used, this generates corrections, which are saved
	80	in a file, which is edited down to produce ../all-xs
	81
	82	=item ./perl -Ilib -wS ext/B/t/concise-xs.t -cr ../all-xs > ../foo 2> ../foo2
	83
	84	This runs the tests specified in the file created in previous example.
	85	-c is used again, and stdout verifies that all the expected results
	86	given by -r ../all-xs are now seen.
	87
	88	Looking at ../foo2, you'll see 34 occurrences of the following error:
	89
	90	# err: Can't use an undefined value as a SCALAR reference at
	91	# lib/B/Concise.pm line 634, <DATA> line 1.
	92
	93	=back
c0939cee	94
	95	=cut
	96
	97	BEGIN {
	98	if ($ENV{PERL_CORE}) {
	99	chdir('t') if -d 't';
	100	@INC = ('.', '../lib');
	101	} else {
	102	unshift @INC, 't';
	103	push @INC, "../../t";
	104	}
	105	require Config;
	106	if (($Config::Config{'extensions'} !~ /\bB\b/) ){
	107	print "1..0 # Skip -- Perl configured without B module\n";
	108	exit 0;
	109	}
28380c63	110	unless ($Config::Config{useperlio}) {
	111	print "1..0 # Skip -- Perl configured without perlio\n";
	112	exit 0;
	113	}
c0939cee	114	}
	115
	116	use Getopt::Std;
	117	use Carp;
2018a5c3	118	use Test::More tests => ( # per-pkg tests (function ct + require_ok)
2018a5c3	119	40 + 16 # Data::Dumper, Digest::MD5
192b9cd1	120	+ 517 + 276 # B::Deparse, B
fba16c4d	121	+ 595 + 190 # POSIX, IO::Socket
192b9cd1	122	- 20); # fudge
c0939cee	123
	124	require_ok("B::Concise");
	125
d51cf0c9	126	my %matchers =
	127	( constant => qr{ (?-x: is a constant sub, optimized to a \w+)
	128	\|(?-x: exists in stash, but has no START) }x,
2018a5c3	129	XS => qr/ is XS code/,
	130	perl => qr/ (next\|db)state/,
	131	noSTART => qr/ exists in stash, but has no START/,
d51cf0c9	132	);
5b493bdf	133
d51cf0c9	134	my $testpkgs = {
	135	# packages to test, with expected types for named funcs
	136
	137	Digest::MD5 => { perl => [qw/ import /],
	138	dflt => 'XS' },
	139
	140	Data::Dumper => { XS => [qw/ bootstrap Dumpxs /],
	141	dflt => 'perl' },
	142	B => {
c737faaf	143	dflt => 'constant', # all but 47/297
d51cf0c9	144	skip => [ 'regex_padav' ], # threaded only
	145	perl => [qw(
	146	walksymtable walkoptree_slow walkoptree_exec
	147	timing_info savesym peekop parents objsym debug
	148	compile_stats clearsym class
	149	)],
	150	XS => [qw(
	151	warnhook walkoptree_debug walkoptree threadsv_names
	152	svref_2object sv_yes sv_undef sv_no save_BEGINs
	153	regex_padav ppname perlstring opnumber minus_c
	154	main_start main_root main_cv init_av inc_gv hash
	155	formfeed end_av dowarn diehook defstash curstash
	156	cstring comppadlist check_av cchar cast_I32 bootstrap
5ce57cc0	157	begin_av amagic_generation sub_generation address
e412117e	158	), $] > 5.009 ? ('unitcheck_av') : ()],
d51cf0c9	159	},
	160
	161	B::Deparse => { dflt => 'perl', # 235 functions
	162
	163	XS => [qw( svref_2object perlstring opnumber main_start
	164	main_root main_cv )],
	165
584420f0	166	constant => [qw/ ASSIGN CVf_LOCKED CVf_LVALUE
d51cf0c9	167	CVf_METHOD LIST_CONTEXT OP_CONST OP_LIST OP_RV2SV
	168	OP_STRINGIFY OPf_KIDS OPf_MOD OPf_REF OPf_SPECIAL
	169	OPf_STACKED OPf_WANT OPf_WANT_LIST OPf_WANT_SCALAR
	170	OPf_WANT_VOID OPpCONST_ARYBASE OPpCONST_BARE
	171	OPpENTERSUB_AMPER OPpEXISTS_SUB OPpITER_REVERSED
	172	OPpLVAL_INTRO OPpOUR_INTRO OPpSLICE OPpSORT_DESCEND
	173	OPpSORT_INPLACE OPpSORT_INTEGER OPpSORT_NUMERIC
	174	OPpSORT_REVERSE OPpTARGET_MY OPpTRANS_COMPLEMENT
	175	OPpTRANS_DELETE OPpTRANS_SQUASH PMf_CONTINUE
	176	PMf_EVAL PMf_EXTENDED PMf_FOLD PMf_GLOBAL PMf_KEEP
7c1f70cb	177	PMf_MULTILINE PMf_ONCE PMf_SINGLELINE
d51cf0c9	178	POSTFIX SVf_FAKE SVf_IOK SVf_NOK SVf_POK SVf_ROK
d449ddce	179	SVpad_OUR SVs_RMG SVs_SMG SWAP_CHILDREN OPpPAD_STATE
7c1f70cb	180	/, $] > 5.009 ? ('RXf_SKIPWHITE') : ('PMf_SKIPWHITE')],
d51cf0c9	181	},
d51cf0c9	182
f9f861ec	183	POSIX => { dflt => 'constant', # all but 252/589
f9f861ec	184	skip => [qw/ _POSIX_JOB_CONTROL /], # platform varying
d51cf0c9	185	perl => [qw/ import croak AUTOLOAD /],
	186
	187	XS => [qw/ write wctomb wcstombs uname tzset tzname
	188	ttyname tmpnam times tcsetpgrp tcsendbreak
	189	tcgetpgrp tcflush tcflow tcdrain tanh tan
	190	sysconf strxfrm strtoul strtol strtod
	191	strftime strcoll sinh sigsuspend sigprocmask
	192	sigpending sigaction setuid setsid setpgid
	193	setlocale setgid read pipe pause pathconf
	194	open nice modf mktime mkfifo mbtowc mbstowcs
	195	mblen lseek log10 localeconv ldexp lchown
	196	isxdigit isupper isspace ispunct isprint
	197	islower isgraph isdigit iscntrl isalpha
	198	isalnum int_macro_int getcwd frexp fpathconf
	199	fmod floor dup2 dup difftime cuserid ctime
	200	ctermid cosh constant close clock ceil
	201	bootstrap atan asin asctime acos access abort
2018a5c3	202	_exit
d51cf0c9	203	/],
d51cf0c9	204	},
2018a5c3	205
f84b4b22	206	IO::Socket => { dflt => 'constant', # 157/190
2018a5c3	207
	208	perl => [qw/ timeout socktype sockopt sockname
	209	socketpair socket sockdomain sockaddr_un
	210	sockaddr_in shutdown setsockopt send
	211	register_domain recv protocol peername
	212	new listen import getsockopt croak
	213	connected connect configure confess close
e412117e	214	carp bind atmark accept
e412117e	215	/, $] > 5.009 ? ('blocking') : () ],
2018a5c3	216
	217	XS => [qw/ unpack_sockaddr_un unpack_sockaddr_in
	218	sockatmark sockaddr_family pack_sockaddr_un
	219	pack_sockaddr_in inet_ntoa inet_aton
	220	/],
	221	},
c0939cee	222	};
	223
	224	############
	225
	226	B::Concise::compile('-nobanner'); # set a silent default
5b493bdf	227	getopts('vaVcr:', \my %opts) or
c0939cee	228	die <<EODIE;
	229
	230	usage: PERL_CORE=1 ./perl ext/B/t/concise-xs.t [-av] [module-list]
	231	tests ability to discern XS funcs using Digest::MD5 package
	232	-v : runs verbosely
	233	-V : more verbosity
	234	-a : runs all modules in CoreList
5b493bdf	235	-c : writes test corrections as a Data::Dumper expression
5b493bdf	236	-r <file> : reads file of tests, as written by -c
468aa647	237	<args> : additional modules are loaded and tested
d51cf0c9	238	(will report failures, since no XS funcs are known apriori)
c0939cee	239
	240	EODIE
	241	;
	242
	243	if (%opts) {
	244	require Data::Dumper;
	245	Data::Dumper->import('Dumper');
	246	$Data::Dumper::Sortkeys = 1;
	247	}
	248	my @argpkgs = @ARGV;
5b493bdf	249	my %report;
	250
	251	if ($opts{r}) {
	252	my $refpkgs = require "$opts{r}";
	253	$testpkgs->{$_} = $refpkgs->{$_} foreach keys %$refpkgs;
468aa647	254	}
5b493bdf	255
	256	unless ($opts{a}) {
	257	unless (@argpkgs) {
	258	foreach $pkg (sort keys %$testpkgs) {
	259	test_pkg($pkg, $testpkgs->{$pkg});
	260	}
	261	} else {
	262	foreach $pkg (@argpkgs) {
	263	test_pkg($pkg, $testpkgs->{$pkg});
	264	}
	265	}
	266	} else {
	267	corecheck();
c0939cee	268	}
c0939cee	269	############
	270
	271	sub test_pkg {
d51cf0c9	272	my ($pkg, $fntypes) = @_;
d51cf0c9	273	require_ok($pkg);
c0939cee	274
d51cf0c9	275	# build %stash: keys are func-names, vals filled in below
c0939cee	276	my (%stash) = map
d51cf0c9	277	( ($_ => 0)
d51cf0c9	278	=> ( grep exists &{"$pkg\::$_"} # grab CODE symbols
c0939cee	279	=> grep !/__ANON__/ # but not anon subs
d51cf0c9	280	=> keys %{$pkg.'::'} # from symbol table
c0939cee	281	));
468aa647	282
d51cf0c9	283	for my $type (keys %matchers) {
	284	foreach my $fn (@{$fntypes->{$type}}) {
	285	carp "$fn can only be one of $type, $stash{$fn}\n"
	286	if $stash{$fn};
	287	$stash{$fn} = $type;
	288	}
	289	}
	290	# set default type for un-named functions
	291	my $dflt = $fntypes->{dflt} \|\| 'perl';
	292	for my $k (keys %stash) {
	293	$stash{$k} = $dflt unless $stash{$k};
	294	}
	295	$stash{$_} = 'skip' foreach @{$fntypes->{skip}};
c0939cee	296
5b493bdf	297	if ($opts{v}) {
d51cf0c9	298	diag("fntypes: " => Dumper($fntypes));
d51cf0c9	299	diag("$pkg stash: " => Dumper(\%stash));
c0939cee	300	}
d51cf0c9	301	foreach my $fn (reverse sort keys %stash) {
	302	next if $stash{$fn} eq 'skip';
	303	my $res = checkXS("${pkg}::$fn", $stash{$fn});
	304	if ($res ne '1') {
	305	push @{$report{$pkg}{$res}}, $fn;
5b493bdf	306	}
c0939cee	307	}
	308	}
	309
	310	sub checkXS {
d51cf0c9	311	my ($func_name, $want) = @_;
	312
	313	croak "unknown type $want: $func_name\n"
	314	unless defined $matchers{$want};
c0939cee	315
c0939cee	316	my ($buf, $err) = render($func_name);
d51cf0c9	317	my $res = like($buf, $matchers{$want}, "$want sub:\t $func_name");
	318
	319	unless ($res) {
	320	# test failed. return type that would give success
	321	for my $m (keys %matchers) {
	322	return $m if $buf =~ $matchers{$m};
	323	}
c0939cee	324	}
d51cf0c9	325	$res;
c0939cee	326	}
	327
	328	sub render {
	329	my ($func_name) = @_;
	330
	331	B::Concise::reset_sequence();
	332	B::Concise::walk_output(\my $buf);
	333
	334	my $walker = B::Concise::compile($func_name);
	335	eval { $walker->() };
	336	diag("err: $@ $buf") if $@;
	337	diag("verbose: $buf") if $opts{V};
	338
	339	return ($buf, $@);
	340	}
	341
	342	sub corecheck {
	343	eval { require Module::CoreList };
	344	if ($@) {
	345	warn "Module::CoreList not available on $]\n";
	346	return;
	347	}
5b493bdf	348	my $mods = $Module::CoreList::version{'5.009002'};
5b493bdf	349	$mods = [ sort keys %$mods ];
c0939cee	350	print Dumper($mods);
c0939cee	351
5b493bdf	352	foreach my $pkgnm (@$mods) {
c0939cee	353	test_pkg($pkgnm);
	354	}
	355	}
	356
5b493bdf	357	END {
5b493bdf	358	if ($opts{c}) {
d51cf0c9	359	$Data::Dumper::Indent = 1;
d51cf0c9	360	print "Corrections: ", Dumper(\%report);
5b493bdf	361
5b493bdf	362	foreach my $pkg (sort keys %report) {
d51cf0c9	363	for my $type (keys %matchers) {
	364	print "$pkg: $type: @{$report{$pkg}{$type}}\n"
	365	if @{$report{$pkg}{$type}};
	366	}
5b493bdf	367	}
5b493bdf	368	}
	369	}
	370
c0939cee	371	__END__