[scpubgit/stemmatology.git] / base / lib / Text / Tradition / Parser / TEI.pm

package Text::Tradition::Parser::TEI;

use strict;
use warnings;
use Text::Tradition::Error;
use Text::Tradition::Parser::Util qw( collate_variants );
use XML::LibXML;
use XML::LibXML::XPathContext;

=head1 NAME

Text::Tradition::Parser::TEI

=head1 SYNOPSIS

  use Text::Tradition;
  
  my $t_from_file = Text::Tradition->new( 
    'name' => 'my text',
    'input' => 'TEI',
    'file' => '/path/to/parallel_seg_file.xml'
    );
    
  my $t_from_string = Text::Tradition->new( 
    'name' => 'my text',
    'input' => 'TEI',
    'string' => $parallel_seg_xml,
    );


=head1 DESCRIPTION

Parser module for Text::Tradition, given a TEI parallel-segmentation file
that describes a text and its variants.  Normally called upon
initialization of Text::Tradition.

The witnesses for the tradition are taken from the <listWit/> element
within the TEI header; the readings are taken from any <p/> element that
appears in the text body (including <head/> elements therein.)

=head1 METHODS

=head2 B<parse>( $tradition, $option_hash )

Takes an initialized tradition and a set of options; creates the
appropriate nodes and edges on the graph, as well as the appropriate
witness objects.  The $option_hash must contain either a 'file' or a
'string' argument with the XML to be parsed.

=begin testing

use Text::Tradition;
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";
eval { no warnings; binmode $DB::OUT, ":utf8"; };

my $par_seg = 't/data/florilegium_tei_ps.xml';
my $t = Text::Tradition->new( 
    'name'  => 'inline', 
    'input' => 'TEI',
    'file'  => $par_seg,
    );

is( ref( $t ), 'Text::Tradition', "Parsed parallel-segmentation TEI" );
if( $t ) {
    is( scalar $t->collation->readings, 311, "Collation has all readings" );
    is( scalar $t->collation->paths, 361, "Collation has all paths" );
}

=end testing

=cut

my $text = {}; # Hash of arrays, one per eventual witness we find.
my $substitutions = {}; # Keep track of merged readings
my $app_anchors = {};   # Track apparatus references
my $app_ac = {};        # Save a.c. readings
my $app_count;          # Keep track of how many apps we have

# Create the package variables for tag names.

# Would really like to do this with varname variables, but apparently this
# is considered a bad idea.  The long way round then.
my( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM ) 
    = ( 'listWit', 'witness', 'text', 'w', 'seg', 'app', 'rdg', 'lem' );
sub _make_tagnames {
    my( $ns ) = @_;
    if( $ns ) {
        $LISTWIT = "$ns:$LISTWIT";
        $WITNESS = "$ns:$WITNESS";
        $TEXT = "$ns:$TEXT";
        $W = "$ns:$W";
        $SEG = "$ns:$SEG";
        $APP = "$ns:$APP";
        $RDG = "$ns:$RDG";
        $LEM = "$ns:$LEM";
    }
}

# Parse the TEI file.
sub parse {
    my( $tradition, $opts ) = @_;
    
    # First, parse the XML.
    my $parser = XML::LibXML->new();
    my $doc;
    if( exists $opts->{'string'} ) {
        $doc = $parser->parse_string( $opts->{'string'} );
    } elsif ( exists $opts->{'file'} ) {
        $doc = $parser->parse_file( $opts->{'file'} );
    } else {
        warn "Could not find string or file option to parse";
        return;
    }
    my $tei = $doc->documentElement();
	unless( $tei->nodeName =~ /^tei(corpus)?$/i ) {
		throw( "Parsed document has non-TEI root element " . $tei->nodeName );
	}
    my $xpc = XML::LibXML::XPathContext->new( $tei );
    my $ns;
    if( $tei->namespaceURI ) {
        $ns = 'tei';
        $xpc->registerNs( $ns, $tei->namespaceURI );
    }
    _make_tagnames( $ns );

    # Then get the witnesses and create the witness objects.
    foreach my $wit_el ( $xpc->findnodes( "//$LISTWIT/$WITNESS" ) ) {
        my $sig = $wit_el->getAttribute( 'xml:id' );
        my $source = $wit_el->toString();
        $tradition->add_witness( sigil => $sig, sourcetype => 'collation' );
    }
    map { $text->{$_->sigil} = [] } $tradition->witnesses;

    # Look for all word/seg node IDs and note their pre-existence.
    my @attrs = $xpc->findnodes( "//$W/attribute::xml:id" );
    _save_preexisting_nodeids( @attrs );

    # Count up how many apps we have.
    my @apps = $xpc->findnodes( "//$APP" );
    $app_count = scalar( @apps );

    # Now go through the children of the text element and pull out the
    # actual text.
    foreach my $xml_el ( $xpc->findnodes( "//$TEXT" ) ) {
        foreach my $xn ( $xml_el->childNodes ) {
            _get_readings( $tradition, $xn );
        }
    }
    # Our $text global now has lists of readings, one per witness.
    # Join them up.
    my $c = $tradition->collation;
    foreach my $sig ( keys %$text ) {
        # Determine the list of readings for 
        my $sequence = $text->{$sig};
        my @real_sequence = ( $c->start );
        push( @$sequence, $c->end );
        foreach( _clean_sequence( $sig, $sequence, 1 ) ) {
            push( @real_sequence, _return_rdg( $_ ) );
        }
        # See if we need to make an a.c. version of the witness.
        if( exists $app_ac->{$sig} ) {
            my @uncorrected;
            push( @uncorrected, @real_sequence );
            # Get rid of any remaining placeholders.
            @real_sequence = _clean_sequence( $sig, \@uncorrected );
            # Do the uncorrections
            foreach my $app ( keys %{$app_ac->{$sig}} ) {
                my $start = _return_rdg( $app_anchors->{$app}->{$sig}->{'start'} ); 
                my $end = _return_rdg( $app_anchors->{$app}->{$sig}->{'end'} );
                my @new = map { _return_rdg( $_ ) } @{$app_ac->{$sig}->{$app}};
                _replace_sequence( \@uncorrected, $start, $end, @new );
            }
            # and record the results.
            $tradition->witness( $sig )->uncorrected_path( \@uncorrected );
            $tradition->witness( $sig )->is_layered( 1 );
        }
        $tradition->witness( $sig )->path( \@real_sequence );
    }
    # Now make our witness paths.
    $tradition->collation->make_witness_paths();
    
    # Calculate the ranks for the nodes.
	$tradition->collation->calculate_ranks();
    
    # Now that we have ranks, see if we have distinct nodes with identical
    # text and identical rank that can be merged.
    $tradition->collation->flatten_ranks();
    
    # And now that we've done that, calculate the common nodes.
    $tradition->collation->calculate_common_readings();
    
    # Save the text for each witness so that we can ensure consistency
    # later on
	$tradition->collation->text_from_paths();	
}

sub _clean_sequence {
    my( $wit, $sequence, $keep_ac ) = @_;
    my @clean_sequence;
    foreach my $rdg ( @$sequence ) {
        if( $rdg =~ /^PH-(.*)$/ ) {
            # It is a placeholder.  Keep it only if we need it for a later
            # a.c. run.
            my $app_id = $1;
            if( $keep_ac && exists $app_ac->{$wit} &&
                exists $app_ac->{$wit}->{$app_id} ) {
				# print STDERR "Retaining empty placeholder for $app_id\n";
				push( @clean_sequence, $rdg );
            }
        } else {
            push( @clean_sequence, $rdg );
        }
    }
    return @clean_sequence;
}

sub _replace_sequence {
    my( $arr, $start, $end, @new ) = @_;
    my( $start_idx, $end_idx );
    foreach my $i ( 0 .. $#{$arr} ) {
    	# If $arr->[$i] is a placeholder, cope.
    	my $iid = ref( $arr->[$i] ) ? $arr->[$i]->id : $arr->[$i];
        $start_idx = $i if( $iid eq $start );
        if( $iid eq $end ) {
            $end_idx = $i;
            last;
        }
    }
    unless( $start_idx && $end_idx ) {
        warn "Could not find start and end";
        return;
    }
    my $length = $end_idx - $start_idx + 1;
    splice( @$arr, $start_idx, $length, @new );
}

sub _return_rdg {
    my( $rdg ) = @_;
    # If we were passed a reading name, return the name.  If we were
    # passed a reading object, return the object.
    my $wantobj = ref( $rdg ) eq 'Text::Tradition::Collation::Reading';
    my $real = $rdg;
    if( exists $substitutions->{ $wantobj ? $rdg->id : $rdg } ) {
        $real = $substitutions->{ $wantobj ? $rdg->id : $rdg };
        $real = $real->id unless $wantobj;
    }
    return $real;
}

## TODO test specific sorts of nodes of the parallel-seg XML.

## Recursive helper function to help us navigate through nested XML,
## picking out the text.  $tradition is the tradition, needed for
## making readings; $xn is the XML node currently being looked at,
## $in_var is a flag to say that we are inside a variant, $ac is a
## flag to say that we are inside an ante-correctionem reading, and
## @cur_wits is the list of witnesses to which this XML node applies.
## Returns the list of readings, if any, created on the run.

{
    my %active_wits;
    my $current_app;
    my $seen_apps;

    sub _get_readings {
        my( $tradition, $xn, $in_var, $ac, @cur_wits ) = @_;
        @cur_wits = grep { $active_wits{$_} } keys %active_wits unless $in_var;

        my @new_readings;
        if( $xn->nodeType == XML_TEXT_NODE ) {
            # Some words, thus make some readings.
            my $str = $xn->data;
            return unless $str =~ /\S/; # skip whitespace-only text nodes
            #print STDERR "Handling text node " . $str . "\n";
            # Check that all the witnesses we have are active.
            foreach my $c ( @cur_wits ) {
                warn "$c is not among active wits" unless $active_wits{$c};
            }
            $str =~ s/^\s+//;
            my $final = $str =~ s/\s+$//;
            foreach my $w ( split( /\s+/, $str ) ) {
                # For now, skip punctuation.
                next if $w !~ /[[:alnum:]]/;
                my $rdg = _make_reading( $tradition->collation, $w );
                push( @new_readings, $rdg );
                foreach ( @cur_wits ) {
                    warn "Empty wit!" unless $_;
                    warn "Empty reading!" unless $rdg;
                    push( @{$text->{$_}}, $rdg ) unless $ac;
                }
            }
        } elsif( $xn->nodeName eq 'w' ) {
            # Everything in this tag is one word.  Also save any original XML ID.
            #print STDERR "Handling word " . $xn->toString . "\n";
            # Check that all the witnesses we have are active.
            foreach my $c ( @cur_wits ) {
                warn "$c is not among active wits" unless $active_wits{$c};
            }
            my $xml_id = $xn->getAttribute( 'xml:id' );
            my $rdg = _make_reading( $tradition->collation, $xn->textContent, $xml_id );
            push( @new_readings, $rdg );
            foreach( @cur_wits ) {
                warn "Empty wit!" unless $_;
                warn "Empty reading!" unless $rdg;
                push( @{$text->{$_}}, $rdg ) unless $ac;
            }
        } elsif ( $xn->nodeName eq 'app' ) {
            $seen_apps++;
            $current_app = $xn->getAttribute( 'xml:id' );
            # print STDERR "Handling app $current_app\n";
            # Keep the reading sets in this app.
            my @sets;
            # Recurse through all children (i.e. rdgs) for sets of words.
            foreach ( $xn->childNodes ) {
                my @rdg_set = _get_readings( $tradition, $_, $in_var, $ac, @cur_wits );
                push( @sets, \@rdg_set ) if @rdg_set;
            }
            # Now collate these sets if we have more than one.
            my $subs = collate_variants( $tradition->collation, @sets ) if @sets > 1;
            map { $substitutions->{$_} = $subs->{$_} } keys %$subs;
            # Return the entire set of unique readings.
            my %unique;
            foreach my $s ( @sets ) {
                map { $unique{$_->id} = $_ } @$s;
            }
            push( @new_readings, values( %unique ) );
            # Exit the current app.
            $current_app = '';
        } elsif ( $xn->nodeName eq 'lem' || $xn->nodeName eq 'rdg' ) {
            # Alter the current witnesses and recurse.
            #print STDERR "Handling reading for " . $xn->getAttribute( 'wit' ) . "\n";
            # TODO handle p.c. and s.l. designations too
            $ac = $xn->getAttribute( 'type' ) && $xn->getAttribute( 'type' ) eq 'a.c.';
            my @rdg_wits = _get_sigla( $xn );
            return unless @rdg_wits;  # Skip readings that appear in no witnesses
            my @words;
            foreach ( $xn->childNodes ) {
                my @rdg_set = _get_readings( $tradition, $_, 1, $ac, @rdg_wits );
                push( @words, @rdg_set ) if @rdg_set;
            }
            # If we have more than one word in a reading, it should become a segment.
            # $tradition->collation->add_segment( @words ) if @words > 1;
            
            if( $ac ) {
                # Add the reading set to the a.c. readings.
                foreach ( @rdg_wits ) {
                    $app_ac->{$_}->{$current_app} = \@words;
                }
            } else {
                # Add the reading set to the app anchors for each witness
                # or put in placeholders for empty p.c. readings
                foreach ( @rdg_wits ) {
                    my $start = @words ? $words[0]->id : "PH-$current_app";
                    my $end = @words ? $words[-1]->id : "PH-$current_app";
                    $app_anchors->{$current_app}->{$_}->{'start'} = $start;
                    $app_anchors->{$current_app}->{$_}->{'end'} = $end;
                    push( @{$text->{$_}}, $start ) unless @words;
                }
            }
            push( @new_readings, @words );
        } elsif( $xn->nodeName eq 'witStart' ) {
            # Add the relevant wit(s) to the active list.
            #print STDERR "Handling witStart\n";
            map { $active_wits{$_} = 1 } @cur_wits;
            # Record a lacuna in all non-active witnesses if this is
            # the first app. Get the full list from $text.
            if( $seen_apps == 1 ) {
                my $i = 0;
                foreach my $sig ( keys %$text ) {
                    next if $active_wits{$sig};
                    my $l = $tradition->collation->add_reading( {
                    	'id' => $current_app . "_$i",
                    	'is_lacuna' => 1 } );
                    $i++;
                    push( @{$text->{$sig}}, $l );
                }
            }
        } elsif( $xn->nodeName eq 'witEnd' ) {
            # Take the relevant wit(s) out of the list.
            #print STDERR "Handling witEnd\n";
            map { $active_wits{$_} = undef } @cur_wits;
            # Record a lacuna, unless this is the last app.
            unless( $seen_apps == $app_count ) {
                foreach my $i ( 0 .. $#cur_wits ) {
                    my $w = $cur_wits[$i];
                    my $l = $tradition->collation->add_reading( {
                    	'id' => $current_app . "_$i",
                    	'is_lacuna' => 1 } );
                    push( @{$text->{$w}}, $l );
                }
            }
        } elsif( $xn->nodeName eq 'witDetail' 
        		 || $xn->nodeName eq 'note' ) {
            # Ignore these for now.
            return;
        } else {
            # Recurse as if this tag weren't there.
            #print STDERR "Recursing on tag " . $xn->nodeName . "\n";
            foreach( $xn->childNodes ) {
                push( @new_readings, _get_readings( $tradition, $_, $in_var, $ac, @cur_wits ) );
            }
        }
        return @new_readings;
    }

}

=begin testing

use XML::LibXML;
use XML::LibXML::XPathContext;
use Text::Tradition::Parser::TEI;

my $xml_str = '<tei><rdg wit="#A #B #C #D">some text</rdg></tei>';
my $el = XML::LibXML->new()->parse_string( $xml_str )->documentElement;
my $xpc = XML::LibXML::XPathContext->new( $el );
my $obj = $xpc->find( '//rdg' );

my @wits = Text::Tradition::Parser::TEI::_get_sigla( $obj );
is( join( ' ', @wits) , "A B C D", "correctly parsed reading wit string" );

=end testing

=cut

# Helper to extract a list of witness sigla from a reading element.
sub _get_sigla {
    my( $rdg ) = @_;
    # Cope if we have been handed a NodeList.  There is only
    # one reading here.
    if( ref( $rdg ) eq 'XML::LibXML::NodeList' ) {
        $rdg = $rdg->shift;
    }

    my @wits;
    if( ref( $rdg ) eq 'XML::LibXML::Element' ) {
        my $witstr = $rdg->getAttribute( 'wit' );
        return () unless $witstr;
        $witstr =~ s/^\s+//;
        $witstr =~ s/\s+$//;
        @wits = split( /\s+/, $witstr );
        map { $_ =~ s/^\#// } @wits;
    }
    return @wits;
}

# Helper with its counters to actually make the readings.
{
    my $word_ctr = 0;
    my %used_nodeids;

    sub _save_preexisting_nodeids {
        foreach( @_ ) {
            $used_nodeids{$_->getValue()} = 1;
        }
    }

    sub _make_reading {
        my( $graph, $word, $xml_id ) = @_;
        if( $xml_id ) {
            if( exists $used_nodeids{$xml_id} ) {
                if( $used_nodeids{$xml_id} != 1 ) {
                    warn "Already used assigned XML ID somewhere else!";
                    $xml_id = undef;
                }
            } else {
                warn "Undetected pre-existing XML ID";
            }
        }
        if( !$xml_id ) {
            until( $xml_id ) {
                my $try_id = 'w'.$word_ctr++;
                next if exists $used_nodeids{$try_id};
                $xml_id = $try_id;
            }
        }
        my $rdg = $graph->add_reading(
        	{ 'id' => $xml_id,
        	  'text' => $word }
        	);
        $used_nodeids{$xml_id} = $rdg;
        return $rdg;
    }
}

1;

sub throw {
	Text::Tradition::Error->throw( 
		'ident' => 'Parser::TEI error',
		'message' => $_[0],
		);
}

=head1 BUGS / TODO

=over

=item * More unit testing

=item * Handle special designations apart from a.c.

=item * Mark common nodes within collated variants

=back

=head1 LICENSE

This package is free software and is provided "as is" without express
or implied warranty.  You can redistribute it and/or modify it under
the same terms as Perl itself.

=head1 AUTHOR

Tara L Andrews E<lt>aurum@cpan.orgE<gt>
Commit	Line	Data
f6066bac	1	package Text::Tradition::Parser::TEI;
	2
	3	use strict;
	4	use warnings;
00311328	5	use Text::Tradition::Error;
910a0a6d	6	use Text::Tradition::Parser::Util qw( collate_variants );
f6066bac	7	use XML::LibXML;
	8	use XML::LibXML::XPathContext;
	9
	10	=head1 NAME
	11
	12	Text::Tradition::Parser::TEI
	13
3b853983	14	=head1 SYNOPSIS
	15
	16	use Text::Tradition;
	17
	18	my $t_from_file = Text::Tradition->new(
	19	'name' => 'my text',
	20	'input' => 'TEI',
	21	'file' => '/path/to/parallel_seg_file.xml'
	22	);
	23
	24	my $t_from_string = Text::Tradition->new(
	25	'name' => 'my text',
	26	'input' => 'TEI',
	27	'string' => $parallel_seg_xml,
	28	);
	29
	30
f6066bac	31	=head1 DESCRIPTION
f6066bac	32
3b853983	33	Parser module for Text::Tradition, given a TEI parallel-segmentation file
	34	that describes a text and its variants. Normally called upon
	35	initialization of Text::Tradition.
	36
	37	The witnesses for the tradition are taken from the <listWit/> element
	38	within the TEI header; the readings are taken from any <p/> element that
	39	appears in the text body (including <head/> elements therein.)
f6066bac	40
	41	=head1 METHODS
	42
e867486f	43	=head2 B<parse>( $tradition, $option_hash )
3b853983	44
	45	Takes an initialized tradition and a set of options; creates the
	46	appropriate nodes and edges on the graph, as well as the appropriate
	47	witness objects. The $option_hash must contain either a 'file' or a
	48	'string' argument with the XML to be parsed.
	49
	50	=begin testing
	51
	52	use Text::Tradition;
	53	binmode STDOUT, ":utf8";
	54	binmode STDERR, ":utf8";
	55	eval { no warnings; binmode $DB::OUT, ":utf8"; };
	56
	57	my $par_seg = 't/data/florilegium_tei_ps.xml';
	58	my $t = Text::Tradition->new(
	59	'name' => 'inline',
	60	'input' => 'TEI',
	61	'file' => $par_seg,
	62	);
f6066bac	63
3b853983	64	is( ref( $t ), 'Text::Tradition', "Parsed parallel-segmentation TEI" );
3b853983	65	if( $t ) {
56eefa04	66	is( scalar $t->collation->readings, 311, "Collation has all readings" );
56eefa04	67	is( scalar $t->collation->paths, 361, "Collation has all paths" );
3b853983	68	}
f6066bac	69
3b853983	70	=end testing
f6066bac	71
	72	=cut
	73
910a0a6d	74	my $text = {}; # Hash of arrays, one per eventual witness we find.
910a0a6d	75	my $substitutions = {}; # Keep track of merged readings
	76	my $app_anchors = {}; # Track apparatus references
	77	my $app_ac = {}; # Save a.c. readings
eca16057	78	my $app_count; # Keep track of how many apps we have
910a0a6d	79
	80	# Create the package variables for tag names.
	81
	82	# Would really like to do this with varname variables, but apparently this
	83	# is considered a bad idea. The long way round then.
	84	my( $LISTWIT, $WITNESS, $TEXT, $W, $SEG, $APP, $RDG, $LEM )
	85	= ( 'listWit', 'witness', 'text', 'w', 'seg', 'app', 'rdg', 'lem' );
3b853983	86	sub _make_tagnames {
910a0a6d	87	my( $ns ) = @_;
	88	if( $ns ) {
	89	$LISTWIT = "$ns:$LISTWIT";
	90	$WITNESS = "$ns:$WITNESS";
	91	$TEXT = "$ns:$TEXT";
	92	$W = "$ns:$W";
	93	$SEG = "$ns:$SEG";
	94	$APP = "$ns:$APP";
	95	$RDG = "$ns:$RDG";
	96	$LEM = "$ns:$LEM";
	97	}
	98	}
	99
	100	# Parse the TEI file.
f6066bac	101	sub parse {
dfc37e38	102	my( $tradition, $opts ) = @_;
f6066bac	103
	104	# First, parse the XML.
	105	my $parser = XML::LibXML->new();
dfc37e38	106	my $doc;
	107	if( exists $opts->{'string'} ) {
	108	$doc = $parser->parse_string( $opts->{'string'} );
	109	} elsif ( exists $opts->{'file'} ) {
	110	$doc = $parser->parse_file( $opts->{'file'} );
	111	} else {
	112	warn "Could not find string or file option to parse";
	113	return;
	114	}
f6066bac	115	my $tei = $doc->documentElement();
00311328	116	unless( $tei->nodeName =~ /^tei(corpus)?$/i ) {
	117	throw( "Parsed document has non-TEI root element " . $tei->nodeName );
	118	}
f2b9605f	119	my $xpc = XML::LibXML::XPathContext->new( $tei );
910a0a6d	120	my $ns;
	121	if( $tei->namespaceURI ) {
	122	$ns = 'tei';
	123	$xpc->registerNs( $ns, $tei->namespaceURI );
	124	}
3b853983	125	_make_tagnames( $ns );
910a0a6d	126
f6066bac	127	# Then get the witnesses and create the witness objects.
910a0a6d	128	foreach my $wit_el ( $xpc->findnodes( "//$LISTWIT/$WITNESS" ) ) {
	129	my $sig = $wit_el->getAttribute( 'xml:id' );
	130	my $source = $wit_el->toString();
82fa4d57	131	$tradition->add_witness( sigil => $sig, sourcetype => 'collation' );
f6066bac	132	}
910a0a6d	133	map { $text->{$_->sigil} = [] } $tradition->witnesses;
eca16057	134
910a0a6d	135	# Look for all word/seg node IDs and note their pre-existence.
a7fb3133	136	my @attrs = $xpc->findnodes( "//$W/attribute::xml:id" );
3b853983	137	_save_preexisting_nodeids( @attrs );
910a0a6d	138
eca16057	139	# Count up how many apps we have.
	140	my @apps = $xpc->findnodes( "//$APP" );
	141	$app_count = scalar( @apps );
	142
910a0a6d	143	# Now go through the children of the text element and pull out the
	144	# actual text.
	145	foreach my $xml_el ( $xpc->findnodes( "//$TEXT" ) ) {
	146	foreach my $xn ( $xml_el->childNodes ) {
	147	_get_readings( $tradition, $xn );
	148	}
	149	}
	150	# Our $text global now has lists of readings, one per witness.
	151	# Join them up.
	152	my $c = $tradition->collation;
	153	foreach my $sig ( keys %$text ) {
910a0a6d	154	# Determine the list of readings for
	155	my $sequence = $text->{$sig};
	156	my @real_sequence = ( $c->start );
	157	push( @$sequence, $c->end );
342c1111	158	foreach( _clean_sequence( $sig, $sequence, 1 ) ) {
342c1111	159	push( @real_sequence, _return_rdg( $_ ) );
910a0a6d	160	}
910a0a6d	161	# See if we need to make an a.c. version of the witness.
	162	if( exists $app_ac->{$sig} ) {
	163	my @uncorrected;
	164	push( @uncorrected, @real_sequence );
342c1111	165	# Get rid of any remaining placeholders.
	166	@real_sequence = _clean_sequence( $sig, \@uncorrected );
	167	# Do the uncorrections
910a0a6d	168	foreach my $app ( keys %{$app_ac->{$sig}} ) {
	169	my $start = _return_rdg( $app_anchors->{$app}->{$sig}->{'start'} );
	170	my $end = _return_rdg( $app_anchors->{$app}->{$sig}->{'end'} );
	171	my @new = map { _return_rdg( $_ ) } @{$app_ac->{$sig}->{$app}};
	172	_replace_sequence( \@uncorrected, $start, $end, @new );
	173	}
342c1111	174	# and record the results.
342c1111	175	$tradition->witness( $sig )->uncorrected_path( \@uncorrected );
1f7aa795	176	$tradition->witness( $sig )->is_layered( 1 );
910a0a6d	177	}
342c1111	178	$tradition->witness( $sig )->path( \@real_sequence );
910a0a6d	179	}
342c1111	180	# Now make our witness paths.
342c1111	181	$tradition->collation->make_witness_paths();
3b853983	182
3b853983	183	# Calculate the ranks for the nodes.
a7fb3133	184	$tradition->collation->calculate_ranks();
3bc0cd18	185
	186	# Now that we have ranks, see if we have distinct nodes with identical
	187	# text and identical rank that can be merged.
0e476982	188	$tradition->collation->flatten_ranks();
861c3e27	189
15db7774	190	# And now that we've done that, calculate the common nodes.
	191	$tradition->collation->calculate_common_readings();
	192
861c3e27	193	# Save the text for each witness so that we can ensure consistency
	194	# later on
	195	$tradition->collation->text_from_paths();
910a0a6d	196	}
	197
	198	sub _clean_sequence {
342c1111	199	my( $wit, $sequence, $keep_ac ) = @_;
910a0a6d	200	my @clean_sequence;
	201	foreach my $rdg ( @$sequence ) {
	202	if( $rdg =~ /^PH-(.*)$/ ) {
342c1111	203	# It is a placeholder. Keep it only if we need it for a later
342c1111	204	# a.c. run.
910a0a6d	205	my $app_id = $1;
342c1111	206	if( $keep_ac && exists $app_ac->{$wit} &&
78fab1cf	207	exists $app_ac->{$wit}->{$app_id} ) {
342c1111	208	# print STDERR "Retaining empty placeholder for $app_id\n";
342c1111	209	push( @clean_sequence, $rdg );
910a0a6d	210	}
	211	} else {
	212	push( @clean_sequence, $rdg );
	213	}
f6066bac	214	}
910a0a6d	215	return @clean_sequence;
910a0a6d	216	}
f6066bac	217
910a0a6d	218	sub _replace_sequence {
	219	my( $arr, $start, $end, @new ) = @_;
	220	my( $start_idx, $end_idx );
	221	foreach my $i ( 0 .. $#{$arr} ) {
342c1111	222	# If $arr->[$i] is a placeholder, cope.
	223	my $iid = ref( $arr->[$i] ) ? $arr->[$i]->id : $arr->[$i];
	224	$start_idx = $i if( $iid eq $start );
	225	if( $iid eq $end ) {
910a0a6d	226	$end_idx = $i;
	227	last;
	228	}
	229	}
	230	unless( $start_idx && $end_idx ) {
	231	warn "Could not find start and end";
	232	return;
f2b9605f	233	}
910a0a6d	234	my $length = $end_idx - $start_idx + 1;
	235	splice( @$arr, $start_idx, $length, @new );
	236	}
f6066bac	237
910a0a6d	238	sub _return_rdg {
	239	my( $rdg ) = @_;
	240	# If we were passed a reading name, return the name. If we were
	241	# passed a reading object, return the object.
	242	my $wantobj = ref( $rdg ) eq 'Text::Tradition::Collation::Reading';
	243	my $real = $rdg;
e4b0f464	244	if( exists $substitutions->{ $wantobj ? $rdg->id : $rdg } ) {
	245	$real = $substitutions->{ $wantobj ? $rdg->id : $rdg };
	246	$real = $real->id unless $wantobj;
910a0a6d	247	}
910a0a6d	248	return $real;
f6066bac	249	}
f6066bac	250
3b853983	251	## TODO test specific sorts of nodes of the parallel-seg XML.
3b853983	252
910a0a6d	253	## Recursive helper function to help us navigate through nested XML,
	254	## picking out the text. $tradition is the tradition, needed for
	255	## making readings; $xn is the XML node currently being looked at,
	256	## $in_var is a flag to say that we are inside a variant, $ac is a
	257	## flag to say that we are inside an ante-correctionem reading, and
	258	## @cur_wits is the list of witnesses to which this XML node applies.
	259	## Returns the list of readings, if any, created on the run.
	260
	261	{
3bc0cd18	262	my %active_wits;
910a0a6d	263	my $current_app;
eca16057	264	my $seen_apps;
910a0a6d	265
	266	sub _get_readings {
	267	my( $tradition, $xn, $in_var, $ac, @cur_wits ) = @_;
3bc0cd18	268	@cur_wits = grep { $active_wits{$_} } keys %active_wits unless $in_var;
910a0a6d	269
	270	my @new_readings;
	271	if( $xn->nodeType == XML_TEXT_NODE ) {
	272	# Some words, thus make some readings.
	273	my $str = $xn->data;
	274	return unless $str =~ /\S/; # skip whitespace-only text nodes
	275	#print STDERR "Handling text node " . $str . "\n";
	276	# Check that all the witnesses we have are active.
	277	foreach my $c ( @cur_wits ) {
3bc0cd18	278	warn "$c is not among active wits" unless $active_wits{$c};
910a0a6d	279	}
	280	$str =~ s/^\s+//;
	281	my $final = $str =~ s/\s+$//;
	282	foreach my $w ( split( /\s+/, $str ) ) {
	283	# For now, skip punctuation.
	284	next if $w !~ /[[:alnum:]]/;
3b853983	285	my $rdg = _make_reading( $tradition->collation, $w );
910a0a6d	286	push( @new_readings, $rdg );
910a0a6d	287	foreach ( @cur_wits ) {
	288	warn "Empty wit!" unless $_;
	289	warn "Empty reading!" unless $rdg;
	290	push( @{$text->{$_}}, $rdg ) unless $ac;
	291	}
	292	}
	293	} elsif( $xn->nodeName eq 'w' ) {
	294	# Everything in this tag is one word. Also save any original XML ID.
	295	#print STDERR "Handling word " . $xn->toString . "\n";
	296	# Check that all the witnesses we have are active.
	297	foreach my $c ( @cur_wits ) {
3bc0cd18	298	warn "$c is not among active wits" unless $active_wits{$c};
910a0a6d	299	}
910a0a6d	300	my $xml_id = $xn->getAttribute( 'xml:id' );
3b853983	301	my $rdg = _make_reading( $tradition->collation, $xn->textContent, $xml_id );
910a0a6d	302	push( @new_readings, $rdg );
910a0a6d	303	foreach( @cur_wits ) {
	304	warn "Empty wit!" unless $_;
	305	warn "Empty reading!" unless $rdg;
	306	push( @{$text->{$_}}, $rdg ) unless $ac;
	307	}
	308	} elsif ( $xn->nodeName eq 'app' ) {
eca16057	309	$seen_apps++;
910a0a6d	310	$current_app = $xn->getAttribute( 'xml:id' );
	311	# print STDERR "Handling app $current_app\n";
	312	# Keep the reading sets in this app.
	313	my @sets;
	314	# Recurse through all children (i.e. rdgs) for sets of words.
	315	foreach ( $xn->childNodes ) {
	316	my @rdg_set = _get_readings( $tradition, $_, $in_var, $ac, @cur_wits );
	317	push( @sets, \@rdg_set ) if @rdg_set;
	318	}
	319	# Now collate these sets if we have more than one.
	320	my $subs = collate_variants( $tradition->collation, @sets ) if @sets > 1;
	321	map { $substitutions->{$_} = $subs->{$_} } keys %$subs;
910a0a6d	322	# Return the entire set of unique readings.
	323	my %unique;
	324	foreach my $s ( @sets ) {
e4b0f464	325	map { $unique{$_->id} = $_ } @$s;
910a0a6d	326	}
	327	push( @new_readings, values( %unique ) );
	328	# Exit the current app.
	329	$current_app = '';
	330	} elsif ( $xn->nodeName eq 'lem' \|\| $xn->nodeName eq 'rdg' ) {
	331	# Alter the current witnesses and recurse.
	332	#print STDERR "Handling reading for " . $xn->getAttribute( 'wit' ) . "\n";
3bc0cd18	333	# TODO handle p.c. and s.l. designations too
910a0a6d	334	$ac = $xn->getAttribute( 'type' ) && $xn->getAttribute( 'type' ) eq 'a.c.';
3b853983	335	my @rdg_wits = _get_sigla( $xn );
a7fb3133	336	return unless @rdg_wits; # Skip readings that appear in no witnesses
910a0a6d	337	my @words;
	338	foreach ( $xn->childNodes ) {
	339	my @rdg_set = _get_readings( $tradition, $_, 1, $ac, @rdg_wits );
	340	push( @words, @rdg_set ) if @rdg_set;
	341	}
	342	# If we have more than one word in a reading, it should become a segment.
	343	# $tradition->collation->add_segment( @words ) if @words > 1;
	344
	345	if( $ac ) {
	346	# Add the reading set to the a.c. readings.
	347	foreach ( @rdg_wits ) {
	348	$app_ac->{$_}->{$current_app} = \@words;
	349	}
	350	} else {
	351	# Add the reading set to the app anchors for each witness
	352	# or put in placeholders for empty p.c. readings
	353	foreach ( @rdg_wits ) {
e4b0f464	354	my $start = @words ? $words[0]->id : "PH-$current_app";
e4b0f464	355	my $end = @words ? $words[-1]->id : "PH-$current_app";
910a0a6d	356	$app_anchors->{$current_app}->{$_}->{'start'} = $start;
	357	$app_anchors->{$current_app}->{$_}->{'end'} = $end;
	358	push( @{$text->{$_}}, $start ) unless @words;
	359	}
	360	}
	361	push( @new_readings, @words );
	362	} elsif( $xn->nodeName eq 'witStart' ) {
	363	# Add the relevant wit(s) to the active list.
	364	#print STDERR "Handling witStart\n";
3bc0cd18	365	map { $active_wits{$_} = 1 } @cur_wits;
	366	# Record a lacuna in all non-active witnesses if this is
	367	# the first app. Get the full list from $text.
	368	if( $seen_apps == 1 ) {
	369	my $i = 0;
	370	foreach my $sig ( keys %$text ) {
	371	next if $active_wits{$sig};
e4b0f464	372	my $l = $tradition->collation->add_reading( {
e4b0f464	373	'id' => $current_app . "_$i",
e4b0f464	374	'is_lacuna' => 1 } );
3bc0cd18	375	$i++;
	376	push( @{$text->{$sig}}, $l );
	377	}
	378	}
910a0a6d	379	} elsif( $xn->nodeName eq 'witEnd' ) {
	380	# Take the relevant wit(s) out of the list.
	381	#print STDERR "Handling witEnd\n";
3bc0cd18	382	map { $active_wits{$_} = undef } @cur_wits;
eca16057	383	# Record a lacuna, unless this is the last app.
	384	unless( $seen_apps == $app_count ) {
	385	foreach my $i ( 0 .. $#cur_wits ) {
	386	my $w = $cur_wits[$i];
e4b0f464	387	my $l = $tradition->collation->add_reading( {
e4b0f464	388	'id' => $current_app . "_$i",
e4b0f464	389	'is_lacuna' => 1 } );
eca16057	390	push( @{$text->{$w}}, $l );
	391	}
	392	}
a7fb3133	393	} elsif( $xn->nodeName eq 'witDetail'
a7fb3133	394	\|\| $xn->nodeName eq 'note' ) {
910a0a6d	395	# Ignore these for now.
	396	return;
	397	} else {
	398	# Recurse as if this tag weren't there.
	399	#print STDERR "Recursing on tag " . $xn->nodeName . "\n";
	400	foreach( $xn->childNodes ) {
	401	push( @new_readings, _get_readings( $tradition, $_, $in_var, $ac, @cur_wits ) );
	402	}
	403	}
	404	return @new_readings;
	405	}
	406
	407	}
	408
3b853983	409	=begin testing
	410
	411	use XML::LibXML;
	412	use XML::LibXML::XPathContext;
	413	use Text::Tradition::Parser::TEI;
	414
	415	my $xml_str = '<tei><rdg wit="#A #B #C #D">some text</rdg></tei>';
	416	my $el = XML::LibXML->new()->parse_string( $xml_str )->documentElement;
	417	my $xpc = XML::LibXML::XPathContext->new( $el );
	418	my $obj = $xpc->find( '//rdg' );
	419
	420	my @wits = Text::Tradition::Parser::TEI::_get_sigla( $obj );
	421	is( join( ' ', @wits) , "A B C D", "correctly parsed reading wit string" );
	422
	423	=end testing
	424
	425	=cut
	426
910a0a6d	427	# Helper to extract a list of witness sigla from a reading element.
3b853983	428	sub _get_sigla {
f6066bac	429	my( $rdg ) = @_;
	430	# Cope if we have been handed a NodeList. There is only
	431	# one reading here.
	432	if( ref( $rdg ) eq 'XML::LibXML::NodeList' ) {
910a0a6d	433	$rdg = $rdg->shift;
f6066bac	434	}
	435
	436	my @wits;
	437	if( ref( $rdg ) eq 'XML::LibXML::Element' ) {
910a0a6d	438	my $witstr = $rdg->getAttribute( 'wit' );
a7fb3133	439	return () unless $witstr;
910a0a6d	440	$witstr =~ s/^\s+//;
	441	$witstr =~ s/\s+$//;
	442	@wits = split( /\s+/, $witstr );
	443	map { $_ =~ s/^\#// } @wits;
f6066bac	444	}
	445	return @wits;
	446	}
	447
910a0a6d	448	# Helper with its counters to actually make the readings.
f2b9605f	449	{
	450	my $word_ctr = 0;
	451	my %used_nodeids;
	452
3b853983	453	sub _save_preexisting_nodeids {
910a0a6d	454	foreach( @_ ) {
	455	$used_nodeids{$_->getValue()} = 1;
	456	}
	457	}
	458
3b853983	459	sub _make_reading {
910a0a6d	460	my( $graph, $word, $xml_id ) = @_;
	461	if( $xml_id ) {
	462	if( exists $used_nodeids{$xml_id} ) {
	463	if( $used_nodeids{$xml_id} != 1 ) {
	464	warn "Already used assigned XML ID somewhere else!";
	465	$xml_id = undef;
	466	}
	467	} else {
	468	warn "Undetected pre-existing XML ID";
	469	}
	470	}
	471	if( !$xml_id ) {
	472	until( $xml_id ) {
	473	my $try_id = 'w'.$word_ctr++;
	474	next if exists $used_nodeids{$try_id};
	475	$xml_id = $try_id;
	476	}
	477	}
e4b0f464	478	my $rdg = $graph->add_reading(
49d4f2ac	479	{ 'id' => $xml_id,
e4b0f464	480	'text' => $word }
e4b0f464	481	);
910a0a6d	482	$used_nodeids{$xml_id} = $rdg;
910a0a6d	483	return $rdg;
f2b9605f	484	}
	485	}
	486
f6066bac	487	1;
3b853983	488
00311328	489	sub throw {
	490	Text::Tradition::Error->throw(
	491	'ident' => 'Parser::TEI error',
	492	'message' => $_[0],
	493	);
	494	}
	495
3b853983	496	=head1 BUGS / TODO
	497
	498	=over
	499
	500	=item * More unit testing
	501
e867486f	502	=item * Handle special designations apart from a.c.
	503
	504	=item * Mark common nodes within collated variants
	505
3b853983	506	=back
	507
	508	=head1 LICENSE
	509
	510	This package is free software and is provided "as is" without express
	511	or implied warranty. You can redistribute it and/or modify it under
	512	the same terms as Perl itself.
	513
	514	=head1 AUTHOR
	515
	516	Tara L Andrews E<lt>aurum@cpan.orgE<gt>